1D optimization

Plot[12Log[λ]-8λ,{λ,0,10},AxesOrigin->{0,0}]

2D optimization

Plot3D[2x y+3x-3(x^2)-(y^2),{x,-5,5},{y,-5,5}]

ContourPlot[2 x y+3 x-3(x^2)-(y^2),{x,-5,5},{y,-5,5},Frame->False,Axes->True]

2D optimization by computer

iterates[{dx_,dy_},xy0_,n_,δ_]:=Module[{xy},
xy = NestList[#+δ{dx[#],dy[#]}&,xy0,n];
Arrow/@Partition[xy,2,1] ];

With[{g= ContourPlot[2 x y+3 x-3(x^2)-(y^2),{x,-5,5},{y,-5,5},Frame->False,AxesLabel->{"x","y"},Axes->True]
},
Manipulate[
dx[{x_,y_}] = 2y+3-6x; dy[{x_,y_}]=2x-2y;
Show[g,Epilog->Dynamic[iterates[{dx,dy},xy0,n,δ]]],
{{n,1},1,100,1,Appearance->"Labeled"},
{{δ,.1},.01,1,Appearance->"Labeled"},
{{xy0,{1,1}},Locator},
SynchronousUpdating->False,
TrackedSymbols:>{n,δ,xy0},
SaveDefinitions->True
]]

Constrained 1D optimization

g1=Plot[12Log[λ]-8λ,{λ,0,10},AxesOrigin->{0,0},PlotRange->{-80,5}];
g2=Plot[12Log[λ]-8λ-(1/(λ-3)),{λ,0,3},PlotRange->{-80,5},PlotStyle->Directive[Lighter[Red],Thickness[.01]]];
g3=Plot[12Log[λ]-8λ-(1/(λ-3)),{λ,3,10},PlotRange->{-80,5},PlotStyle->Directive[Lighter[Red],Thickness[.01]]];
Show[{g2,g3 ,g1,Graphics@{Red,Opacity[.15],Rectangle[{3,0},{0,-100}]}},PlotRange->{{0,10},{-80,5}}]

Show[{g1,Graphics@{Red,Opacity[.15],Rectangle[{3,0},{0,-100}]}},PlotRange->{{0,10},{-80,5}}]

ϵ=.1;Solve[(12/λ)-10+(ϵ/(((λ-3))^2))==0 ,λ]

ϵ=.01;Solve[(12/λ)-10+(ϵ/(((λ-3))^2))==0 ,λ]

ϵ=.001;Solve[(12/λ)-10+(ϵ/(((λ-3))^2))==0 ,λ]

Constrained 2D optimization by computer

D[-(1/(1-(x+y)))-(1/(.6-y)),y]

iterates[{dx_,dy_},xy0_,n_,δ_]:=Module[{xy},
xy = NestList[#+δ{dx[#],dy[#]}&,xy0,n];
Arrow/@Partition[xy,2,1] ];

With[{g=  ContourPlot[2 x y+3 x-3(x^2)-(y^2),{x,0,1.2},{y,0,1},Frame->False,AxesLabel->{"x","y"},Axes->True],
g2=Graphics[{
Red,Opacity[.2],
Polygon[{{1,0},{0,1},{0,2},{2,2},{2,0},{2,0}}],
Polygon[{{0,.6},{2,.6},{2,2},{0,2}}]
}]
},
Manipulate[
dx[{x_,y_}] = 2y+3-6x-(ϵ/(((1-(x+y)))^2)); dy[{x_,y_}]=2x-2y-ϵ((1/(((1-(x+y)))^2))+(1/(((.6-y))^2)));
Show[g,g2,Epilog->Dynamic[iterates[{dx,dy},xy0,n,δ]]],
{{n,1},1,100,1,Appearance->"Labeled"},
{{δ,.1},.01,1,Appearance->"Labeled"},
{{ϵ,.1},.01,1,Appearance->"Labeled"},
{{xy0,{1,1}},Locator},
SynchronousUpdating->False,
TrackedSymbols:>{n,δ,xy0},
SaveDefinitions->True
]]