header {* Generic theorem transfer using relations *}
theory Transfer
imports Plain Hilbert_Choice
begin
subsection {* Relator for function space *}
definition
fun_rel :: "('a => 'c => bool) => ('b => 'd => bool) => ('a => 'b) => ('c => 'd) => bool" (infixr "===>" 55)
where
"fun_rel A B = (λf g. ∀x y. A x y --> B (f x) (g y))"
lemma fun_relI [intro]:
assumes "!!x y. A x y ==> B (f x) (g y)"
shows "(A ===> B) f g"
using assms by (simp add: fun_rel_def)
lemma fun_relD:
assumes "(A ===> B) f g" and "A x y"
shows "B (f x) (g y)"
using assms by (simp add: fun_rel_def)
lemma fun_relD2:
assumes "(A ===> B) f g" and "A x x"
shows "B (f x) (g x)"
using assms unfolding fun_rel_def by auto
lemma fun_relE:
assumes "(A ===> B) f g" and "A x y"
obtains "B (f x) (g y)"
using assms by (simp add: fun_rel_def)
lemma fun_rel_eq:
shows "((op =) ===> (op =)) = (op =)"
by (auto simp add: fun_eq_iff elim: fun_relE)
lemma fun_rel_eq_rel:
shows "((op =) ===> R) = (λf g. ∀x. R (f x) (g x))"
by (simp add: fun_rel_def)
subsection {* Transfer method *}
text {* Explicit tag for relation membership allows for
backward proof methods. *}
definition Rel :: "('a => 'b => bool) => 'a => 'b => bool"
where "Rel r ≡ r"
text {* Handling of equality relations *}
definition is_equality :: "('a => 'a => bool) => bool"
where "is_equality R <-> R = (op =)"
text {* Handling of meta-logic connectives *}
definition transfer_forall where
"transfer_forall ≡ All"
definition transfer_implies where
"transfer_implies ≡ op -->"
definition transfer_bforall :: "('a => bool) => ('a => bool) => bool"
where "transfer_bforall ≡ (λP Q. ∀x. P x --> Q x)"
lemma transfer_forall_eq: "(!!x. P x) ≡ Trueprop (transfer_forall (λx. P x))"
unfolding atomize_all transfer_forall_def ..
lemma transfer_implies_eq: "(A ==> B) ≡ Trueprop (transfer_implies A B)"
unfolding atomize_imp transfer_implies_def ..
lemma transfer_bforall_unfold:
"Trueprop (transfer_bforall P (λx. Q x)) ≡ (!!x. P x ==> Q x)"
unfolding transfer_bforall_def atomize_imp atomize_all ..
lemma transfer_start: "[|P; Rel (op =) P Q|] ==> Q"
unfolding Rel_def by simp
lemma transfer_start': "[|P; Rel (op -->) P Q|] ==> Q"
unfolding Rel_def by simp
lemma transfer_prover_start: "[|x = x'; Rel R x' y|] ==> Rel R x y"
by simp
lemma Rel_eq_refl: "Rel (op =) x x"
unfolding Rel_def ..
lemma Rel_app:
assumes "Rel (A ===> B) f g" and "Rel A x y"
shows "Rel B (f x) (g y)"
using assms unfolding Rel_def fun_rel_def by fast
lemma Rel_abs:
assumes "!!x y. Rel A x y ==> Rel B (f x) (g y)"
shows "Rel (A ===> B) (λx. f x) (λy. g y)"
using assms unfolding Rel_def fun_rel_def by fast
ML_file "Tools/transfer.ML"
setup Transfer.setup
declare refl [transfer_rule]
declare fun_rel_eq [relator_eq]
hide_const (open) Rel
subsection {* Predicates on relations, i.e. ``class constraints'' *}
definition right_total :: "('a => 'b => bool) => bool"
where "right_total R <-> (∀y. ∃x. R x y)"
definition right_unique :: "('a => 'b => bool) => bool"
where "right_unique R <-> (∀x y z. R x y --> R x z --> y = z)"
definition bi_total :: "('a => 'b => bool) => bool"
where "bi_total R <-> (∀x. ∃y. R x y) ∧ (∀y. ∃x. R x y)"
definition bi_unique :: "('a => 'b => bool) => bool"
where "bi_unique R <->
(∀x y z. R x y --> R x z --> y = z) ∧
(∀x y z. R x z --> R y z --> x = y)"
lemma right_total_alt_def:
"right_total R <-> ((R ===> op -->) ===> op -->) All All"
unfolding right_total_def fun_rel_def
apply (rule iffI, fast)
apply (rule allI)
apply (drule_tac x="λx. True" in spec)
apply (drule_tac x="λy. ∃x. R x y" in spec)
apply fast
done
lemma right_unique_alt_def:
"right_unique R <-> (R ===> R ===> op -->) (op =) (op =)"
unfolding right_unique_def fun_rel_def by auto
lemma bi_total_alt_def:
"bi_total R <-> ((R ===> op =) ===> op =) All All"
unfolding bi_total_def fun_rel_def
apply (rule iffI, fast)
apply safe
apply (drule_tac x="λx. ∃y. R x y" in spec)
apply (drule_tac x="λy. True" in spec)
apply fast
apply (drule_tac x="λx. True" in spec)
apply (drule_tac x="λy. ∃x. R x y" in spec)
apply fast
done
lemma bi_unique_alt_def:
"bi_unique R <-> (R ===> R ===> op =) (op =) (op =)"
unfolding bi_unique_def fun_rel_def by auto
text {* Properties are preserved by relation composition. *}
lemma OO_def: "R OO S = (λx z. ∃y. R x y ∧ S y z)"
by auto
lemma bi_total_OO: "[|bi_total A; bi_total B|] ==> bi_total (A OO B)"
unfolding bi_total_def OO_def by metis
lemma bi_unique_OO: "[|bi_unique A; bi_unique B|] ==> bi_unique (A OO B)"
unfolding bi_unique_def OO_def by metis
lemma right_total_OO:
"[|right_total A; right_total B|] ==> right_total (A OO B)"
unfolding right_total_def OO_def by metis
lemma right_unique_OO:
"[|right_unique A; right_unique B|] ==> right_unique (A OO B)"
unfolding right_unique_def OO_def by metis
subsection {* Properties of relators *}
lemma is_equality_eq [transfer_rule]: "is_equality (op =)"
unfolding is_equality_def by simp
lemma right_total_eq [transfer_rule]: "right_total (op =)"
unfolding right_total_def by simp
lemma right_unique_eq [transfer_rule]: "right_unique (op =)"
unfolding right_unique_def by simp
lemma bi_total_eq [transfer_rule]: "bi_total (op =)"
unfolding bi_total_def by simp
lemma bi_unique_eq [transfer_rule]: "bi_unique (op =)"
unfolding bi_unique_def by simp
lemma right_total_fun [transfer_rule]:
"[|right_unique A; right_total B|] ==> right_total (A ===> B)"
unfolding right_total_def fun_rel_def
apply (rule allI, rename_tac g)
apply (rule_tac x="λx. SOME z. B z (g (THE y. A x y))" in exI)
apply clarify
apply (subgoal_tac "(THE y. A x y) = y", simp)
apply (rule someI_ex)
apply (simp)
apply (rule the_equality)
apply assumption
apply (simp add: right_unique_def)
done
lemma right_unique_fun [transfer_rule]:
"[|right_total A; right_unique B|] ==> right_unique (A ===> B)"
unfolding right_total_def right_unique_def fun_rel_def
by (clarify, rule ext, fast)
lemma bi_total_fun [transfer_rule]:
"[|bi_unique A; bi_total B|] ==> bi_total (A ===> B)"
unfolding bi_total_def fun_rel_def
apply safe
apply (rename_tac f)
apply (rule_tac x="λy. SOME z. B (f (THE x. A x y)) z" in exI)
apply clarify
apply (subgoal_tac "(THE x. A x y) = x", simp)
apply (rule someI_ex)
apply (simp)
apply (rule the_equality)
apply assumption
apply (simp add: bi_unique_def)
apply (rename_tac g)
apply (rule_tac x="λx. SOME z. B z (g (THE y. A x y))" in exI)
apply clarify
apply (subgoal_tac "(THE y. A x y) = y", simp)
apply (rule someI_ex)
apply (simp)
apply (rule the_equality)
apply assumption
apply (simp add: bi_unique_def)
done
lemma bi_unique_fun [transfer_rule]:
"[|bi_total A; bi_unique B|] ==> bi_unique (A ===> B)"
unfolding bi_total_def bi_unique_def fun_rel_def fun_eq_iff
by (safe, metis, fast)
subsection {* Transfer rules *}
text {* Transfer rules using implication instead of equality on booleans. *}
lemma eq_imp_transfer [transfer_rule]:
"right_unique A ==> (A ===> A ===> op -->) (op =) (op =)"
unfolding right_unique_alt_def .
lemma forall_imp_transfer [transfer_rule]:
"right_total A ==> ((A ===> op -->) ===> op -->) transfer_forall transfer_forall"
unfolding right_total_alt_def transfer_forall_def .
lemma eq_transfer [transfer_rule]:
assumes "bi_unique A"
shows "(A ===> A ===> op =) (op =) (op =)"
using assms unfolding bi_unique_def fun_rel_def by auto
lemma All_transfer [transfer_rule]:
assumes "bi_total A"
shows "((A ===> op =) ===> op =) All All"
using assms unfolding bi_total_def fun_rel_def by fast
lemma Ex_transfer [transfer_rule]:
assumes "bi_total A"
shows "((A ===> op =) ===> op =) Ex Ex"
using assms unfolding bi_total_def fun_rel_def by fast
lemma If_transfer [transfer_rule]: "(op = ===> A ===> A ===> A) If If"
unfolding fun_rel_def by simp
lemma Let_transfer [transfer_rule]: "(A ===> (A ===> B) ===> B) Let Let"
unfolding fun_rel_def by simp
lemma id_transfer [transfer_rule]: "(A ===> A) id id"
unfolding fun_rel_def by simp
lemma comp_transfer [transfer_rule]:
"((B ===> C) ===> (A ===> B) ===> (A ===> C)) (op o) (op o)"
unfolding fun_rel_def by simp
lemma fun_upd_transfer [transfer_rule]:
assumes [transfer_rule]: "bi_unique A"
shows "((A ===> B) ===> A ===> B ===> A ===> B) fun_upd fun_upd"
unfolding fun_upd_def [abs_def] by transfer_prover
lemma nat_case_transfer [transfer_rule]:
"(A ===> (op = ===> A) ===> op = ===> A) nat_case nat_case"
unfolding fun_rel_def by (simp split: nat.split)
lemma nat_rec_transfer [transfer_rule]:
"(A ===> (op = ===> A ===> A) ===> op = ===> A) nat_rec nat_rec"
unfolding fun_rel_def by (clarsimp, rename_tac n, induct_tac n, simp_all)
lemma funpow_transfer [transfer_rule]:
"(op = ===> (A ===> A) ===> (A ===> A)) compow compow"
unfolding funpow_def by transfer_prover
text {* Fallback rule for transferring universal quantifiers over
correspondence relations that are not bi-total, and do not have
custom transfer rules (e.g. relations between function types). *}
lemma Domainp_iff: "Domainp T x <-> (∃y. T x y)"
by auto
lemma Domainp_forall_transfer [transfer_rule]:
assumes "right_total A"
shows "((A ===> op =) ===> op =)
(transfer_bforall (Domainp A)) transfer_forall"
using assms unfolding right_total_def
unfolding transfer_forall_def transfer_bforall_def fun_rel_def Domainp_iff
by metis
text {* Preferred rule for transferring universal quantifiers over
bi-total correspondence relations (later rules are tried first). *}
lemma forall_transfer [transfer_rule]:
"bi_total A ==> ((A ===> op =) ===> op =) transfer_forall transfer_forall"
unfolding transfer_forall_def by (rule All_transfer)
end