Fixed point for Dynamic Alternative Routing

Erlang[ρ_,c_] := PDF[PoissonDistribution[ρ],c] / CDF[PoissonDistribution[ρ],c];
drift[ρ_,c_][B_] := Erlang[ρ(1+2B(1-B)),c]-B;

plotdrift[c_,ρ_]:=Plot[drift[ρ,c][B],{B,0,.3},AxesOrigin->{0,0}];
plotvec[c_,ρ_]:=VectorPlot[{0,drift[ρ,c][B]},
{time,0,10},{B,0,.25},PlotRange->{{0,10},{0,.25}},
VectorScale->{.0025,20},VectorPoints->{20,10},
AspectRatio->1/GoldenRatio,Axes->True,Frame->False,AxesOrigin->{0,0}]

gnull=Graphics[{},AspectRatio->1/GoldenRatio,Axes->True,Frame->False,AxesOrigin->{0,0},PlotRange->{{0,10},{0,.25}}];

Panel@DynamicModule[{c=5000,ρ=4750,show=False,g1=plotdrift[5000,4750],g2=plotvec[5000,4750]},
Column[{
Row[{"C",Slider[Dynamic[c,{(c=#;g1=plotdrift[c,ρ])&,(c=#;g1=plotdrift[c,ρ];g2=plotvec[c,ρ])&},SynchronousUpdating->False],{1,10000},Appearance->"Labeled"]}],
Row[{"ρ",Slider[Dynamic[ρ,{(ρ=#;g1=plotdrift[c,ρ])&,(ρ=#;g1=plotdrift[c,ρ];g2=plotvec[c,ρ])&},SynchronousUpdating->False],{1,10000},Appearance->"Labeled"]}],
SetterBar[Dynamic[show],{True->"show drift",False->"hide drift"}],
GraphicsRow[{Dynamic[g1],Dynamic[If[show,g2,gnull]]},ImageSize->Large,Frame->All]
}]
]