Erlang[ρ_,C_]:=((PDF[PoissonDistribution[ρ],C])/(CDF[PoissonDistribution[ρ],C]))

UpdateB[{λ0_,λ1_,λ2_,C1_,C2_,m_}][{B1_,B2_}]:=Module[{B1new,B2new},
B1new=Erlang[m(λ1+λ0(1-B2)),C1];
B2new=Erlang[m(λ2+λ0(1-B1new)),C2];
{B1new,B2new}]

Drift[par_][B_]:=UpdateB[par][B]-B;

pp={3,5,7,10,12,1};

VectorPlot[Drift[pp][{b1,b2}],{b1,0,.5},{b2,0,.5},VectorStyle->GrayLevel[.7]]

Iterates[drift_,xy0_,n_,ϵ_]:=Module[{xy},
xy=NestList[#+ϵ drift[#]&,xy0,n];
Arrow/@Partition[xy,2,1] ]

Module[{xy0={.3,.3},g= VectorPlot[Drift[pp][{b1,b2}],{b1,0,.5},{b2,0,.5},VectorStyle->GrayLevel[.7],Frame->False,AxesLabel->{"B1","B2"},Axes->True]},
Manipulate[
LocatorPane[Dynamic[xy0],Show[g,Epilog->Dynamic[Iterates[Drift[pp],xy0,n,ϵ]]]],
{{n,1},1,100,1},
{{ϵ,1},.01,1},
SynchronousUpdating->False,
TrackedSymbols:>{n,ϵ,xy0}
]]