Theory Group

theory Group
imports Lattice FuncSet
(*  Title:      HOL/Algebra/Group.thy
Author: Clemens Ballarin, started 4 February 2003

Based on work by Florian Kammueller, L C Paulson and Markus Wenzel.
*)


theory Group
imports Lattice "~~/src/HOL/Library/FuncSet"
begin

section {* Monoids and Groups *}

subsection {* Definitions *}

text {*
Definitions follow \cite{Jacobson:1985}.
*}


record 'a monoid = "'a partial_object" +
mult :: "['a, 'a] => 'a" (infixl "⊗\<index>" 70)
one :: 'a ("\<one>\<index>")

definition
m_inv :: "('a, 'b) monoid_scheme => 'a => 'a" ("inv\<index> _" [81] 80)
where "invG x = (THE y. y ∈ carrier G & x ⊗G y = \<one>G & y ⊗G x = \<one>G)"

definition
Units :: "_ => 'a set"
--{*The set of invertible elements*}
where "Units G = {y. y ∈ carrier G & (∃x ∈ carrier G. x ⊗G y = \<one>G & y ⊗G x = \<one>G)}"

consts
pow :: "[('a, 'm) monoid_scheme, 'a, 'b::semiring_1] => 'a" (infixr "'(^')\<index>" 75)

overloading nat_pow == "pow :: [_, 'a, nat] => 'a"
begin
definition "nat_pow G a n = nat_rec \<one>G (%u b. b ⊗G a) n"
end

overloading int_pow == "pow :: [_, 'a, int] => 'a"
begin
definition "int_pow G a z =
(let p = nat_rec \<one>G (%u b. b ⊗G a)
in if z < 0 then invG (p (nat (-z))) else p (nat z))"

end

locale monoid =
fixes G (structure)
assumes m_closed [intro, simp]:
"[|x ∈ carrier G; y ∈ carrier G|] ==> x ⊗ y ∈ carrier G"
and m_assoc:
"[|x ∈ carrier G; y ∈ carrier G; z ∈ carrier G|]
==> (x ⊗ y) ⊗ z = x ⊗ (y ⊗ z)"

and one_closed [intro, simp]: "\<one> ∈ carrier G"
and l_one [simp]: "x ∈ carrier G ==> \<one> ⊗ x = x"
and r_one [simp]: "x ∈ carrier G ==> x ⊗ \<one> = x"

lemma monoidI:
fixes G (structure)
assumes m_closed:
"!!x y. [| x ∈ carrier G; y ∈ carrier G |] ==> x ⊗ y ∈ carrier G"
and one_closed: "\<one> ∈ carrier G"
and m_assoc:
"!!x y z. [| x ∈ carrier G; y ∈ carrier G; z ∈ carrier G |] ==>
(x ⊗ y) ⊗ z = x ⊗ (y ⊗ z)"

and l_one: "!!x. x ∈ carrier G ==> \<one> ⊗ x = x"
and r_one: "!!x. x ∈ carrier G ==> x ⊗ \<one> = x"
shows "monoid G"
by (fast intro!: monoid.intro intro: assms)

lemma (in monoid) Units_closed [dest]:
"x ∈ Units G ==> x ∈ carrier G"
by (unfold Units_def) fast

lemma (in monoid) inv_unique:
assumes eq: "y ⊗ x = \<one>" "x ⊗ y' = \<one>"
and G: "x ∈ carrier G" "y ∈ carrier G" "y' ∈ carrier G"
shows "y = y'"
proof -
from G eq have "y = y ⊗ (x ⊗ y')" by simp
also from G have "... = (y ⊗ x) ⊗ y'" by (simp add: m_assoc)
also from G eq have "... = y'" by simp
finally show ?thesis .
qed

lemma (in monoid) Units_m_closed [intro, simp]:
assumes x: "x ∈ Units G" and y: "y ∈ Units G"
shows "x ⊗ y ∈ Units G"
proof -
from x obtain x' where x: "x ∈ carrier G" "x' ∈ carrier G" and xinv: "x ⊗ x' = \<one>" "x' ⊗ x = \<one>"
unfolding Units_def by fast
from y obtain y' where y: "y ∈ carrier G" "y' ∈ carrier G" and yinv: "y ⊗ y' = \<one>" "y' ⊗ y = \<one>"
unfolding Units_def by fast
from x y xinv yinv have "y' ⊗ (x' ⊗ x) ⊗ y = \<one>" by simp
moreover from x y xinv yinv have "x ⊗ (y ⊗ y') ⊗ x' = \<one>" by simp
moreover note x y
ultimately show ?thesis unfolding Units_def
-- "Must avoid premature use of @{text hyp_subst_tac}."
apply (rule_tac CollectI)
apply (rule)
apply (fast)
apply (rule bexI [where x = "y' ⊗ x'"])
apply (auto simp: m_assoc)
done
qed

lemma (in monoid) Units_one_closed [intro, simp]:
"\<one> ∈ Units G"
by (unfold Units_def) auto

lemma (in monoid) Units_inv_closed [intro, simp]:
"x ∈ Units G ==> inv x ∈ carrier G"
apply (unfold Units_def m_inv_def, auto)
apply (rule theI2, fast)
apply (fast intro: inv_unique, fast)
done

lemma (in monoid) Units_l_inv_ex:
"x ∈ Units G ==> ∃y ∈ carrier G. y ⊗ x = \<one>"
by (unfold Units_def) auto

lemma (in monoid) Units_r_inv_ex:
"x ∈ Units G ==> ∃y ∈ carrier G. x ⊗ y = \<one>"
by (unfold Units_def) auto

lemma (in monoid) Units_l_inv [simp]:
"x ∈ Units G ==> inv x ⊗ x = \<one>"
apply (unfold Units_def m_inv_def, auto)
apply (rule theI2, fast)
apply (fast intro: inv_unique, fast)
done

lemma (in monoid) Units_r_inv [simp]:
"x ∈ Units G ==> x ⊗ inv x = \<one>"
apply (unfold Units_def m_inv_def, auto)
apply (rule theI2, fast)
apply (fast intro: inv_unique, fast)
done

lemma (in monoid) Units_inv_Units [intro, simp]:
"x ∈ Units G ==> inv x ∈ Units G"
proof -
assume x: "x ∈ Units G"
show "inv x ∈ Units G"
by (auto simp add: Units_def
intro: Units_l_inv Units_r_inv x Units_closed [OF x])
qed

lemma (in monoid) Units_l_cancel [simp]:
"[| x ∈ Units G; y ∈ carrier G; z ∈ carrier G |] ==>
(x ⊗ y = x ⊗ z) = (y = z)"

proof
assume eq: "x ⊗ y = x ⊗ z"
and G: "x ∈ Units G" "y ∈ carrier G" "z ∈ carrier G"
then have "(inv x ⊗ x) ⊗ y = (inv x ⊗ x) ⊗ z"
by (simp add: m_assoc Units_closed del: Units_l_inv)
with G show "y = z" by simp
next
assume eq: "y = z"
and G: "x ∈ Units G" "y ∈ carrier G" "z ∈ carrier G"
then show "x ⊗ y = x ⊗ z" by simp
qed

lemma (in monoid) Units_inv_inv [simp]:
"x ∈ Units G ==> inv (inv x) = x"
proof -
assume x: "x ∈ Units G"
then have "inv x ⊗ inv (inv x) = inv x ⊗ x" by simp
with x show ?thesis by (simp add: Units_closed del: Units_l_inv Units_r_inv)
qed

lemma (in monoid) inv_inj_on_Units:
"inj_on (m_inv G) (Units G)"
proof (rule inj_onI)
fix x y
assume G: "x ∈ Units G" "y ∈ Units G" and eq: "inv x = inv y"
then have "inv (inv x) = inv (inv y)" by simp
with G show "x = y" by simp
qed

lemma (in monoid) Units_inv_comm:
assumes inv: "x ⊗ y = \<one>"
and G: "x ∈ Units G" "y ∈ Units G"
shows "y ⊗ x = \<one>"
proof -
from G have "x ⊗ y ⊗ x = x ⊗ \<one>" by (auto simp add: inv Units_closed)
with G show ?thesis by (simp del: r_one add: m_assoc Units_closed)
qed

text {* Power *}

lemma (in monoid) nat_pow_closed [intro, simp]:
"x ∈ carrier G ==> x (^) (n::nat) ∈ carrier G"
by (induct n) (simp_all add: nat_pow_def)

lemma (in monoid) nat_pow_0 [simp]:
"x (^) (0::nat) = \<one>"
by (simp add: nat_pow_def)

lemma (in monoid) nat_pow_Suc [simp]:
"x (^) (Suc n) = x (^) n ⊗ x"
by (simp add: nat_pow_def)

lemma (in monoid) nat_pow_one [simp]:
"\<one> (^) (n::nat) = \<one>"
by (induct n) simp_all

lemma (in monoid) nat_pow_mult:
"x ∈ carrier G ==> x (^) (n::nat) ⊗ x (^) m = x (^) (n + m)"
by (induct m) (simp_all add: m_assoc [THEN sym])

lemma (in monoid) nat_pow_pow:
"x ∈ carrier G ==> (x (^) n) (^) m = x (^) (n * m::nat)"
by (induct m) (simp, simp add: nat_pow_mult add_commute)


(* Jacobson defines submonoid here. *)
(* Jacobson defines the order of a monoid here. *)


subsection {* Groups *}

text {*
A group is a monoid all of whose elements are invertible.
*}


locale group = monoid +
assumes Units: "carrier G <= Units G"

lemma (in group) is_group: "group G" by (rule group_axioms)

theorem groupI:
fixes G (structure)
assumes m_closed [simp]:
"!!x y. [| x ∈ carrier G; y ∈ carrier G |] ==> x ⊗ y ∈ carrier G"
and one_closed [simp]: "\<one> ∈ carrier G"
and m_assoc:
"!!x y z. [| x ∈ carrier G; y ∈ carrier G; z ∈ carrier G |] ==>
(x ⊗ y) ⊗ z = x ⊗ (y ⊗ z)"

and l_one [simp]: "!!x. x ∈ carrier G ==> \<one> ⊗ x = x"
and l_inv_ex: "!!x. x ∈ carrier G ==> ∃y ∈ carrier G. y ⊗ x = \<one>"
shows "group G"
proof -
have l_cancel [simp]:
"!!x y z. [| x ∈ carrier G; y ∈ carrier G; z ∈ carrier G |] ==>
(x ⊗ y = x ⊗ z) = (y = z)"

proof
fix x y z
assume eq: "x ⊗ y = x ⊗ z"
and G: "x ∈ carrier G" "y ∈ carrier G" "z ∈ carrier G"
with l_inv_ex obtain x_inv where xG: "x_inv ∈ carrier G"
and l_inv: "x_inv ⊗ x = \<one>" by fast
from G eq xG have "(x_inv ⊗ x) ⊗ y = (x_inv ⊗ x) ⊗ z"
by (simp add: m_assoc)
with G show "y = z" by (simp add: l_inv)
next
fix x y z
assume eq: "y = z"
and G: "x ∈ carrier G" "y ∈ carrier G" "z ∈ carrier G"
then show "x ⊗ y = x ⊗ z" by simp
qed
have r_one:
"!!x. x ∈ carrier G ==> x ⊗ \<one> = x"
proof -
fix x
assume x: "x ∈ carrier G"
with l_inv_ex obtain x_inv where xG: "x_inv ∈ carrier G"
and l_inv: "x_inv ⊗ x = \<one>" by fast
from x xG have "x_inv ⊗ (x ⊗ \<one>) = x_inv ⊗ x"
by (simp add: m_assoc [symmetric] l_inv)
with x xG show "x ⊗ \<one> = x" by simp
qed
have inv_ex:
"!!x. x ∈ carrier G ==> ∃y ∈ carrier G. y ⊗ x = \<one> & x ⊗ y = \<one>"
proof -
fix x
assume x: "x ∈ carrier G"
with l_inv_ex obtain y where y: "y ∈ carrier G"
and l_inv: "y ⊗ x = \<one>" by fast
from x y have "y ⊗ (x ⊗ y) = y ⊗ \<one>"
by (simp add: m_assoc [symmetric] l_inv r_one)
with x y have r_inv: "x ⊗ y = \<one>"
by simp
from x y show "∃y ∈ carrier G. y ⊗ x = \<one> & x ⊗ y = \<one>"
by (fast intro: l_inv r_inv)
qed
then have carrier_subset_Units: "carrier G <= Units G"
by (unfold Units_def) fast
show ?thesis by default (auto simp: r_one m_assoc carrier_subset_Units)
qed

lemma (in monoid) group_l_invI:
assumes l_inv_ex:
"!!x. x ∈ carrier G ==> ∃y ∈ carrier G. y ⊗ x = \<one>"
shows "group G"
by (rule groupI) (auto intro: m_assoc l_inv_ex)

lemma (in group) Units_eq [simp]:
"Units G = carrier G"
proof
show "Units G <= carrier G" by fast
next
show "carrier G <= Units G" by (rule Units)
qed

lemma (in group) inv_closed [intro, simp]:
"x ∈ carrier G ==> inv x ∈ carrier G"
using Units_inv_closed by simp

lemma (in group) l_inv_ex [simp]:
"x ∈ carrier G ==> ∃y ∈ carrier G. y ⊗ x = \<one>"
using Units_l_inv_ex by simp

lemma (in group) r_inv_ex [simp]:
"x ∈ carrier G ==> ∃y ∈ carrier G. x ⊗ y = \<one>"
using Units_r_inv_ex by simp

lemma (in group) l_inv [simp]:
"x ∈ carrier G ==> inv x ⊗ x = \<one>"
using Units_l_inv by simp


subsection {* Cancellation Laws and Basic Properties *}

lemma (in group) l_cancel [simp]:
"[| x ∈ carrier G; y ∈ carrier G; z ∈ carrier G |] ==>
(x ⊗ y = x ⊗ z) = (y = z)"

using Units_l_inv by simp

lemma (in group) r_inv [simp]:
"x ∈ carrier G ==> x ⊗ inv x = \<one>"
proof -
assume x: "x ∈ carrier G"
then have "inv x ⊗ (x ⊗ inv x) = inv x ⊗ \<one>"
by (simp add: m_assoc [symmetric])
with x show ?thesis by (simp del: r_one)
qed

lemma (in group) r_cancel [simp]:
"[| x ∈ carrier G; y ∈ carrier G; z ∈ carrier G |] ==>
(y ⊗ x = z ⊗ x) = (y = z)"

proof
assume eq: "y ⊗ x = z ⊗ x"
and G: "x ∈ carrier G" "y ∈ carrier G" "z ∈ carrier G"
then have "y ⊗ (x ⊗ inv x) = z ⊗ (x ⊗ inv x)"
by (simp add: m_assoc [symmetric] del: r_inv Units_r_inv)
with G show "y = z" by simp
next
assume eq: "y = z"
and G: "x ∈ carrier G" "y ∈ carrier G" "z ∈ carrier G"
then show "y ⊗ x = z ⊗ x" by simp
qed

lemma (in group) inv_one [simp]:
"inv \<one> = \<one>"
proof -
have "inv \<one> = \<one> ⊗ (inv \<one>)" by (simp del: r_inv Units_r_inv)
moreover have "... = \<one>" by simp
finally show ?thesis .
qed

lemma (in group) inv_inv [simp]:
"x ∈ carrier G ==> inv (inv x) = x"
using Units_inv_inv by simp

lemma (in group) inv_inj:
"inj_on (m_inv G) (carrier G)"
using inv_inj_on_Units by simp

lemma (in group) inv_mult_group:
"[| x ∈ carrier G; y ∈ carrier G |] ==> inv (x ⊗ y) = inv y ⊗ inv x"
proof -
assume G: "x ∈ carrier G" "y ∈ carrier G"
then have "inv (x ⊗ y) ⊗ (x ⊗ y) = (inv y ⊗ inv x) ⊗ (x ⊗ y)"
by (simp add: m_assoc) (simp add: m_assoc [symmetric])
with G show ?thesis by (simp del: l_inv Units_l_inv)
qed

lemma (in group) inv_comm:
"[| x ⊗ y = \<one>; x ∈ carrier G; y ∈ carrier G |] ==> y ⊗ x = \<one>"
by (rule Units_inv_comm) auto

lemma (in group) inv_equality:
"[|y ⊗ x = \<one>; x ∈ carrier G; y ∈ carrier G|] ==> inv x = y"
apply (simp add: m_inv_def)
apply (rule the_equality)
apply (simp add: inv_comm [of y x])
apply (rule r_cancel [THEN iffD1], auto)
done

text {* Power *}

lemma (in group) int_pow_def2:
"a (^) (z::int) = (if z < 0 then inv (a (^) (nat (-z))) else a (^) (nat z))"
by (simp add: int_pow_def nat_pow_def Let_def)

lemma (in group) int_pow_0 [simp]:
"x (^) (0::int) = \<one>"
by (simp add: int_pow_def2)

lemma (in group) int_pow_one [simp]:
"\<one> (^) (z::int) = \<one>"
by (simp add: int_pow_def2)


subsection {* Subgroups *}

locale subgroup =
fixes H and G (structure)
assumes subset: "H ⊆ carrier G"
and m_closed [intro, simp]: "[|x ∈ H; y ∈ H|] ==> x ⊗ y ∈ H"
and one_closed [simp]: "\<one> ∈ H"
and m_inv_closed [intro,simp]: "x ∈ H ==> inv x ∈ H"

lemma (in subgroup) is_subgroup:
"subgroup H G" by (rule subgroup_axioms)

declare (in subgroup) group.intro [intro]

lemma (in subgroup) mem_carrier [simp]:
"x ∈ H ==> x ∈ carrier G"
using subset by blast

lemma subgroup_imp_subset:
"subgroup H G ==> H ⊆ carrier G"
by (rule subgroup.subset)

lemma (in subgroup) subgroup_is_group [intro]:
assumes "group G"
shows "group (G(|carrier := H|)),)"
proof -
interpret group G by fact
show ?thesis
apply (rule monoid.group_l_invI)
apply (unfold_locales) [1]
apply (auto intro: m_assoc l_inv mem_carrier)
done
qed

text {*
Since @{term H} is nonempty, it contains some element @{term x}. Since
it is closed under inverse, it contains @{text "inv x"}. Since
it is closed under product, it contains @{text "x ⊗ inv x = \<one>"}.
*}


lemma (in group) one_in_subset:
"[| H ⊆ carrier G; H ≠ {}; ∀a ∈ H. inv a ∈ H; ∀a∈H. ∀b∈H. a ⊗ b ∈ H |]
==> \<one> ∈ H"

by force

text {* A characterization of subgroups: closed, non-empty subset. *}

lemma (in group) subgroupI:
assumes subset: "H ⊆ carrier G" and non_empty: "H ≠ {}"
and inv: "!!a. a ∈ H ==> inv a ∈ H"
and mult: "!!a b. [|a ∈ H; b ∈ H|] ==> a ⊗ b ∈ H"
shows "subgroup H G"
proof (simp add: subgroup_def assms)
show "\<one> ∈ H" by (rule one_in_subset) (auto simp only: assms)
qed

declare monoid.one_closed [iff] group.inv_closed [simp]
monoid.l_one [simp] monoid.r_one [simp] group.inv_inv [simp]

lemma subgroup_nonempty:
"~ subgroup {} G"
by (blast dest: subgroup.one_closed)

lemma (in subgroup) finite_imp_card_positive:
"finite (carrier G) ==> 0 < card H"
proof (rule classical)
assume "finite (carrier G)" and a: "~ 0 < card H"
then have "finite H" by (blast intro: finite_subset [OF subset])
with is_subgroup a have "subgroup {} G" by simp
with subgroup_nonempty show ?thesis by contradiction
qed

(*
lemma (in monoid) Units_subgroup:
"subgroup (Units G) G"
*)



subsection {* Direct Products *}

definition
DirProd :: "_ => _ => ('a × 'b) monoid" (infixr "××" 80) where
"G ×× H =
(|carrier = carrier G × carrier H,
mult = (λ(g, h) (g', h'). (g ⊗G g', h ⊗H h')),
one = (\<one>G, \<one>H)|)),"


lemma DirProd_monoid:
assumes "monoid G" and "monoid H"
shows "monoid (G ×× H)"
proof -
interpret G: monoid G by fact
interpret H: monoid H by fact
from assms
show ?thesis by (unfold monoid_def DirProd_def, auto)
qed


text{*Does not use the previous result because it's easier just to use auto.*}
lemma DirProd_group:
assumes "group G" and "group H"
shows "group (G ×× H)"
proof -
interpret G: group G by fact
interpret H: group H by fact
show ?thesis by (rule groupI)
(auto intro: G.m_assoc H.m_assoc G.l_inv H.l_inv
simp add: DirProd_def)
qed

lemma carrier_DirProd [simp]:
"carrier (G ×× H) = carrier G × carrier H"
by (simp add: DirProd_def)

lemma one_DirProd [simp]:
"\<one>G ×× H = (\<one>G, \<one>H)"
by (simp add: DirProd_def)

lemma mult_DirProd [simp]:
"(g, h) ⊗(G ×× H) (g', h') = (g ⊗G g', h ⊗H h')"
by (simp add: DirProd_def)

lemma inv_DirProd [simp]:
assumes "group G" and "group H"
assumes g: "g ∈ carrier G"
and h: "h ∈ carrier H"
shows "m_inv (G ×× H) (g, h) = (invG g, invH h)"
proof -
interpret G: group G by fact
interpret H: group H by fact
interpret Prod: group "G ×× H"
by (auto intro: DirProd_group group.intro group.axioms assms)
show ?thesis by (simp add: Prod.inv_equality g h)
qed


subsection {* Homomorphisms and Isomorphisms *}

definition
hom :: "_ => _ => ('a => 'b) set" where
"hom G H =
{h. h ∈ carrier G -> carrier H &
(∀x ∈ carrier G. ∀y ∈ carrier G. h (x ⊗G y) = h x ⊗H h y)}"


lemma (in group) hom_compose:
"[|h ∈ hom G H; i ∈ hom H I|] ==> compose (carrier G) i h ∈ hom G I"
by (fastforce simp add: hom_def compose_def)

definition
iso :: "_ => _ => ('a => 'b) set" (infixr "≅" 60)
where "G ≅ H = {h. h ∈ hom G H & bij_betw h (carrier G) (carrier H)}"

lemma iso_refl: "(%x. x) ∈ G ≅ G"
by (simp add: iso_def hom_def inj_on_def bij_betw_def Pi_def)

lemma (in group) iso_sym:
"h ∈ G ≅ H ==> inv_into (carrier G) h ∈ H ≅ G"
apply (simp add: iso_def bij_betw_inv_into)
apply (subgoal_tac "inv_into (carrier G) h ∈ carrier H -> carrier G")
prefer 2 apply (simp add: bij_betw_imp_funcset [OF bij_betw_inv_into])
apply (simp add: hom_def bij_betw_def inv_into_f_eq f_inv_into_f Pi_def)
done

lemma (in group) iso_trans:
"[|h ∈ G ≅ H; i ∈ H ≅ I|] ==> (compose (carrier G) i h) ∈ G ≅ I"
by (auto simp add: iso_def hom_compose bij_betw_compose)

lemma DirProd_commute_iso:
shows "(λ(x,y). (y,x)) ∈ (G ×× H) ≅ (H ×× G)"
by (auto simp add: iso_def hom_def inj_on_def bij_betw_def)

lemma DirProd_assoc_iso:
shows "(λ(x,y,z). (x,(y,z))) ∈ (G ×× H ×× I) ≅ (G ×× (H ×× I))"
by (auto simp add: iso_def hom_def inj_on_def bij_betw_def)


text{*Basis for homomorphism proofs: we assume two groups @{term G} and
@{term H}, with a homomorphism @{term h} between them*}

locale group_hom = G: group G + H: group H for G (structure) and H (structure) +
fixes h
assumes homh: "h ∈ hom G H"

lemma (in group_hom) hom_mult [simp]:
"[| x ∈ carrier G; y ∈ carrier G |] ==> h (x ⊗G y) = h x ⊗H h y"
proof -
assume "x ∈ carrier G" "y ∈ carrier G"
with homh [unfolded hom_def] show ?thesis by simp
qed

lemma (in group_hom) hom_closed [simp]:
"x ∈ carrier G ==> h x ∈ carrier H"
proof -
assume "x ∈ carrier G"
with homh [unfolded hom_def] show ?thesis by auto
qed

lemma (in group_hom) one_closed [simp]:
"h \<one> ∈ carrier H"
by simp

lemma (in group_hom) hom_one [simp]:
"h \<one> = \<one>H"
proof -
have "h \<one> ⊗H \<one>H = h \<one> ⊗H h \<one>"
by (simp add: hom_mult [symmetric] del: hom_mult)
then show ?thesis by (simp del: r_one)
qed

lemma (in group_hom) inv_closed [simp]:
"x ∈ carrier G ==> h (inv x) ∈ carrier H"
by simp

lemma (in group_hom) hom_inv [simp]:
"x ∈ carrier G ==> h (inv x) = invH (h x)"
proof -
assume x: "x ∈ carrier G"
then have "h x ⊗H h (inv x) = \<one>H"
by (simp add: hom_mult [symmetric] del: hom_mult)
also from x have "... = h x ⊗H invH (h x)"
by (simp add: hom_mult [symmetric] del: hom_mult)
finally have "h x ⊗H h (inv x) = h x ⊗H invH (h x)" .
with x show ?thesis by (simp del: H.r_inv H.Units_r_inv)
qed


subsection {* Commutative Structures *}

text {*
Naming convention: multiplicative structures that are commutative
are called \emph{commutative}, additive structures are called
\emph{Abelian}.
*}


locale comm_monoid = monoid +
assumes m_comm: "[|x ∈ carrier G; y ∈ carrier G|] ==> x ⊗ y = y ⊗ x"

lemma (in comm_monoid) m_lcomm:
"[|x ∈ carrier G; y ∈ carrier G; z ∈ carrier G|] ==>
x ⊗ (y ⊗ z) = y ⊗ (x ⊗ z)"

proof -
assume xyz: "x ∈ carrier G" "y ∈ carrier G" "z ∈ carrier G"
from xyz have "x ⊗ (y ⊗ z) = (x ⊗ y) ⊗ z" by (simp add: m_assoc)
also from xyz have "... = (y ⊗ x) ⊗ z" by (simp add: m_comm)
also from xyz have "... = y ⊗ (x ⊗ z)" by (simp add: m_assoc)
finally show ?thesis .
qed

lemmas (in comm_monoid) m_ac = m_assoc m_comm m_lcomm

lemma comm_monoidI:
fixes G (structure)
assumes m_closed:
"!!x y. [| x ∈ carrier G; y ∈ carrier G |] ==> x ⊗ y ∈ carrier G"
and one_closed: "\<one> ∈ carrier G"
and m_assoc:
"!!x y z. [| x ∈ carrier G; y ∈ carrier G; z ∈ carrier G |] ==>
(x ⊗ y) ⊗ z = x ⊗ (y ⊗ z)"

and l_one: "!!x. x ∈ carrier G ==> \<one> ⊗ x = x"
and m_comm:
"!!x y. [| x ∈ carrier G; y ∈ carrier G |] ==> x ⊗ y = y ⊗ x"
shows "comm_monoid G"
using l_one
by (auto intro!: comm_monoid.intro comm_monoid_axioms.intro monoid.intro
intro: assms simp: m_closed one_closed m_comm)

lemma (in monoid) monoid_comm_monoidI:
assumes m_comm:
"!!x y. [| x ∈ carrier G; y ∈ carrier G |] ==> x ⊗ y = y ⊗ x"
shows "comm_monoid G"
by (rule comm_monoidI) (auto intro: m_assoc m_comm)

(*lemma (in comm_monoid) r_one [simp]:
"x ∈ carrier G ==> x ⊗ \<one> = x"
proof -
assume G: "x ∈ carrier G"
then have "x ⊗ \<one> = \<one> ⊗ x" by (simp add: m_comm)
also from G have "... = x" by simp
finally show ?thesis .
qed*)


lemma (in comm_monoid) nat_pow_distr:
"[| x ∈ carrier G; y ∈ carrier G |] ==>
(x ⊗ y) (^) (n::nat) = x (^) n ⊗ y (^) n"

by (induct n) (simp, simp add: m_ac)

locale comm_group = comm_monoid + group

lemma (in group) group_comm_groupI:
assumes m_comm: "!!x y. [| x ∈ carrier G; y ∈ carrier G |] ==>
x ⊗ y = y ⊗ x"

shows "comm_group G"
by default (simp_all add: m_comm)

lemma comm_groupI:
fixes G (structure)
assumes m_closed:
"!!x y. [| x ∈ carrier G; y ∈ carrier G |] ==> x ⊗ y ∈ carrier G"
and one_closed: "\<one> ∈ carrier G"
and m_assoc:
"!!x y z. [| x ∈ carrier G; y ∈ carrier G; z ∈ carrier G |] ==>
(x ⊗ y) ⊗ z = x ⊗ (y ⊗ z)"

and m_comm:
"!!x y. [| x ∈ carrier G; y ∈ carrier G |] ==> x ⊗ y = y ⊗ x"
and l_one: "!!x. x ∈ carrier G ==> \<one> ⊗ x = x"
and l_inv_ex: "!!x. x ∈ carrier G ==> ∃y ∈ carrier G. y ⊗ x = \<one>"
shows "comm_group G"
by (fast intro: group.group_comm_groupI groupI assms)

lemma (in comm_group) inv_mult:
"[| x ∈ carrier G; y ∈ carrier G |] ==> inv (x ⊗ y) = inv x ⊗ inv y"
by (simp add: m_ac inv_mult_group)


subsection {* The Lattice of Subgroups of a Group *}

text_raw {* \label{sec:subgroup-lattice} *}

theorem (in group) subgroups_partial_order:
"partial_order (| carrier = {H. subgroup H G}, eq = op =, le = op ⊆ |)"
by default simp_all

lemma (in group) subgroup_self:
"subgroup (carrier G) G"
by (rule subgroupI) auto

lemma (in group) subgroup_imp_group:
"subgroup H G ==> group (G(| carrier := H |))"
by (erule subgroup.subgroup_is_group) (rule group_axioms)

lemma (in group) is_monoid [intro, simp]:
"monoid G"
by (auto intro: monoid.intro m_assoc)

lemma (in group) subgroup_inv_equality:
"[| subgroup H G; x ∈ H |] ==> m_inv (G (| carrier := H |)) x = inv x"
apply (rule_tac inv_equality [THEN sym])
apply (rule group.l_inv [OF subgroup_imp_group, simplified], assumption+)
apply (rule subsetD [OF subgroup.subset], assumption+)
apply (rule subsetD [OF subgroup.subset], assumption)
apply (rule_tac group.inv_closed [OF subgroup_imp_group, simplified], assumption+)
done

theorem (in group) subgroups_Inter:
assumes subgr: "(!!H. H ∈ A ==> subgroup H G)"
and not_empty: "A ~= {}"
shows "subgroup (\<Inter>A) G"
proof (rule subgroupI)
from subgr [THEN subgroup.subset] and not_empty
show "\<Inter>A ⊆ carrier G" by blast
next
from subgr [THEN subgroup.one_closed]
show "\<Inter>A ~= {}" by blast
next
fix x assume "x ∈ \<Inter>A"
with subgr [THEN subgroup.m_inv_closed]
show "inv x ∈ \<Inter>A" by blast
next
fix x y assume "x ∈ \<Inter>A" "y ∈ \<Inter>A"
with subgr [THEN subgroup.m_closed]
show "x ⊗ y ∈ \<Inter>A" by blast
qed

theorem (in group) subgroups_complete_lattice:
"complete_lattice (| carrier = {H. subgroup H G}, eq = op =, le = op ⊆ |)"
(is "complete_lattice ?L")
proof (rule partial_order.complete_lattice_criterion1)
show "partial_order ?L" by (rule subgroups_partial_order)
next
have "greatest ?L (carrier G) (carrier ?L)"
by (unfold greatest_def) (simp add: subgroup.subset subgroup_self)
then show "∃G. greatest ?L G (carrier ?L)" ..
next
fix A
assume L: "A ⊆ carrier ?L" and non_empty: "A ~= {}"
then have Int_subgroup: "subgroup (\<Inter>A) G"
by (fastforce intro: subgroups_Inter)
have "greatest ?L (\<Inter>A) (Lower ?L A)" (is "greatest _ ?Int _")
proof (rule greatest_LowerI)
fix H
assume H: "H ∈ A"
with L have subgroupH: "subgroup H G" by auto
from subgroupH have groupH: "group (G (| carrier := H |))" (is "group ?H")
by (rule subgroup_imp_group)
from groupH have monoidH: "monoid ?H"
by (rule group.is_monoid)
from H have Int_subset: "?Int ⊆ H" by fastforce
then show "le ?L ?Int H" by simp
next
fix H
assume H: "H ∈ Lower ?L A"
with L Int_subgroup show "le ?L H ?Int"
by (fastforce simp: Lower_def intro: Inter_greatest)
next
show "A ⊆ carrier ?L" by (rule L)
next
show "?Int ∈ carrier ?L" by simp (rule Int_subgroup)
qed
then show "∃I. greatest ?L I (Lower ?L A)" ..
qed

end