Theory Convex_Euclidean_Space

theory Convex_Euclidean_Space
imports Topology_Euclidean_Space Convex Set_Algebras
(*  Title:      HOL/Multivariate_Analysis/Convex_Euclidean_Space.thy
    Author:     Robert Himmelmann, TU Muenchen
    Author:     Bogdan Grechuk, University of Edinburgh
*)

header {* Convex sets, functions and related things. *}

theory Convex_Euclidean_Space
imports
  Topology_Euclidean_Space
  "~~/src/HOL/Library/Convex"
  "~~/src/HOL/Library/Set_Algebras"
begin


(* ------------------------------------------------------------------------- *)
(* To be moved elsewhere                                                     *)
(* ------------------------------------------------------------------------- *)

lemma linear_scaleR: "linear (λx. scaleR c x)"
  by (simp add: linear_iff scaleR_add_right)

lemma linear_scaleR_left: "linear (λr. scaleR r x)"
  by (simp add: linear_iff scaleR_add_left)

lemma injective_scaleR: "c ≠ 0 ==> inj (λx::'a::real_vector. scaleR c x)"
  by (simp add: inj_on_def)

lemma linear_add_cmul:
  assumes "linear f"
  shows "f (a *R x + b *R y) = a *R f x +  b *R f y"
  using linear_add[of f] linear_cmul[of f] assms by simp

lemma mem_convex_alt:
  assumes "convex S" "x ∈ S" "y ∈ S" "u ≥ 0" "v ≥ 0" "u + v > 0"
  shows "((u/(u+v)) *R x + (v/(u+v)) *R y) ∈ S"
  apply (rule convexD)
  using assms
  apply (simp_all add: zero_le_divide_iff add_divide_distrib [symmetric])
  done

lemma inj_on_image_mem_iff: "inj_on f B ==> A ⊆ B ==> f a ∈ f`A ==> a ∈ B ==> a ∈ A"
  by (blast dest: inj_onD)

lemma independent_injective_on_span_image:
  assumes iS: "independent S"
    and lf: "linear f"
    and fi: "inj_on f (span S)"
  shows "independent (f ` S)"
proof -
  {
    fix a
    assume a: "a ∈ S" "f a ∈ span (f ` S - {f a})"
    have eq: "f ` S - {f a} = f ` (S - {a})"
      using fi a span_inc by (auto simp add: inj_on_def)
    from a have "f a ∈ f ` span (S -{a})"
      unfolding eq span_linear_image [OF lf, of "S - {a}"] by blast
    moreover have "span (S - {a}) ⊆ span S"
      using span_mono[of "S - {a}" S] by auto
    ultimately have "a ∈ span (S - {a})"
      using fi a span_inc by (auto simp add: inj_on_def)
    with a(1) iS have False
      by (simp add: dependent_def)
  }
  then show ?thesis
    unfolding dependent_def by blast
qed

lemma dim_image_eq:
  fixes f :: "'n::euclidean_space => 'm::euclidean_space"
  assumes lf: "linear f"
    and fi: "inj_on f (span S)"
  shows "dim (f ` S) = dim (S::'n::euclidean_space set)"
proof -
  obtain B where B: "B ⊆ S" "independent B" "S ⊆ span B" "card B = dim S"
    using basis_exists[of S] by auto
  then have "span S = span B"
    using span_mono[of B S] span_mono[of S "span B"] span_span[of B] by auto
  then have "independent (f ` B)"
    using independent_injective_on_span_image[of B f] B assms by auto
  moreover have "card (f ` B) = card B"
    using assms card_image[of f B] subset_inj_on[of f "span S" B] B span_inc by auto
  moreover have "(f ` B) ⊆ (f ` S)"
    using B by auto
  ultimately have "dim (f ` S) ≥ dim S"
    using independent_card_le_dim[of "f ` B" "f ` S"] B by auto
  then show ?thesis
    using dim_image_le[of f S] assms by auto
qed

lemma linear_injective_on_subspace_0:
  assumes lf: "linear f"
    and "subspace S"
  shows "inj_on f S <-> (∀x ∈ S. f x = 0 --> x = 0)"
proof -
  have "inj_on f S <-> (∀x ∈ S. ∀y ∈ S. f x = f y --> x = y)"
    by (simp add: inj_on_def)
  also have "… <-> (∀x ∈ S. ∀y ∈ S. f x - f y = 0 --> x - y = 0)"
    by simp
  also have "… <-> (∀x ∈ S. ∀y ∈ S. f (x - y) = 0 --> x - y = 0)"
    by (simp add: linear_sub[OF lf])
  also have "… <-> (∀x ∈ S. f x = 0 --> x = 0)"
    using `subspace S` subspace_def[of S] subspace_sub[of S] by auto
  finally show ?thesis .
qed

lemma subspace_Inter: "∀s ∈ f. subspace s ==> subspace (Inter f)"
  unfolding subspace_def by auto

lemma span_eq[simp]: "span s = s <-> subspace s"
  unfolding span_def by (rule hull_eq) (rule subspace_Inter)

lemma substdbasis_expansion_unique:
  assumes d: "d ⊆ Basis"
  shows "(∑i∈d. f i *R i) = (x::'a::euclidean_space) <->
    (∀i∈Basis. (i ∈ d --> f i = x • i) ∧ (i ∉ d --> x • i = 0))"
proof -
  have *: "!!x a b P. x * (if P then a else b) = (if P then x * a else x * b)"
    by auto
  have **: "finite d"
    by (auto intro: finite_subset[OF assms])
  have ***: "!!i. i ∈ Basis ==> (∑i∈d. f i *R i) • i = (∑x∈d. if x = i then f x else 0)"
    using d
    by (auto intro!: setsum.cong simp: inner_Basis inner_setsum_left)
  show ?thesis
    unfolding euclidean_eq_iff[where 'a='a] by (auto simp: setsum.delta[OF **] ***)
qed

lemma independent_substdbasis: "d ⊆ Basis ==> independent d"
  by (rule independent_mono[OF independent_Basis])

lemma dim_cball:
  assumes "e > 0"
  shows "dim (cball (0 :: 'n::euclidean_space) e) = DIM('n)"
proof -
  {
    fix x :: "'n::euclidean_space"
    def y  "(e / norm x) *R x"
    then have "y ∈ cball 0 e"
      using cball_def dist_norm[of 0 y] assms by auto
    moreover have *: "x = (norm x / e) *R y"
      using y_def assms by simp
    moreover from * have "x = (norm x/e) *R y"
      by auto
    ultimately have "x ∈ span (cball 0 e)"
      using span_mul[of y "cball 0 e" "norm x/e"] span_inc[of "cball 0 e"] by auto
  }
  then have "span (cball 0 e) = (UNIV :: 'n::euclidean_space set)"
    by auto
  then show ?thesis
    using dim_span[of "cball (0 :: 'n::euclidean_space) e"] by (auto simp add: dim_UNIV)
qed

lemma indep_card_eq_dim_span:
  fixes B :: "'n::euclidean_space set"
  assumes "independent B"
  shows "finite B ∧ card B = dim (span B)"
  using assms basis_card_eq_dim[of B "span B"] span_inc by auto

lemma setsum_not_0: "setsum f A ≠ 0 ==> ∃a ∈ A. f a ≠ 0"
  by (rule ccontr) auto

lemma translate_inj_on:
  fixes A :: "'a::ab_group_add set"
  shows "inj_on (λx. a + x) A"
  unfolding inj_on_def by auto

lemma translation_assoc:
  fixes a b :: "'a::ab_group_add"
  shows "(λx. b + x) ` ((λx. a + x) ` S) = (λx. (a + b) + x) ` S"
  by auto

lemma translation_invert:
  fixes a :: "'a::ab_group_add"
  assumes "(λx. a + x) ` A = (λx. a + x) ` B"
  shows "A = B"
proof -
  have "(λx. -a + x) ` ((λx. a + x) ` A) = (λx. - a + x) ` ((λx. a + x) ` B)"
    using assms by auto
  then show ?thesis
    using translation_assoc[of "-a" a A] translation_assoc[of "-a" a B] by auto
qed

lemma translation_galois:
  fixes a :: "'a::ab_group_add"
  shows "T = ((λx. a + x) ` S) <-> S = ((λx. (- a) + x) ` T)"
  using translation_assoc[of "-a" a S]
  apply auto
  using translation_assoc[of a "-a" T]
  apply auto
  done

lemma translation_inverse_subset:
  assumes "((λx. - a + x) ` V) ≤ (S :: 'n::ab_group_add set)"
  shows "V ≤ ((λx. a + x) ` S)"
proof -
  {
    fix x
    assume "x ∈ V"
    then have "x-a ∈ S" using assms by auto
    then have "x ∈ {a + v |v. v ∈ S}"
      apply auto
      apply (rule exI[of _ "x-a"])
      apply simp
      done
    then have "x ∈ ((λx. a+x) ` S)" by auto
  }
  then show ?thesis by auto
qed

lemma basis_to_basis_subspace_isomorphism:
  assumes s: "subspace (S:: ('n::euclidean_space) set)"
    and t: "subspace (T :: ('m::euclidean_space) set)"
    and d: "dim S = dim T"
    and B: "B ⊆ S" "independent B" "S ⊆ span B" "card B = dim S"
    and C: "C ⊆ T" "independent C" "T ⊆ span C" "card C = dim T"
  shows "∃f. linear f ∧ f ` B = C ∧ f ` S = T ∧ inj_on f S"
proof -
  from B independent_bound have fB: "finite B"
    by blast
  from C independent_bound have fC: "finite C"
    by blast
  from B(4) C(4) card_le_inj[of B C] d obtain f where
    f: "f ` B ⊆ C" "inj_on f B" using `finite B` `finite C` by auto
  from linear_independent_extend[OF B(2)] obtain g where
    g: "linear g" "∀x ∈ B. g x = f x" by blast
  from inj_on_iff_eq_card[OF fB, of f] f(2)
  have "card (f ` B) = card B" by simp
  with B(4) C(4) have ceq: "card (f ` B) = card C" using d
    by simp
  have "g ` B = f ` B" using g(2)
    by (auto simp add: image_iff)
  also have "… = C" using card_subset_eq[OF fC f(1) ceq] .
  finally have gBC: "g ` B = C" .
  have gi: "inj_on g B" using f(2) g(2)
    by (auto simp add: inj_on_def)
  note g0 = linear_indep_image_lemma[OF g(1) fB, unfolded gBC, OF C(2) gi]
  {
    fix x y
    assume x: "x ∈ S" and y: "y ∈ S" and gxy: "g x = g y"
    from B(3) x y have x': "x ∈ span B" and y': "y ∈ span B"
      by blast+
    from gxy have th0: "g (x - y) = 0"
      by (simp add: linear_sub[OF g(1)])
    have th1: "x - y ∈ span B" using x' y'
      by (metis span_sub)
    have "x = y" using g0[OF th1 th0] by simp
  }
  then have giS: "inj_on g S" unfolding inj_on_def by blast
  from span_subspace[OF B(1,3) s]
  have "g ` S = span (g ` B)"
    by (simp add: span_linear_image[OF g(1)])
  also have "… = span C"
    unfolding gBC ..
  also have "… = T"
    using span_subspace[OF C(1,3) t] .
  finally have gS: "g ` S = T" .
  from g(1) gS giS gBC show ?thesis
    by blast
qed

lemma closure_bounded_linear_image:
  assumes f: "bounded_linear f"
  shows "f ` closure S ⊆ closure (f ` S)"
  using linear_continuous_on [OF f] closed_closure closure_subset
  by (rule image_closure_subset)

lemma closure_linear_image:
  fixes f :: "'m::euclidean_space => 'n::real_normed_vector"
  assumes "linear f"
  shows "f ` (closure S) ≤ closure (f ` S)"
  using assms unfolding linear_conv_bounded_linear
  by (rule closure_bounded_linear_image)

lemma closure_injective_linear_image:
  fixes f :: "'n::euclidean_space => 'n::euclidean_space"
  assumes "linear f" "inj f"
  shows "f ` (closure S) = closure (f ` S)"
proof -
  obtain f' where f': "linear f' ∧ f o f' = id ∧ f' o f = id"
    using assms linear_injective_isomorphism[of f] isomorphism_expand by auto
  then have "f' ` closure (f ` S) ≤ closure (S)"
    using closure_linear_image[of f' "f ` S"] image_comp[of f' f] by auto
  then have "f ` f' ` closure (f ` S) ≤ f ` closure S" by auto
  then have "closure (f ` S) ≤ f ` closure S"
    using image_comp[of f f' "closure (f ` S)"] f' by auto
  then show ?thesis using closure_linear_image[of f S] assms by auto
qed

lemma closure_scaleR:
  fixes S :: "'a::real_normed_vector set"
  shows "(op *R c) ` (closure S) = closure ((op *R c) ` S)"
proof
  show "(op *R c) ` (closure S) ⊆ closure ((op *R c) ` S)"
    using bounded_linear_scaleR_right
    by (rule closure_bounded_linear_image)
  show "closure ((op *R c) ` S) ⊆ (op *R c) ` (closure S)"
    by (intro closure_minimal image_mono closure_subset closed_scaling closed_closure)
qed

lemma fst_linear: "linear fst"
  unfolding linear_iff by (simp add: algebra_simps)

lemma snd_linear: "linear snd"
  unfolding linear_iff by (simp add: algebra_simps)

lemma fst_snd_linear: "linear (λ(x,y). x + y)"
  unfolding linear_iff by (simp add: algebra_simps)

lemma scaleR_2:
  fixes x :: "'a::real_vector"
  shows "scaleR 2 x = x + x"
  unfolding one_add_one [symmetric] scaleR_left_distrib by simp

lemma vector_choose_size:
  "0 ≤ c ==> ∃x::'a::euclidean_space. norm x = c"
  apply (rule exI [where x="c *R (SOME i. i ∈ Basis)"])
  apply (auto simp: SOME_Basis)
  done

lemma setsum_delta_notmem:
  assumes "x ∉ s"
  shows "setsum (λy. if (y = x) then P x else Q y) s = setsum Q s"
    and "setsum (λy. if (x = y) then P x else Q y) s = setsum Q s"
    and "setsum (λy. if (y = x) then P y else Q y) s = setsum Q s"
    and "setsum (λy. if (x = y) then P y else Q y) s = setsum Q s"
  apply (rule_tac [!] setsum.cong)
  using assms
  apply auto
  done

lemma setsum_delta'':
  fixes s::"'a::real_vector set"
  assumes "finite s"
  shows "(∑x∈s. (if y = x then f x else 0) *R x) = (if y∈s then (f y) *R y else 0)"
proof -
  have *: "!!x y. (if y = x then f x else (0::real)) *R x = (if x=y then (f x) *R x else 0)"
    by auto
  show ?thesis
    unfolding * using setsum.delta[OF assms, of y "λx. f x *R x"] by auto
qed

lemma if_smult: "(if P then x else (y::real)) *R v = (if P then x *R v else y *R v)"
  by (fact if_distrib)

lemma dist_triangle_eq:
  fixes x y z :: "'a::real_inner"
  shows "dist x z = dist x y + dist y z <->
    norm (x - y) *R (y - z) = norm (y - z) *R (x - y)"
proof -
  have *: "x - y + (y - z) = x - z" by auto
  show ?thesis unfolding dist_norm norm_triangle_eq[of "x - y" "y - z", unfolded *]
    by (auto simp add:norm_minus_commute)
qed

lemma norm_minus_eqI: "x = - y ==> norm x = norm y" by auto

lemma Min_grI:
  assumes "finite A" "A ≠ {}" "∀a∈A. x < a"
  shows "x < Min A"
  unfolding Min_gr_iff[OF assms(1,2)] using assms(3) by auto

lemma norm_lt: "norm x < norm y <-> inner x x < inner y y"
  unfolding norm_eq_sqrt_inner by simp

lemma norm_le: "norm x ≤ norm y <-> inner x x ≤ inner y y"
  unfolding norm_eq_sqrt_inner by simp


subsection {* Affine set and affine hull *}

definition affine :: "'a::real_vector set => bool"
  where "affine s <-> (∀x∈s. ∀y∈s. ∀u v. u + v = 1 --> u *R x + v *R y ∈ s)"

lemma affine_alt: "affine s <-> (∀x∈s. ∀y∈s. ∀u::real. (1 - u) *R x + u *R y ∈ s)"
  unfolding affine_def by (metis eq_diff_eq')

lemma affine_empty[intro]: "affine {}"
  unfolding affine_def by auto

lemma affine_sing[intro]: "affine {x}"
  unfolding affine_alt by (auto simp add: scaleR_left_distrib [symmetric])

lemma affine_UNIV[intro]: "affine UNIV"
  unfolding affine_def by auto

lemma affine_Inter: "(∀s∈f. affine s) ==> affine (\<Inter> f)"
  unfolding affine_def by auto

lemma affine_Int: "affine s ==> affine t ==> affine (s ∩ t)"
  unfolding affine_def by auto

lemma affine_affine_hull: "affine(affine hull s)"
  unfolding hull_def
  using affine_Inter[of "{t. affine t ∧ s ⊆ t}"] by auto

lemma affine_hull_eq[simp]: "(affine hull s = s) <-> affine s"
  by (metis affine_affine_hull hull_same)


subsubsection {* Some explicit formulations (from Lars Schewe) *}

lemma affine:
  fixes V::"'a::real_vector set"
  shows "affine V <->
    (∀s u. finite s ∧ s ≠ {} ∧ s ⊆ V ∧ setsum u s = 1 --> (setsum (λx. (u x) *R x)) s ∈ V)"
  unfolding affine_def
  apply rule
  apply(rule, rule, rule)
  apply(erule conjE)+
  defer
  apply (rule, rule, rule, rule, rule)
proof -
  fix x y u v
  assume as: "x ∈ V" "y ∈ V" "u + v = (1::real)"
    "∀s u. finite s ∧ s ≠ {} ∧ s ⊆ V ∧ setsum u s = 1 --> (∑x∈s. u x *R x) ∈ V"
  then show "u *R x + v *R y ∈ V"
    apply (cases "x = y")
    using as(4)[THEN spec[where x="{x,y}"], THEN spec[where x="λw. if w = x then u else v"]]
      and as(1-3)
    apply (auto simp add: scaleR_left_distrib[symmetric])
    done
next
  fix s u
  assume as: "∀x∈V. ∀y∈V. ∀u v. u + v = 1 --> u *R x + v *R y ∈ V"
    "finite s" "s ≠ {}" "s ⊆ V" "setsum u s = (1::real)"
  def n  "card s"
  have "card s = 0 ∨ card s = 1 ∨ card s = 2 ∨ card s > 2" by auto
  then show "(∑x∈s. u x *R x) ∈ V"
  proof (auto simp only: disjE)
    assume "card s = 2"
    then have "card s = Suc (Suc 0)"
      by auto
    then obtain a b where "s = {a, b}"
      unfolding card_Suc_eq by auto
    then show ?thesis
      using as(1)[THEN bspec[where x=a], THEN bspec[where x=b]] using as(4,5)
      by (auto simp add: setsum_clauses(2))
  next
    assume "card s > 2"
    then show ?thesis using as and n_def
    proof (induct n arbitrary: u s)
      case 0
      then show ?case by auto
    next
      case (Suc n)
      fix s :: "'a set" and u :: "'a => real"
      assume IA:
        "!!u s.  [|2 < card s; ∀x∈V. ∀y∈V. ∀u v. u + v = 1 --> u *R x + v *R y ∈ V; finite s;
          s ≠ {}; s ⊆ V; setsum u s = 1; n = card s |] ==> (∑x∈s. u x *R x) ∈ V"
        and as:
          "Suc n = card s" "2 < card s" "∀x∈V. ∀y∈V. ∀u v. u + v = 1 --> u *R x + v *R y ∈ V"
           "finite s" "s ≠ {}" "s ⊆ V" "setsum u s = 1"
      have "∃x∈s. u x ≠ 1"
      proof (rule ccontr)
        assume "¬ ?thesis"
        then have "setsum u s = real_of_nat (card s)"
          unfolding card_eq_setsum by auto
        then show False
          using as(7) and `card s > 2`
          by (metis One_nat_def less_Suc0 Zero_not_Suc of_nat_1 of_nat_eq_iff numeral_2_eq_2)
      qed
      then obtain x where x:"x ∈ s" "u x ≠ 1" by auto

      have c: "card (s - {x}) = card s - 1"
        apply (rule card_Diff_singleton)
        using `x∈s` as(4)
        apply auto
        done
      have *: "s = insert x (s - {x})" "finite (s - {x})"
        using `x∈s` and as(4) by auto
      have **: "setsum u (s - {x}) = 1 - u x"
        using setsum_clauses(2)[OF *(2), of u x, unfolded *(1)[symmetric] as(7)] by auto
      have ***: "inverse (1 - u x) * setsum u (s - {x}) = 1"
        unfolding ** using `u x ≠ 1` by auto
      have "(∑xa∈s - {x}. (inverse (1 - u x) * u xa) *R xa) ∈ V"
      proof (cases "card (s - {x}) > 2")
        case True
        then have "s - {x} ≠ {}" "card (s - {x}) = n"
          unfolding c and as(1)[symmetric]
        proof (rule_tac ccontr)
          assume "¬ s - {x} ≠ {}"
          then have "card (s - {x}) = 0" unfolding card_0_eq[OF *(2)] by simp
          then show False using True by auto
        qed auto
        then show ?thesis
          apply (rule_tac IA[of "s - {x}" "λy. (inverse (1 - u x) * u y)"])
          unfolding setsum_right_distrib[symmetric]
          using as and *** and True
          apply auto
          done
      next
        case False
        then have "card (s - {x}) = Suc (Suc 0)"
          using as(2) and c by auto
        then obtain a b where "(s - {x}) = {a, b}" "a≠b"
          unfolding card_Suc_eq by auto
        then show ?thesis
          using as(3)[THEN bspec[where x=a], THEN bspec[where x=b]]
          using *** *(2) and `s ⊆ V`
          unfolding setsum_right_distrib
          by (auto simp add: setsum_clauses(2))
      qed
      then have "u x + (1 - u x) = 1 ==>
          u x *R x + (1 - u x) *R ((∑xa∈s - {x}. u xa *R xa) /R (1 - u x)) ∈ V"
        apply -
        apply (rule as(3)[rule_format])
        unfolding  Real_Vector_Spaces.scaleR_right.setsum
        using x(1) as(6)
        apply auto
        done
      then show "(∑x∈s. u x *R x) ∈ V"
        unfolding scaleR_scaleR[symmetric] and scaleR_right.setsum [symmetric]
        apply (subst *)
        unfolding setsum_clauses(2)[OF *(2)]
        using `u x ≠ 1`
        apply auto
        done
    qed
  next
    assume "card s = 1"
    then obtain a where "s={a}"
      by (auto simp add: card_Suc_eq)
    then show ?thesis
      using as(4,5) by simp
  qed (insert `s≠{}` `finite s`, auto)
qed

lemma affine_hull_explicit:
  "affine hull p =
    {y. ∃s u. finite s ∧ s ≠ {} ∧ s ⊆ p ∧ setsum u s = 1 ∧ setsum (λv. (u v) *R v) s = y}"
  apply (rule hull_unique)
  apply (subst subset_eq)
  prefer 3
  apply rule
  unfolding mem_Collect_eq
  apply (erule exE)+
  apply (erule conjE)+
  prefer 2
  apply rule
proof -
  fix x
  assume "x∈p"
  then show "∃s u. finite s ∧ s ≠ {} ∧ s ⊆ p ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = x"
    apply (rule_tac x="{x}" in exI)
    apply (rule_tac x="λx. 1" in exI)
    apply auto
    done
next
  fix t x s u
  assume as: "p ⊆ t" "affine t" "finite s" "s ≠ {}"
    "s ⊆ p" "setsum u s = 1" "(∑v∈s. u v *R v) = x"
  then show "x ∈ t"
    using as(2)[unfolded affine, THEN spec[where x=s], THEN spec[where x=u]]
    by auto
next
  show "affine {y. ∃s u. finite s ∧ s ≠ {} ∧ s ⊆ p ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = y}"
    unfolding affine_def
    apply (rule, rule, rule, rule, rule)
    unfolding mem_Collect_eq
  proof -
    fix u v :: real
    assume uv: "u + v = 1"
    fix x
    assume "∃s u. finite s ∧ s ≠ {} ∧ s ⊆ p ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = x"
    then obtain sx ux where
      x: "finite sx" "sx ≠ {}" "sx ⊆ p" "setsum ux sx = 1" "(∑v∈sx. ux v *R v) = x"
      by auto
    fix y
    assume "∃s u. finite s ∧ s ≠ {} ∧ s ⊆ p ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = y"
    then obtain sy uy where
      y: "finite sy" "sy ≠ {}" "sy ⊆ p" "setsum uy sy = 1" "(∑v∈sy. uy v *R v) = y" by auto
    have xy: "finite (sx ∪ sy)"
      using x(1) y(1) by auto
    have **: "(sx ∪ sy) ∩ sx = sx" "(sx ∪ sy) ∩ sy = sy"
      by auto
    show "∃s ua. finite s ∧ s ≠ {} ∧ s ⊆ p ∧
        setsum ua s = 1 ∧ (∑v∈s. ua v *R v) = u *R x + v *R y"
      apply (rule_tac x="sx ∪ sy" in exI)
      apply (rule_tac x="λa. (if a∈sx then u * ux a else 0) + (if a∈sy then v * uy a else 0)" in exI)
      unfolding scaleR_left_distrib setsum.distrib if_smult scaleR_zero_left
        ** setsum.inter_restrict[OF xy, symmetric]
      unfolding scaleR_scaleR[symmetric] Real_Vector_Spaces.scaleR_right.setsum [symmetric]
        and setsum_right_distrib[symmetric]
      unfolding x y
      using x(1-3) y(1-3) uv
      apply simp
      done
  qed
qed

lemma affine_hull_finite:
  assumes "finite s"
  shows "affine hull s = {y. ∃u. setsum u s = 1 ∧ setsum (λv. u v *R v) s = y}"
  unfolding affine_hull_explicit and set_eq_iff and mem_Collect_eq
  apply (rule, rule)
  apply (erule exE)+
  apply (erule conjE)+
  defer
  apply (erule exE)
  apply (erule conjE)
proof -
  fix x u
  assume "setsum u s = 1" "(∑v∈s. u v *R v) = x"
  then show "∃sa u. finite sa ∧
      ¬ (∀x. (x ∈ sa) = (x ∈ {})) ∧ sa ⊆ s ∧ setsum u sa = 1 ∧ (∑v∈sa. u v *R v) = x"
    apply (rule_tac x=s in exI, rule_tac x=u in exI)
    using assms
    apply auto
    done
next
  fix x t u
  assume "t ⊆ s"
  then have *: "s ∩ t = t"
    by auto
  assume "finite t" "¬ (∀x. (x ∈ t) = (x ∈ {}))" "setsum u t = 1" "(∑v∈t. u v *R v) = x"
  then show "∃u. setsum u s = 1 ∧ (∑v∈s. u v *R v) = x"
    apply (rule_tac x="λx. if x∈t then u x else 0" in exI)
    unfolding if_smult scaleR_zero_left and setsum.inter_restrict[OF assms, symmetric] and *
    apply auto
    done
qed


subsubsection {* Stepping theorems and hence small special cases *}

lemma affine_hull_empty[simp]: "affine hull {} = {}"
  by (rule hull_unique) auto

lemma affine_hull_finite_step:
  fixes y :: "'a::real_vector"
  shows
    "(∃u. setsum u {} = w ∧ setsum (λx. u x *R x) {} = y) <-> w = 0 ∧ y = 0" (is ?th1)
    and
    "finite s ==>
      (∃u. setsum u (insert a s) = w ∧ setsum (λx. u x *R x) (insert a s) = y) <->
      (∃v u. setsum u s = w - v ∧ setsum (λx. u x *R x) s = y - v *R a)" (is "_ ==> ?lhs = ?rhs")
proof -
  show ?th1 by simp
  assume fin: "finite s"
  show "?lhs = ?rhs"
  proof
    assume ?lhs
    then obtain u where u: "setsum u (insert a s) = w ∧ (∑x∈insert a s. u x *R x) = y"
      by auto
    show ?rhs
    proof (cases "a ∈ s")
      case True
      then have *: "insert a s = s" by auto
      show ?thesis
        using u[unfolded *]
        apply(rule_tac x=0 in exI)
        apply auto
        done
    next
      case False
      then show ?thesis
        apply (rule_tac x="u a" in exI)
        using u and fin
        apply auto
        done
    qed
  next
    assume ?rhs
    then obtain v u where vu: "setsum u s = w - v"  "(∑x∈s. u x *R x) = y - v *R a"
      by auto
    have *: "!!x M. (if x = a then v else M) *R x = (if x = a then v *R x else M *R x)"
      by auto
    show ?lhs
    proof (cases "a ∈ s")
      case True
      then show ?thesis
        apply (rule_tac x="λx. (if x=a then v else 0) + u x" in exI)
        unfolding setsum_clauses(2)[OF fin]
        apply simp
        unfolding scaleR_left_distrib and setsum.distrib
        unfolding vu and * and scaleR_zero_left
        apply (auto simp add: setsum.delta[OF fin])
        done
    next
      case False
      then have **:
        "!!x. x ∈ s ==> u x = (if x = a then v else u x)"
        "!!x. x ∈ s ==> u x *R x = (if x = a then v *R x else u x *R x)" by auto
      from False show ?thesis
        apply (rule_tac x="λx. if x=a then v else u x" in exI)
        unfolding setsum_clauses(2)[OF fin] and * using vu
        using setsum.cong [of s _ "λx. u x *R x" "λx. if x = a then v *R x else u x *R x", OF _ **(2)]
        using setsum.cong [of s _ u "λx. if x = a then v else u x", OF _ **(1)]
        apply auto
        done
    qed
  qed
qed

lemma affine_hull_2:
  fixes a b :: "'a::real_vector"
  shows "affine hull {a,b} = {u *R a + v *R b| u v. (u + v = 1)}"
  (is "?lhs = ?rhs")
proof -
  have *:
    "!!x y z. z = x - y <-> y + z = (x::real)"
    "!!x y z. z = x - y <-> y + z = (x::'a)" by auto
  have "?lhs = {y. ∃u. setsum u {a, b} = 1 ∧ (∑v∈{a, b}. u v *R v) = y}"
    using affine_hull_finite[of "{a,b}"] by auto
  also have "… = {y. ∃v u. u b = 1 - v ∧ u b *R b = y - v *R a}"
    by (simp add: affine_hull_finite_step(2)[of "{b}" a])
  also have "… = ?rhs" unfolding * by auto
  finally show ?thesis by auto
qed

lemma affine_hull_3:
  fixes a b c :: "'a::real_vector"
  shows "affine hull {a,b,c} = { u *R a + v *R b + w *R c| u v w. u + v + w = 1}"
proof -
  have *:
    "!!x y z. z = x - y <-> y + z = (x::real)"
    "!!x y z. z = x - y <-> y + z = (x::'a)" by auto
  show ?thesis
    apply (simp add: affine_hull_finite affine_hull_finite_step)
    unfolding *
    apply auto
    apply (rule_tac x=v in exI)
    apply (rule_tac x=va in exI)
    apply auto
    apply (rule_tac x=u in exI)
    apply force
    done
qed

lemma mem_affine:
  assumes "affine S" "x ∈ S" "y ∈ S" "u + v = 1"
  shows "u *R x + v *R y ∈ S"
  using assms affine_def[of S] by auto

lemma mem_affine_3:
  assumes "affine S" "x ∈ S" "y ∈ S" "z ∈ S" "u + v + w = 1"
  shows "u *R x + v *R y + w *R z ∈ S"
proof -
  have "u *R x + v *R y + w *R z ∈ affine hull {x, y, z}"
    using affine_hull_3[of x y z] assms by auto
  moreover
  have "affine hull {x, y, z} ⊆ affine hull S"
    using hull_mono[of "{x, y, z}" "S"] assms by auto
  moreover
  have "affine hull S = S"
    using assms affine_hull_eq[of S] by auto
  ultimately show ?thesis by auto
qed

lemma mem_affine_3_minus:
  assumes "affine S" "x ∈ S" "y ∈ S" "z ∈ S"
  shows "x + v *R (y-z) ∈ S"
  using mem_affine_3[of S x y z 1 v "-v"] assms
  by (simp add: algebra_simps)


subsubsection {* Some relations between affine hull and subspaces *}

lemma affine_hull_insert_subset_span:
  "affine hull (insert a s) ⊆ {a + v| v . v ∈ span {x - a | x . x ∈ s}}"
  unfolding subset_eq Ball_def
  unfolding affine_hull_explicit span_explicit mem_Collect_eq
  apply (rule, rule)
  apply (erule exE)+
  apply (erule conjE)+
proof -
  fix x t u
  assume as: "finite t" "t ≠ {}" "t ⊆ insert a s" "setsum u t = 1" "(∑v∈t. u v *R v) = x"
  have "(λx. x - a) ` (t - {a}) ⊆ {x - a |x. x ∈ s}"
    using as(3) by auto
  then show "∃v. x = a + v ∧ (∃S u. finite S ∧ S ⊆ {x - a |x. x ∈ s} ∧ (∑v∈S. u v *R v) = v)"
    apply (rule_tac x="x - a" in exI)
    apply (rule conjI, simp)
    apply (rule_tac x="(λx. x - a) ` (t - {a})" in exI)
    apply (rule_tac x="λx. u (x + a)" in exI)
    apply (rule conjI) using as(1) apply simp
    apply (erule conjI)
    using as(1)
    apply (simp add: setsum.reindex[unfolded inj_on_def] scaleR_right_diff_distrib
      setsum_subtractf scaleR_left.setsum[symmetric] setsum_diff1 scaleR_left_diff_distrib)
    unfolding as
    apply simp
    done
qed

lemma affine_hull_insert_span:
  assumes "a ∉ s"
  shows "affine hull (insert a s) = {a + v | v . v ∈ span {x - a | x.  x ∈ s}}"
  apply (rule, rule affine_hull_insert_subset_span)
  unfolding subset_eq Ball_def
  unfolding affine_hull_explicit and mem_Collect_eq
proof (rule, rule, erule exE, erule conjE)
  fix y v
  assume "y = a + v" "v ∈ span {x - a |x. x ∈ s}"
  then obtain t u where obt: "finite t" "t ⊆ {x - a |x. x ∈ s}" "a + (∑v∈t. u v *R v) = y"
    unfolding span_explicit by auto
  def f  "(λx. x + a) ` t"
  have f: "finite f" "f ⊆ s" "(∑v∈f. u (v - a) *R (v - a)) = y - a"
    unfolding f_def using obt by (auto simp add: setsum.reindex[unfolded inj_on_def])
  have *: "f ∩ {a} = {}" "f ∩ - {a} = f"
    using f(2) assms by auto
  show "∃sa u. finite sa ∧ sa ≠ {} ∧ sa ⊆ insert a s ∧ setsum u sa = 1 ∧ (∑v∈sa. u v *R v) = y"
    apply (rule_tac x = "insert a f" in exI)
    apply (rule_tac x = "λx. if x=a then 1 - setsum (λx. u (x - a)) f else u (x - a)" in exI)
    using assms and f
    unfolding setsum_clauses(2)[OF f(1)] and if_smult
    unfolding setsum.If_cases[OF f(1), of "λx. x = a"]
    apply (auto simp add: setsum_subtractf scaleR_left.setsum algebra_simps *)
    done
qed

lemma affine_hull_span:
  assumes "a ∈ s"
  shows "affine hull s = {a + v | v. v ∈ span {x - a | x. x ∈ s - {a}}}"
  using affine_hull_insert_span[of a "s - {a}", unfolded insert_Diff[OF assms]] by auto


subsubsection {* Parallel affine sets *}

definition affine_parallel :: "'a::real_vector set => 'a::real_vector set => bool"
  where "affine_parallel S T <-> (∃a. T = (λx. a + x) ` S)"

lemma affine_parallel_expl_aux:
  fixes S T :: "'a::real_vector set"
  assumes "∀x. x ∈ S <-> a + x ∈ T"
  shows "T = (λx. a + x) ` S"
proof -
  {
    fix x
    assume "x ∈ T"
    then have "( - a) + x ∈ S"
      using assms by auto
    then have "x ∈ ((λx. a + x) ` S)"
      using imageI[of "-a+x" S "(λx. a+x)"] by auto
  }
  moreover have "T ≥ (λx. a + x) ` S"
    using assms by auto
  ultimately show ?thesis by auto
qed

lemma affine_parallel_expl: "affine_parallel S T <-> (∃a. ∀x. x ∈ S <-> a + x ∈ T)"
  unfolding affine_parallel_def
  using affine_parallel_expl_aux[of S _ T] by auto

lemma affine_parallel_reflex: "affine_parallel S S"
  unfolding affine_parallel_def
  apply (rule exI[of _ "0"])
  apply auto
  done

lemma affine_parallel_commut:
  assumes "affine_parallel A B"
  shows "affine_parallel B A"
proof -
  from assms obtain a where B: "B = (λx. a + x) ` A"
    unfolding affine_parallel_def by auto
  have [simp]: "(λx. x - a) = plus (- a)" by (simp add: fun_eq_iff)
  from B show ?thesis
    using translation_galois [of B a A]
    unfolding affine_parallel_def by auto
qed

lemma affine_parallel_assoc:
  assumes "affine_parallel A B"
    and "affine_parallel B C"
  shows "affine_parallel A C"
proof -
  from assms obtain ab where "B = (λx. ab + x) ` A"
    unfolding affine_parallel_def by auto
  moreover
  from assms obtain bc where "C = (λx. bc + x) ` B"
    unfolding affine_parallel_def by auto
  ultimately show ?thesis
    using translation_assoc[of bc ab A] unfolding affine_parallel_def by auto
qed

lemma affine_translation_aux:
  fixes a :: "'a::real_vector"
  assumes "affine ((λx. a + x) ` S)"
  shows "affine S"
proof -
  {
    fix x y u v
    assume xy: "x ∈ S" "y ∈ S" "(u :: real) + v = 1"
    then have "(a + x) ∈ ((λx. a + x) ` S)" "(a + y) ∈ ((λx. a + x) ` S)"
      by auto
    then have h1: "u *R  (a + x) + v *R (a + y) ∈ (λx. a + x) ` S"
      using xy assms unfolding affine_def by auto
    have "u *R (a + x) + v *R (a + y) = (u + v) *R a + (u *R x + v *R y)"
      by (simp add: algebra_simps)
    also have "… = a + (u *R x + v *R y)"
      using `u + v = 1` by auto
    ultimately have "a + (u *R x + v *R y) ∈ (λx. a + x) ` S"
      using h1 by auto
    then have "u *R x + v *R y : S" by auto
  }
  then show ?thesis unfolding affine_def by auto
qed

lemma affine_translation:
  fixes a :: "'a::real_vector"
  shows "affine S <-> affine ((λx. a + x) ` S)"
proof -
  have "affine S ==> affine ((λx. a + x) ` S)"
    using affine_translation_aux[of "-a" "((λx. a + x) ` S)"]
    using translation_assoc[of "-a" a S] by auto
  then show ?thesis using affine_translation_aux by auto
qed

lemma parallel_is_affine:
  fixes S T :: "'a::real_vector set"
  assumes "affine S" "affine_parallel S T"
  shows "affine T"
proof -
  from assms obtain a where "T = (λx. a + x) ` S"
    unfolding affine_parallel_def by auto
  then show ?thesis
    using affine_translation assms by auto
qed

lemma subspace_imp_affine: "subspace s ==> affine s"
  unfolding subspace_def affine_def by auto


subsubsection {* Subspace parallel to an affine set *}

lemma subspace_affine: "subspace S <-> affine S ∧ 0 ∈ S"
proof -
  have h0: "subspace S ==> affine S ∧ 0 ∈ S"
    using subspace_imp_affine[of S] subspace_0 by auto
  {
    assume assm: "affine S ∧ 0 ∈ S"
    {
      fix c :: real
      fix x
      assume x: "x ∈ S"
      have "c *R x = (1-c) *R 0 + c *R x" by auto
      moreover
      have "(1 - c) *R 0 + c *R x ∈ S"
        using affine_alt[of S] assm x by auto
      ultimately have "c *R x ∈ S" by auto
    }
    then have h1: "∀c. ∀x ∈ S. c *R x ∈ S" by auto

    {
      fix x y
      assume xy: "x ∈ S" "y ∈ S"
      def u == "(1 :: real)/2"
      have "(1/2) *R (x+y) = (1/2) *R (x+y)"
        by auto
      moreover
      have "(1/2) *R (x+y)=(1/2) *R x + (1-(1/2)) *R y"
        by (simp add: algebra_simps)
      moreover
      have "(1 - u) *R x + u *R y ∈ S"
        using affine_alt[of S] assm xy by auto
      ultimately
      have "(1/2) *R (x+y) ∈ S"
        using u_def by auto
      moreover
      have "x + y = 2 *R ((1/2) *R (x+y))"
        by auto
      ultimately
      have "x + y ∈ S"
        using h1[rule_format, of "(1/2) *R (x+y)" "2"] by auto
    }
    then have "∀x ∈ S. ∀y ∈ S. x + y ∈ S"
      by auto
    then have "subspace S"
      using h1 assm unfolding subspace_def by auto
  }
  then show ?thesis using h0 by metis
qed

lemma affine_diffs_subspace:
  assumes "affine S" "a ∈ S"
  shows "subspace ((λx. (-a)+x) ` S)"
proof -
  have [simp]: "(λx. x - a) = plus (- a)" by (simp add: fun_eq_iff)
  have "affine ((λx. (-a)+x) ` S)"
    using  affine_translation assms by auto
  moreover have "0 : ((λx. (-a)+x) ` S)"
    using assms exI[of "(λx. x∈S ∧ -a+x = 0)" a] by auto
  ultimately show ?thesis using subspace_affine by auto
qed

lemma parallel_subspace_explicit:
  assumes "affine S"
    and "a ∈ S"
  assumes "L ≡ {y. ∃x ∈ S. (-a) + x = y}"
  shows "subspace L ∧ affine_parallel S L"
proof -
  from assms have "L = plus (- a) ` S" by auto
  then have par: "affine_parallel S L"
    unfolding affine_parallel_def ..
  then have "affine L" using assms parallel_is_affine by auto
  moreover have "0 ∈ L"
    using assms by auto
  ultimately show ?thesis
    using subspace_affine par by auto
qed

lemma parallel_subspace_aux:
  assumes "subspace A"
    and "subspace B"
    and "affine_parallel A B"
  shows "A ⊇ B"
proof -
  from assms obtain a where a: "∀x. x ∈ A <-> a + x ∈ B"
    using affine_parallel_expl[of A B] by auto
  then have "-a ∈ A"
    using assms subspace_0[of B] by auto
  then have "a ∈ A"
    using assms subspace_neg[of A "-a"] by auto
  then show ?thesis
    using assms a unfolding subspace_def by auto
qed

lemma parallel_subspace:
  assumes "subspace A"
    and "subspace B"
    and "affine_parallel A B"
  shows "A = B"
proof
  show "A ⊇ B"
    using assms parallel_subspace_aux by auto
  show "A ⊆ B"
    using assms parallel_subspace_aux[of B A] affine_parallel_commut by auto
qed

lemma affine_parallel_subspace:
  assumes "affine S" "S ≠ {}"
  shows "∃!L. subspace L ∧ affine_parallel S L"
proof -
  have ex: "∃L. subspace L ∧ affine_parallel S L"
    using assms parallel_subspace_explicit by auto
  {
    fix L1 L2
    assume ass: "subspace L1 ∧ affine_parallel S L1" "subspace L2 ∧ affine_parallel S L2"
    then have "affine_parallel L1 L2"
      using affine_parallel_commut[of S L1] affine_parallel_assoc[of L1 S L2] by auto
    then have "L1 = L2"
      using ass parallel_subspace by auto
  }
  then show ?thesis using ex by auto
qed


subsection {* Cones *}

definition cone :: "'a::real_vector set => bool"
  where "cone s <-> (∀x∈s. ∀c≥0. c *R x ∈ s)"

lemma cone_empty[intro, simp]: "cone {}"
  unfolding cone_def by auto

lemma cone_univ[intro, simp]: "cone UNIV"
  unfolding cone_def by auto

lemma cone_Inter[intro]: "∀s∈f. cone s ==> cone (\<Inter>f)"
  unfolding cone_def by auto


subsubsection {* Conic hull *}

lemma cone_cone_hull: "cone (cone hull s)"
  unfolding hull_def by auto

lemma cone_hull_eq: "cone hull s = s <-> cone s"
  apply (rule hull_eq)
  using cone_Inter
  unfolding subset_eq
  apply auto
  done

lemma mem_cone:
  assumes "cone S" "x ∈ S" "c ≥ 0"
  shows "c *R x : S"
  using assms cone_def[of S] by auto

lemma cone_contains_0:
  assumes "cone S"
  shows "S ≠ {} <-> 0 ∈ S"
proof -
  {
    assume "S ≠ {}"
    then obtain a where "a ∈ S" by auto
    then have "0 ∈ S"
      using assms mem_cone[of S a 0] by auto
  }
  then show ?thesis by auto
qed

lemma cone_0: "cone {0}"
  unfolding cone_def by auto

lemma cone_Union[intro]: "(∀s∈f. cone s) --> cone (Union f)"
  unfolding cone_def by blast

lemma cone_iff:
  assumes "S ≠ {}"
  shows "cone S <-> 0 ∈ S ∧ (∀c. c > 0 --> (op *R c) ` S = S)"
proof -
  {
    assume "cone S"
    {
      fix c :: real
      assume "c > 0"
      {
        fix x
        assume "x ∈ S"
        then have "x ∈ (op *R c) ` S"
          unfolding image_def
          using `cone S` `c>0` mem_cone[of S x "1/c"]
            exI[of "(λt. t ∈ S ∧ x = c *R t)" "(1 / c) *R x"]
          by auto
      }
      moreover
      {
        fix x
        assume "x ∈ (op *R c) ` S"
        then have "x ∈ S"
          using `cone S` `c > 0`
          unfolding cone_def image_def `c > 0` by auto
      }
      ultimately have "(op *R c) ` S = S" by auto
    }
    then have "0 ∈ S ∧ (∀c. c > 0 --> (op *R c) ` S = S)"
      using `cone S` cone_contains_0[of S] assms by auto
  }
  moreover
  {
    assume a: "0 ∈ S ∧ (∀c. c > 0 --> (op *R c) ` S = S)"
    {
      fix x
      assume "x ∈ S"
      fix c1 :: real
      assume "c1 ≥ 0"
      then have "c1 = 0 ∨ c1 > 0" by auto
      then have "c1 *R x ∈ S" using a `x ∈ S` by auto
    }
    then have "cone S" unfolding cone_def by auto
  }
  ultimately show ?thesis by blast
qed

lemma cone_hull_empty: "cone hull {} = {}"
  by (metis cone_empty cone_hull_eq)

lemma cone_hull_empty_iff: "S = {} <-> cone hull S = {}"
  by (metis bot_least cone_hull_empty hull_subset xtrans(5))

lemma cone_hull_contains_0: "S ≠ {} <-> 0 ∈ cone hull S"
  using cone_cone_hull[of S] cone_contains_0[of "cone hull S"] cone_hull_empty_iff[of S]
  by auto

lemma mem_cone_hull:
  assumes "x ∈ S" "c ≥ 0"
  shows "c *R x ∈ cone hull S"
  by (metis assms cone_cone_hull hull_inc mem_cone)

lemma cone_hull_expl: "cone hull S = {c *R x | c x. c ≥ 0 ∧ x ∈ S}"
  (is "?lhs = ?rhs")
proof -
  {
    fix x
    assume "x ∈ ?rhs"
    then obtain cx :: real and xx where x: "x = cx *R xx" "cx ≥ 0" "xx ∈ S"
      by auto
    fix c :: real
    assume c: "c ≥ 0"
    then have "c *R x = (c * cx) *R xx"
      using x by (simp add: algebra_simps)
    moreover
    have "c * cx ≥ 0" using c x by auto
    ultimately
    have "c *R x ∈ ?rhs" using x by auto
  }
  then have "cone ?rhs"
    unfolding cone_def by auto
  then have "?rhs ∈ Collect cone"
    unfolding mem_Collect_eq by auto
  {
    fix x
    assume "x ∈ S"
    then have "1 *R x ∈ ?rhs"
      apply auto
      apply (rule_tac x = 1 in exI)
      apply auto
      done
    then have "x ∈ ?rhs" by auto
  }
  then have "S ⊆ ?rhs" by auto
  then have "?lhs ⊆ ?rhs"
    using `?rhs ∈ Collect cone` hull_minimal[of S "?rhs" "cone"] by auto
  moreover
  {
    fix x
    assume "x ∈ ?rhs"
    then obtain cx :: real and xx where x: "x = cx *R xx" "cx ≥ 0" "xx ∈ S"
      by auto
    then have "xx ∈ cone hull S"
      using hull_subset[of S] by auto
    then have "x ∈ ?lhs"
      using x cone_cone_hull[of S] cone_def[of "cone hull S"] by auto
  }
  ultimately show ?thesis by auto
qed

lemma cone_closure:
  fixes S :: "'a::real_normed_vector set"
  assumes "cone S"
  shows "cone (closure S)"
proof (cases "S = {}")
  case True
  then show ?thesis by auto
next
  case False
  then have "0 ∈ S ∧ (∀c. c > 0 --> op *R c ` S = S)"
    using cone_iff[of S] assms by auto
  then have "0 ∈ closure S ∧ (∀c. c > 0 --> op *R c ` closure S = closure S)"
    using closure_subset by (auto simp add: closure_scaleR)
  then show ?thesis
    using cone_iff[of "closure S"] by auto
qed


subsection {* Affine dependence and consequential theorems (from Lars Schewe) *}

definition affine_dependent :: "'a::real_vector set => bool"
  where "affine_dependent s <-> (∃x∈s. x ∈ affine hull (s - {x}))"

lemma affine_dependent_explicit:
  "affine_dependent p <->
    (∃s u. finite s ∧ s ⊆ p ∧ setsum u s = 0 ∧
      (∃v∈s. u v ≠ 0) ∧ setsum (λv. u v *R v) s = 0)"
  unfolding affine_dependent_def affine_hull_explicit mem_Collect_eq
  apply rule
  apply (erule bexE, erule exE, erule exE)
  apply (erule conjE)+
  defer
  apply (erule exE, erule exE)
  apply (erule conjE)+
  apply (erule bexE)
proof -
  fix x s u
  assume as: "x ∈ p" "finite s" "s ≠ {}" "s ⊆ p - {x}" "setsum u s = 1" "(∑v∈s. u v *R v) = x"
  have "x ∉ s" using as(1,4) by auto
  show "∃s u. finite s ∧ s ⊆ p ∧ setsum u s = 0 ∧ (∃v∈s. u v ≠ 0) ∧ (∑v∈s. u v *R v) = 0"
    apply (rule_tac x="insert x s" in exI, rule_tac x="λv. if v = x then - 1 else u v" in exI)
    unfolding if_smult and setsum_clauses(2)[OF as(2)] and setsum_delta_notmem[OF `x∉s`] and as
    using as
    apply auto
    done
next
  fix s u v
  assume as: "finite s" "s ⊆ p" "setsum u s = 0" "(∑v∈s. u v *R v) = 0" "v ∈ s" "u v ≠ 0"
  have "s ≠ {v}"
    using as(3,6) by auto
  then show "∃x∈p. ∃s u. finite s ∧ s ≠ {} ∧ s ⊆ p - {x} ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = x"
    apply (rule_tac x=v in bexI)
    apply (rule_tac x="s - {v}" in exI)
    apply (rule_tac x="λx. - (1 / u v) * u x" in exI)
    unfolding scaleR_scaleR[symmetric] and scaleR_right.setsum [symmetric]
    unfolding setsum_right_distrib[symmetric] and setsum_diff1[OF as(1)]
    using as
    apply auto
    done
qed

lemma affine_dependent_explicit_finite:
  fixes s :: "'a::real_vector set"
  assumes "finite s"
  shows "affine_dependent s <->
    (∃u. setsum u s = 0 ∧ (∃v∈s. u v ≠ 0) ∧ setsum (λv. u v *R v) s = 0)"
  (is "?lhs = ?rhs")
proof
  have *: "!!vt u v. (if vt then u v else 0) *R v = (if vt then (u v) *R v else 0::'a)"
    by auto
  assume ?lhs
  then obtain t u v where
    "finite t" "t ⊆ s" "setsum u t = 0" "v∈t" "u v ≠ 0"  "(∑v∈t. u v *R v) = 0"
    unfolding affine_dependent_explicit by auto
  then show ?rhs
    apply (rule_tac x="λx. if x∈t then u x else 0" in exI)
    apply auto unfolding * and setsum.inter_restrict[OF assms, symmetric]
    unfolding Int_absorb1[OF `t⊆s`]
    apply auto
    done
next
  assume ?rhs
  then obtain u v where "setsum u s = 0"  "v∈s" "u v ≠ 0" "(∑v∈s. u v *R v) = 0"
    by auto
  then show ?lhs unfolding affine_dependent_explicit
    using assms by auto
qed


subsection {* Connectedness of convex sets *}

lemma connectedD:
  "connected S ==> open A ==> open B ==> S ⊆ A ∪ B ==> A ∩ B ∩ S = {} ==> A ∩ S = {} ∨ B ∩ S = {}"
  by (metis connected_def)

lemma convex_connected:
  fixes s :: "'a::real_normed_vector set"
  assumes "convex s"
  shows "connected s"
proof (rule connectedI)
  fix A B
  assume "open A" "open B" "A ∩ B ∩ s = {}" "s ⊆ A ∪ B"
  moreover
  assume "A ∩ s ≠ {}" "B ∩ s ≠ {}"
  then obtain a b where a: "a ∈ A" "a ∈ s" and b: "b ∈ B" "b ∈ s" by auto
  def f  "λu. u *R a + (1 - u) *R b"
  then have "continuous_on {0 .. 1} f"
    by (auto intro!: continuous_intros)
  then have "connected (f ` {0 .. 1})"
    by (auto intro!: connected_continuous_image)
  note connectedD[OF this, of A B]
  moreover have "a ∈ A ∩ f ` {0 .. 1}"
    using a by (auto intro!: image_eqI[of _ _ 1] simp: f_def)
  moreover have "b ∈ B ∩ f ` {0 .. 1}"
    using b by (auto intro!: image_eqI[of _ _ 0] simp: f_def)
  moreover have "f ` {0 .. 1} ⊆ s"
    using `convex s` a b unfolding convex_def f_def by auto
  ultimately show False by auto
qed

text {* One rather trivial consequence. *}

lemma connected_UNIV[intro]: "connected (UNIV :: 'a::real_normed_vector set)"
  by(simp add: convex_connected convex_UNIV)

text {* Balls, being convex, are connected. *}

lemma convex_prod:
  assumes "!!i. i ∈ Basis ==> convex {x. P i x}"
  shows "convex {x. ∀i∈Basis. P i (x•i)}"
  using assms unfolding convex_def
  by (auto simp: inner_add_left)

lemma convex_positive_orthant: "convex {x::'a::euclidean_space. (∀i∈Basis. 0 ≤ x•i)}"
  by (rule convex_prod) (simp add: atLeast_def[symmetric] convex_real_interval)

lemma convex_local_global_minimum:
  fixes s :: "'a::real_normed_vector set"
  assumes "e > 0"
    and "convex_on s f"
    and "ball x e ⊆ s"
    and "∀y∈ball x e. f x ≤ f y"
  shows "∀y∈s. f x ≤ f y"
proof (rule ccontr)
  have "x ∈ s" using assms(1,3) by auto
  assume "¬ ?thesis"
  then obtain y where "y∈s" and y: "f x > f y" by auto
  then have xy: "0 < dist x y"
    by (auto simp add: dist_nz[symmetric])

  then obtain u where "0 < u" "u ≤ 1" and u: "u < e / dist x y"
    using real_lbound_gt_zero[of 1 "e / dist x y"] xy `e>0` by auto
  then have "f ((1-u) *R x + u *R y) ≤ (1-u) * f x + u * f y"
    using `x∈s` `y∈s`
    using assms(2)[unfolded convex_on_def,
      THEN bspec[where x=x], THEN bspec[where x=y], THEN spec[where x="1-u"]]
    by auto
  moreover
  have *: "x - ((1 - u) *R x + u *R y) = u *R (x - y)"
    by (simp add: algebra_simps)
  have "(1 - u) *R x + u *R y ∈ ball x e"
    unfolding mem_ball dist_norm
    unfolding * and norm_scaleR and abs_of_pos[OF `0<u`]
    unfolding dist_norm[symmetric]
    using u
    unfolding pos_less_divide_eq[OF xy]
    by auto
  then have "f x ≤ f ((1 - u) *R x + u *R y)"
    using assms(4) by auto
  ultimately show False
    using mult_strict_left_mono[OF y `u>0`]
    unfolding left_diff_distrib
    by auto
qed

lemma convex_ball:
  fixes x :: "'a::real_normed_vector"
  shows "convex (ball x e)"
proof (auto simp add: convex_def)
  fix y z
  assume yz: "dist x y < e" "dist x z < e"
  fix u v :: real
  assume uv: "0 ≤ u" "0 ≤ v" "u + v = 1"
  have "dist x (u *R y + v *R z) ≤ u * dist x y + v * dist x z"
    using uv yz
    using convex_on_dist [of "ball x e" x, unfolded convex_on_def,
      THEN bspec[where x=y], THEN bspec[where x=z]]
    by auto
  then show "dist x (u *R y + v *R z) < e"
    using convex_bound_lt[OF yz uv] by auto
qed

lemma convex_cball:
  fixes x :: "'a::real_normed_vector"
  shows "convex (cball x e)"
proof -
  {
    fix y z
    assume yz: "dist x y ≤ e" "dist x z ≤ e"
    fix u v :: real
    assume uv: "0 ≤ u" "0 ≤ v" "u + v = 1"
    have "dist x (u *R y + v *R z) ≤ u * dist x y + v * dist x z"
      using uv yz
      using convex_on_dist [of "cball x e" x, unfolded convex_on_def,
        THEN bspec[where x=y], THEN bspec[where x=z]]
      by auto
    then have "dist x (u *R y + v *R z) ≤ e"
      using convex_bound_le[OF yz uv] by auto
  }
  then show ?thesis by (auto simp add: convex_def Ball_def)
qed

lemma connected_ball:
  fixes x :: "'a::real_normed_vector"
  shows "connected (ball x e)"
  using convex_connected convex_ball by auto

lemma connected_cball:
  fixes x :: "'a::real_normed_vector"
  shows "connected (cball x e)"
  using convex_connected convex_cball by auto


subsection {* Convex hull *}

lemma convex_convex_hull: "convex (convex hull s)"
  unfolding hull_def
  using convex_Inter[of "{t. convex t ∧ s ⊆ t}"]
  by auto

lemma convex_hull_eq: "convex hull s = s <-> convex s"
  by (metis convex_convex_hull hull_same)

lemma bounded_convex_hull:
  fixes s :: "'a::real_normed_vector set"
  assumes "bounded s"
  shows "bounded (convex hull s)"
proof -
  from assms obtain B where B: "∀x∈s. norm x ≤ B"
    unfolding bounded_iff by auto
  show ?thesis
    apply (rule bounded_subset[OF bounded_cball, of _ 0 B])
    unfolding subset_hull[of convex, OF convex_cball]
    unfolding subset_eq mem_cball dist_norm using B
    apply auto
    done
qed

lemma finite_imp_bounded_convex_hull:
  fixes s :: "'a::real_normed_vector set"
  shows "finite s ==> bounded (convex hull s)"
  using bounded_convex_hull finite_imp_bounded
  by auto


subsubsection {* Convex hull is "preserved" by a linear function *}

lemma convex_hull_linear_image:
  assumes f: "linear f"
  shows "f ` (convex hull s) = convex hull (f ` s)"
proof
  show "convex hull (f ` s) ⊆ f ` (convex hull s)"
    by (intro hull_minimal image_mono hull_subset convex_linear_image assms convex_convex_hull)
  show "f ` (convex hull s) ⊆ convex hull (f ` s)"
  proof (unfold image_subset_iff_subset_vimage, rule hull_minimal)
    show "s ⊆ f -` (convex hull (f ` s))"
      by (fast intro: hull_inc)
    show "convex (f -` (convex hull (f ` s)))"
      by (intro convex_linear_vimage [OF f] convex_convex_hull)
  qed
qed

lemma in_convex_hull_linear_image:
  assumes "linear f"
    and "x ∈ convex hull s"
  shows "f x ∈ convex hull (f ` s)"
  using convex_hull_linear_image[OF assms(1)] assms(2) by auto

lemma convex_hull_Times:
  "convex hull (s × t) = (convex hull s) × (convex hull t)"
proof
  show "convex hull (s × t) ⊆ (convex hull s) × (convex hull t)"
    by (intro hull_minimal Sigma_mono hull_subset convex_Times convex_convex_hull)
  have "∀x∈convex hull s. ∀y∈convex hull t. (x, y) ∈ convex hull (s × t)"
  proof (intro hull_induct)
    fix x y assume "x ∈ s" and "y ∈ t"
    then show "(x, y) ∈ convex hull (s × t)"
      by (simp add: hull_inc)
  next
    fix x let ?S = "((λy. (0, y)) -` (λp. (- x, 0) + p) ` (convex hull s × t))"
    have "convex ?S"
      by (intro convex_linear_vimage convex_translation convex_convex_hull,
        simp add: linear_iff)
    also have "?S = {y. (x, y) ∈ convex hull (s × t)}"
      by (auto simp add: image_def Bex_def)
    finally show "convex {y. (x, y) ∈ convex hull (s × t)}" .
  next
    show "convex {x. ∀y∈convex hull t. (x, y) ∈ convex hull (s × t)}"
    proof (unfold Collect_ball_eq, rule convex_INT [rule_format])
      fix y let ?S = "((λx. (x, 0)) -` (λp. (0, - y) + p) ` (convex hull s × t))"
      have "convex ?S"
      by (intro convex_linear_vimage convex_translation convex_convex_hull,
        simp add: linear_iff)
      also have "?S = {x. (x, y) ∈ convex hull (s × t)}"
        by (auto simp add: image_def Bex_def)
      finally show "convex {x. (x, y) ∈ convex hull (s × t)}" .
    qed
  qed
  then show "(convex hull s) × (convex hull t) ⊆ convex hull (s × t)"
    unfolding subset_eq split_paired_Ball_Sigma .
qed


subsubsection {* Stepping theorems for convex hulls of finite sets *}

lemma convex_hull_empty[simp]: "convex hull {} = {}"
  by (rule hull_unique) auto

lemma convex_hull_singleton[simp]: "convex hull {a} = {a}"
  by (rule hull_unique) auto

lemma convex_hull_insert:
  fixes s :: "'a::real_vector set"
  assumes "s ≠ {}"
  shows "convex hull (insert a s) =
    {x. ∃u≥0. ∃v≥0. ∃b. (u + v = 1) ∧ b ∈ (convex hull s) ∧ (x = u *R a + v *R b)}"
  (is "_ = ?hull")
  apply (rule, rule hull_minimal, rule)
  unfolding insert_iff
  prefer 3
  apply rule
proof -
  fix x
  assume x: "x = a ∨ x ∈ s"
  then show "x ∈ ?hull"
    apply rule
    unfolding mem_Collect_eq
    apply (rule_tac x=1 in exI)
    defer
    apply (rule_tac x=0 in exI)
    using assms hull_subset[of s convex]
    apply auto
    done
next
  fix x
  assume "x ∈ ?hull"
  then obtain u v b where obt: "u≥0" "v≥0" "u + v = 1" "b ∈ convex hull s" "x = u *R a + v *R b"
    by auto
  have "a ∈ convex hull insert a s" "b ∈ convex hull insert a s"
    using hull_mono[of s "insert a s" convex] hull_mono[of "{a}" "insert a s" convex] and obt(4)
    by auto
  then show "x ∈ convex hull insert a s"
    unfolding obt(5) using obt(1-3)
    by (rule convexD [OF convex_convex_hull])
next
  show "convex ?hull"
  proof (rule convexI)
    fix x y u v
    assume as: "(0::real) ≤ u" "0 ≤ v" "u + v = 1" "x∈?hull" "y∈?hull"
    from as(4) obtain u1 v1 b1 where
      obt1: "u1≥0" "v1≥0" "u1 + v1 = 1" "b1 ∈ convex hull s" "x = u1 *R a + v1 *R b1"
      by auto
    from as(5) obtain u2 v2 b2 where
      obt2: "u2≥0" "v2≥0" "u2 + v2 = 1" "b2 ∈ convex hull s" "y = u2 *R a + v2 *R b2"
      by auto
    have *: "!!(x::'a) s1 s2. x - s1 *R x - s2 *R x = ((1::real) - (s1 + s2)) *R x"
      by (auto simp add: algebra_simps)
    have **: "∃b ∈ convex hull s. u *R x + v *R y =
      (u * u1) *R a + (v * u2) *R a + (b - (u * u1) *R b - (v * u2) *R b)"
    proof (cases "u * v1 + v * v2 = 0")
      case True
      have *: "!!(x::'a) s1 s2. x - s1 *R x - s2 *R x = ((1::real) - (s1 + s2)) *R x"
        by (auto simp add: algebra_simps)
      from True have ***: "u * v1 = 0" "v * v2 = 0"
        using mult_nonneg_nonneg[OF `u≥0` `v1≥0`] mult_nonneg_nonneg[OF `v≥0` `v2≥0`]
        by arith+
      then have "u * u1 + v * u2 = 1"
        using as(3) obt1(3) obt2(3) by auto
      then show ?thesis
        unfolding obt1(5) obt2(5) *
        using assms hull_subset[of s convex]
        by (auto simp add: *** scaleR_right_distrib)
    next
      case False
      have "1 - (u * u1 + v * u2) = (u + v) - (u * u1 + v * u2)"
        using as(3) obt1(3) obt2(3) by (auto simp add: field_simps)
      also have "… = u * (v1 + u1 - u1) + v * (v2 + u2 - u2)"
        using as(3) obt1(3) obt2(3) by (auto simp add: field_simps)
      also have "… = u * v1 + v * v2"
        by simp
      finally have **:"1 - (u * u1 + v * u2) = u * v1 + v * v2" by auto
      have "0 ≤ u * v1 + v * v2" "0 ≤ u * v1" "0 ≤ u * v1 + v * v2" "0 ≤ v * v2"
        using as(1,2) obt1(1,2) obt2(1,2) by auto
      then show ?thesis
        unfolding obt1(5) obt2(5)
        unfolding * and **
        using False
        apply (rule_tac
          x = "((u * v1) / (u * v1 + v * v2)) *R b1 + ((v * v2) / (u * v1 + v * v2)) *R b2" in bexI)
        defer
        apply (rule convexD [OF convex_convex_hull])
        using obt1(4) obt2(4)
        unfolding add_divide_distrib[symmetric] and zero_le_divide_iff
        apply (auto simp add: scaleR_left_distrib scaleR_right_distrib)
        done
    qed
    have u1: "u1 ≤ 1"
      unfolding obt1(3)[symmetric] and not_le using obt1(2) by auto
    have u2: "u2 ≤ 1"
      unfolding obt2(3)[symmetric] and not_le using obt2(2) by auto
    have "u1 * u + u2 * v ≤ max u1 u2 * u + max u1 u2 * v"
      apply (rule add_mono)
      apply (rule_tac [!] mult_right_mono)
      using as(1,2) obt1(1,2) obt2(1,2)
      apply auto
      done
    also have "… ≤ 1"
      unfolding distrib_left[symmetric] and as(3) using u1 u2 by auto
    finally show "u *R x + v *R y ∈ ?hull"
      unfolding mem_Collect_eq
      apply (rule_tac x="u * u1 + v * u2" in exI)
      apply (rule conjI)
      defer
      apply (rule_tac x="1 - u * u1 - v * u2" in exI)
      unfolding Bex_def
      using as(1,2) obt1(1,2) obt2(1,2) **
      apply (auto simp add: algebra_simps)
      done
  qed
qed


subsubsection {* Explicit expression for convex hull *}

lemma convex_hull_indexed:
  fixes s :: "'a::real_vector set"
  shows "convex hull s =
    {y. ∃k u x.
      (∀i∈{1::nat .. k}. 0 ≤ u i ∧ x i ∈ s) ∧
      (setsum u {1..k} = 1) ∧ (setsum (λi. u i *R x i) {1..k} = y)}"
  (is "?xyz = ?hull")
  apply (rule hull_unique)
  apply rule
  defer
  apply (rule convexI)
proof -
  fix x
  assume "x∈s"
  then show "x ∈ ?hull"
    unfolding mem_Collect_eq
    apply (rule_tac x=1 in exI, rule_tac x="λx. 1" in exI)
    apply auto
    done
next
  fix t
  assume as: "s ⊆ t" "convex t"
  show "?hull ⊆ t"
    apply rule
    unfolding mem_Collect_eq
    apply (elim exE conjE)
  proof -
    fix x k u y
    assume assm:
      "∀i∈{1::nat..k}. 0 ≤ u i ∧ y i ∈ s"
      "setsum u {1..k} = 1" "(∑i = 1..k. u i *R y i) = x"
    show "x∈t"
      unfolding assm(3) [symmetric]
      apply (rule as(2)[unfolded convex, rule_format])
      using assm(1,2) as(1) apply auto
      done
  qed
next
  fix x y u v
  assume uv: "0 ≤ u" "0 ≤ v" "u + v = (1::real)"
  assume xy: "x ∈ ?hull" "y ∈ ?hull"
  from xy obtain k1 u1 x1 where
    x: "∀i∈{1::nat..k1}. 0≤u1 i ∧ x1 i ∈ s" "setsum u1 {Suc 0..k1} = 1" "(∑i = Suc 0..k1. u1 i *R x1 i) = x"
    by auto
  from xy obtain k2 u2 x2 where
    y: "∀i∈{1::nat..k2}. 0≤u2 i ∧ x2 i ∈ s" "setsum u2 {Suc 0..k2} = 1" "(∑i = Suc 0..k2. u2 i *R x2 i) = y"
    by auto
  have *: "!!P (x1::'a) x2 s1 s2 i.
    (if P i then s1 else s2) *R (if P i then x1 else x2) = (if P i then s1 *R x1 else s2 *R x2)"
    "{1..k1 + k2} ∩ {1..k1} = {1..k1}" "{1..k1 + k2} ∩ - {1..k1} = (λi. i + k1) ` {1..k2}"
    prefer 3
    apply (rule, rule)
    unfolding image_iff
    apply (rule_tac x = "x - k1" in bexI)
    apply (auto simp add: not_le)
    done
  have inj: "inj_on (λi. i + k1) {1..k2}"
    unfolding inj_on_def by auto
  show "u *R x + v *R y ∈ ?hull"
    apply rule
    apply (rule_tac x="k1 + k2" in exI)
    apply (rule_tac x="λi. if i ∈ {1..k1} then u * u1 i else v * u2 (i - k1)" in exI)
    apply (rule_tac x="λi. if i ∈ {1..k1} then x1 i else x2 (i - k1)" in exI)
    apply (rule, rule)
    defer
    apply rule
    unfolding * and setsum.If_cases[OF finite_atLeastAtMost[of 1 "k1 + k2"]] and
      setsum.reindex[OF inj] and o_def Collect_mem_eq
    unfolding scaleR_scaleR[symmetric] scaleR_right.setsum [symmetric] setsum_right_distrib[symmetric]
  proof -
    fix i
    assume i: "i ∈ {1..k1+k2}"
    show "0 ≤ (if i ∈ {1..k1} then u * u1 i else v * u2 (i - k1)) ∧
      (if i ∈ {1..k1} then x1 i else x2 (i - k1)) ∈ s"
    proof (cases "i∈{1..k1}")
      case True
      then show ?thesis
        using uv(1) x(1)[THEN bspec[where x=i]] by auto
    next
      case False
      def j  "i - k1"
      from i False have "j ∈ {1..k2}"
        unfolding j_def by auto
      then show ?thesis
        using False uv(2) y(1)[THEN bspec[where x=j]]
        by (auto simp: j_def[symmetric])
    qed
  qed (auto simp add: not_le x(2,3) y(2,3) uv(3))
qed

lemma convex_hull_finite:
  fixes s :: "'a::real_vector set"
  assumes "finite s"
  shows "convex hull s = {y. ∃u. (∀x∈s. 0 ≤ u x) ∧
    setsum u s = 1 ∧ setsum (λx. u x *R x) s = y}"
  (is "?HULL = ?set")
proof (rule hull_unique, auto simp add: convex_def[of ?set])
  fix x
  assume "x ∈ s"
  then show "∃u. (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ (∑x∈s. u x *R x) = x"
    apply (rule_tac x="λy. if x=y then 1 else 0" in exI)
    apply auto
    unfolding setsum.delta'[OF assms] and setsum_delta''[OF assms]
    apply auto
    done
next
  fix u v :: real
  assume uv: "0 ≤ u" "0 ≤ v" "u + v = 1"
  fix ux assume ux: "∀x∈s. 0 ≤ ux x" "setsum ux s = (1::real)"
  fix uy assume uy: "∀x∈s. 0 ≤ uy x" "setsum uy s = (1::real)"
  {
    fix x
    assume "x∈s"
    then have "0 ≤ u * ux x + v * uy x"
      using ux(1)[THEN bspec[where x=x]] uy(1)[THEN bspec[where x=x]] and uv(1,2)
      by auto
  }
  moreover
  have "(∑x∈s. u * ux x + v * uy x) = 1"
    unfolding setsum.distrib and setsum_right_distrib[symmetric] and ux(2) uy(2)
    using uv(3) by auto
  moreover
  have "(∑x∈s. (u * ux x + v * uy x) *R x) = u *R (∑x∈s. ux x *R x) + v *R (∑x∈s. uy x *R x)"
    unfolding scaleR_left_distrib and setsum.distrib and scaleR_scaleR[symmetric]
      and scaleR_right.setsum [symmetric]
    by auto
  ultimately
  show "∃uc. (∀x∈s. 0 ≤ uc x) ∧ setsum uc s = 1 ∧
      (∑x∈s. uc x *R x) = u *R (∑x∈s. ux x *R x) + v *R (∑x∈s. uy x *R x)"
    apply (rule_tac x="λx. u * ux x + v * uy x" in exI)
    apply auto
    done
next
  fix t
  assume t: "s ⊆ t" "convex t"
  fix u
  assume u: "∀x∈s. 0 ≤ u x" "setsum u s = (1::real)"
  then show "(∑x∈s. u x *R x) ∈ t"
    using t(2)[unfolded convex_explicit, THEN spec[where x=s], THEN spec[where x=u]]
    using assms and t(1) by auto
qed


subsubsection {* Another formulation from Lars Schewe *}

lemma setsum_constant_scaleR:
  fixes y :: "'a::real_vector"
  shows "(∑x∈A. y) = of_nat (card A) *R y"
  apply (cases "finite A")
  apply (induct set: finite)
  apply (simp_all add: algebra_simps)
  done

lemma convex_hull_explicit:
  fixes p :: "'a::real_vector set"
  shows "convex hull p =
    {y. ∃s u. finite s ∧ s ⊆ p ∧ (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ setsum (λv. u v *R v) s = y}"
  (is "?lhs = ?rhs")
proof -
  {
    fix x
    assume "x∈?lhs"
    then obtain k u y where
        obt: "∀i∈{1::nat..k}. 0 ≤ u i ∧ y i ∈ p" "setsum u {1..k} = 1" "(∑i = 1..k. u i *R y i) = x"
      unfolding convex_hull_indexed by auto

    have fin: "finite {1..k}" by auto
    have fin': "!!v. finite {i ∈ {1..k}. y i = v}" by auto
    {
      fix j
      assume "j∈{1..k}"
      then have "y j ∈ p" "0 ≤ setsum u {i. Suc 0 ≤ i ∧ i ≤ k ∧ y i = y j}"
        using obt(1)[THEN bspec[where x=j]] and obt(2)
        apply simp
        apply (rule setsum_nonneg)
        using obt(1)
        apply auto
        done
    }
    moreover
    have "(∑v∈y ` {1..k}. setsum u {i ∈ {1..k}. y i = v}) = 1"
      unfolding setsum_image_gen[OF fin, symmetric] using obt(2) by auto
    moreover have "(∑v∈y ` {1..k}. setsum u {i ∈ {1..k}. y i = v} *R v) = x"
      using setsum_image_gen[OF fin, of "λi. u i *R y i" y, symmetric]
      unfolding scaleR_left.setsum using obt(3) by auto
    ultimately
    have "∃s u. finite s ∧ s ⊆ p ∧ (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = x"
      apply (rule_tac x="y ` {1..k}" in exI)
      apply (rule_tac x="λv. setsum u {i∈{1..k}. y i = v}" in exI)
      apply auto
      done
    then have "x∈?rhs" by auto
  }
  moreover
  {
    fix y
    assume "y∈?rhs"
    then obtain s u where
      obt: "finite s" "s ⊆ p" "∀x∈s. 0 ≤ u x" "setsum u s = 1" "(∑v∈s. u v *R v) = y"
      by auto

    obtain f where f: "inj_on f {1..card s}" "f ` {1..card s} = s"
      using ex_bij_betw_nat_finite_1[OF obt(1)] unfolding bij_betw_def by auto

    {
      fix i :: nat
      assume "i∈{1..card s}"
      then have "f i ∈ s"
        apply (subst f(2)[symmetric])
        apply auto
        done
      then have "0 ≤ u (f i)" "f i ∈ p" using obt(2,3) by auto
    }
    moreover have *: "finite {1..card s}" by auto
    {
      fix y
      assume "y∈s"
      then obtain i where "i∈{1..card s}" "f i = y"
        using f using image_iff[of y f "{1..card s}"]
        by auto
      then have "{x. Suc 0 ≤ x ∧ x ≤ card s ∧ f x = y} = {i}"
        apply auto
        using f(1)[unfolded inj_on_def]
        apply(erule_tac x=x in ballE)
        apply auto
        done
      then have "card {x. Suc 0 ≤ x ∧ x ≤ card s ∧ f x = y} = 1" by auto
      then have "(∑x∈{x ∈ {1..card s}. f x = y}. u (f x)) = u y"
          "(∑x∈{x ∈ {1..card s}. f x = y}. u (f x) *R f x) = u y *R y"
        by (auto simp add: setsum_constant_scaleR)
    }
    then have "(∑x = 1..card s. u (f x)) = 1" "(∑i = 1..card s. u (f i) *R f i) = y"
      unfolding setsum_image_gen[OF *(1), of "λx. u (f x) *R f x" f]
        and setsum_image_gen[OF *(1), of "λx. u (f x)" f]
      unfolding f
      using setsum.cong [of s s "λy. (∑x∈{x ∈ {1..card s}. f x = y}. u (f x) *R f x)" "λv. u v *R v"]
      using setsum.cong [of s s "λy. (∑x∈{x ∈ {1..card s}. f x = y}. u (f x))" u]
      unfolding obt(4,5)
      by auto
    ultimately
    have "∃k u x. (∀i∈{1..k}. 0 ≤ u i ∧ x i ∈ p) ∧ setsum u {1..k} = 1 ∧
        (∑i::nat = 1..k. u i *R x i) = y"
      apply (rule_tac x="card s" in exI)
      apply (rule_tac x="u o f" in exI)
      apply (rule_tac x=f in exI)
      apply fastforce
      done
    then have "y ∈ ?lhs"
      unfolding convex_hull_indexed by auto
  }
  ultimately show ?thesis
    unfolding set_eq_iff by blast
qed


subsubsection {* A stepping theorem for that expansion *}

lemma convex_hull_finite_step:
  fixes s :: "'a::real_vector set"
  assumes "finite s"
  shows
    "(∃u. (∀x∈insert a s. 0 ≤ u x) ∧ setsum u (insert a s) = w ∧ setsum (λx. u x *R x) (insert a s) = y)
      <-> (∃v≥0. ∃u. (∀x∈s. 0 ≤ u x) ∧ setsum u s = w - v ∧ setsum (λx. u x *R x) s = y - v *R a)"
  (is "?lhs = ?rhs")
proof (rule, case_tac[!] "a∈s")
  assume "a ∈ s"
  then have *: "insert a s = s" by auto
  assume ?lhs
  then show ?rhs
    unfolding *
    apply (rule_tac x=0 in exI)
    apply auto
    done
next
  assume ?lhs
  then obtain u where
      u: "∀x∈insert a s. 0 ≤ u x" "setsum u (insert a s) = w" "(∑x∈insert a s. u x *R x) = y"
    by auto
  assume "a ∉ s"
  then show ?rhs
    apply (rule_tac x="u a" in exI)
    using u(1)[THEN bspec[where x=a]]
    apply simp
    apply (rule_tac x=u in exI)
    using u[unfolded setsum_clauses(2)[OF assms]] and `a∉s`
    apply auto
    done
next
  assume "a ∈ s"
  then have *: "insert a s = s" by auto
  have fin: "finite (insert a s)" using assms by auto
  assume ?rhs
  then obtain v u where uv: "v≥0" "∀x∈s. 0 ≤ u x" "setsum u s = w - v" "(∑x∈s. u x *R x) = y - v *R a"
    by auto
  show ?lhs
    apply (rule_tac x = "λx. (if a = x then v else 0) + u x" in exI)
    unfolding scaleR_left_distrib and setsum.distrib and setsum_delta''[OF fin] and setsum.delta'[OF fin]
    unfolding setsum_clauses(2)[OF assms]
    using uv and uv(2)[THEN bspec[where x=a]] and `a∈s`
    apply auto
    done
next
  assume ?rhs
  then obtain v u where
    uv: "v≥0" "∀x∈s. 0 ≤ u x" "setsum u s = w - v" "(∑x∈s. u x *R x) = y - v *R a"
    by auto
  moreover
  assume "a ∉ s"
  moreover
  have "(∑x∈s. if a = x then v else u x) = setsum u s"
    and "(∑x∈s. (if a = x then v else u x) *R x) = (∑x∈s. u x *R x)"
    apply (rule_tac setsum.cong) apply rule
    defer
    apply (rule_tac setsum.cong) apply rule
    using `a ∉ s`
    apply auto
    done
  ultimately show ?lhs
    apply (rule_tac x="λx. if a = x then v else u x" in exI)
    unfolding setsum_clauses(2)[OF assms]
    apply auto
    done
qed


subsubsection {* Hence some special cases *}

lemma convex_hull_2:
  "convex hull {a,b} = {u *R a + v *R b | u v. 0 ≤ u ∧ 0 ≤ v ∧ u + v = 1}"
proof -
  have *: "!!u. (∀x∈{a, b}. 0 ≤ u x) <-> 0 ≤ u a ∧ 0 ≤ u b"
    by auto
  have **: "finite {b}" by auto
  show ?thesis
    apply (simp add: convex_hull_finite)
    unfolding convex_hull_finite_step[OF **, of a 1, unfolded * conj_assoc]
    apply auto
    apply (rule_tac x=v in exI)
    apply (rule_tac x="1 - v" in exI)
    apply simp
    apply (rule_tac x=u in exI)
    apply simp
    apply (rule_tac x="λx. v" in exI)
    apply simp
    done
qed

lemma convex_hull_2_alt: "convex hull {a,b} = {a + u *R (b - a) | u.  0 ≤ u ∧ u ≤ 1}"
  unfolding convex_hull_2
proof (rule Collect_cong)
  have *: "!!x y ::real. x + y = 1 <-> x = 1 - y"
    by auto
  fix x
  show "(∃v u. x = v *R a + u *R b ∧ 0 ≤ v ∧ 0 ≤ u ∧ v + u = 1) <->
    (∃u. x = a + u *R (b - a) ∧ 0 ≤ u ∧ u ≤ 1)"
    unfolding *
    apply auto
    apply (rule_tac[!] x=u in exI)
    apply (auto simp add: algebra_simps)
    done
qed

lemma convex_hull_3:
  "convex hull {a,b,c} = { u *R a + v *R b + w *R c | u v w. 0 ≤ u ∧ 0 ≤ v ∧ 0 ≤ w ∧ u + v + w = 1}"
proof -
  have fin: "finite {a,b,c}" "finite {b,c}" "finite {c}"
    by auto
  have *: "!!x y z ::real. x + y + z = 1 <-> x = 1 - y - z"
    by (auto simp add: field_simps)
  show ?thesis
    unfolding convex_hull_finite[OF fin(1)] and convex_hull_finite_step[OF fin(2)] and *
    unfolding convex_hull_finite_step[OF fin(3)]
    apply (rule Collect_cong)
    apply simp
    apply auto
    apply (rule_tac x=va in exI)
    apply (rule_tac x="u c" in exI)
    apply simp
    apply (rule_tac x="1 - v - w" in exI)
    apply simp
    apply (rule_tac x=v in exI)
    apply simp
    apply (rule_tac x="λx. w" in exI)
    apply simp
    done
qed

lemma convex_hull_3_alt:
  "convex hull {a,b,c} = {a + u *R (b - a) + v *R (c - a) | u v.  0 ≤ u ∧ 0 ≤ v ∧ u + v ≤ 1}"
proof -
  have *: "!!x y z ::real. x + y + z = 1 <-> x = 1 - y - z"
    by auto
  show ?thesis
    unfolding convex_hull_3
    apply (auto simp add: *)
    apply (rule_tac x=v in exI)
    apply (rule_tac x=w in exI)
    apply (simp add: algebra_simps)
    apply (rule_tac x=u in exI)
    apply (rule_tac x=v in exI)
    apply (simp add: algebra_simps)
    done
qed


subsection {* Relations among closure notions and corresponding hulls *}

lemma affine_imp_convex: "affine s ==> convex s"
  unfolding affine_def convex_def by auto

lemma subspace_imp_convex: "subspace s ==> convex s"
  using subspace_imp_affine affine_imp_convex by auto

lemma affine_hull_subset_span: "(affine hull s) ⊆ (span s)"
  by (metis hull_minimal span_inc subspace_imp_affine subspace_span)

lemma convex_hull_subset_span: "(convex hull s) ⊆ (span s)"
  by (metis hull_minimal span_inc subspace_imp_convex subspace_span)

lemma convex_hull_subset_affine_hull: "(convex hull s) ⊆ (affine hull s)"
  by (metis affine_affine_hull affine_imp_convex hull_minimal hull_subset)


lemma affine_dependent_imp_dependent: "affine_dependent s ==> dependent s"
  unfolding affine_dependent_def dependent_def
  using affine_hull_subset_span by auto

lemma dependent_imp_affine_dependent:
  assumes "dependent {x - a| x . x ∈ s}"
    and "a ∉ s"
  shows "affine_dependent (insert a s)"
proof -
  from assms(1)[unfolded dependent_explicit] obtain S u v
    where obt: "finite S" "S ⊆ {x - a |x. x ∈ s}" "v∈S" "u v  ≠ 0" "(∑v∈S. u v *R v) = 0"
    by auto
  def t  "(λx. x + a) ` S"

  have inj: "inj_on (λx. x + a) S"
    unfolding inj_on_def by auto
  have "0 ∉ S"
    using obt(2) assms(2) unfolding subset_eq by auto
  have fin: "finite t" and "t ⊆ s"
    unfolding t_def using obt(1,2) by auto
  then have "finite (insert a t)" and "insert a t ⊆ insert a s"
    by auto
  moreover have *: "!!P Q. (∑x∈t. (if x = a then P x else Q x)) = (∑x∈t. Q x)"
    apply (rule setsum.cong)
    using `a∉s` `t⊆s`
    apply auto
    done
  have "(∑x∈insert a t. if x = a then - (∑x∈t. u (x - a)) else u (x - a)) = 0"
    unfolding setsum_clauses(2)[OF fin]
    using `a∉s` `t⊆s`
    apply auto
    unfolding *
    apply auto
    done
  moreover have "∃v∈insert a t. (if v = a then - (∑x∈t. u (x - a)) else u (v - a)) ≠ 0"
    apply (rule_tac x="v + a" in bexI)
    using obt(3,4) and `0∉S`
    unfolding t_def
    apply auto
    done
  moreover have *: "!!P Q. (∑x∈t. (if x = a then P x else Q x) *R x) = (∑x∈t. Q x *R x)"
    apply (rule setsum.cong)
    using `a∉s` `t⊆s`
    apply auto
    done
  have "(∑x∈t. u (x - a)) *R a = (∑v∈t. u (v - a) *R v)"
    unfolding scaleR_left.setsum
    unfolding t_def and setsum.reindex[OF inj] and o_def
    using obt(5)
    by (auto simp add: setsum.distrib scaleR_right_distrib)
  then have "(∑v∈insert a t. (if v = a then - (∑x∈t. u (x - a)) else u (v - a)) *R v) = 0"
    unfolding setsum_clauses(2)[OF fin]
    using `a∉s` `t⊆s`
    by (auto simp add: *)
  ultimately show ?thesis
    unfolding affine_dependent_explicit
    apply (rule_tac x="insert a t" in exI)
    apply auto
    done
qed

lemma convex_cone:
  "convex s ∧ cone s <-> (∀x∈s. ∀y∈s. (x + y) ∈ s) ∧ (∀x∈s. ∀c≥0. (c *R x) ∈ s)"
  (is "?lhs = ?rhs")
proof -
  {
    fix x y
    assume "x∈s" "y∈s" and ?lhs
    then have "2 *R x ∈s" "2 *R y ∈ s"
      unfolding cone_def by auto
    then have "x + y ∈ s"
      using `?lhs`[unfolded convex_def, THEN conjunct1]
      apply (erule_tac x="2*R x" in ballE)
      apply (erule_tac x="2*R y" in ballE)
      apply (erule_tac x="1/2" in allE)
      apply simp
      apply (erule_tac x="1/2" in allE)
      apply auto
      done
  }
  then show ?thesis
    unfolding convex_def cone_def by blast
qed

lemma affine_dependent_biggerset:
  fixes s :: "'a::euclidean_space set"
  assumes "finite s" "card s ≥ DIM('a) + 2"
  shows "affine_dependent s"
proof -
  have "s ≠ {}" using assms by auto
  then obtain a where "a∈s" by auto
  have *: "{x - a |x. x ∈ s - {a}} = (λx. x - a) ` (s - {a})"
    by auto
  have "card {x - a |x. x ∈ s - {a}} = card (s - {a})"
    unfolding *
    apply (rule card_image)
    unfolding inj_on_def
    apply auto
    done
  also have "… > DIM('a)" using assms(2)
    unfolding card_Diff_singleton[OF assms(1) `a∈s`] by auto
  finally show ?thesis
    apply (subst insert_Diff[OF `a∈s`, symmetric])
    apply (rule dependent_imp_affine_dependent)
    apply (rule dependent_biggerset)
    apply auto
    done
qed

lemma affine_dependent_biggerset_general:
  assumes "finite (s :: 'a::euclidean_space set)"
    and "card s ≥ dim s + 2"
  shows "affine_dependent s"
proof -
  from assms(2) have "s ≠ {}" by auto
  then obtain a where "a∈s" by auto
  have *: "{x - a |x. x ∈ s - {a}} = (λx. x - a) ` (s - {a})"
    by auto
  have **: "card {x - a |x. x ∈ s - {a}} = card (s - {a})"
    unfolding *
    apply (rule card_image)
    unfolding inj_on_def
    apply auto
    done
  have "dim {x - a |x. x ∈ s - {a}} ≤ dim s"
    apply (rule subset_le_dim)
    unfolding subset_eq
    using `a∈s`
    apply (auto simp add:span_superset span_sub)
    done
  also have "… < dim s + 1" by auto
  also have "… ≤ card (s - {a})"
    using assms
    using card_Diff_singleton[OF assms(1) `a∈s`]
    by auto
  finally show ?thesis
    apply (subst insert_Diff[OF `a∈s`, symmetric])
    apply (rule dependent_imp_affine_dependent)
    apply (rule dependent_biggerset_general)
    unfolding **
    apply auto
    done
qed


subsection {* Caratheodory's theorem. *}

lemma convex_hull_caratheodory:
  fixes p :: "('a::euclidean_space) set"
  shows "convex hull p =
    {y. ∃s u. finite s ∧ s ⊆ p ∧ card s ≤ DIM('a) + 1 ∧
      (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ setsum (λv. u v *R v) s = y}"
  unfolding convex_hull_explicit set_eq_iff mem_Collect_eq
proof (rule, rule)
  fix y
  let ?P = "λn. ∃s u. finite s ∧ card s = n ∧ s ⊆ p ∧ (∀x∈s. 0 ≤ u x) ∧
    setsum u s = 1 ∧ (∑v∈s. u v *R v) = y"
  assume "∃s u. finite s ∧ s ⊆ p ∧ (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = y"
  then obtain N where "?P N" by auto
  then have "∃n≤N. (∀k<n. ¬ ?P k) ∧ ?P n"
    apply (rule_tac ex_least_nat_le)
    apply auto
    done
  then obtain n where "?P n" and smallest: "∀k<n. ¬ ?P k"
    by blast
  then obtain s u where obt: "finite s" "card s = n" "s⊆p" "∀x∈s. 0 ≤ u x"
    "setsum u s = 1"  "(∑v∈s. u v *R v) = y" by auto

  have "card s ≤ DIM('a) + 1"
  proof (rule ccontr, simp only: not_le)
    assume "DIM('a) + 1 < card s"
    then have "affine_dependent s"
      using affine_dependent_biggerset[OF obt(1)] by auto
    then obtain w v where wv: "setsum w s = 0" "v∈s" "w v ≠ 0" "(∑v∈s. w v *R v) = 0"
      using affine_dependent_explicit_finite[OF obt(1)] by auto
    def i  "(λv. (u v) / (- w v)) ` {v∈s. w v < 0}"
    def t  "Min i"
    have "∃x∈s. w x < 0"
    proof (rule ccontr, simp add: not_less)
      assume as:"∀x∈s. 0 ≤ w x"
      then have "setsum w (s - {v}) ≥ 0"
        apply (rule_tac setsum_nonneg)
        apply auto
        done
      then have "setsum w s > 0"
        unfolding setsum.remove[OF obt(1) `v∈s`]
        using as[THEN bspec[where x=v]] and `v∈s`
        using `w v ≠ 0`
        by auto
      then show False using wv(1) by auto
    qed
    then have "i ≠ {}" unfolding i_def by auto

    then have "t ≥ 0"
      using Min_ge_iff[of i 0 ] and obt(1)
      unfolding t_def i_def
      using obt(4)[unfolded le_less]
      by (auto simp: divide_le_0_iff)
    have t: "∀v∈s. u v + t * w v ≥ 0"
    proof
      fix v
      assume "v ∈ s"
      then have v: "0 ≤ u v"
        using obt(4)[THEN bspec[where x=v]] by auto
      show "0 ≤ u v + t * w v"
      proof (cases "w v < 0")
        case False
        thus ?thesis using v `t≥0` by auto
      next
        case True
        then have "t ≤ u v / (- w v)"
          using `v∈s`
          unfolding t_def i_def
          apply (rule_tac Min_le)
          using obt(1)
          apply auto
          done
        then show ?thesis
          unfolding real_0_le_add_iff
          using pos_le_divide_eq[OF True[unfolded neg_0_less_iff_less[symmetric]]]
          by auto
      qed
    qed

    obtain a where "a ∈ s" and "t = (λv. (u v) / (- w v)) a" and "w a < 0"
      using Min_in[OF _ `i≠{}`] and obt(1) unfolding i_def t_def by auto
    then have a: "a ∈ s" "u a + t * w a = 0" by auto
    have *: "!!f. setsum f (s - {a}) = setsum f s - ((f a)::'b::ab_group_add)"
      unfolding setsum.remove[OF obt(1) `a∈s`] by auto
    have "(∑v∈s. u v + t * w v) = 1"
      unfolding setsum.distrib wv(1) setsum_right_distrib[symmetric] obt(5) by auto
    moreover have "(∑v∈s. u v *R v + (t * w v) *R v) - (u a *R a + (t * w a) *R a) = y"
      unfolding setsum.distrib obt(6) scaleR_scaleR[symmetric] scaleR_right.setsum [symmetric] wv(4)
      using a(2) [THEN eq_neg_iff_add_eq_0 [THEN iffD2]] by simp
    ultimately have "?P (n - 1)"
      apply (rule_tac x="(s - {a})" in exI)
      apply (rule_tac x="λv. u v + t * w v" in exI)
      using obt(1-3) and t and a
      apply (auto simp add: * scaleR_left_distrib)
      done
    then show False
      using smallest[THEN spec[where x="n - 1"]] by auto
  qed
  then show "∃s u. finite s ∧ s ⊆ p ∧ card s ≤ DIM('a) + 1 ∧
      (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = y"
    using obt by auto
qed auto

lemma caratheodory:
  "convex hull p =
    {x::'a::euclidean_space. ∃s. finite s ∧ s ⊆ p ∧
      card s ≤ DIM('a) + 1 ∧ x ∈ convex hull s}"
  unfolding set_eq_iff
  apply rule
  apply rule
  unfolding mem_Collect_eq
proof -
  fix x
  assume "x ∈ convex hull p"
  then obtain s u where "finite s" "s ⊆ p" "card s ≤ DIM('a) + 1"
    "∀x∈s. 0 ≤ u x" "setsum u s = 1" "(∑v∈s. u v *R v) = x"
    unfolding convex_hull_caratheodory by auto
  then show "∃s. finite s ∧ s ⊆ p ∧ card s ≤ DIM('a) + 1 ∧ x ∈ convex hull s"
    apply (rule_tac x=s in exI)
    using hull_subset[of s convex]
    using convex_convex_hull[unfolded convex_explicit, of s,
      THEN spec[where x=s], THEN spec[where x=u]]
    apply auto
    done
next
  fix x
  assume "∃s. finite s ∧ s ⊆ p ∧ card s ≤ DIM('a) + 1 ∧ x ∈ convex hull s"
  then obtain s where "finite s" "s ⊆ p" "card s ≤ DIM('a) + 1" "x ∈ convex hull s"
    by auto
  then show "x ∈ convex hull p"
    using hull_mono[OF `s⊆p`] by auto
qed


subsection {* Some Properties of Affine Dependent Sets *}

lemma affine_independent_empty: "¬ affine_dependent {}"
  by (simp add: affine_dependent_def)

lemma affine_independent_sing: "¬ affine_dependent {a}"
  by (simp add: affine_dependent_def)

lemma affine_hull_translation: "affine hull ((λx. a + x) `  S) = (λx. a + x) ` (affine hull S)"
proof -
  have "affine ((λx. a + x) ` (affine hull S))"
    using affine_translation affine_affine_hull by auto
  moreover have "(λx. a + x) `  S ⊆ (λx. a + x) ` (affine hull S)"
    using hull_subset[of S] by auto
  ultimately have h1: "affine hull ((λx. a + x) `  S) ⊆ (λx. a + x) ` (affine hull S)"
    by (metis hull_minimal)
  have "affine((λx. -a + x) ` (affine hull ((λx. a + x) `  S)))"
    using affine_translation affine_affine_hull by (auto simp del: uminus_add_conv_diff)
  moreover have "(λx. -a + x) ` (λx. a + x) `  S ⊆ (λx. -a + x) ` (affine hull ((λx. a + x) `  S))"
    using hull_subset[of "(λx. a + x) `  S"] by auto
  moreover have "S = (λx. -a + x) ` (λx. a + x) `  S"
    using translation_assoc[of "-a" a] by auto
  ultimately have "(λx. -a + x) ` (affine hull ((λx. a + x) `  S)) >= (affine hull S)"
    by (metis hull_minimal)
  then have "affine hull ((λx. a + x) ` S) >= (λx. a + x) ` (affine hull S)"
    by auto
  then show ?thesis using h1 by auto
qed

lemma affine_dependent_translation:
  assumes "affine_dependent S"
  shows "affine_dependent ((λx. a + x) ` S)"
proof -
  obtain x where x: "x ∈ S ∧ x ∈ affine hull (S - {x})"
    using assms affine_dependent_def by auto
  have "op + a ` (S - {x}) = op + a ` S - {a + x}"
    by auto
  then have "a + x ∈ affine hull ((λx. a + x) ` S - {a + x})"
    using affine_hull_translation[of a "S - {x}"] x by auto
  moreover have "a + x ∈ (λx. a + x) ` S"
    using x by auto
  ultimately show ?thesis
    unfolding affine_dependent_def by auto
qed

lemma affine_dependent_translation_eq:
  "affine_dependent S <-> affine_dependent ((λx. a + x) ` S)"
proof -
  {
    assume "affine_dependent ((λx. a + x) ` S)"
    then have "affine_dependent S"
      using affine_dependent_translation[of "((λx. a + x) ` S)" "-a"] translation_assoc[of "-a" a]
      by auto
  }
  then show ?thesis
    using affine_dependent_translation by auto
qed

lemma affine_hull_0_dependent:
  assumes "0 ∈ affine hull S"
  shows "dependent S"
proof -
  obtain s u where s_u: "finite s ∧ s ≠ {} ∧ s ⊆ S ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = 0"
    using assms affine_hull_explicit[of S] by auto
  then have "∃v∈s. u v ≠ 0"
    using setsum_not_0[of "u" "s"] by auto
  then have "finite s ∧ s ⊆ S ∧ (∃v∈s. u v ≠ 0 ∧ (∑v∈s. u v *R v) = 0)"
    using s_u by auto
  then show ?thesis
    unfolding dependent_explicit[of S] by auto
qed

lemma affine_dependent_imp_dependent2:
  assumes "affine_dependent (insert 0 S)"
  shows "dependent S"
proof -
  obtain x where x: "x ∈ insert 0 S ∧ x ∈ affine hull (insert 0 S - {x})"
    using affine_dependent_def[of "(insert 0 S)"] assms by blast
  then have "x ∈ span (insert 0 S - {x})"
    using affine_hull_subset_span by auto
  moreover have "span (insert 0 S - {x}) = span (S - {x})"
    using insert_Diff_if[of "0" S "{x}"] span_insert_0[of "S-{x}"] by auto
  ultimately have "x ∈ span (S - {x})" by auto
  then have "x ≠ 0 ==> dependent S"
    using x dependent_def by auto
  moreover
  {
    assume "x = 0"
    then have "0 ∈ affine hull S"
      using x hull_mono[of "S - {0}" S] by auto
    then have "dependent S"
      using affine_hull_0_dependent by auto
  }
  ultimately show ?thesis by auto
qed

lemma affine_dependent_iff_dependent:
  assumes "a ∉ S"
  shows "affine_dependent (insert a S) <-> dependent ((λx. -a + x) ` S)"
proof -
  have "(op + (- a) ` S) = {x - a| x . x : S}" by auto
  then show ?thesis
    using affine_dependent_translation_eq[of "(insert a S)" "-a"]
      affine_dependent_imp_dependent2 assms
      dependent_imp_affine_dependent[of a S]
    by (auto simp del: uminus_add_conv_diff)
qed

lemma affine_dependent_iff_dependent2:
  assumes "a ∈ S"
  shows "affine_dependent S <-> dependent ((λx. -a + x) ` (S-{a}))"
proof -
  have "insert a (S - {a}) = S"
    using assms by auto
  then show ?thesis
    using assms affine_dependent_iff_dependent[of a "S-{a}"] by auto
qed

lemma affine_hull_insert_span_gen:
  "affine hull (insert a s) = (λx. a + x) ` span ((λx. - a + x) ` s)"
proof -
  have h1: "{x - a |x. x ∈ s} = ((λx. -a+x) ` s)"
    by auto
  {
    assume "a ∉ s"
    then have ?thesis
      using affine_hull_insert_span[of a s] h1 by auto
  }
  moreover
  {
    assume a1: "a ∈ s"
    have "∃x. x ∈ s ∧ -a+x=0"
      apply (rule exI[of _ a])
      using a1
      apply auto
      done
    then have "insert 0 ((λx. -a+x) ` (s - {a})) = (λx. -a+x) ` s"
      by auto
    then have "span ((λx. -a+x) ` (s - {a}))=span ((λx. -a+x) ` s)"
      using span_insert_0[of "op + (- a) ` (s - {a})"] by (auto simp del: uminus_add_conv_diff)
    moreover have "{x - a |x. x ∈ (s - {a})} = ((λx. -a+x) ` (s - {a}))"
      by auto
    moreover have "insert a (s - {a}) = insert a s"
      using assms by auto
    ultimately have ?thesis
      using assms affine_hull_insert_span[of "a" "s-{a}"] by auto
  }
  ultimately show ?thesis by auto
qed

lemma affine_hull_span2:
  assumes "a ∈ s"
  shows "affine hull s = (λx. a+x) ` span ((λx. -a+x) ` (s-{a}))"
  using affine_hull_insert_span_gen[of a "s - {a}", unfolded insert_Diff[OF assms]]
  by auto

lemma affine_hull_span_gen:
  assumes "a ∈ affine hull s"
  shows "affine hull s = (λx. a+x) ` span ((λx. -a+x) ` s)"
proof -
  have "affine hull (insert a s) = affine hull s"
    using hull_redundant[of a affine s] assms by auto
  then show ?thesis
    using affine_hull_insert_span_gen[of a "s"] by auto
qed

lemma affine_hull_span_0:
  assumes "0 ∈ affine hull S"
  shows "affine hull S = span S"
  using affine_hull_span_gen[of "0" S] assms by auto


lemma extend_to_affine_basis:
  fixes S V :: "'n::euclidean_space set"
  assumes "¬ affine_dependent S" "S ⊆ V" "S ≠ {}"
  shows "∃T. ¬ affine_dependent T ∧ S ⊆ T ∧ T ⊆ V ∧ affine hull T = affine hull V"
proof -
  obtain a where a: "a ∈ S"
    using assms by auto
  then have h0: "independent  ((λx. -a + x) ` (S-{a}))"
    using affine_dependent_iff_dependent2 assms by auto
  then obtain B where B:
    "(λx. -a+x) ` (S - {a}) ⊆ B ∧ B ⊆ (λx. -a+x) ` V ∧ independent B ∧ (λx. -a+x) ` V ⊆ span B"
     using maximal_independent_subset_extend[of "(λx. -a+x) ` (S-{a})" "(λx. -a + x) ` V"] assms
     by blast
  def T  "(λx. a+x) ` insert 0 B"
  then have "T = insert a ((λx. a+x) ` B)"
    by auto
  then have "affine hull T = (λx. a+x) ` span B"
    using affine_hull_insert_span_gen[of a "((λx. a+x) ` B)"] translation_assoc[of "-a" a B]
    by auto
  then have "V ⊆ affine hull T"
    using B assms translation_inverse_subset[of a V "span B"]
    by auto
  moreover have "T ⊆ V"
    using T_def B a assms by auto
  ultimately have "affine hull T = affine hull V"
    by (metis Int_absorb1 Int_absorb2 hull_hull hull_mono)
  moreover have "S ⊆ T"
    using T_def B translation_inverse_subset[of a "S-{a}" B]
    by auto
  moreover have "¬ affine_dependent T"
    using T_def affine_dependent_translation_eq[of "insert 0 B"]
      affine_dependent_imp_dependent2 B
    by auto
  ultimately show ?thesis using `T ⊆ V` by auto
qed

lemma affine_basis_exists:
  fixes V :: "'n::euclidean_space set"
  shows "∃B. B ⊆ V ∧ ¬ affine_dependent B ∧ affine hull V = affine hull B"
proof (cases "V = {}")
  case True
  then show ?thesis
    using affine_independent_empty by auto
next
  case False
  then obtain x where "x ∈ V" by auto
  then show ?thesis
    using affine_dependent_def[of "{x}"] extend_to_affine_basis[of "{x}" V]
    by auto
qed


subsection {* Affine Dimension of a Set *}

definition "aff_dim V =
  (SOME d :: int.
    ∃B. affine hull B = affine hull V ∧ ¬ affine_dependent B ∧ of_nat (card B) = d + 1)"

lemma aff_dim_basis_exists:
  fixes V :: "('n::euclidean_space) set"
  shows "∃B. affine hull B = affine hull V ∧ ¬ affine_dependent B ∧ of_nat (card B) = aff_dim V + 1"
proof -
  obtain B where "¬ affine_dependent B ∧ affine hull B = affine hull V"
    using affine_basis_exists[of V] by auto
  then show ?thesis
    unfolding aff_dim_def
      some_eq_ex[of "λd. ∃B. affine hull B = affine hull V ∧ ¬ affine_dependent B ∧ of_nat (card B) = d + 1"]
    apply auto
    apply (rule exI[of _ "int (card B) - (1 :: int)"])
    apply (rule exI[of _ "B"])
    apply auto
    done
qed

lemma affine_hull_nonempty: "S ≠ {} <-> affine hull S ≠ {}"
proof -
  have "S = {} ==> affine hull S = {}"
    using affine_hull_empty by auto
  moreover have "affine hull S = {} ==> S = {}"
    unfolding hull_def by auto
  ultimately show ?thesis by blast
qed

lemma aff_dim_parallel_subspace_aux:
  fixes B :: "'n::euclidean_space set"
  assumes "¬ affine_dependent B" "a ∈ B"
  shows "finite B ∧ ((card B) - 1 = dim (span ((λx. -a+x) ` (B-{a}))))"
proof -
  have "independent ((λx. -a + x) ` (B-{a}))"
    using affine_dependent_iff_dependent2 assms by auto
  then have fin: "dim (span ((λx. -a+x) ` (B-{a}))) = card ((λx. -a + x) ` (B-{a}))"
    "finite ((λx. -a + x) ` (B - {a}))"
    using indep_card_eq_dim_span[of "(λx. -a+x) ` (B-{a})"] by auto
  show ?thesis
  proof (cases "(λx. -a + x) ` (B - {a}) = {}")
    case True
    have "B = insert a ((λx. a + x) ` (λx. -a + x) ` (B - {a}))"
      using translation_assoc[of "a" "-a" "(B - {a})"] assms by auto
    then have "B = {a}" using True by auto
    then show ?thesis using assms fin by auto
  next
    case False
    then have "card ((λx. -a + x) ` (B - {a})) > 0"
      using fin by auto
    moreover have h1: "card ((λx. -a + x) ` (B-{a})) = card (B-{a})"
       apply (rule card_image)
       using translate_inj_on
       apply (auto simp del: uminus_add_conv_diff)
       done
    ultimately have "card (B-{a}) > 0" by auto
    then have *: "finite (B - {a})"
      using card_gt_0_iff[of "(B - {a})"] by auto
    then have "card (B - {a}) = card B - 1"
      using card_Diff_singleton assms by auto
    with * show ?thesis using fin h1 by auto
  qed
qed

lemma aff_dim_parallel_subspace:
  fixes V L :: "'n::euclidean_space set"
  assumes "V ≠ {}"
    and "subspace L"
    and "affine_parallel (affine hull V) L"
  shows "aff_dim V = int (dim L)"
proof -
  obtain B where
    B: "affine hull B = affine hull V ∧ ¬ affine_dependent B ∧ int (card B) = aff_dim V + 1"
    using aff_dim_basis_exists by auto
  then have "B ≠ {}"
    using assms B affine_hull_nonempty[of V] affine_hull_nonempty[of B]
    by auto
  then obtain a where a: "a ∈ B" by auto
  def Lb  "span ((λx. -a+x) ` (B-{a}))"
  moreover have "affine_parallel (affine hull B) Lb"
    using Lb_def B assms affine_hull_span2[of a B] a
      affine_parallel_commut[of "Lb" "(affine hull B)"]
    unfolding affine_parallel_def
    by auto
  moreover have "subspace Lb"
    using Lb_def subspace_span by auto
  moreover have "affine hull B ≠ {}"
    using assms B affine_hull_nonempty[of V] by auto
  ultimately have "L = Lb"
    using assms affine_parallel_subspace[of "affine hull B"] affine_affine_hull[of B] B
    by auto
  then have "dim L = dim Lb"
    by auto
  moreover have "card B - 1 = dim Lb" and "finite B"
    using Lb_def aff_dim_parallel_subspace_aux a B by auto
  ultimately show ?thesis
    using B `B ≠ {}` card_gt_0_iff[of B] by auto
qed

lemma aff_independent_finite:
  fixes B :: "'n::euclidean_space set"
  assumes "¬ affine_dependent B"
  shows "finite B"
proof -
  {
    assume "B ≠ {}"
    then obtain a where "a ∈ B" by auto
    then have ?thesis
      using aff_dim_parallel_subspace_aux assms by auto
  }
  then show ?thesis by auto
qed

lemma independent_finite:
  fixes B :: "'n::euclidean_space set"
  assumes "independent B"
  shows "finite B"
  using affine_dependent_imp_dependent[of B] aff_independent_finite[of B] assms
  by auto

lemma subspace_dim_equal:
  assumes "subspace (S :: ('n::euclidean_space) set)"
    and "subspace T"
    and "S ⊆ T"
    and "dim S ≥ dim T"
  shows "S = T"
proof -
  obtain B where B: "B ≤ S" "independent B ∧ S ⊆ span B" "card B = dim S"
    using basis_exists[of S] by auto
  then have "span B ⊆ S"
    using span_mono[of B S] span_eq[of S] assms by metis
  then have "span B = S"
    using B by auto
  have "dim S = dim T"
    using assms dim_subset[of S T] by auto
  then have "T ⊆ span B"
    using card_eq_dim[of B T] B independent_finite assms by auto
  then show ?thesis
    using assms `span B = S` by auto
qed

lemma span_substd_basis:
  assumes d: "d ⊆ Basis"
  shows "span d = {x. ∀i∈Basis. i ∉ d --> x•i = 0}"
  (is "_ = ?B")
proof -
  have "d ⊆ ?B"
    using d by (auto simp: inner_Basis)
  moreover have s: "subspace ?B"
    using subspace_substandard[of "λi. i ∉ d"] .
  ultimately have "span d ⊆ ?B"
    using span_mono[of d "?B"] span_eq[of "?B"] by blast
  moreover have *: "card d ≤ dim (span d)"
    using independent_card_le_dim[of d "span d"] independent_substdbasis[OF assms] span_inc[of d]
    by auto
  moreover from * have "dim ?B ≤ dim (span d)"
    using dim_substandard[OF assms] by auto
  ultimately show ?thesis
    using s subspace_dim_equal[of "span d" "?B"] subspace_span[of d] by auto
qed

lemma basis_to_substdbasis_subspace_isomorphism:
  fixes B :: "'a::euclidean_space set"
  assumes "independent B"
  shows "∃f d::'a set. card d = card B ∧ linear f ∧ f ` B = d ∧
    f ` span B = {x. ∀i∈Basis. i ∉ d --> x • i = 0} ∧ inj_on f (span B) ∧ d ⊆ Basis"
proof -
  have B: "card B = dim B"
    using dim_unique[of B B "card B"] assms span_inc[of B] by auto
  have "dim B ≤ card (Basis :: 'a set)"
    using dim_subset_UNIV[of B] by simp
  from ex_card[OF this] obtain d :: "'a set" where d: "d ⊆ Basis" and t: "card d = dim B"
    by auto
  let ?t = "{x::'a::euclidean_space. ∀i∈Basis. i ∉ d --> x•i = 0}"
  have "∃f. linear f ∧ f ` B = d ∧ f ` span B = ?t ∧ inj_on f (span B)"
    apply (rule basis_to_basis_subspace_isomorphism[of "span B" ?t B "d"])
    apply (rule subspace_span)
    apply (rule subspace_substandard)
    defer
    apply (rule span_inc)
    apply (rule assms)
    defer
    unfolding dim_span[of B]
    apply(rule B)
    unfolding span_substd_basis[OF d, symmetric]
    apply (rule span_inc)
    apply (rule independent_substdbasis[OF d])
    apply rule
    apply assumption
    unfolding t[symmetric] span_substd_basis[OF d] dim_substandard[OF d]
    apply auto
    done
  with t `card B = dim B` d show ?thesis by auto
qed

lemma aff_dim_empty:
  fixes S :: "'n::euclidean_space set"
  shows "S = {} <-> aff_dim S = -1"
proof -
  obtain B where *: "affine hull B = affine hull S"
    and "¬ affine_dependent B"
    and "int (card B) = aff_dim S + 1"
    using aff_dim_basis_exists by auto
  moreover
  from * have "S = {} <-> B = {}"
    using affine_hull_nonempty[of B] affine_hull_nonempty[of S] by auto
  ultimately show ?thesis
    using aff_independent_finite[of B] card_gt_0_iff[of B] by auto
qed

lemma aff_dim_affine_hull: "aff_dim (affine hull S) = aff_dim S"
  unfolding aff_dim_def using hull_hull[of _ S] by auto

lemma aff_dim_affine_hull2:
  assumes "affine hull S = affine hull T"
  shows "aff_dim S = aff_dim T"
  unfolding aff_dim_def using assms by auto

lemma aff_dim_unique:
  fixes B V :: "'n::euclidean_space set"
  assumes "affine hull B = affine hull V ∧ ¬ affine_dependent B"
  shows "of_nat (card B) = aff_dim V + 1"
proof (cases "B = {}")
  case True
  then have "V = {}"
    using affine_hull_nonempty[of V] affine_hull_nonempty[of B] assms
    by auto
  then have "aff_dim V = (-1::int)"
    using aff_dim_empty by auto
  then show ?thesis
    using `B = {}` by auto
next
  case False
  then obtain a where a: "a ∈ B" by auto
  def Lb  "span ((λx. -a+x) ` (B-{a}))"
  have "affine_parallel (affine hull B) Lb"
    using Lb_def affine_hull_span2[of a B] a
      affine_parallel_commut[of "Lb" "(affine hull B)"]
    unfolding affine_parallel_def by auto
  moreover have "subspace Lb"
    using Lb_def subspace_span by auto
  ultimately have "aff_dim B = int(dim Lb)"
    using aff_dim_parallel_subspace[of B Lb] `B ≠ {}` by auto
  moreover have "(card B) - 1 = dim Lb" "finite B"
    using Lb_def aff_dim_parallel_subspace_aux a assms by auto
  ultimately have "of_nat (card B) = aff_dim B + 1"
    using `B ≠ {}` card_gt_0_iff[of B] by auto
  then show ?thesis
    using aff_dim_affine_hull2 assms by auto
qed

lemma aff_dim_affine_independent:
  fixes B :: "'n::euclidean_space set"
  assumes "¬ affine_dependent B"
  shows "of_nat (card B) = aff_dim B + 1"
  using aff_dim_unique[of B B] assms by auto

lemma aff_dim_sing:
  fixes a :: "'n::euclidean_space"
  shows "aff_dim {a} = 0"
  using aff_dim_affine_independent[of "{a}"] affine_independent_sing by auto

lemma aff_dim_inner_basis_exists:
  fixes V :: "('n::euclidean_space) set"
  shows "∃B. B ⊆ V ∧ affine hull B = affine hull V ∧
    ¬ affine_dependent B ∧ of_nat (card B) = aff_dim V + 1"
proof -
  obtain B where B: "¬ affine_dependent B" "B ⊆ V" "affine hull B = affine hull V"
    using affine_basis_exists[of V] by auto
  then have "of_nat(card B) = aff_dim V+1" using aff_dim_unique by auto
  with B show ?thesis by auto
qed

lemma aff_dim_le_card:
  fixes V :: "'n::euclidean_space set"
  assumes "finite V"
  shows "aff_dim V ≤ of_nat (card V) - 1"
proof -
  obtain B where B: "B ⊆ V" "of_nat (card B) = aff_dim V + 1"
    using aff_dim_inner_basis_exists[of V] by auto
  then have "card B ≤ card V"
    using assms card_mono by auto
  with B show ?thesis by auto
qed

lemma aff_dim_parallel_eq:
  fixes S T :: "'n::euclidean_space set"
  assumes "affine_parallel (affine hull S) (affine hull T)"
  shows "aff_dim S = aff_dim T"
proof -
  {
    assume "T ≠ {}" "S ≠ {}"
    then obtain L where L: "subspace L ∧ affine_parallel (affine hull T) L"
      using affine_parallel_subspace[of "affine hull T"]
        affine_affine_hull[of T] affine_hull_nonempty
      by auto
    then have "aff_dim T = int (dim L)"
      using aff_dim_parallel_subspace `T ≠ {}` by auto
    moreover have *: "subspace L ∧ affine_parallel (affine hull S) L"
       using L affine_parallel_assoc[of "affine hull S" "affine hull T" L] assms by auto
    moreover from * have "aff_dim S = int (dim L)"
      using aff_dim_parallel_subspace `S ≠ {}` by auto
    ultimately have ?thesis by auto
  }
  moreover
  {
    assume "S = {}"
    then have "S = {}" and "T = {}"
      using assms affine_hull_nonempty
      unfolding affine_parallel_def
      by auto
    then have ?thesis using aff_dim_empty by auto
  }
  moreover
  {
    assume "T = {}"
    then have "S = {}" and "T = {}"
      using assms affine_hull_nonempty
      unfolding affine_parallel_def
      by auto
    then have ?thesis
      using aff_dim_empty by auto
  }
  ultimately show ?thesis by blast
qed

lemma aff_dim_translation_eq:
  fixes a :: "'n::euclidean_space"
  shows "aff_dim ((λx. a + x) ` S) = aff_dim S"
proof -
  have "affine_parallel (affine hull S) (affine hull ((λx. a + x) ` S))"
    unfolding affine_parallel_def
    apply (rule exI[of _ "a"])
    using affine_hull_translation[of a S]
    apply auto
    done
  then show ?thesis
    using aff_dim_parallel_eq[of S "(λx. a + x) ` S"] by auto
qed

lemma aff_dim_affine:
  fixes S L :: "'n::euclidean_space set"
  assumes "S ≠ {}"
    and "affine S"
    and "subspace L"
    and "affine_parallel S L"
  shows "aff_dim S = int (dim L)"
proof -
  have *: "affine hull S = S"
    using assms affine_hull_eq[of S] by auto
  then have "affine_parallel (affine hull S) L"
    using assms by (simp add: *)
  then show ?thesis
    using assms aff_dim_parallel_subspace[of S L] by blast
qed

lemma dim_affine_hull:
  fixes S :: "'n::euclidean_space set"
  shows "dim (affine hull S) = dim S"
proof -
  have "dim (affine hull S) ≥ dim S"
    using dim_subset by auto
  moreover have "dim (span S) ≥ dim (affine hull S)"
    using dim_subset affine_hull_subset_span by auto
  moreover have "dim (span S) = dim S"
    using dim_span by auto
  ultimately show ?thesis by auto
qed

lemma aff_dim_subspace:
  fixes S :: "'n::euclidean_space set"
  assumes "S ≠ {}"
    and "subspace S"
  shows "aff_dim S = int (dim S)"
  using aff_dim_affine[of S S] assms subspace_imp_affine[of S] affine_parallel_reflex[of S]
  by auto

lemma aff_dim_zero:
  fixes S :: "'n::euclidean_space set"
  assumes "0 ∈ affine hull S"
  shows "aff_dim S = int (dim S)"
proof -
  have "subspace (affine hull S)"
    using subspace_affine[of "affine hull S"] affine_affine_hull assms
    by auto
  then have "aff_dim (affine hull S) = int (dim (affine hull S))"
    using assms aff_dim_subspace[of "affine hull S"] by auto
  then show ?thesis
    using aff_dim_affine_hull[of S] dim_affine_hull[of S]
    by auto
qed

lemma aff_dim_univ: "aff_dim (UNIV :: 'n::euclidean_space set) = int(DIM('n))"
  using aff_dim_subspace[of "(UNIV :: 'n::euclidean_space set)"]
    dim_UNIV[where 'a="'n::euclidean_space"]
  by auto

lemma aff_dim_geq:
  fixes V :: "'n::euclidean_space set"
  shows "aff_dim V ≥ -1"
proof -
  obtain B where "affine hull B = affine hull V"
    and "¬ affine_dependent B"
    and "int (card B) = aff_dim V + 1"
    using aff_dim_basis_exists by auto
  then show ?thesis by auto
qed

lemma independent_card_le_aff_dim:
  fixes B :: "'n::euclidean_space set"
  assumes "B ⊆ V"
  assumes "¬ affine_dependent B"
  shows "int (card B) ≤ aff_dim V + 1"
proof (cases "B = {}")
  case True
  then have "-1 ≤ aff_dim V"
    using aff_dim_geq by auto
  with True show ?thesis by auto
next
  case False
  then obtain T where T: "¬ affine_dependent T ∧ B ⊆ T ∧ T ⊆ V ∧ affine hull T = affine hull V"
    using assms extend_to_affine_basis[of B V] by auto
  then have "of_nat (card T) = aff_dim V + 1"
    using aff_dim_unique by auto
  then show ?thesis
    using T card_mono[of T B] aff_independent_finite[of T] by auto
qed

lemma aff_dim_subset:
  fixes S T :: "'n::euclidean_space set"
  assumes "S ⊆ T"
  shows "aff_dim S ≤ aff_dim T"
proof -
  obtain B where B: "¬ affine_dependent B" "B ⊆ S" "affine hull B = affine hull S"
    "of_nat (card B) = aff_dim S + 1"
    using aff_dim_inner_basis_exists[of S] by auto
  then have "int (card B) ≤ aff_dim T + 1"
    using assms independent_card_le_aff_dim[of B T] by auto
  with B show ?thesis by auto
qed

lemma aff_dim_subset_univ:
  fixes S :: "'n::euclidean_space set"
  shows "aff_dim S ≤ int (DIM('n))"
proof -
  have "aff_dim (UNIV :: 'n::euclidean_space set) = int(DIM('n))"
    using aff_dim_univ by auto
  then show "aff_dim (S:: 'n::euclidean_space set) ≤ int(DIM('n))"
    using assms aff_dim_subset[of S "(UNIV :: ('n::euclidean_space) set)"] subset_UNIV by auto
qed

lemma affine_dim_equal:
  fixes S :: "'n::euclidean_space set"
  assumes "affine S" "affine T" "S ≠ {}" "S ⊆ T" "aff_dim S = aff_dim T"
  shows "S = T"
proof -
  obtain a where "a ∈ S" using assms by auto
  then have "a ∈ T" using assms by auto
  def LS  "{y. ∃x ∈ S. (-a) + x = y}"
  then have ls: "subspace LS" "affine_parallel S LS"
    using assms parallel_subspace_explicit[of S a LS] `a ∈ S` by auto
  then have h1: "int(dim LS) = aff_dim S"
    using assms aff_dim_affine[of S LS] by auto
  have "T ≠ {}" using assms by auto
  def LT  "{y. ∃x ∈ T. (-a) + x = y}"
  then have lt: "subspace LT ∧ affine_parallel T LT"
    using assms parallel_subspace_explicit[of T a LT] `a ∈ T` by auto
  then have "int(dim LT) = aff_dim T"
    using assms aff_dim_affine[of T LT] `T ≠ {}` by auto
  then have "dim LS = dim LT"
    using h1 assms by auto
  moreover have "LS ≤ LT"
    using LS_def LT_def assms by auto
  ultimately have "LS = LT"
    using subspace_dim_equal[of LS LT] ls lt by auto
  moreover have "S = {x. ∃y ∈ LS. a+y=x}"
    using LS_def by auto
  moreover have "T = {x. ∃y ∈ LT. a+y=x}"
    using LT_def by auto
  ultimately show ?thesis by auto
qed

lemma affine_hull_univ:
  fixes S :: "'n::euclidean_space set"
  assumes "aff_dim S = int(DIM('n))"
  shows "affine hull S = (UNIV :: ('n::euclidean_space) set)"
proof -
  have "S ≠ {}"
    using assms aff_dim_empty[of S] by auto
  have h0: "S ⊆ affine hull S"
    using hull_subset[of S _] by auto
  have h1: "aff_dim (UNIV :: ('n::euclidean_space) set) = aff_dim S"
    using aff_dim_univ assms by auto
  then have h2: "aff_dim (affine hull S) ≤ aff_dim (UNIV :: ('n::euclidean_space) set)"
    using aff_dim_subset_univ[of "affine hull S"] assms h0 by auto
  have h3: "aff_dim S ≤ aff_dim (affine hull S)"
    using h0 aff_dim_subset[of S "affine hull S"] assms by auto
  then have h4: "aff_dim (affine hull S) = aff_dim (UNIV :: ('n::euclidean_space) set)"
    using h0 h1 h2 by auto
  then show ?thesis
    using affine_dim_equal[of "affine hull S" "(UNIV :: ('n::euclidean_space) set)"]
      affine_affine_hull[of S] affine_UNIV assms h4 h0 `S ≠ {}`
    by auto
qed

lemma aff_dim_convex_hull:
  fixes S :: "'n::euclidean_space set"
  shows "aff_dim (convex hull S) = aff_dim S"
  using aff_dim_affine_hull[of S] convex_hull_subset_affine_hull[of S]
    hull_subset[of S "convex"] aff_dim_subset[of S "convex hull S"]
    aff_dim_subset[of "convex hull S" "affine hull S"]
  by auto

lemma aff_dim_cball:
  fixes a :: "'n::euclidean_space"
  assumes "e > 0"
  shows "aff_dim (cball a e) = int (DIM('n))"
proof -
  have "(λx. a + x) ` (cball 0 e) ⊆ cball a e"
    unfolding cball_def dist_norm by auto
  then have "aff_dim (cball (0 :: 'n::euclidean_space) e) ≤ aff_dim (cball a e)"
    using aff_dim_translation_eq[of a "cball 0 e"]
          aff_dim_subset[of "op + a ` cball 0 e" "cball a e"]
    by auto
  moreover have "aff_dim (cball (0 :: 'n::euclidean_space) e) = int (DIM('n))"
    using hull_inc[of "(0 :: 'n::euclidean_space)" "cball 0 e"]
      centre_in_cball[of "(0 :: 'n::euclidean_space)"] assms
    by (simp add: dim_cball[of e] aff_dim_zero[of "cball 0 e"])
  ultimately show ?thesis
    using aff_dim_subset_univ[of "cball a e"] by auto
qed

lemma aff_dim_open:
  fixes S :: "'n::euclidean_space set"
  assumes "open S"
    and "S ≠ {}"
  shows "aff_dim S = int (DIM('n))"
proof -
  obtain x where "x ∈ S"
    using assms by auto
  then obtain e where e: "e > 0" "cball x e ⊆ S"
    using open_contains_cball[of S] assms by auto
  then have "aff_dim (cball x e) ≤ aff_dim S"
    using aff_dim_subset by auto
  with e show ?thesis
    using aff_dim_cball[of e x] aff_dim_subset_univ[of S] by auto
qed

lemma low_dim_interior:
  fixes S :: "'n::euclidean_space set"
  assumes "¬ aff_dim S = int (DIM('n))"
  shows "interior S = {}"
proof -
  have "aff_dim(interior S) ≤ aff_dim S"
    using interior_subset aff_dim_subset[of "interior S" S] by auto
  then show ?thesis
    using aff_dim_open[of "interior S"] aff_dim_subset_univ[of S] assms by auto
qed

subsection {* Relative interior of a set *}

definition "rel_interior S =
  {x. ∃T. openin (subtopology euclidean (affine hull S)) T ∧ x ∈ T ∧ T ⊆ S}"

lemma rel_interior:
  "rel_interior S = {x ∈ S. ∃T. open T ∧ x ∈ T ∧ T ∩ affine hull S ⊆ S}"
  unfolding rel_interior_def[of S] openin_open[of "affine hull S"]
  apply auto
proof -
  fix x T
  assume *: "x ∈ S" "open T" "x ∈ T" "T ∩ affine hull S ⊆ S"
  then have **: "x ∈ T ∩ affine hull S"
    using hull_inc by auto
  show "∃Tb. (∃Ta. open Ta ∧ Tb = affine hull S ∩ Ta) ∧ x ∈ Tb ∧ Tb ⊆ S"
    apply (rule_tac x = "T ∩ (affine hull S)" in exI)
    using * **
    apply auto
    done
qed

lemma mem_rel_interior: "x ∈ rel_interior S <-> (∃T. open T ∧ x ∈ T ∩ S ∧ T ∩ affine hull S ⊆ S)"
  by (auto simp add: rel_interior)

lemma mem_rel_interior_ball:
  "x ∈ rel_interior S <-> x ∈ S ∧ (∃e. e > 0 ∧ ball x e ∩ affine hull S ⊆ S)"
  apply (simp add: rel_interior, safe)
  apply (force simp add: open_contains_ball)
  apply (rule_tac x = "ball x e" in exI)
  apply simp
  done

lemma rel_interior_ball:
  "rel_interior S = {x ∈ S. ∃e. e > 0 ∧ ball x e ∩ affine hull S ⊆ S}"
  using mem_rel_interior_ball [of _ S] by auto

lemma mem_rel_interior_cball:
  "x ∈ rel_interior S <-> x ∈ S ∧ (∃e. e > 0 ∧ cball x e ∩ affine hull S ⊆ S)"
  apply (simp add: rel_interior, safe)
  apply (force simp add: open_contains_cball)
  apply (rule_tac x = "ball x e" in exI)
  apply (simp add: subset_trans [OF ball_subset_cball])
  apply auto
  done

lemma rel_interior_cball:
  "rel_interior S = {x ∈ S. ∃e. e > 0 ∧ cball x e ∩ affine hull S ⊆ S}"
  using mem_rel_interior_cball [of _ S] by auto

lemma rel_interior_empty: "rel_interior {} = {}"
   by (auto simp add: rel_interior_def)

lemma affine_hull_sing: "affine hull {a :: 'n::euclidean_space} = {a}"
  by (metis affine_hull_eq affine_sing)

lemma rel_interior_sing: "rel_interior {a :: 'n::euclidean_space} = {a}"
  unfolding rel_interior_ball affine_hull_sing
  apply auto
  apply (rule_tac x = "1 :: real" in exI)
  apply simp
  done

lemma subset_rel_interior:
  fixes S T :: "'n::euclidean_space set"
  assumes "S ⊆ T"
    and "affine hull S = affine hull T"
  shows "rel_interior S ⊆ rel_interior T"
  using assms by (auto simp add: rel_interior_def)

lemma rel_interior_subset: "rel_interior S ⊆ S"
  by (auto simp add: rel_interior_def)

lemma rel_interior_subset_closure: "rel_interior S ⊆ closure S"
  using rel_interior_subset by (auto simp add: closure_def)

lemma interior_subset_rel_interior: "interior S ⊆ rel_interior S"
  by (auto simp add: rel_interior interior_def)

lemma interior_rel_interior:
  fixes S :: "'n::euclidean_space set"
  assumes "aff_dim S = int(DIM('n))"
  shows "rel_interior S = interior S"
proof -
  have "affine hull S = UNIV"
    using assms affine_hull_univ[of S] by auto
  then show ?thesis
    unfolding rel_interior interior_def by auto
qed

lemma rel_interior_open:
  fixes S :: "'n::euclidean_space set"
  assumes "open S"
  shows "rel_interior S = S"
  by (metis assms interior_eq interior_subset_rel_interior rel_interior_subset set_eq_subset)

lemma interior_rel_interior_gen:
  fixes S :: "'n::euclidean_space set"
  shows "interior S = (if aff_dim S = int(DIM('n)) then rel_interior S else {})"
  by (metis interior_rel_interior low_dim_interior)

lemma rel_interior_univ:
  fixes S :: "'n::euclidean_space set"
  shows "rel_interior (affine hull S) = affine hull S"
proof -
  have *: "rel_interior (affine hull S) ⊆ affine hull S"
    using rel_interior_subset by auto
  {
    fix x
    assume x: "x ∈ affine hull S"
    def e  "1::real"
    then have "e > 0" "ball x e ∩ affine hull (affine hull S) ⊆ affine hull S"
      using hull_hull[of _ S] by auto
    then have "x ∈ rel_interior (affine hull S)"
      using x rel_interior_ball[of "affine hull S"] by auto
  }
  then show ?thesis using * by auto
qed

lemma rel_interior_univ2: "rel_interior (UNIV :: ('n::euclidean_space) set) = UNIV"
  by (metis open_UNIV rel_interior_open)

lemma rel_interior_convex_shrink:
  fixes S :: "'a::euclidean_space set"
  assumes "convex S"
    and "c ∈ rel_interior S"
    and "x ∈ S"
    and "0 < e"
    and "e ≤ 1"
  shows "x - e *R (x - c) ∈ rel_interior S"
proof -
  obtain d where "d > 0" and d: "ball c d ∩ affine hull S ⊆ S"
    using assms(2) unfolding  mem_rel_interior_ball by auto
  {
    fix y
    assume as: "dist (x - e *R (x - c)) y < e * d" "y ∈ affine hull S"
    have *: "y = (1 - (1 - e)) *R ((1 / e) *R y - ((1 - e) / e) *R x) + (1 - e) *R x"
      using `e > 0` by (auto simp add: scaleR_left_diff_distrib scaleR_right_diff_distrib)
    have "x ∈ affine hull S"
      using assms hull_subset[of S] by auto
    moreover have "1 / e + - ((1 - e) / e) = 1"
      using `e > 0` left_diff_distrib[of "1" "(1-e)" "1/e"] by auto
    ultimately have **: "(1 / e) *R y - ((1 - e) / e) *R x ∈ affine hull S"
      using as affine_affine_hull[of S] mem_affine[of "affine hull S" y x "(1 / e)" "-((1 - e) / e)"]
      by (simp add: algebra_simps)
    have "dist c ((1 / e) *R y - ((1 - e) / e) *R x) = abs(1/e) * norm (e *R c - y + (1 - e) *R x)"
      unfolding dist_norm norm_scaleR[symmetric]
      apply (rule arg_cong[where f=norm])
      using `e > 0`
      apply (auto simp add: euclidean_eq_iff[where 'a='a] field_simps inner_simps)
      done
    also have "… = abs (1/e) * norm (x - e *R (x - c) - y)"
      by (auto intro!:arg_cong[where f=norm] simp add: algebra_simps)
    also have "… < d"
      using as[unfolded dist_norm] and `e > 0`
      by (auto simp add:pos_divide_less_eq[OF `e > 0`] mult.commute)
    finally have "y ∈ S"
      apply (subst *)
      apply (rule assms(1)[unfolded convex_alt,rule_format])
      apply (rule d[unfolded subset_eq,rule_format])
      unfolding mem_ball
      using assms(3-5) **
      apply auto
      done
  }
  then have "ball (x - e *R (x - c)) (e*d) ∩ affine hull S ⊆ S"
    by auto
  moreover have "e * d > 0"
    using `e > 0` `d > 0` by simp
  moreover have c: "c ∈ S"
    using assms rel_interior_subset by auto
  moreover from c have "x - e *R (x - c) ∈ S"
    using mem_convex[of S x c e]
    apply (simp add: algebra_simps)
    using assms
    apply auto
    done
  ultimately show ?thesis
    using mem_rel_interior_ball[of "x - e *R (x - c)" S] `e > 0` by auto
qed

lemma interior_real_semiline:
  fixes a :: real
  shows "interior {a..} = {a<..}"
proof -
  {
    fix y
    assume "a < y"
    then have "y ∈ interior {a..}"
      apply (simp add: mem_interior)
      apply (rule_tac x="(y-a)" in exI)
      apply (auto simp add: dist_norm)
      done
  }
  moreover
  {
    fix y
    assume "y ∈ interior {a..}"
    then obtain e where e: "e > 0" "cball y e ⊆ {a..}"
      using mem_interior_cball[of y "{a..}"] by auto
    moreover from e have "y - e ∈ cball y e"
      by (auto simp add: cball_def dist_norm)
    ultimately have "a ≤ y - e" by auto
    then have "a < y" using e by auto
  }
  ultimately show ?thesis by auto
qed

lemma rel_interior_real_box:
  fixes a b :: real
  assumes "a < b"
  shows "rel_interior {a .. b} = {a <..< b}"
proof -
  have "box a b ≠ {}"
    using assms
    unfolding set_eq_iff
    by (auto intro!: exI[of _ "(a + b) / 2"] simp: box_def)
  then show ?thesis
    using interior_rel_interior_gen[of "cbox a b", symmetric]
    by (simp split: split_if_asm del: box_real add: box_real[symmetric] interior_cbox)
qed

lemma rel_interior_real_semiline:
  fixes a :: real
  shows "rel_interior {a..} = {a<..}"
proof -
  have *: "{a<..} ≠ {}"
    unfolding set_eq_iff by (auto intro!: exI[of _ "a + 1"])
  then show ?thesis using interior_real_semiline interior_rel_interior_gen[of "{a..}"]
    by (auto split: split_if_asm)
qed

subsubsection {* Relative open sets *}

definition "rel_open S <-> rel_interior S = S"

lemma rel_open: "rel_open S <-> openin (subtopology euclidean (affine hull S)) S"
  unfolding rel_open_def rel_interior_def
  apply auto
  using openin_subopen[of "subtopology euclidean (affine hull S)" S]
  apply auto
  done

lemma opein_rel_interior: "openin (subtopology euclidean (affine hull S)) (rel_interior S)"
  apply (simp add: rel_interior_def)
  apply (subst openin_subopen)
  apply blast
  done

lemma affine_rel_open:
  fixes S :: "'n::euclidean_space set"
  assumes "affine S"
  shows "rel_open S"
  unfolding rel_open_def
  using assms rel_interior_univ[of S] affine_hull_eq[of S]
  by metis

lemma affine_closed:
  fixes S :: "'n::euclidean_space set"
  assumes "affine S"
  shows "closed S"
proof -
  {
    assume "S ≠ {}"
    then obtain L where L: "subspace L" "affine_parallel S L"
      using assms affine_parallel_subspace[of S] by auto
    then obtain a where a: "S = (op + a ` L)"
      using affine_parallel_def[of L S] affine_parallel_commut by auto
    from L have "closed L" using closed_subspace by auto
    then have "closed S"
      using closed_translation a by auto
  }
  then show ?thesis by auto
qed

lemma closure_affine_hull:
  fixes S :: "'n::euclidean_space set"
  shows "closure S ⊆ affine hull S"
  by (intro closure_minimal hull_subset affine_closed affine_affine_hull)

lemma closure_same_affine_hull:
  fixes S :: "'n::euclidean_space set"
  shows "affine hull (closure S) = affine hull S"
proof -
  have "affine hull (closure S) ⊆ affine hull S"
    using hull_mono[of "closure S" "affine hull S" "affine"]
      closure_affine_hull[of S] hull_hull[of "affine" S]
    by auto
  moreover have "affine hull (closure S) ⊇ affine hull S"
    using hull_mono[of "S" "closure S" "affine"] closure_subset by auto
  ultimately show ?thesis by auto
qed

lemma closure_aff_dim:
  fixes S :: "'n::euclidean_space set"
  shows "aff_dim (closure S) = aff_dim S"
proof -
  have "aff_dim S ≤ aff_dim (closure S)"
    using aff_dim_subset closure_subset by auto
  moreover have "aff_dim (closure S) ≤ aff_dim (affine hull S)"
    using aff_dim_subset closure_affine_hull by auto
  moreover have "aff_dim (affine hull S) = aff_dim S"
    using aff_dim_affine_hull by auto
  ultimately show ?thesis by auto
qed

lemma rel_interior_closure_convex_shrink:
  fixes S :: "_::euclidean_space set"
  assumes "convex S"
    and "c ∈ rel_interior S"
    and "x ∈ closure S"
    and "e > 0"
    and "e ≤ 1"
  shows "x - e *R (x - c) ∈ rel_interior S"
proof -
  obtain d where "d > 0" and d: "ball c d ∩ affine hull S ⊆ S"
    using assms(2) unfolding mem_rel_interior_ball by auto
  have "∃y ∈ S. norm (y - x) * (1 - e) < e * d"
  proof (cases "x ∈ S")
    case True
    then show ?thesis using `e > 0` `d > 0`
      apply (rule_tac bexI[where x=x])
      apply (auto)
      done
  next
    case False
    then have x: "x islimpt S"
      using assms(3)[unfolded closure_def] by auto
    show ?thesis
    proof (cases "e = 1")
      case True
      obtain y where "y ∈ S" "y ≠ x" "dist y x < 1"
        using x[unfolded islimpt_approachable,THEN spec[where x=1]] by auto
      then show ?thesis
        apply (rule_tac x=y in bexI)
        unfolding True
        using `d > 0`
        apply auto
        done
    next
      case False
      then have "0 < e * d / (1 - e)" and *: "1 - e > 0"
        using `e ≤ 1` `e > 0` `d > 0` by (auto)
      then obtain y where "y ∈ S" "y ≠ x" "dist y x < e * d / (1 - e)"
        using x[unfolded islimpt_approachable,THEN spec[where x="e*d / (1 - e)"]] by auto
      then show ?thesis
        apply (rule_tac x=y in bexI)
        unfolding dist_norm
        using pos_less_divide_eq[OF *]
        apply auto
        done
    qed
  qed
  then obtain y where "y ∈ S" and y: "norm (y - x) * (1 - e) < e * d"
    by auto
  def z  "c + ((1 - e) / e) *R (x - y)"
  have *: "x - e *R (x - c) = y - e *R (y - z)"
    unfolding z_def using `e > 0`
    by (auto simp add: scaleR_right_diff_distrib scaleR_right_distrib scaleR_left_diff_distrib)
  have zball: "z ∈ ball c d"
    using mem_ball z_def dist_norm[of c]
    using y and assms(4,5)
    by (auto simp add:field_simps norm_minus_commute)
  have "x ∈ affine hull S"
    using closure_affine_hull assms by auto
  moreover have "y ∈ affine hull S"
    using `y ∈ S` hull_subset[of S] by auto
  moreover have "c ∈ affine hull S"
    using assms rel_interior_subset hull_subset[of S] by auto
  ultimately have "z ∈ affine hull S"
    using z_def affine_affine_hull[of S]
      mem_affine_3_minus [of "affine hull S" c x y "(1 - e) / e"]
      assms
    by (auto simp add: field_simps)
  then have "z ∈ S" using d zball by auto
  obtain d1 where "d1 > 0" and d1: "ball z d1 ≤ ball c d"
    using zball open_ball[of c d] openE[of "ball c d" z] by auto
  then have "ball z d1 ∩ affine hull S ⊆ ball c d ∩ affine hull S"
    by auto
  then have "ball z d1 ∩ affine hull S ⊆ S"
    using d by auto
  then have "z ∈ rel_interior S"
    using mem_rel_interior_ball using `d1 > 0` `z ∈ S` by auto
  then have "y - e *R (y - z) ∈ rel_interior S"
    using rel_interior_convex_shrink[of S z y e] assms `y ∈ S` by auto
  then show ?thesis using * by auto
qed


subsubsection{* Relative interior preserves under linear transformations *}

lemma rel_interior_translation_aux:
  fixes a :: "'n::euclidean_space"
  shows "((λx. a + x) ` rel_interior S) ⊆ rel_interior ((λx. a + x) ` S)"
proof -
  {
    fix x
    assume x: "x ∈ rel_interior S"
    then obtain T where "open T" "x ∈ T ∩ S" "T ∩ affine hull S ⊆ S"
      using mem_rel_interior[of x S] by auto
    then have "open ((λx. a + x) ` T)"
      and "a + x ∈ ((λx. a + x) ` T) ∩ ((λx. a + x) ` S)"
      and "((λx. a + x) ` T) ∩ affine hull ((λx. a + x) ` S) ⊆ (λx. a + x) ` S"
      using affine_hull_translation[of a S] open_translation[of T a] x by auto
    then have "a + x ∈ rel_interior ((λx. a + x) ` S)"
      using mem_rel_interior[of "a+x" "((λx. a + x) ` S)"] by auto
  }
  then show ?thesis by auto
qed

lemma rel_interior_translation:
  fixes a :: "'n::euclidean_space"
  shows "rel_interior ((λx. a + x) ` S) = (λx. a + x) ` rel_interior S"
proof -
  have "(λx. (-a) + x) ` rel_interior ((λx. a + x) ` S) ⊆ rel_interior S"
    using rel_interior_translation_aux[of "-a" "(λx. a + x) ` S"]
      translation_assoc[of "-a" "a"]
    by auto
  then have "((λx. a + x) ` rel_interior S) ⊇ rel_interior ((λx. a + x) ` S)"
    using translation_inverse_subset[of a "rel_interior (op + a ` S)" "rel_interior S"]
    by auto
  then show ?thesis
    using rel_interior_translation_aux[of a S] by auto
qed


lemma affine_hull_linear_image:
  assumes "bounded_linear f"
  shows "f ` (affine hull s) = affine hull f ` s"
  apply rule
  unfolding subset_eq ball_simps
  apply (rule_tac[!] hull_induct, rule hull_inc)
  prefer 3
  apply (erule imageE)
  apply (rule_tac x=xa in image_eqI)
  apply assumption
  apply (rule hull_subset[unfolded subset_eq, rule_format])
  apply assumption
proof -
  interpret f: bounded_linear f by fact
  show "affine {x. f x ∈ affine hull f ` s}"
    unfolding affine_def
    by (auto simp add: f.scaleR f.add affine_affine_hull[unfolded affine_def, rule_format])
  show "affine {x. x ∈ f ` (affine hull s)}"
    using affine_affine_hull[unfolded affine_def, of s]
    unfolding affine_def by (auto simp add: f.scaleR [symmetric] f.add [symmetric])
qed auto


lemma rel_interior_injective_on_span_linear_image:
  fixes f :: "'m::euclidean_space => 'n::euclidean_space"
    and S :: "'m::euclidean_space set"
  assumes "bounded_linear f"
    and "inj_on f (span S)"
  shows "rel_interior (f ` S) = f ` (rel_interior S)"
proof -
  {
    fix z
    assume z: "z ∈ rel_interior (f ` S)"
    then have "z ∈ f ` S"
      using rel_interior_subset[of "f ` S"] by auto
    then obtain x where x: "x ∈ S" "f x = z" by auto
    obtain e2 where e2: "e2 > 0" "cball z e2 ∩ affine hull (f ` S) ⊆ (f ` S)"
      using z rel_interior_cball[of "f ` S"] by auto
    obtain K where K: "K > 0" "!!x. norm (f x) ≤ norm x * K"
     using assms Real_Vector_Spaces.bounded_linear.pos_bounded[of f] by auto
    def e1  "1 / K"
    then have e1: "e1 > 0" "!!x. e1 * norm (f x) ≤ norm x"
      using K pos_le_divide_eq[of e1] by auto
    def e  "e1 * e2"
    then have "e > 0" using e1 e2 by auto
    {
      fix y
      assume y: "y ∈ cball x e ∩ affine hull S"
      then have h1: "f y ∈ affine hull (f ` S)"
        using affine_hull_linear_image[of f S] assms by auto
      from y have "norm (x-y) ≤ e1 * e2"
        using cball_def[of x e] dist_norm[of x y] e_def by auto
      moreover have "f x - f y = f (x - y)"
        using assms linear_sub[of f x y] linear_conv_bounded_linear[of f] by auto
      moreover have "e1 * norm (f (x-y)) ≤ norm (x - y)"
        using e1 by auto
      ultimately have "e1 * norm ((f x)-(f y)) ≤ e1 * e2"
        by auto
      then have "f y ∈ cball z e2"
        using cball_def[of "f x" e2] dist_norm[of "f x" "f y"] e1 x by auto
      then have "f y ∈ f ` S"
        using y e2 h1 by auto
      then have "y ∈ S"
        using assms y hull_subset[of S] affine_hull_subset_span
          inj_on_image_mem_iff[of f "span S" S y]
        by auto
    }
    then have "z ∈ f ` (rel_interior S)"
      using mem_rel_interior_cball[of x S] `e > 0` x by auto
  }
  moreover
  {
    fix x
    assume x: "x ∈ rel_interior S"
    then obtain e2 where e2: "e2 > 0" "cball x e2 ∩ affine hull S ⊆ S"
      using rel_interior_cball[of S] by auto
    have "x ∈ S" using x rel_interior_subset by auto
    then have *: "f x ∈ f ` S" by auto
    have "∀x∈span S. f x = 0 --> x = 0"
      using assms subspace_span linear_conv_bounded_linear[of f]
        linear_injective_on_subspace_0[of f "span S"]
      by auto
    then obtain e1 where e1: "e1 > 0" "∀x ∈ span S. e1 * norm x ≤ norm (f x)"
      using assms injective_imp_isometric[of "span S" f]
        subspace_span[of S] closed_subspace[of "span S"]
      by auto
    def e  "e1 * e2"
    hence "e > 0" using e1 e2 by auto
    {
      fix y
      assume y: "y ∈ cball (f x) e ∩ affine hull (f ` S)"
      then have "y ∈ f ` (affine hull S)"
        using affine_hull_linear_image[of f S] assms by auto
      then obtain xy where xy: "xy ∈ affine hull S" "f xy = y" by auto
      with y have "norm (f x - f xy) ≤ e1 * e2"
        using cball_def[of "f x" e] dist_norm[of "f x" y] e_def by auto
      moreover have "f x - f xy = f (x - xy)"
        using assms linear_sub[of f x xy] linear_conv_bounded_linear[of f] by auto
      moreover have *: "x - xy ∈ span S"
        using subspace_sub[of "span S" x xy] subspace_span `x ∈ S` xy
          affine_hull_subset_span[of S] span_inc
        by auto
      moreover from * have "e1 * norm (x - xy) ≤ norm (f (x - xy))"
        using e1 by auto
      ultimately have "e1 * norm (x - xy) ≤ e1 * e2"
        by auto
      then have "xy ∈ cball x e2"
        using cball_def[of x e2] dist_norm[of x xy] e1 by auto
      then have "y ∈ f ` S"
        using xy e2 by auto
    }
    then have "f x ∈ rel_interior (f ` S)"
      using mem_rel_interior_cball[of "(f x)" "(f ` S)"] * `e > 0` by auto
  }
  ultimately show ?thesis by auto
qed

lemma rel_interior_injective_linear_image:
  fixes f :: "'m::euclidean_space => 'n::euclidean_space"
  assumes "bounded_linear f"
    and "inj f"
  shows "rel_interior (f ` S) = f ` (rel_interior S)"
  using assms rel_interior_injective_on_span_linear_image[of f S]
    subset_inj_on[of f "UNIV" "span S"]
  by auto


subsection{* Some Properties of subset of standard basis *}

lemma affine_hull_substd_basis:
  assumes "d ⊆ Basis"
  shows "affine hull (insert 0 d) = {x::'a::euclidean_space. ∀i∈Basis. i ∉ d --> x•i = 0}"
  (is "affine hull (insert 0 ?A) = ?B")
proof -
  have *: "!!A. op + (0::'a) ` A = A" "!!A. op + (- (0::'a)) ` A = A"
    by auto
  show ?thesis
    unfolding affine_hull_insert_span_gen span_substd_basis[OF assms,symmetric] * ..
qed

lemma affine_hull_convex_hull: "affine hull (convex hull S) = affine hull S"
  by (metis Int_absorb1 Int_absorb2 convex_hull_subset_affine_hull hull_hull hull_mono hull_subset)


subsection {* Openness and compactness are preserved by convex hull operation. *}

lemma open_convex_hull[intro]:
  fixes s :: "'a::real_normed_vector set"
  assumes "open s"
  shows "open (convex hull s)"
  unfolding open_contains_cball convex_hull_explicit
  unfolding mem_Collect_eq ball_simps(8)
proof (rule, rule)
  fix a
  assume "∃sa u. finite sa ∧ sa ⊆ s ∧ (∀x∈sa. 0 ≤ u x) ∧ setsum u sa = 1 ∧ (∑v∈sa. u v *R v) = a"
  then obtain t u where obt: "finite t" "t⊆s" "∀x∈t. 0 ≤ u x" "setsum u t = 1" "(∑v∈t. u v *R v) = a"
    by auto

  from assms[unfolded open_contains_cball] obtain b
    where b: "∀x∈s. 0 < b x ∧ cball x (b x) ⊆ s"
    using bchoice[of s "λx e. e > 0 ∧ cball x e ⊆ s"] by auto
  have "b ` t ≠ {}"
    using obt by auto
  def i  "b ` t"

  show "∃e > 0.
    cball a e ⊆ {y. ∃sa u. finite sa ∧ sa ⊆ s ∧ (∀x∈sa. 0 ≤ u x) ∧ setsum u sa = 1 ∧ (∑v∈sa. u v *R v) = y}"
    apply (rule_tac x = "Min i" in exI)
    unfolding subset_eq
    apply rule
    defer
    apply rule
    unfolding mem_Collect_eq
  proof -
    show "0 < Min i"
      unfolding i_def and Min_gr_iff[OF finite_imageI[OF obt(1)] `b \` t≠{}`]
      using b
      apply simp
      apply rule
      apply (erule_tac x=x in ballE)
      using `t⊆s`
      apply auto
      done
  next
    fix y
    assume "y ∈ cball a (Min i)"
    then have y: "norm (a - y) ≤ Min i"
      unfolding dist_norm[symmetric] by auto
    {
      fix x
      assume "x ∈ t"
      then have "Min i ≤ b x"
        unfolding i_def
        apply (rule_tac Min_le)
        using obt(1)
        apply auto
        done
      then have "x + (y - a) ∈ cball x (b x)"
        using y unfolding mem_cball dist_norm by auto
      moreover from `x∈t` have "x ∈ s"
        using obt(2) by auto
      ultimately have "x + (y - a) ∈ s"
        using y and b[THEN bspec[where x=x]] unfolding subset_eq by fast
    }
    moreover
    have *: "inj_on (λv. v + (y - a)) t"
      unfolding inj_on_def by auto
    have "(∑v∈(λv. v + (y - a)) ` t. u (v - (y - a))) = 1"
      unfolding setsum.reindex[OF *] o_def using obt(4) by auto
    moreover have "(∑v∈(λv. v + (y - a)) ` t. u (v - (y - a)) *R v) = y"
      unfolding setsum.reindex[OF *] o_def using obt(4,5)
      by (simp add: setsum.distrib setsum_subtractf scaleR_left.setsum[symmetric] scaleR_right_distrib)
    ultimately
    show "∃sa u. finite sa ∧ (∀x∈sa. x ∈ s) ∧ (∀x∈sa. 0 ≤ u x) ∧ setsum u sa = 1 ∧ (∑v∈sa. u v *R v) = y"
      apply (rule_tac x="(λv. v + (y - a)) ` t" in exI)
      apply (rule_tac x="λv. u (v - (y - a))" in exI)
      using obt(1, 3)
      apply auto
      done
  qed
qed

lemma compact_convex_combinations:
  fixes s t :: "'a::real_normed_vector set"
  assumes "compact s" "compact t"
  shows "compact { (1 - u) *R x + u *R y | x y u. 0 ≤ u ∧ u ≤ 1 ∧ x ∈ s ∧ y ∈ t}"
proof -
  let ?X = "{0..1} × s × t"
  let ?h = "(λz. (1 - fst z) *R fst (snd z) + fst z *R snd (snd z))"
  have *: "{ (1 - u) *R x + u *R y | x y u. 0 ≤ u ∧ u ≤ 1 ∧ x ∈ s ∧ y ∈ t} = ?h ` ?X"
    apply (rule set_eqI)
    unfolding image_iff mem_Collect_eq
    apply rule
    apply auto
    apply (rule_tac x=u in rev_bexI)
    apply simp
    apply (erule rev_bexI)
    apply (erule rev_bexI)
    apply simp
    apply auto
    done
  have "continuous_on ?X (λz. (1 - fst z) *R fst (snd z) + fst z *R snd (snd z))"
    unfolding continuous_on by (rule ballI) (intro tendsto_intros)
  then show ?thesis
    unfolding *
    apply (rule compact_continuous_image)
    apply (intro compact_Times compact_Icc assms)
    done
qed

lemma finite_imp_compact_convex_hull:
  fixes s :: "'a::real_normed_vector set"
  assumes "finite s"
  shows "compact (convex hull s)"
proof (cases "s = {}")
  case True
  then show ?thesis by simp
next
  case False
  with assms show ?thesis
  proof (induct rule: finite_ne_induct)
    case (singleton x)
    show ?case by simp
  next
    case (insert x A)
    let ?f = "λ(u, y::'a). u *R x + (1 - u) *R y"
    let ?T = "{0..1::real} × (convex hull A)"
    have "continuous_on ?T ?f"
      unfolding split_def continuous_on by (intro ballI tendsto_intros)
    moreover have "compact ?T"
      by (intro compact_Times compact_Icc insert)
    ultimately have "compact (?f ` ?T)"
      by (rule compact_continuous_image)
    also have "?f ` ?T = convex hull (insert x A)"
      unfolding convex_hull_insert [OF `A ≠ {}`]
      apply safe
      apply (rule_tac x=a in exI, simp)
      apply (rule_tac x="1 - a" in exI, simp)
      apply fast
      apply (rule_tac x="(u, b)" in image_eqI, simp_all)
      done
    finally show "compact (convex hull (insert x A))" .
  qed
qed

lemma compact_convex_hull:
  fixes s :: "'a::euclidean_space set"
  assumes "compact s"
  shows "compact (convex hull s)"
proof (cases "s = {}")
  case True
  then show ?thesis using compact_empty by simp
next
  case False
  then obtain w where "w ∈ s" by auto
  show ?thesis
    unfolding caratheodory[of s]
  proof (induct ("DIM('a) + 1"))
    case 0
    have *: "{x.∃sa. finite sa ∧ sa ⊆ s ∧ card sa ≤ 0 ∧ x ∈ convex hull sa} = {}"
      using compact_empty by auto
    from 0 show ?case unfolding * by simp
  next
    case (Suc n)
    show ?case
    proof (cases "n = 0")
      case True
      have "{x. ∃t. finite t ∧ t ⊆ s ∧ card t ≤ Suc n ∧ x ∈ convex hull t} = s"
        unfolding set_eq_iff and mem_Collect_eq
      proof (rule, rule)
        fix x
        assume "∃t. finite t ∧ t ⊆ s ∧ card t ≤ Suc n ∧ x ∈ convex hull t"
        then obtain t where t: "finite t" "t ⊆ s" "card t ≤ Suc n" "x ∈ convex hull t"
          by auto
        show "x ∈ s"
        proof (cases "card t = 0")
          case True
          then show ?thesis
            using t(4) unfolding card_0_eq[OF t(1)] by simp
        next
          case False
          then have "card t = Suc 0" using t(3) `n=0` by auto
          then obtain a where "t = {a}" unfolding card_Suc_eq by auto
          then show ?thesis using t(2,4) by simp
        qed
      next
        fix x assume "x∈s"
        then show "∃t. finite t ∧ t ⊆ s ∧ card t ≤ Suc n ∧ x ∈ convex hull t"
          apply (rule_tac x="{x}" in exI)
          unfolding convex_hull_singleton
          apply auto
          done
      qed
      then show ?thesis using assms by simp
    next
      case False
      have "{x. ∃t. finite t ∧ t ⊆ s ∧ card t ≤ Suc n ∧ x ∈ convex hull t} =
        {(1 - u) *R x + u *R y | x y u.
          0 ≤ u ∧ u ≤ 1 ∧ x ∈ s ∧ y ∈ {x. ∃t. finite t ∧ t ⊆ s ∧ card t ≤ n ∧ x ∈ convex hull t}}"
        unfolding set_eq_iff and mem_Collect_eq
      proof (rule, rule)
        fix x
        assume "∃u v c. x = (1 - c) *R u + c *R v ∧
          0 ≤ c ∧ c ≤ 1 ∧ u ∈ s ∧ (∃t. finite t ∧ t ⊆ s ∧ card t ≤ n ∧ v ∈ convex hull t)"
        then obtain u v c t where obt: "x = (1 - c) *R u + c *R v"
          "0 ≤ c ∧ c ≤ 1" "u ∈ s" "finite t" "t ⊆ s" "card t ≤ n"  "v ∈ convex hull t"
          by auto
        moreover have "(1 - c) *R u + c *R v ∈ convex hull insert u t"
          apply (rule mem_convex)
          using obt(2) and convex_convex_hull and hull_subset[of "insert u t" convex]
          using obt(7) and hull_mono[of t "insert u t"]
          apply auto
          done
        ultimately show "∃t. finite t ∧ t ⊆ s ∧ card t ≤ Suc n ∧ x ∈ convex hull t"
          apply (rule_tac x="insert u t" in exI)
          apply (auto simp add: card_insert_if)
          done
      next
        fix x
        assume "∃t. finite t ∧ t ⊆ s ∧ card t ≤ Suc n ∧ x ∈ convex hull t"
        then obtain t where t: "finite t" "t ⊆ s" "card t ≤ Suc n" "x ∈ convex hull t"
          by auto
        show "∃u v c. x = (1 - c) *R u + c *R v ∧
          0 ≤ c ∧ c ≤ 1 ∧ u ∈ s ∧ (∃t. finite t ∧ t ⊆ s ∧ card t ≤ n ∧ v ∈ convex hull t)"
        proof (cases "card t = Suc n")
          case False
          then have "card t ≤ n" using t(3) by auto
          then show ?thesis
            apply (rule_tac x=w in exI, rule_tac x=x in exI, rule_tac x=1 in exI)
            using `w∈s` and t
            apply (auto intro!: exI[where x=t])
            done
        next
          case True
          then obtain a u where au: "t = insert a u" "a∉u"
            apply (drule_tac card_eq_SucD)
            apply auto
            done
          show ?thesis
          proof (cases "u = {}")
            case True
            then have "x = a" using t(4)[unfolded au] by auto
            show ?thesis unfolding `x = a`
              apply (rule_tac x=a in exI)
              apply (rule_tac x=a in exI)
              apply (rule_tac x=1 in exI)
              using t and `n ≠ 0`
              unfolding au
              apply (auto intro!: exI[where x="{a}"])
              done
          next
            case False
            obtain ux vx b where obt: "ux≥0" "vx≥0" "ux + vx = 1"
              "b ∈ convex hull u" "x = ux *R a + vx *R b"
              using t(4)[unfolded au convex_hull_insert[OF False]]
              by auto
            have *: "1 - vx = ux" using obt(3) by auto
            show ?thesis
              apply (rule_tac x=a in exI)
              apply (rule_tac x=b in exI)
              apply (rule_tac x=vx in exI)
              using obt and t(1-3)
              unfolding au and * using card_insert_disjoint[OF _ au(2)]
              apply (auto intro!: exI[where x=u])
              done
          qed
        qed
      qed
      then show ?thesis
        using compact_convex_combinations[OF assms Suc] by simp
    qed
  qed
qed


subsection {* Extremal points of a simplex are some vertices. *}

lemma dist_increases_online:
  fixes a b d :: "'a::real_inner"
  assumes "d ≠ 0"
  shows "dist a (b + d) > dist a b ∨ dist a (b - d) > dist a b"
proof (cases "inner a d - inner b d > 0")
  case True
  then have "0 < inner d d + (inner a d * 2 - inner b d * 2)"
    apply (rule_tac add_pos_pos)
    using assms
    apply auto
    done
  then show ?thesis
    apply (rule_tac disjI2)
    unfolding dist_norm and norm_eq_sqrt_inner and real_sqrt_less_iff
    apply  (simp add: algebra_simps inner_commute)
    done
next
  case False
  then have "0 < inner d d + (inner b d * 2 - inner a d * 2)"
    apply (rule_tac add_pos_nonneg)
    using assms
    apply auto
    done
  then show ?thesis
    apply (rule_tac disjI1)
    unfolding dist_norm and norm_eq_sqrt_inner and real_sqrt_less_iff
    apply (simp add: algebra_simps inner_commute)
    done
qed

lemma norm_increases_online:
  fixes d :: "'a::real_inner"
  shows "d ≠ 0 ==> norm (a + d) > norm a ∨ norm(a - d) > norm a"
  using dist_increases_online[of d a 0] unfolding dist_norm by auto

lemma simplex_furthest_lt:
  fixes s :: "'a::real_inner set"
  assumes "finite s"
  shows "∀x ∈ convex hull s.  x ∉ s --> (∃y ∈ convex hull s. norm (x - a) < norm(y - a))"
  using assms
proof induct
  fix x s
  assume as: "finite s" "x∉s" "∀x∈convex hull s. x ∉ s --> (∃y∈convex hull s. norm (x - a) < norm (y - a))"
  show "∀xa∈convex hull insert x s. xa ∉ insert x s -->
    (∃y∈convex hull insert x s. norm (xa - a) < norm (y - a))"
  proof (rule, rule, cases "s = {}")
    case False
    fix y
    assume y: "y ∈ convex hull insert x s" "y ∉ insert x s"
    obtain u v b where obt: "u≥0" "v≥0" "u + v = 1" "b ∈ convex hull s" "y = u *R x + v *R b"
      using y(1)[unfolded convex_hull_insert[OF False]] by auto
    show "∃z∈convex hull insert x s. norm (y - a) < norm (z - a)"
    proof (cases "y ∈ convex hull s")
      case True
      then obtain z where "z ∈ convex hull s" "norm (y - a) < norm (z - a)"
        using as(3)[THEN bspec[where x=y]] and y(2) by auto
      then show ?thesis
        apply (rule_tac x=z in bexI)
        unfolding convex_hull_insert[OF False]
        apply auto
        done
    next
      case False
      show ?thesis
        using obt(3)
      proof (cases "u = 0", case_tac[!] "v = 0")
        assume "u = 0" "v ≠ 0"
        then have "y = b" using obt by auto
        then show ?thesis using False and obt(4) by auto
      next
        assume "u ≠ 0" "v = 0"
        then have "y = x" using obt by auto
        then show ?thesis using y(2) by auto
      next
        assume "u ≠ 0" "v ≠ 0"
        then obtain w where w: "w>0" "w<u" "w<v"
          using real_lbound_gt_zero[of u v] and obt(1,2) by auto
        have "x ≠ b"
        proof
          assume "x = b"
          then have "y = b" unfolding obt(5)
            using obt(3) by (auto simp add: scaleR_left_distrib[symmetric])
          then show False using obt(4) and False by simp
        qed
        then have *: "w *R (x - b) ≠ 0" using w(1) by auto
        show ?thesis
          using dist_increases_online[OF *, of a y]
        proof (elim disjE)
          assume "dist a y < dist a (y + w *R (x - b))"
          then have "norm (y - a) < norm ((u + w) *R x + (v - w) *R b - a)"
            unfolding dist_commute[of a]
            unfolding dist_norm obt(5)
            by (simp add: algebra_simps)
          moreover have "(u + w) *R x + (v - w) *R b ∈ convex hull insert x s"
            unfolding convex_hull_insert[OF `s≠{}`] and mem_Collect_eq
            apply (rule_tac x="u + w" in exI)
            apply rule
            defer
            apply (rule_tac x="v - w" in exI)
            using `u ≥ 0` and w and obt(3,4)
            apply auto
            done
          ultimately show ?thesis by auto
        next
          assume "dist a y < dist a (y - w *R (x - b))"
          then have "norm (y - a) < norm ((u - w) *R x + (v + w) *R b - a)"
            unfolding dist_commute[of a]
            unfolding dist_norm obt(5)
            by (simp add: algebra_simps)
          moreover have "(u - w) *R x + (v + w) *R b ∈ convex hull insert x s"
            unfolding convex_hull_insert[OF `s≠{}`] and mem_Collect_eq
            apply (rule_tac x="u - w" in exI)
            apply rule
            defer
            apply (rule_tac x="v + w" in exI)
            using `u ≥ 0` and w and obt(3,4)
            apply auto
            done
          ultimately show ?thesis by auto
        qed
      qed auto
    qed
  qed auto
qed (auto simp add: assms)

lemma simplex_furthest_le:
  fixes s :: "'a::real_inner set"
  assumes "finite s"
    and "s ≠ {}"
  shows "∃y∈s. ∀x∈ convex hull s. norm (x - a) ≤ norm (y - a)"
proof -
  have "convex hull s ≠ {}"
    using hull_subset[of s convex] and assms(2) by auto
  then obtain x where x: "x ∈ convex hull s" "∀y∈convex hull s. norm (y - a) ≤ norm (x - a)"
    using distance_attains_sup[OF finite_imp_compact_convex_hull[OF assms(1)], of a]
    unfolding dist_commute[of a]
    unfolding dist_norm
    by auto
  show ?thesis
  proof (cases "x ∈ s")
    case False
    then obtain y where "y ∈ convex hull s" "norm (x - a) < norm (y - a)"
      using simplex_furthest_lt[OF assms(1), THEN bspec[where x=x]] and x(1)
      by auto
    then show ?thesis
      using x(2)[THEN bspec[where x=y]] by auto
  next
    case True
    with x show ?thesis by auto
  qed
qed

lemma simplex_furthest_le_exists:
  fixes s :: "('a::real_inner) set"
  shows "finite s ==> ∀x∈(convex hull s). ∃y∈s. norm (x - a) ≤ norm (y - a)"
  using simplex_furthest_le[of s] by (cases "s = {}") auto

lemma simplex_extremal_le:
  fixes s :: "'a::real_inner set"
  assumes "finite s"
    and "s ≠ {}"
  shows "∃u∈s. ∃v∈s. ∀x∈convex hull s. ∀y ∈ convex hull s. norm (x - y) ≤ norm (u - v)"
proof -
  have "convex hull s ≠ {}"
    using hull_subset[of s convex] and assms(2) by auto
  then obtain u v where obt: "u ∈ convex hull s" "v ∈ convex hull s"
    "∀x∈convex hull s. ∀y∈convex hull s. norm (x - y) ≤ norm (u - v)"
    using compact_sup_maxdistance[OF finite_imp_compact_convex_hull[OF assms(1)]]
    by (auto simp: dist_norm)
  then show ?thesis
  proof (cases "u∉s ∨ v∉s", elim disjE)
    assume "u ∉ s"
    then obtain y where "y ∈ convex hull s" "norm (u - v) < norm (y - v)"
      using simplex_furthest_lt[OF assms(1), THEN bspec[where x=u]] and obt(1)
      by auto
    then show ?thesis
      using obt(3)[THEN bspec[where x=y], THEN bspec[where x=v]] and obt(2)
      by auto
  next
    assume "v ∉ s"
    then obtain y where "y ∈ convex hull s" "norm (v - u) < norm (y - u)"
      using simplex_furthest_lt[OF assms(1), THEN bspec[where x=v]] and obt(2)
      by auto
    then show ?thesis
      using obt(3)[THEN bspec[where x=u], THEN bspec[where x=y]] and obt(1)
      by (auto simp add: norm_minus_commute)
  qed auto
qed

lemma simplex_extremal_le_exists:
  fixes s :: "'a::real_inner set"
  shows "finite s ==> x ∈ convex hull s ==> y ∈ convex hull s ==>
    ∃u∈s. ∃v∈s. norm (x - y) ≤ norm (u - v)"
  using convex_hull_empty simplex_extremal_le[of s]
  by(cases "s = {}") auto


subsection {* Closest point of a convex set is unique, with a continuous projection. *}

definition closest_point :: "'a::{real_inner,heine_borel} set => 'a => 'a"
  where "closest_point s a = (SOME x. x ∈ s ∧ (∀y∈s. dist a x ≤ dist a y))"

lemma closest_point_exists:
  assumes "closed s"
    and "s ≠ {}"
  shows "closest_point s a ∈ s"
    and "∀y∈s. dist a (closest_point s a) ≤ dist a y"
  unfolding closest_point_def
  apply(rule_tac[!] someI2_ex)
  using distance_attains_inf[OF assms(1,2), of a]
  apply auto
  done

lemma closest_point_in_set: "closed s ==> s ≠ {} ==> closest_point s a ∈ s"
  by (meson closest_point_exists)

lemma closest_point_le: "closed s ==> x ∈ s ==> dist a (closest_point s a) ≤ dist a x"
  using closest_point_exists[of s] by auto

lemma closest_point_self:
  assumes "x ∈ s"
  shows "closest_point s x = x"
  unfolding closest_point_def
  apply (rule some1_equality, rule ex1I[of _ x])
  using assms
  apply auto
  done

lemma closest_point_refl: "closed s ==> s ≠ {} ==> closest_point s x = x <-> x ∈ s"
  using closest_point_in_set[of s x] closest_point_self[of x s]
  by auto

lemma closer_points_lemma:
  assumes "inner y z > 0"
  shows "∃u>0. ∀v>0. v ≤ u --> norm(v *R z - y) < norm y"
proof -
  have z: "inner z z > 0"
    unfolding inner_gt_zero_iff using assms by auto
  then show ?thesis
    using assms
    apply (rule_tac x = "inner y z / inner z z" in exI)
    apply rule
    defer
  proof rule+
    fix v
    assume "0 < v" and "v ≤ inner y z / inner z z"
    then show "norm (v *R z - y) < norm y"
      unfolding norm_lt using z and assms
      by (simp add: field_simps inner_diff inner_commute mult_strict_left_mono[OF _ `0<v`])
  qed auto
qed

lemma closer_point_lemma:
  assumes "inner (y - x) (z - x) > 0"
  shows "∃u>0. u ≤ 1 ∧ dist (x + u *R (z - x)) y < dist x y"
proof -
  obtain u where "u > 0"
    and u: "∀v>0. v ≤ u --> norm (v *R (z - x) - (y - x)) < norm (y - x)"
    using closer_points_lemma[OF assms] by auto
  show ?thesis
    apply (rule_tac x="min u 1" in exI)
    using u[THEN spec[where x="min u 1"]] and `u > 0`
    unfolding dist_norm by (auto simp add: norm_minus_commute field_simps)
qed

lemma any_closest_point_dot:
  assumes "convex s" "closed s" "x ∈ s" "y ∈ s" "∀z∈s. dist a x ≤ dist a z"
  shows "inner (a - x) (y - x) ≤ 0"
proof (rule ccontr)
  assume "¬ ?thesis"
  then obtain u where u: "u>0" "u≤1" "dist (x + u *R (y - x)) a < dist x a"
    using closer_point_lemma[of a x y] by auto
  let ?z = "(1 - u) *R x + u *R y"
  have "?z ∈ s"
    using mem_convex[OF assms(1,3,4), of u] using u by auto
  then show False
    using assms(5)[THEN bspec[where x="?z"]] and u(3)
    by (auto simp add: dist_commute algebra_simps)
qed

lemma any_closest_point_unique:
  fixes x :: "'a::real_inner"
  assumes "convex s" "closed s" "x ∈ s" "y ∈ s"
    "∀z∈s. dist a x ≤ dist a z" "∀z∈s. dist a y ≤ dist a z"
  shows "x = y"
  using any_closest_point_dot[OF assms(1-4,5)] and any_closest_point_dot[OF assms(1-2,4,3,6)]
  unfolding norm_pths(1) and norm_le_square
  by (auto simp add: algebra_simps)

lemma closest_point_unique:
  assumes "convex s" "closed s" "x ∈ s" "∀z∈s. dist a x ≤ dist a z"
  shows "x = closest_point s a"
  using any_closest_point_unique[OF assms(1-3) _ assms(4), of "closest_point s a"]
  using closest_point_exists[OF assms(2)] and assms(3) by auto

lemma closest_point_dot:
  assumes "convex s" "closed s" "x ∈ s"
  shows "inner (a - closest_point s a) (x - closest_point s a) ≤ 0"
  apply (rule any_closest_point_dot[OF assms(1,2) _ assms(3)])
  using closest_point_exists[OF assms(2)] and assms(3)
  apply auto
  done

lemma closest_point_lt:
  assumes "convex s" "closed s" "x ∈ s" "x ≠ closest_point s a"
  shows "dist a (closest_point s a) < dist a x"
  apply (rule ccontr)
  apply (rule_tac notE[OF assms(4)])
  apply (rule closest_point_unique[OF assms(1-3), of a])
  using closest_point_le[OF assms(2), of _ a]
  apply fastforce
  done

lemma closest_point_lipschitz:
  assumes "convex s"
    and "closed s" "s ≠ {}"
  shows "dist (closest_point s x) (closest_point s y) ≤ dist x y"
proof -
  have "inner (x - closest_point s x) (closest_point s y - closest_point s x) ≤ 0"
    and "inner (y - closest_point s y) (closest_point s x - closest_point s y) ≤ 0"
    apply (rule_tac[!] any_closest_point_dot[OF assms(1-2)])
    using closest_point_exists[OF assms(2-3)]
    apply auto
    done
  then show ?thesis unfolding dist_norm and norm_le
    using inner_ge_zero[of "(x - closest_point s x) - (y - closest_point s y)"]
    by (simp add: inner_add inner_diff inner_commute)
qed

lemma continuous_at_closest_point:
  assumes "convex s"
    and "closed s"
    and "s ≠ {}"
  shows "continuous (at x) (closest_point s)"
  unfolding continuous_at_eps_delta
  using le_less_trans[OF closest_point_lipschitz[OF assms]] by auto

lemma continuous_on_closest_point:
  assumes "convex s"
    and "closed s"
    and "s ≠ {}"
  shows "continuous_on t (closest_point s)"
  by (metis continuous_at_imp_continuous_on continuous_at_closest_point[OF assms])


subsubsection {* Various point-to-set separating/supporting hyperplane theorems. *}

lemma supporting_hyperplane_closed_point:
  fixes z :: "'a::{real_inner,heine_borel}"
  assumes "convex s"
    and "closed s"
    and "s ≠ {}"
    and "z ∉ s"
  shows "∃a b. ∃y∈s. inner a z < b ∧ inner a y = b ∧ (∀x∈s. inner a x ≥ b)"
proof -
  from distance_attains_inf[OF assms(2-3)]
  obtain y where "y ∈ s" and y: "∀x∈s. dist z y ≤ dist z x"
    by auto
  show ?thesis
    apply (rule_tac x="y - z" in exI)
    apply (rule_tac x="inner (y - z) y" in exI)
    apply (rule_tac x=y in bexI)
    apply rule
    defer
    apply rule
    defer
    apply rule
    apply (rule ccontr)
    using `y ∈ s`
  proof -
    show "inner (y - z) z < inner (y - z) y"
      apply (subst diff_less_iff(1)[symmetric])
      unfolding inner_diff_right[symmetric] and inner_gt_zero_iff
      using `y∈s` `z∉s`
      apply auto
      done
  next
    fix x
    assume "x ∈ s"
    have *: "∀u. 0 ≤ u ∧ u ≤ 1 --> dist z y ≤ dist z ((1 - u) *R y + u *R x)"
      using assms(1)[unfolded convex_alt] and y and `x∈s` and `y∈s` by auto
    assume "¬ inner (y - z) y ≤ inner (y - z) x"
    then obtain v where "v > 0" "v ≤ 1" "dist (y + v *R (x - y)) z < dist y z"
      using closer_point_lemma[of z y x] by (auto simp add: inner_diff)
    then show False
      using *[THEN spec[where x=v]] by (auto simp add: dist_commute algebra_simps)
  qed auto
qed

lemma separating_hyperplane_closed_point:
  fixes z :: "'a::{real_inner,heine_borel}"
  assumes "convex s"
    and "closed s"
    and "z ∉ s"
  shows "∃a b. inner a z < b ∧ (∀x∈s. inner a x > b)"
proof (cases "s = {}")
  case True
  then show ?thesis
    apply (rule_tac x="-z" in exI)
    apply (rule_tac x=1 in exI)
    using less_le_trans[OF _ inner_ge_zero[of z]]
    apply auto
    done
next
  case False
  obtain y where "y ∈ s" and y: "∀x∈s. dist z y ≤ dist z x"
    using distance_attains_inf[OF assms(2) False] by auto
  show ?thesis
    apply (rule_tac x="y - z" in exI)
    apply (rule_tac x="inner (y - z) z + (norm (y - z))2 / 2" in exI)
    apply rule
    defer
    apply rule
  proof -
    fix x
    assume "x ∈ s"
    have "¬ 0 < inner (z - y) (x - y)"
      apply (rule notI)
      apply (drule closer_point_lemma)
    proof -
      assume "∃u>0. u ≤ 1 ∧ dist (y + u *R (x - y)) z < dist y z"
      then obtain u where "u > 0" "u ≤ 1" "dist (y + u *R (x - y)) z < dist y z"
        by auto
      then show False using y[THEN bspec[where x="y + u *R (x - y)"]]
        using assms(1)[unfolded convex_alt, THEN bspec[where x=y]]
        using `x∈s` `y∈s` by (auto simp add: dist_commute algebra_simps)
    qed
    moreover have "0 < (norm (y - z))2"
      using `y∈s` `z∉s` by auto
    then have "0 < inner (y - z) (y - z)"
      unfolding power2_norm_eq_inner by simp
    ultimately show "inner (y - z) z + (norm (y - z))2 / 2 < inner (y - z) x"
      unfolding power2_norm_eq_inner and not_less
      by (auto simp add: field_simps inner_commute inner_diff)
  qed (insert `y∈s` `z∉s`, auto)
qed

lemma separating_hyperplane_closed_0:
  assumes "convex (s::('a::euclidean_space) set)"
    and "closed s"
    and "0 ∉ s"
  shows "∃a b. a ≠ 0 ∧ 0 < b ∧ (∀x∈s. inner a x > b)"
proof (cases "s = {}")
  case True
  have "norm ((SOME i. i∈Basis)::'a) = 1" "(SOME i. i∈Basis) ≠ (0::'a)"
    defer
    apply (subst norm_le_zero_iff[symmetric])
    apply (auto simp: SOME_Basis)
    done
  then show ?thesis
    apply (rule_tac x="SOME i. i∈Basis" in exI)
    apply (rule_tac x=1 in exI)
    using True using DIM_positive[where 'a='a]
    apply auto
    done
next
  case False
  then show ?thesis
    using False using separating_hyperplane_closed_point[OF assms]
    apply (elim exE)
    unfolding inner_zero_right
    apply (rule_tac x=a in exI)
    apply (rule_tac x=b in exI)
    apply auto
    done
qed


subsubsection {* Now set-to-set for closed/compact sets *}

lemma separating_hyperplane_closed_compact:
  fixes s :: "'a::euclidean_space set"
  assumes "convex s"
    and "closed s"
    and "convex t"
    and "compact t"
    and "t ≠ {}"
    and "s ∩ t = {}"
  shows "∃a b. (∀x∈s. inner a x < b) ∧ (∀x∈t. inner a x > b)"
proof (cases "s = {}")
  case True
  obtain b where b: "b > 0" "∀x∈t. norm x ≤ b"
    using compact_imp_bounded[OF assms(4)] unfolding bounded_pos by auto
  obtain z :: 'a where z: "norm z = b + 1"
    using vector_choose_size[of "b + 1"] and b(1) by auto
  then have "z ∉ t" using b(2)[THEN bspec[where x=z]] by auto
  then obtain a b where ab: "inner a z < b" "∀x∈t. b < inner a x"
    using separating_hyperplane_closed_point[OF assms(3) compact_imp_closed[OF assms(4)], of z]
    by auto
  then show ?thesis
    using True by auto
next
  case False
  then obtain y where "y ∈ s" by auto
  obtain a b where "0 < b" "∀x∈{x - y |x y. x ∈ s ∧ y ∈ t}. b < inner a x"
    using separating_hyperplane_closed_point[OF convex_differences[OF assms(1,3)], of 0]
    using closed_compact_differences[OF assms(2,4)]
    using assms(6) by auto blast
  then have ab: "∀x∈s. ∀y∈t. b + inner a y < inner a x"
    apply -
    apply rule
    apply rule
    apply (erule_tac x="x - y" in ballE)
    apply (auto simp add: inner_diff)
    done
  def k  "SUP x:t. a • x"
  show ?thesis
    apply (rule_tac x="-a" in exI)
    apply (rule_tac x="-(k + b / 2)" in exI)
    apply (intro conjI ballI)
    unfolding inner_minus_left and neg_less_iff_less
  proof -
    fix x assume "x ∈ t"
    then have "inner a x - b / 2 < k"
      unfolding k_def
    proof (subst less_cSUP_iff)
      show "t ≠ {}" by fact
      show "bdd_above (op • a ` t)"
        using ab[rule_format, of y] `y ∈ s`
        by (intro bdd_aboveI2[where M="inner a y - b"]) (auto simp: field_simps intro: less_imp_le)
    qed (auto intro!: bexI[of _ x] `0<b`)
    then show "inner a x < k + b / 2"
      by auto
  next
    fix x
    assume "x ∈ s"
    then have "k ≤ inner a x - b"
      unfolding k_def
      apply (rule_tac cSUP_least)
      using assms(5)
      using ab[THEN bspec[where x=x]]
      apply auto
      done
    then show "k + b / 2 < inner a x"
      using `0 < b` by auto
  qed
qed

lemma separating_hyperplane_compact_closed:
  fixes s :: "'a::euclidean_space set"
  assumes "convex s"
    and "compact s"
    and "s ≠ {}"
    and "convex t"
    and "closed t"
    and "s ∩ t = {}"
  shows "∃a b. (∀x∈s. inner a x < b) ∧ (∀x∈t. inner a x > b)"
proof -
  obtain a b where "(∀x∈t. inner a x < b) ∧ (∀x∈s. b < inner a x)"
    using separating_hyperplane_closed_compact[OF assms(4-5,1-2,3)] and assms(6)
    by auto
  then show ?thesis
    apply (rule_tac x="-a" in exI)
    apply (rule_tac x="-b" in exI)
    apply auto
    done
qed


subsubsection {* General case without assuming closure and getting non-strict separation *}

lemma separating_hyperplane_set_0:
  assumes "convex s" "(0::'a::euclidean_space) ∉ s"
  shows "∃a. a ≠ 0 ∧ (∀x∈s. 0 ≤ inner a x)"
proof -
  let ?k = "λc. {x::'a. 0 ≤ inner c x}"
  have "frontier (cball 0 1) ∩ (\<Inter> (?k ` s)) ≠ {}"
    apply (rule compact_imp_fip)
    apply (rule compact_frontier[OF compact_cball])
    defer
    apply rule
    apply rule
    apply (erule conjE)
  proof -
    fix f
    assume as: "f ⊆ ?k ` s" "finite f"
    obtain c where c: "f = ?k ` c" "c ⊆ s" "finite c"
      using finite_subset_image[OF as(2,1)] by auto
    then obtain a b where ab: "a ≠ 0" "0 < b" "∀x∈convex hull c. b < inner a x"
      using separating_hyperplane_closed_0[OF convex_convex_hull, of c]
      using finite_imp_compact_convex_hull[OF c(3), THEN compact_imp_closed] and assms(2)
      using subset_hull[of convex, OF assms(1), symmetric, of c]
      by auto
    then have "∃x. norm x = 1 ∧ (∀y∈c. 0 ≤ inner y x)"
      apply (rule_tac x = "inverse(norm a) *R a" in exI)
      using hull_subset[of c convex]
      unfolding subset_eq and inner_scaleR
      by (auto simp add: inner_commute del: ballE elim!: ballE)
    then show "frontier (cball 0 1) ∩ \<Inter>f ≠ {}"
      unfolding c(1) frontier_cball dist_norm by auto
  qed (insert closed_halfspace_ge, auto)
  then obtain x where "norm x = 1" "∀y∈s. x∈?k y"
    unfolding frontier_cball dist_norm by auto
  then show ?thesis
    apply (rule_tac x=x in exI)
    apply (auto simp add: inner_commute)
    done
qed

lemma separating_hyperplane_sets:
  fixes s t :: "'a::euclidean_space set"
  assumes "convex s"
    and "convex t"
    and "s ≠ {}"
    and "t ≠ {}"
    and "s ∩ t = {}"
  shows "∃a b. a ≠ 0 ∧ (∀x∈s. inner a x ≤ b) ∧ (∀x∈t. inner a x ≥ b)"
proof -
  from separating_hyperplane_set_0[OF convex_differences[OF assms(2,1)]]
  obtain a where "a ≠ 0" "∀x∈{x - y |x y. x ∈ t ∧ y ∈ s}. 0 ≤ inner a x"
    using assms(3-5) by auto
  then have *: "!!x y. x ∈ t ==> y ∈ s ==> inner a y ≤ inner a x"
    by (force simp add: inner_diff)
  then have bdd: "bdd_above ((op • a)`s)"
    using `t ≠ {}` by (auto intro: bdd_aboveI2[OF *])
  show ?thesis
    using `a≠0`
    by (intro exI[of _ a] exI[of _ "SUP x:s. a • x"])
       (auto intro!: cSUP_upper bdd cSUP_least `a ≠ 0` `s ≠ {}` *)
qed


subsection {* More convexity generalities *}

lemma convex_closure:
  fixes s :: "'a::real_normed_vector set"
  assumes "convex s"
  shows "convex (closure s)"
  apply (rule convexI)
  apply (unfold closure_sequential, elim exE)
  apply (rule_tac x="λn. u *R xa n + v *R xb n" in exI)
  apply (rule,rule)
  apply (rule convexD [OF assms])
  apply (auto del: tendsto_const intro!: tendsto_intros)
  done

lemma convex_interior:
  fixes s :: "'a::real_normed_vector set"
  assumes "convex s"
  shows "convex (interior s)"
  unfolding convex_alt Ball_def mem_interior
  apply (rule,rule,rule,rule,rule,rule)
  apply (elim exE conjE)
proof -
  fix x y u
  assume u: "0 ≤ u" "u ≤ (1::real)"
  fix e d
  assume ed: "ball x e ⊆ s" "ball y d ⊆ s" "0<d" "0<e"
  show "∃e>0. ball ((1 - u) *R x + u *R y) e ⊆ s"
    apply (rule_tac x="min d e" in exI)
    apply rule
    unfolding subset_eq
    defer
    apply rule
  proof -
    fix z
    assume "z ∈ ball ((1 - u) *R x + u *R y) (min d e)"
    then have "(1- u) *R (z - u *R (y - x)) + u *R (z + (1 - u) *R (y - x)) ∈ s"
      apply (rule_tac assms[unfolded convex_alt, rule_format])
      using ed(1,2) and u
      unfolding subset_eq mem_ball Ball_def dist_norm
      apply (auto simp add: algebra_simps)
      done
    then show "z ∈ s"
      using u by (auto simp add: algebra_simps)
  qed(insert u ed(3-4), auto)
qed

lemma convex_hull_eq_empty[simp]: "convex hull s = {} <-> s = {}"
  using hull_subset[of s convex] convex_hull_empty by auto


subsection {* Moving and scaling convex hulls. *}

lemma convex_hull_set_plus:
  "convex hull (s + t) = convex hull s + convex hull t"
  unfolding set_plus_image
  apply (subst convex_hull_linear_image [symmetric])
  apply (simp add: linear_iff scaleR_right_distrib)
  apply (simp add: convex_hull_Times)
  done

lemma translation_eq_singleton_plus: "(λx. a + x) ` t = {a} + t"
  unfolding set_plus_def by auto

lemma convex_hull_translation:
  "convex hull ((λx. a + x) ` s) = (λx. a + x) ` (convex hull s)"
  unfolding translation_eq_singleton_plus
  by (simp only: convex_hull_set_plus convex_hull_singleton)

lemma convex_hull_scaling:
  "convex hull ((λx. c *R x) ` s) = (λx. c *R x) ` (convex hull s)"
  using linear_scaleR by (rule convex_hull_linear_image [symmetric])

lemma convex_hull_affinity:
  "convex hull ((λx. a + c *R x) ` s) = (λx. a + c *R x) ` (convex hull s)"
  by(simp only: image_image[symmetric] convex_hull_scaling convex_hull_translation)


subsection {* Convexity of cone hulls *}

lemma convex_cone_hull:
  assumes "convex S"
  shows "convex (cone hull S)"
proof (rule convexI)
  fix x y
  assume xy: "x ∈ cone hull S" "y ∈ cone hull S"
  then have "S ≠ {}"
    using cone_hull_empty_iff[of S] by auto
  fix u v :: real
  assume uv: "u ≥ 0" "v ≥ 0" "u + v = 1"
  then have *: "u *R x ∈ cone hull S" "v *R y ∈ cone hull S"
    using cone_cone_hull[of S] xy cone_def[of "cone hull S"] by auto
  from * obtain cx :: real and xx where x: "u *R x = cx *R xx" "cx ≥ 0" "xx ∈ S"
    using cone_hull_expl[of S] by auto
  from * obtain cy :: real and yy where y: "v *R y = cy *R yy" "cy ≥ 0" "yy ∈ S"
    using cone_hull_expl[of S] by auto
  {
    assume "cx + cy ≤ 0"
    then have "u *R x = 0" and "v *R y = 0"
      using x y by auto
    then have "u *R x + v *R y = 0"
      by auto
    then have "u *R x + v *R y ∈ cone hull S"
      using cone_hull_contains_0[of S] `S ≠ {}` by auto
  }
  moreover
  {
    assume "cx + cy > 0"
    then have "(cx / (cx + cy)) *R xx + (cy / (cx + cy)) *R yy ∈ S"
      using assms mem_convex_alt[of S xx yy cx cy] x y by auto
    then have "cx *R xx + cy *R yy ∈ cone hull S"
      using mem_cone_hull[of "(cx/(cx+cy)) *R xx + (cy/(cx+cy)) *R yy" S "cx+cy"] `cx+cy>0`
      by (auto simp add: scaleR_right_distrib)
    then have "u *R x + v *R y ∈ cone hull S"
      using x y by auto
  }
  moreover have "cx + cy ≤ 0 ∨ cx + cy > 0" by auto
  ultimately show "u *R x + v *R y ∈ cone hull S" by blast
qed

lemma cone_convex_hull:
  assumes "cone S"
  shows "cone (convex hull S)"
proof (cases "S = {}")
  case True
  then show ?thesis by auto
next
  case False
  then have *: "0 ∈ S ∧ (∀c. c > 0 --> op *R c ` S = S)"
    using cone_iff[of S] assms by auto
  {
    fix c :: real
    assume "c > 0"
    then have "op *R c ` (convex hull S) = convex hull (op *R c ` S)"
      using convex_hull_scaling[of _ S] by auto
    also have "… = convex hull S"
      using * `c > 0` by auto
    finally have "op *R c ` (convex hull S) = convex hull S"
      by auto
  }
  then have "0 ∈ convex hull S" "!!c. c > 0 ==> (op *R c ` (convex hull S)) = (convex hull S)"
    using * hull_subset[of S convex] by auto
  then show ?thesis
    using `S ≠ {}` cone_iff[of "convex hull S"] by auto
qed

subsection {* Convex set as intersection of halfspaces *}

lemma convex_halfspace_intersection:
  fixes s :: "('a::euclidean_space) set"
  assumes "closed s" "convex s"
  shows "s = \<Inter> {h. s ⊆ h ∧ (∃a b. h = {x. inner a x ≤ b})}"
  apply (rule set_eqI)
  apply rule
  unfolding Inter_iff Ball_def mem_Collect_eq
  apply (rule,rule,erule conjE)
proof -
  fix x
  assume "∀xa. s ⊆ xa ∧ (∃a b. xa = {x. inner a x ≤ b}) --> x ∈ xa"
  then have "∀a b. s ⊆ {x. inner a x ≤ b} --> x ∈ {x. inner a x ≤ b}"
    by blast
  then show "x ∈ s"
    apply (rule_tac ccontr)
    apply (drule separating_hyperplane_closed_point[OF assms(2,1)])
    apply (erule exE)+
    apply (erule_tac x="-a" in allE)
    apply (erule_tac x="-b" in allE)
    apply auto
    done
qed auto


subsection {* Radon's theorem (from Lars Schewe) *}

lemma radon_ex_lemma:
  assumes "finite c" "affine_dependent c"
  shows "∃u. setsum u c = 0 ∧ (∃v∈c. u v ≠ 0) ∧ setsum (λv. u v *R v) c = 0"
proof -
  from assms(2)[unfolded affine_dependent_explicit]
  obtain s u where
      "finite s" "s ⊆ c" "setsum u s = 0" "∃v∈s. u v ≠ 0" "(∑v∈s. u v *R v) = 0"
    by blast
  then show ?thesis
    apply (rule_tac x="λv. if v∈s then u v else 0" in exI)
    unfolding if_smult scaleR_zero_left and setsum.inter_restrict[OF assms(1), symmetric]
    apply (auto simp add: Int_absorb1)
    done
qed

lemma radon_s_lemma:
  assumes "finite s"
    and "setsum f s = (0::real)"
  shows "setsum f {x∈s. 0 < f x} = - setsum f {x∈s. f x < 0}"
proof -
  have *: "!!x. (if f x < 0 then f x else 0) + (if 0 < f x then f x else 0) = f x"
    by auto
  show ?thesis
    unfolding real_add_eq_0_iff[symmetric] and setsum.inter_filter[OF assms(1)]
      and setsum.distrib[symmetric] and *
    using assms(2)
    apply assumption
    done
qed

lemma radon_v_lemma:
  assumes "finite s"
    and "setsum f s = 0"
    and "∀x. g x = (0::real) --> f x = (0::'a::euclidean_space)"
  shows "(setsum f {x∈s. 0 < g x}) = - setsum f {x∈s. g x < 0}"
proof -
  have *: "!!x. (if 0 < g x then f x else 0) + (if g x < 0 then f x else 0) = f x"
    using assms(3) by auto
  show ?thesis
    unfolding eq_neg_iff_add_eq_0 and setsum.inter_filter[OF assms(1)]
      and setsum.distrib[symmetric] and *
    using assms(2)
    apply assumption
    done
qed

lemma radon_partition:
  assumes "finite c" "affine_dependent c"
  shows "∃m p. m ∩ p = {} ∧ m ∪ p = c ∧ (convex hull m) ∩ (convex hull p) ≠ {}"
proof -
  obtain u v where uv: "setsum u c = 0" "v∈c" "u v ≠ 0"  "(∑v∈c. u v *R v) = 0"
    using radon_ex_lemma[OF assms] by auto
  have fin: "finite {x ∈ c. 0 < u x}" "finite {x ∈ c. 0 > u x}"
    using assms(1) by auto
  def z  "inverse (setsum u {x∈c. u x > 0}) *R setsum (λx. u x *R x) {x∈c. u x > 0}"
  have "setsum u {x ∈ c. 0 < u x} ≠ 0"
  proof (cases "u v ≥ 0")
    case False
    then have "u v < 0" by auto
    then show ?thesis
    proof (cases "∃w∈{x ∈ c. 0 < u x}. u w > 0")
      case True
      then show ?thesis
        using setsum_nonneg_eq_0_iff[of _ u, OF fin(1)] by auto
    next
      case False
      then have "setsum u c ≤ setsum (λx. if x=v then u v else 0) c"
        apply (rule_tac setsum_mono)
        apply auto
        done
      then show ?thesis
        unfolding setsum.delta[OF assms(1)] using uv(2) and `u v < 0` and uv(1) by auto
    qed
  qed (insert setsum_nonneg_eq_0_iff[of _ u, OF fin(1)] uv(2-3), auto)

  then have *: "setsum u {x∈c. u x > 0} > 0"
    unfolding less_le
    apply (rule_tac conjI)
    apply (rule_tac setsum_nonneg)
    apply auto
    done
  moreover have "setsum u ({x ∈ c. 0 < u x} ∪ {x ∈ c. u x < 0}) = setsum u c"
    "(∑x∈{x ∈ c. 0 < u x} ∪ {x ∈ c. u x < 0}. u x *R x) = (∑x∈c. u x *R x)"
    using assms(1)
    apply (rule_tac[!] setsum.mono_neutral_left)
    apply auto
    done
  then have "setsum u {x ∈ c. 0 < u x} = - setsum u {x ∈ c. 0 > u x}"
    "(∑x∈{x ∈ c. 0 < u x}. u x *R x) = - (∑x∈{x ∈ c. 0 > u x}. u x *R x)"
    unfolding eq_neg_iff_add_eq_0
    using uv(1,4)
    by (auto simp add: setsum.union_inter_neutral[OF fin, symmetric])
  moreover have "∀x∈{v ∈ c. u v < 0}. 0 ≤ inverse (setsum u {x ∈ c. 0 < u x}) * - u x"
    apply rule
    apply (rule mult_nonneg_nonneg)
    using *
    apply auto
    done
  ultimately have "z ∈ convex hull {v ∈ c. u v ≤ 0}"
    unfolding convex_hull_explicit mem_Collect_eq
    apply (rule_tac x="{v ∈ c. u v < 0}" in exI)
    apply (rule_tac x="λy. inverse (setsum u {x∈c. u x > 0}) * - u y" in exI)
    using assms(1) unfolding scaleR_scaleR[symmetric] scaleR_right.setsum [symmetric] and z_def
    apply (auto simp add: setsum_negf setsum_right_distrib[symmetric])
    done
  moreover have "∀x∈{v ∈ c. 0 < u v}. 0 ≤ inverse (setsum u {x ∈ c. 0 < u x}) * u x"
    apply rule
    apply (rule mult_nonneg_nonneg)
    using *
    apply auto
    done
  then have "z ∈ convex hull {v ∈ c. u v > 0}"
    unfolding convex_hull_explicit mem_Collect_eq
    apply (rule_tac x="{v ∈ c. 0 < u v}" in exI)
    apply (rule_tac x="λy. inverse (setsum u {x∈c. u x > 0}) * u y" in exI)
    using assms(1)
    unfolding scaleR_scaleR[symmetric] scaleR_right.setsum [symmetric] and z_def
    using *
    apply (auto simp add: setsum_negf setsum_right_distrib[symmetric])
    done
  ultimately show ?thesis
    apply (rule_tac x="{v∈c. u v ≤ 0}" in exI)
    apply (rule_tac x="{v∈c. u v > 0}" in exI)
    apply auto
    done
qed

lemma radon:
  assumes "affine_dependent c"
  obtains m p where "m ⊆ c" "p ⊆ c" "m ∩ p = {}" "(convex hull m) ∩ (convex hull p) ≠ {}"
proof -
  from assms[unfolded affine_dependent_explicit]
  obtain s u where
      "finite s" "s ⊆ c" "setsum u s = 0" "∃v∈s. u v ≠ 0" "(∑v∈s. u v *R v) = 0"
    by blast
  then have *: "finite s" "affine_dependent s" and s: "s ⊆ c"
    unfolding affine_dependent_explicit by auto
  from radon_partition[OF *]
  obtain m p where "m ∩ p = {}" "m ∪ p = s" "convex hull m ∩ convex hull p ≠ {}"
    by blast
  then show ?thesis
    apply (rule_tac that[of p m])
    using s
    apply auto
    done
qed


subsection {* Helly's theorem *}

lemma helly_induct:
  fixes f :: "'a::euclidean_space set set"
  assumes "card f = n"
    and "n ≥ DIM('a) + 1"
    and "∀s∈f. convex s" "∀t⊆f. card t = DIM('a) + 1 --> \<Inter> t ≠ {}"
  shows "\<Inter>f ≠ {}"
  using assms
proof (induct n arbitrary: f)
  case 0
  then show ?case by auto
next
  case (Suc n)
  have "finite f"
    using `card f = Suc n` by (auto intro: card_ge_0_finite)
  show "\<Inter>f ≠ {}"
    apply (cases "n = DIM('a)")
    apply (rule Suc(5)[rule_format])
    unfolding `card f = Suc n`
  proof -
    assume ng: "n ≠ DIM('a)"
    then have "∃X. ∀s∈f. X s ∈ \<Inter>(f - {s})"
      apply (rule_tac bchoice)
      unfolding ex_in_conv
      apply (rule, rule Suc(1)[rule_format])
      unfolding card_Diff_singleton_if[OF `finite f`] `card f = Suc n`
      defer
      defer
      apply (rule Suc(4)[rule_format])
      defer
      apply (rule Suc(5)[rule_format])
      using Suc(3) `finite f`
      apply auto
      done
    then obtain X where X: "∀s∈f. X s ∈ \<Inter>(f - {s})" by auto
    show ?thesis
    proof (cases "inj_on X f")
      case False
      then obtain s t where st: "s≠t" "s∈f" "t∈f" "X s = X t"
        unfolding inj_on_def by auto
      then have *: "\<Inter>f = \<Inter>(f - {s}) ∩ \<Inter>(f - {t})" by auto
      show ?thesis
        unfolding *
        unfolding ex_in_conv[symmetric]
        apply (rule_tac x="X s" in exI)
        apply rule
        apply (rule X[rule_format])
        using X st
        apply auto
        done
    next
      case True
      then obtain m p where mp: "m ∩ p = {}" "m ∪ p = X ` f" "convex hull m ∩ convex hull p ≠ {}"
        using radon_partition[of "X ` f"] and affine_dependent_biggerset[of "X ` f"]
        unfolding card_image[OF True] and `card f = Suc n`
        using Suc(3) `finite f` and ng
        by auto
      have "m ⊆ X ` f" "p ⊆ X ` f"
        using mp(2) by auto
      then obtain g h where gh:"m = X ` g" "p = X ` h" "g ⊆ f" "h ⊆ f"
        unfolding subset_image_iff by auto
      then have "f ∪ (g ∪ h) = f" by auto
      then have f: "f = g ∪ h"
        using inj_on_Un_image_eq_iff[of X f "g ∪ h"] and True
        unfolding mp(2)[unfolded image_Un[symmetric] gh]
        by auto
      have *: "g ∩ h = {}"
        using mp(1)
        unfolding gh
        using inj_on_image_Int[OF True gh(3,4)]
        by auto
      have "convex hull (X ` h) ⊆ \<Inter>g" "convex hull (X ` g) ⊆ \<Inter>h"
        apply (rule_tac [!] hull_minimal)
        using Suc gh(3-4)
        unfolding subset_eq
        apply (rule_tac [2] convex_Inter, rule_tac [4] convex_Inter)
        apply rule
        prefer 3
        apply rule
      proof -
        fix x
        assume "x ∈ X ` g"
        then obtain y where "y ∈ g" "x = X y"
          unfolding image_iff ..
        then show "x ∈ \<Inter>h"
          using X[THEN bspec[where x=y]] using * f by auto
      next
        fix x
        assume "x ∈ X ` h"
        then obtain y where "y ∈ h" "x = X y"
          unfolding image_iff ..
        then show "x ∈ \<Inter>g"
          using X[THEN bspec[where x=y]] using * f by auto
      qed auto
      then show ?thesis
        unfolding f using mp(3)[unfolded gh] by blast
    qed
  qed auto
qed

lemma helly:
  fixes f :: "'a::euclidean_space set set"
  assumes "card f ≥ DIM('a) + 1" "∀s∈f. convex s"
    and "∀t⊆f. card t = DIM('a) + 1 --> \<Inter> t ≠ {}"
  shows "\<Inter>f ≠ {}"
  apply (rule helly_induct)
  using assms
  apply auto
  done


subsection {* Homeomorphism of all convex compact sets with nonempty interior *}

lemma compact_frontier_line_lemma:
  fixes s :: "'a::euclidean_space set"
  assumes "compact s"
    and "0 ∈ s"
    and "x ≠ 0"
  obtains u where "0 ≤ u" and "(u *R x) ∈ frontier s" "∀v>u. (v *R x) ∉ s"
proof -
  obtain b where b: "b > 0" "∀x∈s. norm x ≤ b"
    using compact_imp_bounded[OF assms(1), unfolded bounded_pos] by auto
  let ?A = "{y. ∃u. 0 ≤ u ∧ u ≤ b / norm(x) ∧ (y = u *R x)}"
  have A: "?A = (λu. u *R x) ` {0 .. b / norm x}"
    by auto
  have *: "!!x A B. x∈A ==> x∈B ==> A∩B ≠ {}" by blast
  have "compact ?A"
    unfolding A
    apply (rule compact_continuous_image)
    apply (rule continuous_at_imp_continuous_on)
    apply rule
    apply (intro continuous_intros)
    apply (rule compact_Icc)
    done
  moreover have "{y. ∃u≥0. u ≤ b / norm x ∧ y = u *R x} ∩ s ≠ {}"
    apply(rule *[OF _ assms(2)])
    unfolding mem_Collect_eq
    using `b > 0` assms(3)
    apply auto
    done
  ultimately obtain u y where obt: "u≥0" "u ≤ b / norm x" "y = u *R x"
    "y ∈ ?A" "y ∈ s" "∀z∈?A ∩ s. dist 0 z ≤ dist 0 y"
    using distance_attains_sup[OF compact_inter[OF _ assms(1), of ?A], of 0]
    by auto

  have "norm x > 0"
    using assms(3)[unfolded zero_less_norm_iff[symmetric]] by auto
  {
    fix v
    assume as: "v > u" "v *R x ∈ s"
    then have "v ≤ b / norm x"
      using b(2)[rule_format, OF as(2)]
      using `u≥0`
      unfolding pos_le_divide_eq[OF `norm x > 0`]
      by auto
    then have "norm (v *R x) ≤ norm y"
      apply (rule_tac obt(6)[rule_format, unfolded dist_0_norm])
      apply (rule IntI)
      defer
      apply (rule as(2))
      unfolding mem_Collect_eq
      apply (rule_tac x=v in exI)
      using as(1) `u≥0`
      apply (auto simp add: field_simps)
      done
    then have False
      unfolding obt(3) using `u≥0` `norm x > 0` `v > u`
      by (auto simp add:field_simps)
  } note u_max = this

  have "u *R x ∈ frontier s"
    unfolding frontier_straddle
    apply (rule,rule,rule)
    apply (rule_tac x="u *R x" in bexI)
    unfolding obt(3)[symmetric]
    prefer 3
    apply (rule_tac x="(u + (e / 2) / norm x) *R x" in exI)
    apply (rule, rule)
  proof -
    fix e
    assume "e > 0" and as: "(u + e / 2 / norm x) *R x ∈ s"
    then have "u + e / 2 / norm x > u"
      using `norm x > 0` by (auto simp del:zero_less_norm_iff)
    then show False using u_max[OF _ as] by auto
  qed (insert `y∈s`, auto simp add: dist_norm scaleR_left_distrib obt(3))
  then show ?thesis by(metis that[of u] u_max obt(1))
qed

lemma starlike_compact_projective:
  assumes "compact s"
    and "cball (0::'a::euclidean_space) 1 ⊆ s "
    and "∀x∈s. ∀u. 0 ≤ u ∧ u < 1 --> u *R x ∈ s - frontier s"
  shows "s homeomorphic (cball (0::'a::euclidean_space) 1)"
proof -
  have fs: "frontier s ⊆ s"
    apply (rule frontier_subset_closed)
    using compact_imp_closed[OF assms(1)]
    apply simp
    done
  def pi  "λx::'a. inverse (norm x) *R x"
  have "0 ∉ frontier s"
    unfolding frontier_straddle
    apply (rule notI)
    apply (erule_tac x=1 in allE)
    using assms(2)[unfolded subset_eq Ball_def mem_cball]
    apply auto
    done
  have injpi: "!!x y. pi x = pi y ∧ norm x = norm y <-> x = y"
    unfolding pi_def by auto

  have contpi: "continuous_on (UNIV - {0}) pi"
    apply (rule continuous_at_imp_continuous_on)
    apply rule unfolding pi_def
    apply (intro continuous_intros)
    apply simp
    done
  def sphere  "{x::'a. norm x = 1}"
  have pi: "!!x. x ≠ 0 ==> pi x ∈ sphere" "!!x u. u>0 ==> pi (u *R x) = pi x"
    unfolding pi_def sphere_def by auto

  have "0 ∈ s"
    using assms(2) and centre_in_cball[of 0 1] by auto
  have front_smul: "∀x∈frontier s. ∀u≥0. u *R x ∈ s <-> u ≤ 1"
  proof (rule,rule,rule)
    fix x and u :: real
    assume x: "x ∈ frontier s" and "0 ≤ u"
    then have "x ≠ 0"
      using `0 ∉ frontier s` by auto
    obtain v where v: "0 ≤ v" "v *R x ∈ frontier s" "∀w>v. w *R x ∉ s"
      using compact_frontier_line_lemma[OF assms(1) `0∈s` `x≠0`] by auto
    have "v = 1"
      apply (rule ccontr)
      unfolding neq_iff
      apply (erule disjE)
    proof -
      assume "v < 1"
      then show False
        using v(3)[THEN spec[where x=1]] using x and fs by auto
    next
      assume "v > 1"
      then show False
        using assms(3)[THEN bspec[where x="v *R x"], THEN spec[where x="inverse v"]]
        using v and x and fs
        unfolding inverse_less_1_iff by auto
    qed
    show "u *R x ∈ s <-> u ≤ 1"
      apply rule
      using v(3)[unfolded `v=1`, THEN spec[where x=u]]
    proof -
      assume "u ≤ 1"
      then show "u *R x ∈ s"
      apply (cases "u = 1")
        using assms(3)[THEN bspec[where x=x], THEN spec[where x=u]]
        using `0≤u` and x and fs
        apply auto
        done
    qed auto
  qed

  have "∃surf. homeomorphism (frontier s) sphere pi surf"
    apply (rule homeomorphism_compact)
    apply (rule compact_frontier[OF assms(1)])
    apply (rule continuous_on_subset[OF contpi])
    defer
    apply (rule set_eqI)
    apply rule
    unfolding inj_on_def
    prefer 3
    apply(rule,rule,rule)
  proof -
    fix x
    assume "x ∈ pi ` frontier s"
    then obtain y where "y ∈ frontier s" "x = pi y" by auto
    then show "x ∈ sphere"
      using pi(1)[of y] and `0 ∉ frontier s` by auto
  next
    fix x
    assume "x ∈ sphere"
    then have "norm x = 1" "x ≠ 0"
      unfolding sphere_def by auto
    then obtain u where "0 ≤ u" "u *R x ∈ frontier s" "∀v>u. v *R x ∉ s"
      using compact_frontier_line_lemma[OF assms(1) `0∈s`, of x] by auto
    then show "x ∈ pi ` frontier s"
      unfolding image_iff le_less pi_def
      apply (rule_tac x="u *R x" in bexI)
      using `norm x = 1` `0 ∉ frontier s`
      apply auto
      done
  next
    fix x y
    assume as: "x ∈ frontier s" "y ∈ frontier s" "pi x = pi y"
    then have xys: "x ∈ s" "y ∈ s"
      using fs by auto
    from as(1,2) have nor: "norm x ≠ 0" "norm y ≠ 0"
      using `0∉frontier s` by auto
    from nor have x: "x = norm x *R ((inverse (norm y)) *R y)"
      unfolding as(3)[unfolded pi_def, symmetric] by auto
    from nor have y: "y = norm y *R ((inverse (norm x)) *R x)"
      unfolding as(3)[unfolded pi_def] by auto
    have "0 ≤ norm y * inverse (norm x)" and "0 ≤ norm x * inverse (norm y)"
      using nor
      apply auto
      done
    then have "norm x = norm y"
      apply -
      apply (rule ccontr)
      unfolding neq_iff
      using x y and front_smul[THEN bspec, OF as(1), THEN spec[where x="norm y * (inverse (norm x))"]]
      using front_smul[THEN bspec, OF as(2), THEN spec[where x="norm x * (inverse (norm y))"]]
      using xys nor
      apply (auto simp add: field_simps)
      done
    then show "x = y"
      apply (subst injpi[symmetric])
      using as(3)
      apply auto
      done
  qed (insert `0 ∉ frontier s`, auto)
  then obtain surf where
    surf: "∀x∈frontier s. surf (pi x) = x"  "pi ` frontier s = sphere" "continuous_on (frontier s) pi"
    "∀y∈sphere. pi (surf y) = y" "surf ` sphere = frontier s" "continuous_on sphere surf"
    unfolding homeomorphism_def by auto

  have cont_surfpi: "continuous_on (UNIV -  {0}) (surf o pi)"
    apply (rule continuous_on_compose)
    apply (rule contpi)
    apply (rule continuous_on_subset[of sphere])
    apply (rule surf(6))
    using pi(1)
    apply auto
    done

  {
    fix x
    assume as: "x ∈ cball (0::'a) 1"
    have "norm x *R surf (pi x) ∈ s"
    proof (cases "x=0 ∨ norm x = 1")
      case False
      then have "pi x ∈ sphere" "norm x < 1"
        using pi(1)[of x] as by(auto simp add: dist_norm)
      then show ?thesis
        apply (rule_tac assms(3)[rule_format, THEN DiffD1])
        apply (rule_tac fs[unfolded subset_eq, rule_format])
        unfolding surf(5)[symmetric]
        apply auto
        done
    next
      case True
      then show ?thesis
        apply rule
        defer
        unfolding pi_def
        apply (rule fs[unfolded subset_eq, rule_format])
        unfolding surf(5)[unfolded sphere_def, symmetric]
        using `0∈s`
        apply auto
        done
    qed
  } note hom = this

  {
    fix x
    assume "x ∈ s"
    then have "x ∈ (λx. norm x *R surf (pi x)) ` cball 0 1"
    proof (cases "x = 0")
      case True
      show ?thesis
        unfolding image_iff True
        apply (rule_tac x=0 in bexI)
        apply auto
        done
    next
      let ?a = "inverse (norm (surf (pi x)))"
      case False
      then have invn: "inverse (norm x) ≠ 0" by auto
      from False have pix: "pi x∈sphere" using pi(1) by auto
      then have "pi (surf (pi x)) = pi x"
        apply (rule_tac surf(4)[rule_format])
        apply assumption
        done
      then have **: "norm x *R (?a *R surf (pi x)) = x"
        apply (rule_tac scaleR_left_imp_eq[OF invn])
        unfolding pi_def
        using invn
        apply auto
        done
      then have *: "?a * norm x > 0" and "?a > 0" "?a ≠ 0"
        using surf(5) `0∉frontier s`
        apply -
        apply (rule mult_pos_pos)
        using False[unfolded zero_less_norm_iff[symmetric]]
        apply auto
        done
      have "norm (surf (pi x)) ≠ 0"
        using ** False by auto
      then have "norm x = norm ((?a * norm x) *R surf (pi x))"
        unfolding norm_scaleR abs_mult abs_norm_cancel abs_of_pos[OF `?a > 0`] by auto
      moreover have "pi x = pi ((inverse (norm (surf (pi x))) * norm x) *R surf (pi x))"
        unfolding pi(2)[OF *] surf(4)[rule_format, OF pix] ..
      moreover have "surf (pi x) ∈ frontier s"
        using surf(5) pix by auto
      then have "dist 0 (inverse (norm (surf (pi x))) *R x) ≤ 1"
        unfolding dist_norm
        using ** and *
        using front_smul[THEN bspec[where x="surf (pi x)"], THEN spec[where x="norm x * ?a"]]
        using False `x∈s`
        by (auto simp add: field_simps)
      ultimately show ?thesis
        unfolding image_iff
        apply (rule_tac x="inverse (norm (surf(pi x))) *R x" in bexI)
        apply (subst injpi[symmetric])
        unfolding abs_mult abs_norm_cancel abs_of_pos[OF `?a > 0`]
        unfolding pi(2)[OF `?a > 0`]
        apply auto
        done
    qed
  } note hom2 = this

  show ?thesis
    apply (subst homeomorphic_sym)
    apply (rule homeomorphic_compact[where f="λx. norm x *R surf (pi x)"])
    apply (rule compact_cball)
    defer
    apply (rule set_eqI)
    apply rule
    apply (erule imageE)
    apply (drule hom)
    prefer 4
    apply (rule continuous_at_imp_continuous_on)
    apply rule
    apply (rule_tac [3] hom2)
  proof -
    fix x :: 'a
    assume as: "x ∈ cball 0 1"
    then show "continuous (at x) (λx. norm x *R surf (pi x))"
    proof (cases "x = 0")
      case False
      then show ?thesis
        apply (intro continuous_intros)
        using cont_surfpi
        unfolding continuous_on_eq_continuous_at[OF open_delete[OF open_UNIV]] o_def
        apply auto
        done
    next
      case True
      obtain B where B: "∀x∈s. norm x ≤ B"
        using compact_imp_bounded[OF assms(1)] unfolding bounded_iff by auto
      then have "B > 0"
        using assms(2)
        unfolding subset_eq
        apply (erule_tac x="SOME i. i∈Basis" in ballE)
        defer
        apply (erule_tac x="SOME i. i∈Basis" in ballE)
        unfolding Ball_def mem_cball dist_norm
        using DIM_positive[where 'a='a]
        apply (auto simp: SOME_Basis)
        done
      show ?thesis
        unfolding True continuous_at Lim_at
        apply(rule,rule)
        apply(rule_tac x="e / B" in exI)
        apply rule
        apply (rule divide_pos_pos)
        prefer 3
        apply(rule,rule,erule conjE)
        unfolding norm_zero scaleR_zero_left dist_norm diff_0_right norm_scaleR abs_norm_cancel
      proof -
        fix e and x :: 'a
        assume as: "norm x < e / B" "0 < norm x" "e > 0"
        then have "surf (pi x) ∈ frontier s"
          using pi(1)[of x] unfolding surf(5)[symmetric] by auto
        then have "norm (surf (pi x)) ≤ B"
          using B fs by auto
        then have "norm x * norm (surf (pi x)) ≤ norm x * B"
          using as(2) by auto
        also have "… < e / B * B"
          apply (rule mult_strict_right_mono)
          using as(1) `B>0`
          apply auto
          done
        also have "… = e" using `B > 0` by auto
        finally show "norm x * norm (surf (pi x)) < e" .
      qed (insert `B>0`, auto)
    qed
  next
    {
      fix x
      assume as: "surf (pi x) = 0"
      have "x = 0"
      proof (rule ccontr)
        assume "x ≠ 0"
        then have "pi x ∈ sphere"
          using pi(1) by auto
        then have "surf (pi x) ∈ frontier s"
          using surf(5) by auto
        then show False
          using `0∉frontier s` unfolding as by simp
      qed
    } note surf_0 = this
    show "inj_on (λx. norm x *R surf (pi x)) (cball 0 1)"
      unfolding inj_on_def
    proof (rule,rule,rule)
      fix x y
      assume as: "x ∈ cball 0 1" "y ∈ cball 0 1" "norm x *R surf (pi x) = norm y *R surf (pi y)"
      then show "x = y"
      proof (cases "x=0 ∨ y=0")
        case True
        then show ?thesis
          using as by (auto elim: surf_0)
      next
        case False
        then have "pi (surf (pi x)) = pi (surf (pi y))"
          using as(3)
          using pi(2)[of "norm x" "surf (pi x)"] pi(2)[of "norm y" "surf (pi y)"]
          by auto
        moreover have "pi x ∈ sphere" "pi y ∈ sphere"
          using pi(1) False by auto
        ultimately have *: "pi x = pi y"
          using surf(4)[THEN bspec[where x="pi x"]] surf(4)[THEN bspec[where x="pi y"]]
          by auto
        moreover have "norm x = norm y"
          using as(3)[unfolded *] using False
          by (auto dest:surf_0)
        ultimately show ?thesis
          using injpi by auto
      qed
    qed
  qed auto
qed

lemma homeomorphic_convex_compact_lemma:
  fixes s :: "'a::euclidean_space set"
  assumes "convex s"
    and "compact s"
    and "cball 0 1 ⊆ s"
  shows "s homeomorphic (cball (0::'a) 1)"
proof (rule starlike_compact_projective[OF assms(2-3)], clarify)
  fix x u
  assume "x ∈ s" and "0 ≤ u" and "u < (1::real)"
  have "open (ball (u *R x) (1 - u))"
    by (rule open_ball)
  moreover have "u *R x ∈ ball (u *R x) (1 - u)"
    unfolding centre_in_ball using `u < 1` by simp
  moreover have "ball (u *R x) (1 - u) ⊆ s"
  proof
    fix y
    assume "y ∈ ball (u *R x) (1 - u)"
    then have "dist (u *R x) y < 1 - u"
      unfolding mem_ball .
    with `u < 1` have "inverse (1 - u) *R (y - u *R x) ∈ cball 0 1"
      by (simp add: dist_norm inverse_eq_divide norm_minus_commute)
    with assms(3) have "inverse (1 - u) *R (y - u *R x) ∈ s" ..
    with assms(1) have "(1 - u) *R ((y - u *R x) /R (1 - u)) + u *R x ∈ s"
      using `x ∈ s` `0 ≤ u` `u < 1` [THEN less_imp_le] by (rule mem_convex)
    then show "y ∈ s" using `u < 1`
      by simp
  qed
  ultimately have "u *R x ∈ interior s" ..
  then show "u *R x ∈ s - frontier s"
    using frontier_def and interior_subset by auto
qed

lemma homeomorphic_convex_compact_cball:
  fixes e :: real
    and s :: "'a::euclidean_space set"
  assumes "convex s"
    and "compact s"
    and "interior s ≠ {}"
    and "e > 0"
  shows "s homeomorphic (cball (b::'a) e)"
proof -
  obtain a where "a ∈ interior s"
    using assms(3) by auto
  then obtain d where "d > 0" and d: "cball a d ⊆ s"
    unfolding mem_interior_cball by auto
  let ?d = "inverse d" and ?n = "0::'a"
  have "cball ?n 1 ⊆ (λx. inverse d *R (x - a)) ` s"
    apply rule
    apply (rule_tac x="d *R x + a" in image_eqI)
    defer
    apply (rule d[unfolded subset_eq, rule_format])
    using `d > 0`
    unfolding mem_cball dist_norm
    apply (auto simp add: mult_right_le_one_le)
    done
  then have "(λx. inverse d *R (x - a)) ` s homeomorphic cball ?n 1"
    using homeomorphic_convex_compact_lemma[of "(λx. ?d *R -a + ?d *R x) ` s",
      OF convex_affinity compact_affinity]
    using assms(1,2)
    by (auto simp add: scaleR_right_diff_distrib)
  then show ?thesis
    apply (rule_tac homeomorphic_trans[OF _ homeomorphic_balls(2)[of 1 _ ?n]])
    apply (rule homeomorphic_trans[OF homeomorphic_affinity[of "?d" s "?d *R -a"]])
    using `d>0` `e>0`
    apply (auto simp add: scaleR_right_diff_distrib)
    done
qed

lemma homeomorphic_convex_compact:
  fixes s :: "'a::euclidean_space set"
    and t :: "'a set"
  assumes "convex s" "compact s" "interior s ≠ {}"
    and "convex t" "compact t" "interior t ≠ {}"
  shows "s homeomorphic t"
  using assms
  by (meson zero_less_one homeomorphic_trans homeomorphic_convex_compact_cball homeomorphic_sym)


subsection {* Epigraphs of convex functions *}

definition "epigraph s (f :: _ => real) = {xy. fst xy ∈ s ∧ f (fst xy) ≤ snd xy}"

lemma mem_epigraph: "(x, y) ∈ epigraph s f <-> x ∈ s ∧ f x ≤ y"
  unfolding epigraph_def by auto

lemma convex_epigraph: "convex (epigraph s f) <-> convex_on s f ∧ convex s"
  unfolding convex_def convex_on_def
  unfolding Ball_def split_paired_All epigraph_def
  unfolding mem_Collect_eq fst_conv snd_conv fst_add snd_add fst_scaleR snd_scaleR Ball_def[symmetric]
  apply safe
  defer
  apply (erule_tac x=x in allE)
  apply (erule_tac x="f x" in allE)
  apply safe
  apply (erule_tac x=xa in allE)
  apply (erule_tac x="f xa" in allE)
  prefer 3
  apply (rule_tac y="u * f a + v * f aa" in order_trans)
  defer
  apply (auto intro!:mult_left_mono add_mono)
  done

lemma convex_epigraphI: "convex_on s f ==> convex s ==> convex (epigraph s f)"
  unfolding convex_epigraph by auto

lemma convex_epigraph_convex: "convex s ==> convex_on s f <-> convex(epigraph s f)"
  by (simp add: convex_epigraph)


subsubsection {* Use this to derive general bound property of convex function *}

lemma convex_on:
  assumes "convex s"
  shows "convex_on s f <->
    (∀k u x. (∀i∈{1..k::nat}. 0 ≤ u i ∧ x i ∈ s) ∧ setsum u {1..k} = 1 -->
      f (setsum (λi. u i *R x i) {1..k} ) ≤ setsum (λi. u i * f(x i)) {1..k})"
  unfolding convex_epigraph_convex[OF assms] convex epigraph_def Ball_def mem_Collect_eq
  unfolding fst_setsum snd_setsum fst_scaleR snd_scaleR
  apply safe
  apply (drule_tac x=k in spec)
  apply (drule_tac x=u in spec)
  apply (drule_tac x="λi. (x i, f (x i))" in spec)
  apply simp
  using assms[unfolded convex]
  apply simp
  apply (rule_tac y="∑i = 1..k. u i * f (fst (x i))" in order_trans)
  defer
  apply (rule setsum_mono)
  apply (erule_tac x=i in allE)
  unfolding real_scaleR_def
  apply (rule mult_left_mono)
  using assms[unfolded convex]
  apply auto
  done


subsection {* Convexity of general and special intervals *}

lemma is_interval_convex:
  fixes s :: "'a::euclidean_space set"
  assumes "is_interval s"
  shows "convex s"
proof (rule convexI)
  fix x y and u v :: real
  assume as: "x ∈ s" "y ∈ s" "0 ≤ u" "0 ≤ v" "u + v = 1"
  then have *: "u = 1 - v" "1 - v ≥ 0" and **: "v = 1 - u" "1 - u ≥ 0"
    by auto
  {
    fix a b
    assume "¬ b ≤ u * a + v * b"
    then have "u * a < (1 - v) * b"
      unfolding not_le using as(4) by (auto simp add: field_simps)
    then have "a < b"
      unfolding * using as(4) *(2)
      apply (rule_tac mult_left_less_imp_less[of "1 - v"])
      apply (auto simp add: field_simps)
      done
    then have "a ≤ u * a + v * b"
      unfolding * using as(4)
      by (auto simp add: field_simps intro!:mult_right_mono)
  }
  moreover
  {
    fix a b
    assume "¬ u * a + v * b ≤ a"
    then have "v * b > (1 - u) * a"
      unfolding not_le using as(4) by (auto simp add: field_simps)
    then have "a < b"
      unfolding * using as(4)
      apply (rule_tac mult_left_less_imp_less)
      apply (auto simp add: field_simps)
      done
    then have "u * a + v * b ≤ b"
      unfolding **
      using **(2) as(3)
      by (auto simp add: field_simps intro!:mult_right_mono)
  }
  ultimately show "u *R x + v *R y ∈ s"
    apply -
    apply (rule assms[unfolded is_interval_def, rule_format, OF as(1,2)])
    using as(3-) DIM_positive[where 'a='a]
    apply (auto simp: inner_simps)
    done
qed

lemma is_interval_connected:
  fixes s :: "'a::euclidean_space set"
  shows "is_interval s ==> connected s"
  using is_interval_convex convex_connected by auto

lemma convex_box: "convex (cbox a b)" "convex (box a (b::'a::euclidean_space))"
  apply (rule_tac[!] is_interval_convex)+
  using is_interval_box is_interval_cbox
  apply auto
  done

subsection {* On @{text "real"}, @{text "is_interval"}, @{text "convex"} and @{text "connected"} are all equivalent. *}

lemma is_interval_1:
  "is_interval (s::real set) <-> (∀a∈s. ∀b∈s. ∀ x. a ≤ x ∧ x ≤ b --> x ∈ s)"
  unfolding is_interval_def by auto

lemma is_interval_connected_1:
  fixes s :: "real set"
  shows "is_interval s <-> connected s"
  apply rule
  apply (rule is_interval_connected, assumption)
  unfolding is_interval_1
  apply rule
  apply rule
  apply rule
  apply rule
  apply (erule conjE)
  apply (rule ccontr)
proof -
  fix a b x
  assume as: "connected s" "a ∈ s" "b ∈ s" "a ≤ x" "x ≤ b" "x ∉ s"
  then have *: "a < x" "x < b"
    unfolding not_le [symmetric] by auto
  let ?halfl = "{..<x} "
  let ?halfr = "{x<..}"
  {
    fix y
    assume "y ∈ s"
    with `x ∉ s` have "x ≠ y" by auto
    then have "y ∈ ?halfr ∪ ?halfl" by auto
  }
  moreover have "a ∈ ?halfl" "b ∈ ?halfr" using * by auto
  then have "?halfl ∩ s ≠ {}" "?halfr ∩ s ≠ {}"
    using as(2-3) by auto
  ultimately show False
    apply (rule_tac notE[OF as(1)[unfolded connected_def]])
    apply (rule_tac x = ?halfl in exI)
    apply (rule_tac x = ?halfr in exI)
    apply rule
    apply (rule open_lessThan)
    apply rule
    apply (rule open_greaterThan)
    apply auto
    done
qed

lemma is_interval_convex_1:
  fixes s :: "real set"
  shows "is_interval s <-> convex s"
  by (metis is_interval_convex convex_connected is_interval_connected_1)

lemma convex_connected_1:
  fixes s :: "real set"
  shows "connected s <-> convex s"
  by (metis is_interval_convex convex_connected is_interval_connected_1)


subsection {* Another intermediate value theorem formulation *}

lemma ivt_increasing_component_on_1:
  fixes f :: "real => 'a::euclidean_space"
  assumes "a ≤ b"
    and "continuous_on (cbox a b) f"
    and "(f a)•k ≤ y" "y ≤ (f b)•k"
  shows "∃x∈cbox a b. (f x)•k = y"
proof -
  have "f a ∈ f ` cbox a b" "f b ∈ f ` cbox a b"
    apply (rule_tac[!] imageI)
    using assms(1)
    apply auto
    done
  then show ?thesis
    using connected_ivt_component[of "f ` cbox a b" "f a" "f b" k y]
    using connected_continuous_image[OF assms(2) convex_connected[OF convex_box(1)]]
    using assms
    by auto
qed

lemma ivt_increasing_component_1:
  fixes f :: "real => 'a::euclidean_space"
  shows "a ≤ b ==> ∀x∈cbox a b. continuous (at x) f ==>
    f a•k ≤ y ==> y ≤ f b•k ==> ∃x∈cbox a b. (f x)•k = y"
  by (rule ivt_increasing_component_on_1) (auto simp add: continuous_at_imp_continuous_on)

lemma ivt_decreasing_component_on_1:
  fixes f :: "real => 'a::euclidean_space"
  assumes "a ≤ b"
    and "continuous_on (cbox a b) f"
    and "(f b)•k ≤ y"
    and "y ≤ (f a)•k"
  shows "∃x∈cbox a b. (f x)•k = y"
  apply (subst neg_equal_iff_equal[symmetric])
  using ivt_increasing_component_on_1[of a b "λx. - f x" k "- y"]
  using assms using continuous_on_minus
  apply auto
  done

lemma ivt_decreasing_component_1:
  fixes f :: "real => 'a::euclidean_space"
  shows "a ≤ b ==> ∀x∈cbox a b. continuous (at x) f ==>
    f b•k ≤ y ==> y ≤ f a•k ==> ∃x∈cbox a b. (f x)•k = y"
  by (rule ivt_decreasing_component_on_1) (auto simp: continuous_at_imp_continuous_on)


subsection {* A bound within a convex hull, and so an interval *}

lemma convex_on_convex_hull_bound:
  assumes "convex_on (convex hull s) f"
    and "∀x∈s. f x ≤ b"
  shows "∀x∈ convex hull s. f x ≤ b"
proof
  fix x
  assume "x ∈ convex hull s"
  then obtain k u v where
    obt: "∀i∈{1..k::nat}. 0 ≤ u i ∧ v i ∈ s" "setsum u {1..k} = 1" "(∑i = 1..k. u i *R v i) = x"
    unfolding convex_hull_indexed mem_Collect_eq by auto
  have "(∑i = 1..k. u i * f (v i)) ≤ b"
    using setsum_mono[of "{1..k}" "λi. u i * f (v i)" "λi. u i * b"]
    unfolding setsum_left_distrib[symmetric] obt(2) mult_1
    apply (drule_tac meta_mp)
    apply (rule mult_left_mono)
    using assms(2) obt(1)
    apply auto
    done
  then show "f x ≤ b"
    using assms(1)[unfolded convex_on[OF convex_convex_hull], rule_format, of k u v]
    unfolding obt(2-3)
    using obt(1) and hull_subset[unfolded subset_eq, rule_format, of _ s]
    by auto
qed

lemma inner_setsum_Basis[simp]: "i ∈ Basis ==> (∑Basis) • i = 1"
  by (simp add: inner_setsum_left setsum.If_cases inner_Basis)

lemma convex_set_plus:
  assumes "convex s" and "convex t" shows "convex (s + t)"
proof -
  have "convex {x + y |x y. x ∈ s ∧ y ∈ t}"
    using assms by (rule convex_sums)
  moreover have "{x + y |x y. x ∈ s ∧ y ∈ t} = s + t"
    unfolding set_plus_def by auto
  finally show "convex (s + t)" .
qed

lemma convex_set_setsum:
  assumes "!!i. i ∈ A ==> convex (B i)"
  shows "convex (∑i∈A. B i)"
proof (cases "finite A")
  case True then show ?thesis using assms
    by induct (auto simp: convex_set_plus)
qed auto

lemma finite_set_setsum:
  assumes "finite A" and "∀i∈A. finite (B i)" shows "finite (∑i∈A. B i)"
  using assms by (induct set: finite, simp, simp add: finite_set_plus)

lemma set_setsum_eq:
  "finite A ==> (∑i∈A. B i) = {∑i∈A. f i |f. ∀i∈A. f i ∈ B i}"
  apply (induct set: finite)
  apply simp
  apply simp
  apply (safe elim!: set_plus_elim)
  apply (rule_tac x="fun_upd f x a" in exI)
  apply simp
  apply (rule_tac f="λx. a + x" in arg_cong)
  apply (rule setsum.cong [OF refl])
  apply clarsimp
  apply fast
  done

lemma box_eq_set_setsum_Basis:
  shows "{x. ∀i∈Basis. x•i ∈ B i} = (∑i∈Basis. image (λx. x *R i) (B i))"
  apply (subst set_setsum_eq [OF finite_Basis])
  apply safe
  apply (fast intro: euclidean_representation [symmetric])
  apply (subst inner_setsum_left)
  apply (subgoal_tac "(∑x∈Basis. f x • i) = f i • i")
  apply (drule (1) bspec)
  apply clarsimp
  apply (frule setsum.remove [OF finite_Basis])
  apply (erule trans)
  apply simp
  apply (rule setsum.neutral)
  apply clarsimp
  apply (frule_tac x=i in bspec, assumption)
  apply (drule_tac x=x in bspec, assumption)
  apply clarsimp
  apply (cut_tac u=x and v=i in inner_Basis, assumption+)
  apply (rule ccontr)
  apply simp
  done

lemma convex_hull_set_setsum:
  "convex hull (∑i∈A. B i) = (∑i∈A. convex hull (B i))"
proof (cases "finite A")
  assume "finite A" then show ?thesis
    by (induct set: finite, simp, simp add: convex_hull_set_plus)
qed simp

lemma convex_hull_eq_real_cbox:
  fixes x y :: real assumes "x ≤ y"
  shows "convex hull {x, y} = cbox x y"
proof (rule hull_unique)
  show "{x, y} ⊆ cbox x y" using `x ≤ y` by auto
  show "convex (cbox x y)"
    by (rule convex_box)
next
  fix s assume "{x, y} ⊆ s" and "convex s"
  then show "cbox x y ⊆ s"
    unfolding is_interval_convex_1 [symmetric] is_interval_def Basis_real_def
    by - (clarify, simp (no_asm_use), fast)
qed

lemma unit_interval_convex_hull:
  "cbox (0::'a::euclidean_space) One = convex hull {x. ∀i∈Basis. (x•i = 0) ∨ (x•i = 1)}"
  (is "?int = convex hull ?points")
proof -
  have One[simp]: "!!i. i ∈ Basis ==> One • i = 1"
    by (simp add: One_def inner_setsum_left setsum.If_cases inner_Basis)
  have "?int = {x. ∀i∈Basis. x • i ∈ cbox 0 1}"
    by (auto simp: cbox_def)
  also have "… = (∑i∈Basis. (λx. x *R i) ` cbox 0 1)"
    by (simp only: box_eq_set_setsum_Basis)
  also have "… = (∑i∈Basis. (λx. x *R i) ` (convex hull {0, 1}))"
    by (simp only: convex_hull_eq_real_cbox zero_le_one)
  also have "… = (∑i∈Basis. convex hull ((λx. x *R i) ` {0, 1}))"
    by (simp only: convex_hull_linear_image linear_scaleR_left)
  also have "… = convex hull (∑i∈Basis. (λx. x *R i) ` {0, 1})"
    by (simp only: convex_hull_set_setsum)
  also have "… = convex hull {x. ∀i∈Basis. x•i ∈ {0, 1}}"
    by (simp only: box_eq_set_setsum_Basis)
  also have "convex hull {x. ∀i∈Basis. x•i ∈ {0, 1}} = convex hull ?points"
    by simp
  finally show ?thesis .
qed

text {* And this is a finite set of vertices. *}

lemma unit_cube_convex_hull:
  obtains s :: "'a::euclidean_space set"
    where "finite s" and "cbox 0 (∑Basis) = convex hull s"
  apply (rule that[of "{x::'a. ∀i∈Basis. x•i=0 ∨ x•i=1}"])
  apply (rule finite_subset[of _ "(λs. (∑i∈Basis. (if i∈s then 1 else 0) *R i)::'a) ` Pow Basis"])
  prefer 3
  apply (rule unit_interval_convex_hull)
  apply rule
  unfolding mem_Collect_eq
proof -
  fix x :: 'a
  assume as: "∀i∈Basis. x • i = 0 ∨ x • i = 1"
  show "x ∈ (λs. ∑i∈Basis. (if i∈s then 1 else 0) *R i) ` Pow Basis"
    apply (rule image_eqI[where x="{i. i∈Basis ∧ x•i = 1}"])
    using as
    apply (subst euclidean_eq_iff)
    apply auto
    done
qed auto

text {* Hence any cube (could do any nonempty interval). *}

lemma cube_convex_hull:
  assumes "d > 0"
  obtains s :: "'a::euclidean_space set" where
    "finite s" and "cbox (x - (∑i∈Basis. d*Ri)) (x + (∑i∈Basis. d*Ri)) = convex hull s"
proof -
  let ?d = "(∑i∈Basis. d*Ri)::'a"
  have *: "cbox (x - ?d) (x + ?d) = (λy. x - ?d + (2 * d) *R y) ` cbox 0 (∑Basis)"
    apply (rule set_eqI, rule)
    unfolding image_iff
    defer
    apply (erule bexE)
  proof -
    fix y
    assume as: "y∈cbox (x - ?d) (x + ?d)"
    {
      fix i :: 'a
      assume i: "i ∈ Basis"
      have "x • i ≤ d + y • i" "y • i ≤ d + x • i"
        using as[unfolded mem_box, THEN bspec[where x=i]] i
        by (auto simp: inner_simps)
      then have "1 ≥ inverse d * (x • i - y • i)" "1 ≥ inverse d * (y • i - x • i)"
        apply (rule_tac[!] mult_left_le_imp_le[OF _ assms])
        unfolding mult.assoc[symmetric]
        using assms
        by (auto simp add: field_simps)
      then have "inverse d * (x • i * 2) ≤ 2 + inverse d * (y • i * 2)"
        "inverse d * (y • i * 2) ≤ 2 + inverse d * (x • i * 2)"
        using `0<d` by (auto simp add: field_simps) }
    then have "inverse (2 * d) *R (y - (x - ?d)) ∈ cbox 0 (∑Basis)"
      unfolding mem_box using assms
      by (auto simp add: field_simps inner_simps simp del: inverse_eq_divide)
    then show "∃z∈cbox 0 (∑Basis). y = x - ?d + (2 * d) *R z"
      apply -
      apply (rule_tac x="inverse (2 * d) *R (y - (x - ?d))" in bexI)
      using assms
      apply auto
      done
  next
    fix y z
    assume as: "z∈cbox 0 (∑Basis)" "y = x - ?d + (2*d) *R z"
    have "!!i. i∈Basis ==> 0 ≤ d * (z • i) ∧ d * (z • i) ≤ d"
      using assms as(1)[unfolded mem_box]
      apply (erule_tac x=i in ballE)
      apply rule
      prefer 2
      apply (rule mult_right_le_one_le)
      using assms
      apply auto
      done
    then show "y ∈ cbox (x - ?d) (x + ?d)"
      unfolding as(2) mem_box
      apply -
      apply rule
      using as(1)[unfolded mem_box]
      apply (erule_tac x=i in ballE)
      using assms
      apply (auto simp: inner_simps)
      done
  qed
  obtain s where "finite s" "cbox 0 (∑Basis::'a) = convex hull s"
    using unit_cube_convex_hull by auto
  then show ?thesis
    apply (rule_tac that[of "(λy. x - ?d + (2 * d) *R y)` s"])
    unfolding * and convex_hull_affinity
    apply auto
    done
qed


subsection {* Bounded convex function on open set is continuous *}

lemma convex_on_bounded_continuous:
  fixes s :: "('a::real_normed_vector) set"
  assumes "open s"
    and "convex_on s f"
    and "∀x∈s. abs(f x) ≤ b"
  shows "continuous_on s f"
  apply (rule continuous_at_imp_continuous_on)
  unfolding continuous_at_real_range
proof (rule,rule,rule)
  fix x and e :: real
  assume "x ∈ s" "e > 0"
  def B  "abs b + 1"
  have B: "0 < B" "!!x. x∈s ==> abs (f x) ≤ B"
    unfolding B_def
    defer
    apply (drule assms(3)[rule_format])
    apply auto
    done
  obtain k where "k > 0" and k: "cball x k ⊆ s"
    using assms(1)[unfolded open_contains_cball, THEN bspec[where x=x]]
    using `x∈s` by auto
  show "∃d>0. ∀x'. norm (x' - x) < d --> ¦f x' - f x¦ < e"
    apply (rule_tac x="min (k / 2) (e / (2 * B) * k)" in exI)
    apply rule
    defer
  proof (rule, rule)
    fix y
    assume as: "norm (y - x) < min (k / 2) (e / (2 * B) * k)"
    show "¦f y - f x¦ < e"
    proof (cases "y = x")
      case False
      def t  "k / norm (y - x)"
      have "2 < t" "0<t"
        unfolding t_def using as False and `k>0`
        by (auto simp add:field_simps)
      have "y ∈ s"
        apply (rule k[unfolded subset_eq,rule_format])
        unfolding mem_cball dist_norm
        apply (rule order_trans[of _ "2 * norm (x - y)"])
        using as
        by (auto simp add: field_simps norm_minus_commute)
      {
        def w  "x + t *R (y - x)"
        have "w ∈ s"
          unfolding w_def
          apply (rule k[unfolded subset_eq,rule_format])
          unfolding mem_cball dist_norm
          unfolding t_def
          using `k>0`
          apply auto
          done
        have "(1 / t) *R x + - x + ((t - 1) / t) *R x = (1 / t - 1 + (t - 1) / t) *R x"
          by (auto simp add: algebra_simps)
        also have "… = 0"
          using `t > 0` by (auto simp add:field_simps)
        finally have w: "(1 / t) *R w + ((t - 1) / t) *R x = y"
          unfolding w_def using False and `t > 0`
          by (auto simp add: algebra_simps)
        have  "2 * B < e * t"
          unfolding t_def using `0 < e` `0 < k` `B > 0` and as and False
          by (auto simp add:field_simps)
        then have "(f w - f x) / t < e"
          using B(2)[OF `w∈s`] and B(2)[OF `x∈s`]
          using `t > 0` by (auto simp add:field_simps)
        then have th1: "f y - f x < e"
          apply -
          apply (rule le_less_trans)
          defer
          apply assumption
          using assms(2)[unfolded convex_on_def,rule_format,of w x "1/t" "(t - 1)/t", unfolded w]
          using `0 < t` `2 < t` and `x ∈ s` `w ∈ s`
          by (auto simp add:field_simps)
      }
      moreover
      {
        def w  "x - t *R (y - x)"
        have "w ∈ s"
          unfolding w_def
          apply (rule k[unfolded subset_eq,rule_format])
          unfolding mem_cball dist_norm
          unfolding t_def
          using `k > 0`
          apply auto
          done
        have "(1 / (1 + t)) *R x + (t / (1 + t)) *R x = (1 / (1 + t) + t / (1 + t)) *R x"
          by (auto simp add: algebra_simps)
        also have "… = x"
          using `t > 0` by (auto simp add:field_simps)
        finally have w: "(1 / (1+t)) *R w + (t / (1 + t)) *R y = x"
          unfolding w_def using False and `t > 0`
          by (auto simp add: algebra_simps)
        have "2 * B < e * t"
          unfolding t_def
          using `0 < e` `0 < k` `B > 0` and as and False
          by (auto simp add:field_simps)
        then have *: "(f w - f y) / t < e"
          using B(2)[OF `w∈s`] and B(2)[OF `y∈s`]
          using `t > 0`
          by (auto simp add:field_simps)
        have "f x ≤ 1 / (1 + t) * f w + (t / (1 + t)) * f y"
          using assms(2)[unfolded convex_on_def,rule_format,of w y "1/(1+t)" "t / (1+t)",unfolded w]
          using `0 < t` `2 < t` and `y ∈ s` `w ∈ s`
          by (auto simp add:field_simps)
        also have "… = (f w + t * f y) / (1 + t)"
          using `t > 0` unfolding divide_inverse by (auto simp add: field_simps)
        also have "… < e + f y"
          using `t > 0` * `e > 0` by (auto simp add: field_simps)
        finally have "f x - f y < e" by auto
      }
      ultimately show ?thesis by auto
    qed (insert `0<e`, auto)
  qed (insert `0<e` `0<k` `0<B`, auto simp: field_simps)
qed


subsection {* Upper bound on a ball implies upper and lower bounds *}

lemma convex_bounds_lemma:
  fixes x :: "'a::real_normed_vector"
  assumes "convex_on (cball x e) f"
    and "∀y ∈ cball x e. f y ≤ b"
  shows "∀y ∈ cball x e. abs (f y) ≤ b + 2 * abs (f x)"
  apply rule
proof (cases "0 ≤ e")
  case True
  fix y
  assume y: "y ∈ cball x e"
  def z  "2 *R x - y"
  have *: "x - (2 *R x - y) = y - x"
    by (simp add: scaleR_2)
  have z: "z ∈ cball x e"
    using y unfolding z_def mem_cball dist_norm * by (auto simp add: norm_minus_commute)
  have "(1 / 2) *R y + (1 / 2) *R z = x"
    unfolding z_def by (auto simp add: algebra_simps)
  then show "¦f y¦ ≤ b + 2 * ¦f x¦"
    using assms(1)[unfolded convex_on_def,rule_format, OF y z, of "1/2" "1/2"]
    using assms(2)[rule_format,OF y] assms(2)[rule_format,OF z]
    by (auto simp add:field_simps)
next
  case False
  fix y
  assume "y ∈ cball x e"
  then have "dist x y < 0"
    using False unfolding mem_cball not_le by (auto simp del: dist_not_less_zero)
  then show "¦f y¦ ≤ b + 2 * ¦f x¦"
    using zero_le_dist[of x y] by auto
qed


subsubsection {* Hence a convex function on an open set is continuous *}

lemma real_of_nat_ge_one_iff: "1 ≤ real (n::nat) <-> 1 ≤ n"
  by auto

lemma convex_on_continuous:
  assumes "open (s::('a::euclidean_space) set)" "convex_on s f"
  shows "continuous_on s f"
  unfolding continuous_on_eq_continuous_at[OF assms(1)]
proof
  note dimge1 = DIM_positive[where 'a='a]
  fix x
  assume "x ∈ s"
  then obtain e where e: "cball x e ⊆ s" "e > 0"
    using assms(1) unfolding open_contains_cball by auto
  def d  "e / real DIM('a)"
  have "0 < d"
    unfolding d_def using `e > 0` dimge1 by auto
  let ?d = "(∑i∈Basis. d *R i)::'a"
  obtain c
    where c: "finite c"
    and c1: "convex hull c ⊆ cball x e"
    and c2: "cball x d ⊆ convex hull c"
  proof
    def c  "∑i∈Basis. (λa. a *R i) ` {x•i - d, x•i + d}"
    show "finite c"
      unfolding c_def by (simp add: finite_set_setsum)
    have 1: "convex hull c = {a. ∀i∈Basis. a • i ∈ cbox (x • i - d) (x • i + d)}"
      unfolding box_eq_set_setsum_Basis
      unfolding c_def convex_hull_set_setsum
      apply (subst convex_hull_linear_image [symmetric])
      apply (simp add: linear_iff scaleR_add_left)
      apply (rule setsum.cong [OF refl])
      apply (rule image_cong [OF _ refl])
      apply (rule convex_hull_eq_real_cbox)
      apply (cut_tac `0 < d`, simp)
      done
    then have 2: "convex hull c = {a. ∀i∈Basis. a • i ∈ cball (x • i) d}"
      by (simp add: dist_norm abs_le_iff algebra_simps)
    show "cball x d ⊆ convex hull c"
      unfolding 2
      apply clarsimp
      apply (simp only: dist_norm)
      apply (subst inner_diff_left [symmetric])
      apply simp
      apply (erule (1) order_trans [OF Basis_le_norm])
      done
    have e': "e = (∑(i::'a)∈Basis. d)"
      by (simp add: d_def real_of_nat_def DIM_positive)
    show "convex hull c ⊆ cball x e"
      unfolding 2
      apply clarsimp
      apply (subst euclidean_dist_l2)
      apply (rule order_trans [OF setL2_le_setsum])
      apply (rule zero_le_dist)
      unfolding e'
      apply (rule setsum_mono)
      apply simp
      done
  qed
  def k  "Max (f ` c)"
  have "convex_on (convex hull c) f"
    apply(rule convex_on_subset[OF assms(2)])
    apply(rule subset_trans[OF _ e(1)])
    apply(rule c1)
    done
  then have k: "∀y∈convex hull c. f y ≤ k"
    apply (rule_tac convex_on_convex_hull_bound)
    apply assumption
    unfolding k_def
    apply (rule, rule Max_ge)
    using c(1)
    apply auto
    done
  have "d ≤ e"
    unfolding d_def
    apply (rule mult_imp_div_pos_le)
    using `e > 0`
    unfolding mult_le_cancel_left1
    apply (auto simp: real_of_nat_ge_one_iff Suc_le_eq DIM_positive)
    done
  then have dsube: "cball x d ⊆ cball x e"
    by (rule subset_cball)
  have conv: "convex_on (cball x d) f"
    apply (rule convex_on_subset)
    apply (rule convex_on_subset[OF assms(2)])
    apply (rule e(1))
    apply (rule dsube)
    done
  then have "∀y∈cball x d. abs (f y) ≤ k + 2 * abs (f x)"
    apply (rule convex_bounds_lemma)
    apply (rule ballI)
    apply (rule k [rule_format])
    apply (erule rev_subsetD)
    apply (rule c2)
    done
  then have "continuous_on (ball x d) f"
    apply (rule_tac convex_on_bounded_continuous)
    apply (rule open_ball, rule convex_on_subset[OF conv])
    apply (rule ball_subset_cball)
    apply force
    done
  then show "continuous (at x) f"
    unfolding continuous_on_eq_continuous_at[OF open_ball]
    using `d > 0` by auto
qed


subsection {* Line segments, Starlike Sets, etc. *}

(* Use the same overloading tricks as for intervals, so that
   segment[a,b] is closed and segment(a,b) is open relative to affine hull. *)

definition midpoint :: "'a::real_vector => 'a => 'a"
  where "midpoint a b = (inverse (2::real)) *R (a + b)"

definition open_segment :: "'a::real_vector => 'a => 'a set"
  where "open_segment a b = {(1 - u) *R a + u *R b | u::real.  0 < u ∧ u < 1}"

definition closed_segment :: "'a::real_vector => 'a => 'a set"
  where "closed_segment a b = {(1 - u) *R a + u *R b | u::real. 0 ≤ u ∧ u ≤ 1}"

definition "between = (λ(a,b) x. x ∈ closed_segment a b)"

lemmas segment = open_segment_def closed_segment_def

lemma open_closed_segment: "u ∈ open_segment w z ==> u ∈ closed_segment w z"
  by (auto simp add: closed_segment_def open_segment_def)

definition "starlike s <-> (∃a∈s. ∀x∈s. closed_segment a x ⊆ s)"

lemma midpoint_refl: "midpoint x x = x"
  unfolding midpoint_def
  unfolding scaleR_right_distrib
  unfolding scaleR_left_distrib[symmetric]
  by auto

lemma midpoint_sym: "midpoint a b = midpoint b a"
  unfolding midpoint_def by (auto simp add: scaleR_right_distrib)

lemma midpoint_eq_iff: "midpoint a b = c <-> a + b = c + c"
proof -
  have "midpoint a b = c <-> scaleR 2 (midpoint a b) = scaleR 2 c"
    by simp
  then show ?thesis
    unfolding midpoint_def scaleR_2 [symmetric] by simp
qed

lemma dist_midpoint:
  fixes a b :: "'a::real_normed_vector" shows
  "dist a (midpoint a b) = (dist a b) / 2" (is ?t1)
  "dist b (midpoint a b) = (dist a b) / 2" (is ?t2)
  "dist (midpoint a b) a = (dist a b) / 2" (is ?t3)
  "dist (midpoint a b) b = (dist a b) / 2" (is ?t4)
proof -
  have *: "!!x y::'a. 2 *R x = - y ==> norm x = (norm y) / 2"
    unfolding equation_minus_iff by auto
  have **: "!!x y::'a. 2 *R x =   y ==> norm x = (norm y) / 2"
    by auto
  note scaleR_right_distrib [simp]
  show ?t1
    unfolding midpoint_def dist_norm
    apply (rule **)
    apply (simp add: scaleR_right_diff_distrib)
    apply (simp add: scaleR_2)
    done
  show ?t2
    unfolding midpoint_def dist_norm
    apply (rule *)
    apply (simp add: scaleR_right_diff_distrib)
    apply (simp add: scaleR_2)
    done
  show ?t3
    unfolding midpoint_def dist_norm
    apply (rule *)
    apply (simp add: scaleR_right_diff_distrib)
    apply (simp add: scaleR_2)
    done
  show ?t4
    unfolding midpoint_def dist_norm
    apply (rule **)
    apply (simp add: scaleR_right_diff_distrib)
    apply (simp add: scaleR_2)
    done
qed

lemma midpoint_eq_endpoint:
  "midpoint a b = a <-> a = b"
  "midpoint a b = b <-> a = b"
  unfolding midpoint_eq_iff by auto

lemma convex_contains_segment:
  "convex s <-> (∀a∈s. ∀b∈s. closed_segment a b ⊆ s)"
  unfolding convex_alt closed_segment_def by auto

lemma convex_imp_starlike:
  "convex s ==> s ≠ {} ==> starlike s"
  unfolding convex_contains_segment starlike_def by auto

lemma segment_convex_hull:
  "closed_segment a b = convex hull {a,b}"
proof -
  have *: "!!x. {x} ≠ {}" by auto
  have **: "!!u v. u + v = 1 <-> u = 1 - (v::real)" by auto
  show ?thesis
    unfolding segment convex_hull_insert[OF *] convex_hull_singleton
    apply (rule set_eqI)
    unfolding mem_Collect_eq
    apply (rule, erule exE)
    apply (rule_tac x="1 - u" in exI)
    apply rule
    defer
    apply (rule_tac x=u in exI)
    defer
    apply (elim exE conjE)
    apply (rule_tac x="1 - u" in exI)
    unfolding **
    apply auto
    done
qed

lemma convex_segment: "convex (closed_segment a b)"
  unfolding segment_convex_hull by(rule convex_convex_hull)

lemma ends_in_segment: "a ∈ closed_segment a b" "b ∈ closed_segment a b"
  unfolding segment_convex_hull
  apply (rule_tac[!] hull_subset[unfolded subset_eq, rule_format])
  apply auto
  done

lemma segment_furthest_le:
  fixes a b x y :: "'a::euclidean_space"
  assumes "x ∈ closed_segment a b"
  shows "norm (y - x) ≤ norm (y - a) ∨  norm (y - x) ≤ norm (y - b)"
proof -
  obtain z where "z ∈ {a, b}" "norm (x - y) ≤ norm (z - y)"
    using simplex_furthest_le[of "{a, b}" y]
    using assms[unfolded segment_convex_hull]
    by auto
  then show ?thesis
    by (auto simp add:norm_minus_commute)
qed

lemma segment_bound:
  fixes x a b :: "'a::euclidean_space"
  assumes "x ∈ closed_segment a b"
  shows "norm (x - a) ≤ norm (b - a)" "norm (x - b) ≤ norm (b - a)"
  using segment_furthest_le[OF assms, of a]
  using segment_furthest_le[OF assms, of b]
  by (auto simp add:norm_minus_commute)

lemma segment_refl: "closed_segment a a = {a}"
  unfolding segment by (auto simp add: algebra_simps)

lemma between_mem_segment: "between (a,b) x <-> x ∈ closed_segment a b"
  unfolding between_def by auto

lemma between: "between (a, b) (x::'a::euclidean_space) <-> dist a b = (dist a x) + (dist x b)"
proof (cases "a = b")
  case True
  then show ?thesis
    unfolding between_def split_conv
    by (auto simp add:segment_refl dist_commute)
next
  case False
  then have Fal: "norm (a - b) ≠ 0" and Fal2: "norm (a - b) > 0"
    by auto
  have *: "!!u. a - ((1 - u) *R a + u *R b) = u *R (a - b)"
    by (auto simp add: algebra_simps)
  show ?thesis
    unfolding between_def split_conv closed_segment_def mem_Collect_eq
    apply rule
    apply (elim exE conjE)
    apply (subst dist_triangle_eq)
  proof -
    fix u
    assume as: "x = (1 - u) *R a + u *R b" "0 ≤ u" "u ≤ 1"
    then have *: "a - x = u *R (a - b)" "x - b = (1 - u) *R (a - b)"
      unfolding as(1) by (auto simp add:algebra_simps)
    show "norm (a - x) *R (x - b) = norm (x - b) *R (a - x)"
      unfolding norm_minus_commute[of x a] * using as(2,3)
      by (auto simp add: field_simps)
  next
    assume as: "dist a b = dist a x + dist x b"
    have "norm (a - x) / norm (a - b) ≤ 1"
      using Fal2 unfolding as[unfolded dist_norm] norm_ge_zero by auto
    then show "∃u. x = (1 - u) *R a + u *R b ∧ 0 ≤ u ∧ u ≤ 1"
      apply (rule_tac x="dist a x / dist a b" in exI)
      unfolding dist_norm
      apply (subst euclidean_eq_iff)
      apply rule
      defer
      apply rule
      prefer 3
      apply rule
    proof -
      fix i :: 'a
      assume i: "i ∈ Basis"
      have "((1 - norm (a - x) / norm (a - b)) *R a + (norm (a - x) / norm (a - b)) *R b) • i =
        ((norm (a - b) - norm (a - x)) * (a • i) + norm (a - x) * (b • i)) / norm (a - b)"
        using Fal by (auto simp add: field_simps inner_simps)
      also have "… = x•i"
        apply (rule divide_eq_imp[OF Fal])
        unfolding as[unfolded dist_norm]
        using as[unfolded dist_triangle_eq]
        apply -
        apply (subst (asm) euclidean_eq_iff)
        using i
        apply (erule_tac x=i in ballE)
        apply (auto simp add: field_simps inner_simps)
        done
      finally show "x • i =
        ((1 - norm (a - x) / norm (a - b)) *R a + (norm (a - x) / norm (a - b)) *R b) • i"
        by auto
    qed (insert Fal2, auto)
  qed
qed

lemma between_midpoint:
  fixes a :: "'a::euclidean_space"
  shows "between (a,b) (midpoint a b)" (is ?t1)
    and "between (b,a) (midpoint a b)" (is ?t2)
proof -
  have *: "!!x y z. x = (1/2::real) *R z ==> y = (1/2) *R z ==> norm z = norm x + norm y"
    by auto
  show ?t1 ?t2
    unfolding between midpoint_def dist_norm
    apply(rule_tac[!] *)
    unfolding euclidean_eq_iff[where 'a='a]
    apply (auto simp add: field_simps inner_simps)
    done
qed

lemma between_mem_convex_hull:
  "between (a,b) x <-> x ∈ convex hull {a,b}"
  unfolding between_mem_segment segment_convex_hull ..


subsection {* Shrinking towards the interior of a convex set *}

lemma mem_interior_convex_shrink:
  fixes s :: "'a::euclidean_space set"
  assumes "convex s"
    and "c ∈ interior s"
    and "x ∈ s"
    and "0 < e"
    and "e ≤ 1"
  shows "x - e *R (x - c) ∈ interior s"
proof -
  obtain d where "d > 0" and d: "ball c d ⊆ s"
    using assms(2) unfolding mem_interior by auto
  show ?thesis
    unfolding mem_interior
    apply (rule_tac x="e*d" in exI)
    apply rule
    defer
    unfolding subset_eq Ball_def mem_ball
  proof (rule, rule)
    fix y
    assume as: "dist (x - e *R (x - c)) y < e * d"
    have *: "y = (1 - (1 - e)) *R ((1 / e) *R y - ((1 - e) / e) *R x) + (1 - e) *R x"
      using `e > 0` by (auto simp add: scaleR_left_diff_distrib scaleR_right_diff_distrib)
    have "dist c ((1 / e) *R y - ((1 - e) / e) *R x) = abs(1/e) * norm (e *R c - y + (1 - e) *R x)"
      unfolding dist_norm
      unfolding norm_scaleR[symmetric]
      apply (rule arg_cong[where f=norm])
      using `e > 0`
      by (auto simp add: euclidean_eq_iff[where 'a='a] field_simps inner_simps)
    also have "… = abs (1/e) * norm (x - e *R (x - c) - y)"
      by (auto intro!:arg_cong[where f=norm] simp add: algebra_simps)
    also have "… < d"
      using as[unfolded dist_norm] and `e > 0`
      by (auto simp add:pos_divide_less_eq[OF `e > 0`] mult.commute)
    finally show "y ∈ s"
      apply (subst *)
      apply (rule assms(1)[unfolded convex_alt,rule_format])
      apply (rule d[unfolded subset_eq,rule_format])
      unfolding mem_ball
      using assms(3-5)
      apply auto
      done
  qed (insert `e>0` `d>0`, auto)
qed

lemma mem_interior_closure_convex_shrink:
  fixes s :: "'a::euclidean_space set"
  assumes "convex s"
    and "c ∈ interior s"
    and "x ∈ closure s"
    and "0 < e"
    and "e ≤ 1"
  shows "x - e *R (x - c) ∈ interior s"
proof -
  obtain d where "d > 0" and d: "ball c d ⊆ s"
    using assms(2) unfolding mem_interior by auto
  have "∃y∈s. norm (y - x) * (1 - e) < e * d"
  proof (cases "x ∈ s")
    case True
    then show ?thesis
      using `e > 0` `d > 0`
      apply (rule_tac bexI[where x=x])
      apply (auto)
      done
  next
    case False
    then have x: "x islimpt s"
      using assms(3)[unfolded closure_def] by auto
    show ?thesis
    proof (cases "e = 1")
      case True
      obtain y where "y ∈ s" "y ≠ x" "dist y x < 1"
        using x[unfolded islimpt_approachable,THEN spec[where x=1]] by auto
      then show ?thesis
        apply (rule_tac x=y in bexI)
        unfolding True
        using `d > 0`
        apply auto
        done
    next
      case False
      then have "0 < e * d / (1 - e)" and *: "1 - e > 0"
        using `e ≤ 1` `e > 0` `d > 0` by auto
      then obtain y where "y ∈ s" "y ≠ x" "dist y x < e * d / (1 - e)"
        using x[unfolded islimpt_approachable,THEN spec[where x="e*d / (1 - e)"]] by auto
      then show ?thesis
        apply (rule_tac x=y in bexI)
        unfolding dist_norm
        using pos_less_divide_eq[OF *]
        apply auto
        done
    qed
  qed
  then obtain y where "y ∈ s" and y: "norm (y - x) * (1 - e) < e * d"
    by auto
  def z  "c + ((1 - e) / e) *R (x - y)"
  have *: "x - e *R (x - c) = y - e *R (y - z)"
    unfolding z_def using `e > 0`
    by (auto simp add: scaleR_right_diff_distrib scaleR_right_distrib scaleR_left_diff_distrib)
  have "z ∈ interior s"
    apply (rule interior_mono[OF d,unfolded subset_eq,rule_format])
    unfolding interior_open[OF open_ball] mem_ball z_def dist_norm using y and assms(4,5)
    apply (auto simp add:field_simps norm_minus_commute)
    done
  then show ?thesis
    unfolding *
    apply -
    apply (rule mem_interior_convex_shrink)
    using assms(1,4-5) `y∈s`
    apply auto
    done
qed


subsection {* Some obvious but surprisingly hard simplex lemmas *}

lemma simplex:
  assumes "finite s"
    and "0 ∉ s"
  shows "convex hull (insert 0 s) =
    {y. (∃u. (∀x∈s. 0 ≤ u x) ∧ setsum u s ≤ 1 ∧ setsum (λx. u x *R x) s = y)}"
  unfolding convex_hull_finite[OF finite.insertI[OF assms(1)]]
  apply (rule set_eqI, rule)
  unfolding mem_Collect_eq
  apply (erule_tac[!] exE)
  apply (erule_tac[!] conjE)+
  unfolding setsum_clauses(2)[OF assms(1)]
  apply (rule_tac x=u in exI)
  defer
  apply (rule_tac x="λx. if x = 0 then 1 - setsum u s else u x" in exI)
  using assms(2)
  unfolding if_smult and setsum_delta_notmem[OF assms(2)]
  apply auto
  done

lemma substd_simplex:
  assumes d: "d ⊆ Basis"
  shows "convex hull (insert 0 d) =
    {x. (∀i∈Basis. 0 ≤ x•i) ∧ (∑i∈d. x•i) ≤ 1 ∧ (∀i∈Basis. i ∉ d --> x•i = 0)}"
  (is "convex hull (insert 0 ?p) = ?s")
proof -
  let ?D = d
  have "0 ∉ ?p"
    using assms by (auto simp: image_def)
  from d have "finite d"
    by (blast intro: finite_subset finite_Basis)
  show ?thesis
    unfolding simplex[OF `finite d` `0 ∉ ?p`]
    apply (rule set_eqI)
    unfolding mem_Collect_eq
    apply rule
    apply (elim exE conjE)
    apply (erule_tac[2] conjE)+
  proof -
    fix x :: "'a::euclidean_space"
    fix u
    assume as: "∀x∈?D. 0 ≤ u x" "setsum u ?D ≤ 1" "(∑x∈?D. u x *R x) = x"
    have *: "∀i∈Basis. i:d --> u i = x•i"
      and "(∀i∈Basis. i ∉ d --> x • i = 0)"
      using as(3)
      unfolding substdbasis_expansion_unique[OF assms]
      by auto
    then have **: "setsum u ?D = setsum (op • x) ?D"
      apply -
      apply (rule setsum.cong)
      using assms
      apply auto
      done
    have "(∀i∈Basis. 0 ≤ x•i) ∧ setsum (op • x) ?D ≤ 1"
    proof (rule,rule)
      fix i :: 'a
      assume i: "i ∈ Basis"
      have "i ∈ d ==> 0 ≤ x•i"
        unfolding *[rule_format,OF i,symmetric]
         apply (rule_tac as(1)[rule_format])
         apply auto
         done
      moreover have "i ∉ d ==> 0 ≤ x•i"
        using `(∀i∈Basis. i ∉ d --> x • i = 0)`[rule_format, OF i] by auto
      ultimately show "0 ≤ x•i" by auto
    qed (insert as(2)[unfolded **], auto)
    then show "(∀i∈Basis. 0 ≤ x•i) ∧ setsum (op • x) ?D ≤ 1 ∧ (∀i∈Basis. i ∉ d --> x • i = 0)"
      using `(∀i∈Basis. i ∉ d --> x • i = 0)` by auto
  next
    fix x :: "'a::euclidean_space"
    assume as: "∀i∈Basis. 0 ≤ x • i" "setsum (op • x) ?D ≤ 1" "(∀i∈Basis. i ∉ d --> x • i = 0)"
    show "∃u. (∀x∈?D. 0 ≤ u x) ∧ setsum u ?D ≤ 1 ∧ (∑x∈?D. u x *R x) = x"
      using as d
      unfolding substdbasis_expansion_unique[OF assms]
      apply (rule_tac x="inner x" in exI)
      apply auto
      done
  qed
qed

lemma std_simplex:
  "convex hull (insert 0 Basis) =
    {x::'a::euclidean_space. (∀i∈Basis. 0 ≤ x•i) ∧ setsum (λi. x•i) Basis ≤ 1}"
  using substd_simplex[of Basis] by auto

lemma interior_std_simplex:
  "interior (convex hull (insert 0 Basis)) =
    {x::'a::euclidean_space. (∀i∈Basis. 0 < x•i) ∧ setsum (λi. x•i) Basis < 1}"
  apply (rule set_eqI)
  unfolding mem_interior std_simplex
  unfolding subset_eq mem_Collect_eq Ball_def mem_ball
  unfolding Ball_def[symmetric]
  apply rule
  apply (elim exE conjE)
  defer
  apply (erule conjE)
proof -
  fix x :: 'a
  fix e
  assume "e > 0" and as: "∀xa. dist x xa < e --> (∀x∈Basis. 0 ≤ xa • x) ∧ setsum (op • xa) Basis ≤ 1"
  show "(∀xa∈Basis. 0 < x • xa) ∧ setsum (op • x) Basis < 1"
    apply safe
  proof -
    fix i :: 'a
    assume i: "i ∈ Basis"
    then show "0 < x • i"
      using as[THEN spec[where x="x - (e / 2) *R i"]] and `e > 0`
      unfolding dist_norm
      by (auto elim!: ballE[where x=i] simp: inner_simps)
  next
    have **: "dist x (x + (e / 2) *R (SOME i. i∈Basis)) < e" using `e > 0`
      unfolding dist_norm
      by (auto intro!: mult_strict_left_mono simp: SOME_Basis)
    have "!!i. i ∈ Basis ==> (x + (e / 2) *R (SOME i. i∈Basis)) • i =
      x•i + (if i = (SOME i. i∈Basis) then e/2 else 0)"
      by (auto simp: SOME_Basis inner_Basis inner_simps)
    then have *: "setsum (op • (x + (e / 2) *R (SOME i. i∈Basis))) Basis =
      setsum (λi. x•i + (if (SOME i. i∈Basis) = i then e/2 else 0)) Basis"
      apply (rule_tac setsum.cong)
      apply auto
      done
    have "setsum (op • x) Basis < setsum (op • (x + (e / 2) *R (SOME i. i∈Basis))) Basis"
      unfolding * setsum.distrib
      using `e > 0` DIM_positive[where 'a='a]
      apply (subst setsum.delta')
      apply (auto simp: SOME_Basis)
      done
    also have "… ≤ 1"
      using **
      apply (drule_tac as[rule_format])
      apply auto
      done
    finally show "setsum (op • x) Basis < 1" by auto
  qed
next
  fix x :: 'a
  assume as: "∀i∈Basis. 0 < x • i" "setsum (op • x) Basis < 1"
  obtain a :: 'b where "a ∈ UNIV" using UNIV_witness ..
  let ?d = "(1 - setsum (op • x) Basis) / real (DIM('a))"
  have "Min ((op • x) ` Basis) > 0"
    apply (rule Min_grI)
    using as(1)
    apply auto
    done
  moreover have "?d > 0"
    using as(2) by (auto simp: Suc_le_eq DIM_positive)
  ultimately show "∃e>0. ∀y. dist x y < e --> (∀i∈Basis. 0 ≤ y • i) ∧ setsum (op • y) Basis ≤ 1"
    apply (rule_tac x="min (Min ((op • x) ` Basis)) ?D" in exI)
    apply rule
    defer
    apply (rule, rule)
  proof -
    fix y
    assume y: "dist x y < min (Min (op • x ` Basis)) ?d"
    have "setsum (op • y) Basis ≤ setsum (λi. x•i + ?d) Basis"
    proof (rule setsum_mono)
      fix i :: 'a
      assume i: "i ∈ Basis"
      then have "abs (y•i - x•i) < ?d"
        apply -
        apply (rule le_less_trans)
        using Basis_le_norm[OF i, of "y - x"]
        using y[unfolded min_less_iff_conj dist_norm, THEN conjunct2]
        apply (auto simp add: norm_minus_commute inner_diff_left)
        done
      then show "y • i ≤ x • i + ?d" by auto
    qed
    also have "… ≤ 1"
      unfolding setsum.distrib setsum_constant real_eq_of_nat
      by (auto simp add: Suc_le_eq)
    finally show "(∀i∈Basis. 0 ≤ y • i) ∧ setsum (op • y) Basis ≤ 1"
    proof safe
      fix i :: 'a
      assume i: "i ∈ Basis"
      have "norm (x - y) < x•i"
        apply (rule less_le_trans)
        apply (rule y[unfolded min_less_iff_conj dist_norm, THEN conjunct1])
        using i
        apply auto
        done
      then show "0 ≤ y•i"
        using Basis_le_norm[OF i, of "x - y"] and as(1)[rule_format, OF i]
        by (auto simp: inner_simps)
    qed
  qed auto
qed

lemma interior_std_simplex_nonempty:
  obtains a :: "'a::euclidean_space" where
    "a ∈ interior(convex hull (insert 0 Basis))"
proof -
  let ?D = "Basis :: 'a set"
  let ?a = "setsum (λb::'a. inverse (2 * real DIM('a)) *R b) Basis"
  {
    fix i :: 'a
    assume i: "i ∈ Basis"
    have "?a • i = inverse (2 * real DIM('a))"
      by (rule trans[of _ "setsum (λj. if i = j then inverse (2 * real DIM('a)) else 0) ?D"])
         (simp_all add: setsum.If_cases i) }
  note ** = this
  show ?thesis
    apply (rule that[of ?a])
    unfolding interior_std_simplex mem_Collect_eq
  proof safe
    fix i :: 'a
    assume i: "i ∈ Basis"
    show "0 < ?a • i"
      unfolding **[OF i] by (auto simp add: Suc_le_eq DIM_positive)
  next
    have "setsum (op • ?a) ?D = setsum (λi. inverse (2 * real DIM('a))) ?D"
      apply (rule setsum.cong)
      apply rule
      apply auto
      done
    also have "… < 1"
      unfolding setsum_constant real_eq_of_nat divide_inverse[symmetric]
      by (auto simp add: field_simps)
    finally show "setsum (op • ?a) ?D < 1" by auto
  qed
qed

lemma rel_interior_substd_simplex:
  assumes d: "d ⊆ Basis"
  shows "rel_interior (convex hull (insert 0 d)) =
    {x::'a::euclidean_space. (∀i∈d. 0 < x•i) ∧ (∑i∈d. x•i) < 1 ∧ (∀i∈Basis. i ∉ d --> x•i = 0)}"
  (is "rel_interior (convex hull (insert 0 ?p)) = ?s")
proof -
  have "finite d"
    apply (rule finite_subset)
    using assms
    apply auto
    done
  show ?thesis
  proof (cases "d = {}")
    case True
    then show ?thesis
      using rel_interior_sing using euclidean_eq_iff[of _ 0] by auto
  next
    case False
    have h0: "affine hull (convex hull (insert 0 ?p)) =
      {x::'a::euclidean_space. (∀i∈Basis. i ∉ d --> x•i = 0)}"
      using affine_hull_convex_hull affine_hull_substd_basis assms by auto
    have aux: "!!x::'a. ∀i∈Basis. (∀i∈d. 0 ≤ x•i) ∧ (∀i∈Basis. i ∉ d --> x•i = 0) --> 0 ≤ x•i"
      by auto
    {
      fix x :: "'a::euclidean_space"
      assume x: "x ∈ rel_interior (convex hull (insert 0 ?p))"
      then obtain e where e0: "e > 0" and
        "ball x e ∩ {xa. (∀i∈Basis. i ∉ d --> xa•i = 0)} ⊆ convex hull (insert 0 ?p)"
        using mem_rel_interior_ball[of x "convex hull (insert 0 ?p)"] h0 by auto
      then have as: "∀xa. dist x xa < e ∧ (∀i∈Basis. i ∉ d --> xa•i = 0) -->
        (∀i∈d. 0 ≤ xa • i) ∧ setsum (op • xa) d ≤ 1"
        unfolding ball_def unfolding substd_simplex[OF assms] using assms by auto
      have x0: "(∀i∈Basis. i ∉ d --> x•i = 0)"
        using x rel_interior_subset  substd_simplex[OF assms] by auto
      have "(∀i∈d. 0 < x • i) ∧ setsum (op • x) d < 1 ∧ (∀i∈Basis. i ∉ d --> x•i = 0)"
        apply rule
        apply rule
      proof -
        fix i :: 'a
        assume "i ∈ d"
        then have "∀ia∈d. 0 ≤ (x - (e / 2) *R i) • ia"
          apply -
          apply (rule as[rule_format,THEN conjunct1])
          unfolding dist_norm
          using d `e > 0` x0
          apply (auto simp: inner_simps inner_Basis)
          done
        then show "0 < x • i"
          apply (erule_tac x=i in ballE)
          using `e > 0` `i ∈ d` d
          apply (auto simp: inner_simps inner_Basis)
          done
      next
        obtain a where a: "a ∈ d"
          using `d ≠ {}` by auto
        then have **: "dist x (x + (e / 2) *R a) < e"
          using `e > 0` norm_Basis[of a] d
          unfolding dist_norm
          by auto
        have "!!i. i ∈ Basis ==> (x + (e / 2) *R a) • i = x•i + (if i = a then e/2 else 0)"
          using a d by (auto simp: inner_simps inner_Basis)
        then have *: "setsum (op • (x + (e / 2) *R a)) d =
          setsum (λi. x•i + (if a = i then e/2 else 0)) d"
          using d by (intro setsum.cong) auto
        have "a ∈ Basis"
          using `a ∈ d` d by auto
        then have h1: "(∀i∈Basis. i ∉ d --> (x + (e / 2) *R a) • i = 0)"
          using x0 d `a∈d` by (auto simp add: inner_add_left inner_Basis)
        have "setsum (op • x) d < setsum (op • (x + (e / 2) *R a)) d"
          unfolding * setsum.distrib
          using `e > 0` `a ∈ d`
          using `finite d`
          by (auto simp add: setsum.delta')
        also have "… ≤ 1"
          using ** h1 as[rule_format, of "x + (e / 2) *R a"]
          by auto
        finally show "setsum (op • x) d < 1 ∧ (∀i∈Basis. i ∉ d --> x•i = 0)"
          using x0 by auto
      qed
    }
    moreover
    {
      fix x :: "'a::euclidean_space"
      assume as: "x ∈ ?s"
      have "∀i. 0 < x•i ∨ 0 = x•i --> 0 ≤ x•i"
        by auto
      moreover have "∀i. i ∈ d ∨ i ∉ d" by auto
      ultimately
      have "∀i. (∀i∈d. 0 < x•i) ∧ (∀i. i ∉ d --> x•i = 0) --> 0 ≤ x•i"
        by metis
      then have h2: "x ∈ convex hull (insert 0 ?p)"
        using as assms
        unfolding substd_simplex[OF assms] by fastforce
      obtain a where a: "a ∈ d"
        using `d ≠ {}` by auto
      let ?d = "(1 - setsum (op • x) d) / real (card d)"
      have "0 < card d" using `d ≠ {}` `finite d`
        by (simp add: card_gt_0_iff)
      have "Min ((op • x) ` d) > 0"
        using as `d ≠ {}` `finite d` by (simp add: Min_grI)
      moreover have "?d > 0" using as using `0 < card d` by auto
      ultimately have h3: "min (Min ((op • x) ` d)) ?d > 0"
        by auto

      have "x ∈ rel_interior (convex hull (insert 0 ?p))"
        unfolding rel_interior_ball mem_Collect_eq h0
        apply (rule,rule h2)
        unfolding substd_simplex[OF assms]
        apply (rule_tac x="min (Min ((op • x) ` d)) ?d" in exI)
        apply (rule, rule h3)
        apply safe
        unfolding mem_ball
      proof -
        fix y :: 'a
        assume y: "dist x y < min (Min (op • x ` d)) ?d"
        assume y2: "∀i∈Basis. i ∉ d --> y•i = 0"
        have "setsum (op • y) d ≤ setsum (λi. x•i + ?d) d"
        proof (rule setsum_mono)
          fix i
          assume "i ∈ d"
          with d have i: "i ∈ Basis"
            by auto
          have "abs (y•i - x•i) < ?d"
            apply (rule le_less_trans)
            using Basis_le_norm[OF i, of "y - x"]
            using y[unfolded min_less_iff_conj dist_norm, THEN conjunct2]
            apply (auto simp add: norm_minus_commute inner_simps)
            done
          then show "y • i ≤ x • i + ?d" by auto
        qed
        also have "… ≤ 1"
          unfolding setsum.distrib setsum_constant real_eq_of_nat
          using `0 < card d`
          by auto
        finally show "setsum (op • y) d ≤ 1" .

        fix i :: 'a
        assume i: "i ∈ Basis"
        then show "0 ≤ y•i"
        proof (cases "i∈d")
          case True
          have "norm (x - y) < x•i"
            using y[unfolded min_less_iff_conj dist_norm, THEN conjunct1]
            using Min_gr_iff[of "op • x ` d" "norm (x - y)"] `0 < card d` `i:d`
            by (simp add: card_gt_0_iff)
          then show "0 ≤ y•i"
            using Basis_le_norm[OF i, of "x - y"] and as(1)[rule_format]
            by (auto simp: inner_simps)
        qed (insert y2, auto)
      qed
    }
    ultimately have
      "!!x. x ∈ rel_interior (convex hull insert 0 d) <->
        x ∈ {x. (∀i∈d. 0 < x • i) ∧ setsum (op • x) d < 1 ∧ (∀i∈Basis. i ∉ d --> x • i = 0)}"
      by blast
    then show ?thesis by (rule set_eqI)
  qed
qed

lemma rel_interior_substd_simplex_nonempty:
  assumes "d ≠ {}"
    and "d ⊆ Basis"
  obtains a :: "'a::euclidean_space"
    where "a ∈ rel_interior (convex hull (insert 0 d))"
proof -
  let ?D = d
  let ?a = "setsum (λb::'a::euclidean_space. inverse (2 * real (card d)) *R b) ?D"
  have "finite d"
    apply (rule finite_subset)
    using assms(2)
    apply auto
    done
  then have d1: "0 < real (card d)"
    using `d ≠ {}` by auto
  {
    fix i
    assume "i ∈ d"
    have "?a • i = inverse (2 * real (card d))"
      apply (rule trans[of _ "setsum (λj. if i = j then inverse (2 * real (card d)) else 0) ?D"])
      unfolding inner_setsum_left
      apply (rule setsum.cong)
      using `i ∈ d` `finite d` setsum.delta'[of d i "(λk. inverse (2 * real (card d)))"]
        d1 assms(2)
      by (auto simp: inner_Basis set_rev_mp[OF _ assms(2)])
  }
  note ** = this
  show ?thesis
    apply (rule that[of ?a])
    unfolding rel_interior_substd_simplex[OF assms(2)] mem_Collect_eq
  proof safe
    fix i
    assume "i ∈ d"
    have "0 < inverse (2 * real (card d))"
      using d1 by auto
    also have "… = ?a • i" using **[of i] `i ∈ d`
      by auto
    finally show "0 < ?a • i" by auto
  next
    have "setsum (op • ?a) ?D = setsum (λi. inverse (2 * real (card d))) ?D"
      by (rule setsum.cong) (rule refl, rule **)
    also have "… < 1"
      unfolding setsum_constant real_eq_of_nat divide_real_def[symmetric]
      by (auto simp add: field_simps)
    finally show "setsum (op • ?a) ?D < 1" by auto
  next
    fix i
    assume "i ∈ Basis" and "i ∉ d"
    have "?a ∈ span d"
    proof (rule span_setsum[of d "(λb. b /R (2 * real (card d)))" d])
      {
        fix x :: "'a::euclidean_space"
        assume "x ∈ d"
        then have "x ∈ span d"
          using span_superset[of _ "d"] by auto
        then have "x /R (2 * real (card d)) ∈ span d"
          using span_mul[of x "d" "(inverse (real (card d)) / 2)"] by auto
      }
      then show "∀x∈d. x /R (2 * real (card d)) ∈ span d"
        by auto
    qed
    then show "?a • i = 0 "
      using `i ∉ d` unfolding span_substd_basis[OF assms(2)] using `i ∈ Basis` by auto
  qed
qed


subsection {* Relative interior of convex set *}

lemma rel_interior_convex_nonempty_aux:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
    and "0 ∈ S"
  shows "rel_interior S ≠ {}"
proof (cases "S = {0}")
  case True
  then show ?thesis using rel_interior_sing by auto
next
  case False
  obtain B where B: "independent B ∧ B ≤ S ∧ S ≤ span B ∧ card B = dim S"
    using basis_exists[of S] by auto
  then have "B ≠ {}"
    using B assms `S ≠ {0}` span_empty by auto
  have "insert 0 B ≤ span B"
    using subspace_span[of B] subspace_0[of "span B"] span_inc by auto
  then have "span (insert 0 B) ≤ span B"
    using span_span[of B] span_mono[of "insert 0 B" "span B"] by blast
  then have "convex hull insert 0 B ≤ span B"
    using convex_hull_subset_span[of "insert 0 B"] by auto
  then have "span (convex hull insert 0 B) ≤ span B"
    using span_span[of B] span_mono[of "convex hull insert 0 B" "span B"] by blast
  then have *: "span (convex hull insert 0 B) = span B"
    using span_mono[of B "convex hull insert 0 B"] hull_subset[of "insert 0 B"] by auto
  then have "span (convex hull insert 0 B) = span S"
    using B span_mono[of B S] span_mono[of S "span B"] span_span[of B] by auto
  moreover have "0 ∈ affine hull (convex hull insert 0 B)"
    using hull_subset[of "convex hull insert 0 B"] hull_subset[of "insert 0 B"] by auto
  ultimately have **: "affine hull (convex hull insert 0 B) = affine hull S"
    using affine_hull_span_0[of "convex hull insert 0 B"] affine_hull_span_0[of "S"]
      assms hull_subset[of S]
    by auto
  obtain d and f :: "'n => 'n" where
    fd: "card d = card B" "linear f" "f ` B = d"
      "f ` span B = {x. ∀i∈Basis. i ∉ d --> x • i = (0::real)} ∧ inj_on f (span B)"
    and d: "d ⊆ Basis"
    using basis_to_substdbasis_subspace_isomorphism[of B,OF _ ] B by auto
  then have "bounded_linear f"
    using linear_conv_bounded_linear by auto
  have "d ≠ {}"
    using fd B `B ≠ {}` by auto
  have "insert 0 d = f ` (insert 0 B)"
    using fd linear_0 by auto
  then have "(convex hull (insert 0 d)) = f ` (convex hull (insert 0 B))"
    using convex_hull_linear_image[of f "(insert 0 d)"]
      convex_hull_linear_image[of f "(insert 0 B)"] `linear f`
    by auto
  moreover have "rel_interior (f ` (convex hull insert 0 B)) =
    f ` rel_interior (convex hull insert 0 B)"
    apply (rule  rel_interior_injective_on_span_linear_image[of f "(convex hull insert 0 B)"])
    using `bounded_linear f` fd *
    apply auto
    done
  ultimately have "rel_interior (convex hull insert 0 B) ≠ {}"
    using rel_interior_substd_simplex_nonempty[OF `d ≠ {}` d]
    apply auto
    apply blast
    done
  moreover have "convex hull (insert 0 B) ⊆ S"
    using B assms hull_mono[of "insert 0 B" "S" "convex"] convex_hull_eq
    by auto
  ultimately show ?thesis
    using subset_rel_interior[of "convex hull insert 0 B" S] ** by auto
qed

lemma rel_interior_convex_nonempty:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
  shows "rel_interior S = {} <-> S = {}"
proof -
  {
    assume "S ≠ {}"
    then obtain a where "a ∈ S" by auto
    then have "0 ∈ op + (-a) ` S"
      using assms exI[of "(λx. x ∈ S ∧ - a + x = 0)" a] by auto
    then have "rel_interior (op + (-a) ` S) ≠ {}"
      using rel_interior_convex_nonempty_aux[of "op + (-a) ` S"]
        convex_translation[of S "-a"] assms
      by auto
    then have "rel_interior S ≠ {}"
      using rel_interior_translation by auto
  }
  then show ?thesis
    using rel_interior_empty by auto
qed

lemma convex_rel_interior:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
  shows "convex (rel_interior S)"
proof -
  {
    fix x y and u :: real
    assume assm: "x ∈ rel_interior S" "y ∈ rel_interior S" "0 ≤ u" "u ≤ 1"
    then have "x ∈ S"
      using rel_interior_subset by auto
    have "x - u *R (x-y) ∈ rel_interior S"
    proof (cases "0 = u")
      case False
      then have "0 < u" using assm by auto
      then show ?thesis
        using assm rel_interior_convex_shrink[of S y x u] assms `x ∈ S` by auto
    next
      case True
      then show ?thesis using assm by auto
    qed
    then have "(1 - u) *R x + u *R y ∈ rel_interior S"
      by (simp add: algebra_simps)
  }
  then show ?thesis
    unfolding convex_alt by auto
qed

lemma convex_closure_rel_interior:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
  shows "closure (rel_interior S) = closure S"
proof -
  have h1: "closure (rel_interior S) ≤ closure S"
    using closure_mono[of "rel_interior S" S] rel_interior_subset[of S] by auto
  show ?thesis
  proof (cases "S = {}")
    case False
    then obtain a where a: "a ∈ rel_interior S"
      using rel_interior_convex_nonempty assms by auto
    { fix x
      assume x: "x ∈ closure S"
      {
        assume "x = a"
        then have "x ∈ closure (rel_interior S)"
          using a unfolding closure_def by auto
      }
      moreover
      {
        assume "x ≠ a"
         {
           fix e :: real
           assume "e > 0"
           def e1  "min 1 (e/norm (x - a))"
           then have e1: "e1 > 0" "e1 ≤ 1" "e1 * norm (x - a) ≤ e"
             using `x ≠ a` `e > 0` le_divide_eq[of e1 e "norm (x - a)"]
             by simp_all
           then have *: "x - e1 *R (x - a) : rel_interior S"
             using rel_interior_closure_convex_shrink[of S a x e1] assms x a e1_def
             by auto
           have "∃y. y ∈ rel_interior S ∧ y ≠ x ∧ dist y x ≤ e"
              apply (rule_tac x="x - e1 *R (x - a)" in exI)
              using * e1 dist_norm[of "x - e1 *R (x - a)" x] `x ≠ a`
              apply simp
              done
        }
        then have "x islimpt rel_interior S"
          unfolding islimpt_approachable_le by auto
        then have "x ∈ closure(rel_interior S)"
          unfolding closure_def by auto
      }
      ultimately have "x ∈ closure(rel_interior S)" by auto
    }
    then show ?thesis using h1 by auto
  next
    case True
    then have "rel_interior S = {}"
      using rel_interior_empty by auto
    then have "closure (rel_interior S) = {}"
      using closure_empty by auto
    with True show ?thesis by auto
  qed
qed

lemma rel_interior_same_affine_hull:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
  shows "affine hull (rel_interior S) = affine hull S"
  by (metis assms closure_same_affine_hull convex_closure_rel_interior)

lemma rel_interior_aff_dim:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
  shows "aff_dim (rel_interior S) = aff_dim S"
  by (metis aff_dim_affine_hull2 assms rel_interior_same_affine_hull)

lemma rel_interior_rel_interior:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
  shows "rel_interior (rel_interior S) = rel_interior S"
proof -
  have "openin (subtopology euclidean (affine hull (rel_interior S))) (rel_interior S)"
    using opein_rel_interior[of S] rel_interior_same_affine_hull[of S] assms by auto
  then show ?thesis
    using rel_interior_def by auto
qed

lemma rel_interior_rel_open:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
  shows "rel_open (rel_interior S)"
  unfolding rel_open_def using rel_interior_rel_interior assms by auto

lemma convex_rel_interior_closure_aux:
  fixes x y z :: "'n::euclidean_space"
  assumes "0 < a" "0 < b" "(a + b) *R z = a *R x + b *R y"
  obtains e where "0 < e" "e ≤ 1" "z = y - e *R (y - x)"
proof -
  def e  "a / (a + b)"
  have "z = (1 / (a + b)) *R ((a + b) *R z)"
    apply auto
    using assms
    apply simp
    done
  also have "… = (1 / (a + b)) *R (a *R x + b *R y)"
    using assms scaleR_cancel_left[of "1/(a+b)" "(a + b) *R z" "a *R x + b *R y"]
    by auto
  also have "… = y - e *R (y-x)"
    using e_def
    apply (simp add: algebra_simps)
    using scaleR_left_distrib[of "a/(a+b)" "b/(a+b)" y] assms add_divide_distrib[of a b "a+b"]
    apply auto
    done
  finally have "z = y - e *R (y-x)"
    by auto
  moreover have "e > 0" using e_def assms by auto
  moreover have "e ≤ 1" using e_def assms by auto
  ultimately show ?thesis using that[of e] by auto
qed

lemma convex_rel_interior_closure:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
  shows "rel_interior (closure S) = rel_interior S"
proof (cases "S = {}")
  case True
  then show ?thesis
    using assms rel_interior_convex_nonempty by auto
next
  case False
  have "rel_interior (closure S) ⊇ rel_interior S"
    using subset_rel_interior[of S "closure S"] closure_same_affine_hull closure_subset
    by auto
  moreover
  {
    fix z
    assume z: "z ∈ rel_interior (closure S)"
    obtain x where x: "x ∈ rel_interior S"
      using `S ≠ {}` assms rel_interior_convex_nonempty by auto
    have "z ∈ rel_interior S"
    proof (cases "x = z")
      case True
      then show ?thesis using x by auto
    next
      case False
      obtain e where e: "e > 0" "cball z e ∩ affine hull closure S ≤ closure S"
        using z rel_interior_cball[of "closure S"] by auto
      hence *: "0 < e/norm(z-x)" using e False by auto
      def y  "z + (e/norm(z-x)) *R (z-x)"
      have yball: "y ∈ cball z e"
        using mem_cball y_def dist_norm[of z y] e by auto
      have "x ∈ affine hull closure S"
        using x rel_interior_subset_closure hull_inc[of x "closure S"] by auto
      moreover have "z ∈ affine hull closure S"
        using z rel_interior_subset hull_subset[of "closure S"] by auto
      ultimately have "y ∈ affine hull closure S"
        using y_def affine_affine_hull[of "closure S"]
          mem_affine_3_minus [of "affine hull closure S" z z x "e/norm(z-x)"] by auto
      then have "y ∈ closure S" using e yball by auto
      have "(1 + (e/norm(z-x))) *R z = (e/norm(z-x)) *R x + y"
        using y_def by (simp add: algebra_simps)
      then obtain e1 where "0 < e1" "e1 ≤ 1" "z = y - e1 *R (y - x)"
        using * convex_rel_interior_closure_aux[of "e / norm (z - x)" 1 z x y]
        by (auto simp add: algebra_simps)
      then show ?thesis
        using rel_interior_closure_convex_shrink assms x `y ∈ closure S`
        by auto
    qed
  }
  ultimately show ?thesis by auto
qed

lemma convex_interior_closure:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
  shows "interior (closure S) = interior S"
  using closure_aff_dim[of S] interior_rel_interior_gen[of S]
    interior_rel_interior_gen[of "closure S"]
    convex_rel_interior_closure[of S] assms
  by auto

lemma closure_eq_rel_interior_eq:
  fixes S1 S2 :: "'n::euclidean_space set"
  assumes "convex S1"
    and "convex S2"
  shows "closure S1 = closure S2 <-> rel_interior S1 = rel_interior S2"
  by (metis convex_rel_interior_closure convex_closure_rel_interior assms)

lemma closure_eq_between:
  fixes S1 S2 :: "'n::euclidean_space set"
  assumes "convex S1"
    and "convex S2"
  shows "closure S1 = closure S2 <-> rel_interior S1 ≤ S2 ∧ S2 ⊆ closure S1"
  (is "?A <-> ?B")
proof
  assume ?A
  then show ?B
    by (metis assms closure_subset convex_rel_interior_closure rel_interior_subset)
next
  assume ?B
  then have "closure S1 ⊆ closure S2"
    by (metis assms(1) convex_closure_rel_interior closure_mono)
  moreover from `?B` have "closure S1 ⊇ closure S2"
    by (metis closed_closure closure_minimal)
  ultimately show ?A ..
qed

lemma open_inter_closure_rel_interior:
  fixes S A :: "'n::euclidean_space set"
  assumes "convex S"
    and "open A"
  shows "A ∩ closure S = {} <-> A ∩ rel_interior S = {}"
  by (metis assms convex_closure_rel_interior open_inter_closure_eq_empty)

definition "rel_frontier S = closure S - rel_interior S"

lemma closed_affine_hull:
  fixes S :: "'n::euclidean_space set"
  shows "closed (affine hull S)"
  by (metis affine_affine_hull affine_closed)

lemma closed_rel_frontier:
  fixes S :: "'n::euclidean_space set"
  shows "closed (rel_frontier S)"
proof -
  have *: "closedin (subtopology euclidean (affine hull S)) (closure S - rel_interior S)"
    apply (rule closedin_diff[of "subtopology euclidean (affine hull S)""closure S" "rel_interior S"])
    using closed_closedin_trans[of "affine hull S" "closure S"] closed_affine_hull[of S]
      closure_affine_hull[of S] opein_rel_interior[of S]
    apply auto
    done
  show ?thesis
    apply (rule closedin_closed_trans[of "affine hull S" "rel_frontier S"])
    unfolding rel_frontier_def
    using * closed_affine_hull
    apply auto
    done
qed


lemma convex_rel_frontier_aff_dim:
  fixes S1 S2 :: "'n::euclidean_space set"
  assumes "convex S1"
    and "convex S2"
    and "S2 ≠ {}"
    and "S1 ≤ rel_frontier S2"
  shows "aff_dim S1 < aff_dim S2"
proof -
  have "S1 ⊆ closure S2"
    using assms unfolding rel_frontier_def by auto
  then have *: "affine hull S1 ⊆ affine hull S2"
    using hull_mono[of "S1" "closure S2"] closure_same_affine_hull[of S2]
    by auto
  then have "aff_dim S1 ≤ aff_dim S2"
    using * aff_dim_affine_hull[of S1] aff_dim_affine_hull[of S2]
      aff_dim_subset[of "affine hull S1" "affine hull S2"]
    by auto
  moreover
  {
    assume eq: "aff_dim S1 = aff_dim S2"
    then have "S1 ≠ {}"
      using aff_dim_empty[of S1] aff_dim_empty[of S2] `S2 ≠ {}` by auto
    have **: "affine hull S1 = affine hull S2"
       apply (rule affine_dim_equal)
       using * affine_affine_hull
       apply auto
       using `S1 ≠ {}` hull_subset[of S1]
       apply auto
       using eq aff_dim_affine_hull[of S1] aff_dim_affine_hull[of S2]
       apply auto
       done
    obtain a where a: "a ∈ rel_interior S1"
      using `S1 ≠ {}` rel_interior_convex_nonempty assms by auto
    obtain T where T: "open T" "a ∈ T ∩ S1" "T ∩ affine hull S1 ⊆ S1"
       using mem_rel_interior[of a S1] a by auto
    then have "a ∈ T ∩ closure S2"
      using a assms unfolding rel_frontier_def by auto
    then obtain b where b: "b ∈ T ∩ rel_interior S2"
      using open_inter_closure_rel_interior[of S2 T] assms T by auto
    then have "b ∈ affine hull S1"
      using rel_interior_subset hull_subset[of S2] ** by auto
    then have "b ∈ S1"
      using T b by auto
    then have False
      using b assms unfolding rel_frontier_def by auto
  }
  ultimately show ?thesis
    using less_le by auto
qed


lemma convex_rel_interior_if:
  fixes S ::  "'n::euclidean_space set"
  assumes "convex S"
    and "z ∈ rel_interior S"
  shows "∀x∈affine hull S. ∃m. m > 1 ∧ (∀e. e > 1 ∧ e ≤ m --> (1 - e) *R x + e *R z ∈ S)"
proof -
  obtain e1 where e1: "e1 > 0 ∧ cball z e1 ∩ affine hull S ⊆ S"
    using mem_rel_interior_cball[of z S] assms by auto
  {
    fix x
    assume x: "x ∈ affine hull S"
    {
      assume "x ≠ z"
      def m  "1 + e1/norm(x-z)"
      hence "m > 1" using e1 `x ≠ z` by auto
      {
        fix e
        assume e: "e > 1 ∧ e ≤ m"
        have "z ∈ affine hull S"
          using assms rel_interior_subset hull_subset[of S] by auto
        then have *: "(1 - e)*R x + e *R z ∈ affine hull S"
          using mem_affine[of "affine hull S" x z "(1-e)" e] affine_affine_hull[of S] x
          by auto
        have "norm (z + e *R x - (x + e *R z)) = norm ((e - 1) *R (x - z))"
          by (simp add: algebra_simps)
        also have "… = (e - 1) * norm (x-z)"
          using norm_scaleR e by auto
        also have "… ≤ (m - 1) * norm (x - z)"
          using e mult_right_mono[of _ _ "norm(x-z)"] by auto
        also have "… = (e1 / norm (x - z)) * norm (x - z)"
          using m_def by auto
        also have "… = e1"
          using `x ≠ z` e1 by simp
        finally have **: "norm (z + e *R x - (x + e *R z)) ≤ e1"
          by auto
        have "(1 - e)*R x+ e *R z ∈ cball z e1"
          using m_def **
          unfolding cball_def dist_norm
          by (auto simp add: algebra_simps)
        then have "(1 - e) *R x+ e *R z ∈ S"
          using e * e1 by auto
      }
      then have "∃m. m > 1 ∧ (∀e. e > 1 ∧ e ≤ m --> (1 - e) *R x + e *R z ∈ S )"
        using `m> 1 ` by auto
    }
    moreover
    {
      assume "x = z"
      def m  "1 + e1"
      then have "m > 1"
        using e1 by auto
      {
        fix e
        assume e: "e > 1 ∧ e ≤ m"
        then have "(1 - e) *R x + e *R z ∈ S"
          using e1 x `x = z` by (auto simp add: algebra_simps)
        then have "(1 - e) *R x + e *R z ∈ S"
          using e by auto
      }
      then have "∃m. m > 1 ∧ (∀e. e > 1 ∧ e ≤ m --> (1 - e) *R x + e *R z ∈ S)"
        using `m > 1` by auto
    }
    ultimately have "∃m. m > 1 ∧ (∀e. e > 1 ∧ e ≤ m --> (1 - e) *R x + e *R z ∈ S )"
      by auto
  }
  then show ?thesis by auto
qed

lemma convex_rel_interior_if2:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
  assumes "z ∈ rel_interior S"
  shows "∀x∈affine hull S. ∃e. e > 1 ∧ (1 - e)*R x + e *R z ∈ S"
  using convex_rel_interior_if[of S z] assms by auto

lemma convex_rel_interior_only_if:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
    and "S ≠ {}"
  assumes "∀x∈S. ∃e. e > 1 ∧ (1 - e) *R x + e *R z ∈ S"
  shows "z ∈ rel_interior S"
proof -
  obtain x where x: "x ∈ rel_interior S"
    using rel_interior_convex_nonempty assms by auto
  then have "x ∈ S"
    using rel_interior_subset by auto
  then obtain e where e: "e > 1 ∧ (1 - e) *R x + e *R z ∈ S"
    using assms by auto
  def y  "(1 - e) *R x + e *R z"
  then have "y ∈ S" using e by auto
  def e1  "1/e"
  then have "0 < e1 ∧ e1 < 1" using e by auto
  then have "z  =y - (1 - e1) *R (y - x)"
    using e1_def y_def by (auto simp add: algebra_simps)
  then show ?thesis
    using rel_interior_convex_shrink[of S x y "1-e1"] `0 < e1 ∧ e1 < 1` `y ∈ S` x assms
    by auto
qed

lemma convex_rel_interior_iff:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
    and "S ≠ {}"
  shows "z ∈ rel_interior S <-> (∀x∈S. ∃e. e > 1 ∧ (1 - e) *R x + e *R z ∈ S)"
  using assms hull_subset[of S "affine"]
    convex_rel_interior_if[of S z] convex_rel_interior_only_if[of S z]
  by auto

lemma convex_rel_interior_iff2:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
    and "S ≠ {}"
  shows "z ∈ rel_interior S <-> (∀x∈affine hull S. ∃e. e > 1 ∧ (1 - e) *R x + e *R z ∈ S)"
  using assms hull_subset[of S] convex_rel_interior_if2[of S z] convex_rel_interior_only_if[of S z]
  by auto

lemma convex_interior_iff:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
  shows "z ∈ interior S <-> (∀x. ∃e. e > 0 ∧ z + e *R x ∈ S)"
proof (cases "aff_dim S = int DIM('n)")
  case False
  {
    assume "z ∈ interior S"
    then have False
      using False interior_rel_interior_gen[of S] by auto
  }
  moreover
  {
    assume r: "∀x. ∃e. e > 0 ∧ z + e *R x ∈ S"
    {
      fix x
      obtain e1 where e1: "e1 > 0 ∧ z + e1 *R (x - z) ∈ S"
        using r by auto
      obtain e2 where e2: "e2 > 0 ∧ z + e2 *R (z - x) ∈ S"
        using r by auto
      def x1  "z + e1 *R (x - z)"
      then have x1: "x1 ∈ affine hull S"
        using e1 hull_subset[of S] by auto
      def x2  "z + e2 *R (z - x)"
      then have x2: "x2 ∈ affine hull S"
        using e2 hull_subset[of S] by auto
      have *: "e1/(e1+e2) + e2/(e1+e2) = 1"
        using add_divide_distrib[of e1 e2 "e1+e2"] e1 e2 by simp
      then have "z = (e2/(e1+e2)) *R x1 + (e1/(e1+e2)) *R x2"
        using x1_def x2_def
        apply (auto simp add: algebra_simps)
        using scaleR_left_distrib[of "e1/(e1+e2)" "e2/(e1+e2)" z]
        apply auto
        done
      then have z: "z ∈ affine hull S"
        using mem_affine[of "affine hull S" x1 x2 "e2/(e1+e2)" "e1/(e1+e2)"]
          x1 x2 affine_affine_hull[of S] *
        by auto
      have "x1 - x2 = (e1 + e2) *R (x - z)"
        using x1_def x2_def by (auto simp add: algebra_simps)
      then have "x = z+(1/(e1+e2)) *R (x1-x2)"
        using e1 e2 by simp
      then have "x ∈ affine hull S"
        using mem_affine_3_minus[of "affine hull S" z x1 x2 "1/(e1+e2)"]
          x1 x2 z affine_affine_hull[of S]
        by auto
    }
    then have "affine hull S = UNIV"
      by auto
    then have "aff_dim S = int DIM('n)"
      using aff_dim_affine_hull[of S] by (simp add: aff_dim_univ)
    then have False
      using False by auto
  }
  ultimately show ?thesis by auto
next
  case True
  then have "S ≠ {}"
    using aff_dim_empty[of S] by auto
  have *: "affine hull S = UNIV"
    using True affine_hull_univ by auto
  {
    assume "z ∈ interior S"
    then have "z ∈ rel_interior S"
      using True interior_rel_interior_gen[of S] by auto
    then have **: "∀x. ∃e. e > 1 ∧ (1 - e) *R x + e *R z ∈ S"
      using convex_rel_interior_iff2[of S z] assms `S ≠ {}` * by auto
    fix x
    obtain e1 where e1: "e1 > 1" "(1 - e1) *R (z - x) + e1 *R z ∈ S"
      using **[rule_format, of "z-x"] by auto
    def e  "e1 - 1"
    then have "(1 - e1) *R (z - x) + e1 *R z = z + e *R x"
      by (simp add: algebra_simps)
    then have "e > 0" "z + e *R x ∈ S"
      using e1 e_def by auto
    then have "∃e. e > 0 ∧ z + e *R x ∈ S"
      by auto
  }
  moreover
  {
    assume r: "∀x. ∃e. e > 0 ∧ z + e *R x ∈ S"
    {
      fix x
      obtain e1 where e1: "e1 > 0" "z + e1 *R (z - x) ∈ S"
        using r[rule_format, of "z-x"] by auto
      def e  "e1 + 1"
      then have "z + e1 *R (z - x) = (1 - e) *R x + e *R z"
        by (simp add: algebra_simps)
      then have "e > 1" "(1 - e)*R x + e *R z ∈ S"
        using e1 e_def by auto
      then have "∃e. e > 1 ∧ (1 - e) *R x + e *R z ∈ S" by auto
    }
    then have "z ∈ rel_interior S"
      using convex_rel_interior_iff2[of S z] assms `S ≠ {}` by auto
    then have "z ∈ interior S"
      using True interior_rel_interior_gen[of S] by auto
  }
  ultimately show ?thesis by auto
qed


subsubsection {* Relative interior and closure under common operations *}

lemma rel_interior_inter_aux: "\<Inter>{rel_interior S |S. S : I} ⊆ \<Inter>I"
proof -
  {
    fix y
    assume "y ∈ \<Inter>{rel_interior S |S. S : I}"
    then have y: "∀S ∈ I. y ∈ rel_interior S"
      by auto
    {
      fix S
      assume "S ∈ I"
      then have "y ∈ S"
        using rel_interior_subset y by auto
    }
    then have "y ∈ \<Inter>I" by auto
  }
  then show ?thesis by auto
qed

lemma closure_inter: "closure (\<Inter>I) ≤ \<Inter>{closure S |S. S ∈ I}"
proof -
  {
    fix y
    assume "y ∈ \<Inter>I"
    then have y: "∀S ∈ I. y ∈ S" by auto
    {
      fix S
      assume "S ∈ I"
      then have "y ∈ closure S"
        using closure_subset y by auto
    }
    then have "y ∈ \<Inter>{closure S |S. S ∈ I}"
      by auto
  }
  then have "\<Inter>I ⊆ \<Inter>{closure S |S. S ∈ I}"
    by auto
  moreover have "closed (\<Inter>{closure S |S. S ∈ I})"
    unfolding closed_Inter closed_closure by auto
  ultimately show ?thesis using closure_hull[of "\<Inter>I"]
    hull_minimal[of "\<Inter>I" "\<Inter>{closure S |S. S ∈ I}" "closed"] by auto
qed

lemma convex_closure_rel_interior_inter:
  assumes "∀S∈I. convex (S :: 'n::euclidean_space set)"
    and "\<Inter>{rel_interior S |S. S ∈ I} ≠ {}"
  shows "\<Inter>{closure S |S. S ∈ I} ≤ closure (\<Inter>{rel_interior S |S. S ∈ I})"
proof -
  obtain x where x: "∀S∈I. x ∈ rel_interior S"
    using assms by auto
  {
    fix y
    assume "y ∈ \<Inter>{closure S |S. S ∈ I}"
    then have y: "∀S ∈ I. y ∈ closure S"
      by auto
    {
      assume "y = x"
      then have "y ∈ closure (\<Inter>{rel_interior S |S. S ∈ I})"
        using x closure_subset[of "\<Inter>{rel_interior S |S. S ∈ I}"] by auto
    }
    moreover
    {
      assume "y ≠ x"
      { fix e :: real
        assume e: "e > 0"
        def e1  "min 1 (e/norm (y - x))"
        then have e1: "e1 > 0" "e1 ≤ 1" "e1 * norm (y - x) ≤ e"
          using `y ≠ x` `e > 0` le_divide_eq[of e1 e "norm (y - x)"]
          by simp_all
        def z  "y - e1 *R (y - x)"
        {
          fix S
          assume "S ∈ I"
          then have "z ∈ rel_interior S"
            using rel_interior_closure_convex_shrink[of S x y e1] assms x y e1 z_def
            by auto
        }
        then have *: "z ∈ \<Inter>{rel_interior S |S. S ∈ I}"
          by auto
        have "∃z. z ∈ \<Inter>{rel_interior S |S. S ∈ I} ∧ z ≠ y ∧ dist z y ≤ e"
          apply (rule_tac x="z" in exI)
          using `y ≠ x` z_def * e1 e dist_norm[of z y]
          apply simp
          done
      }
      then have "y islimpt \<Inter>{rel_interior S |S. S ∈ I}"
        unfolding islimpt_approachable_le by blast
      then have "y ∈ closure (\<Inter>{rel_interior S |S. S ∈ I})"
        unfolding closure_def by auto
    }
    ultimately have "y ∈ closure (\<Inter>{rel_interior S |S. S ∈ I})"
      by auto
  }
  then show ?thesis by auto
qed


lemma convex_closure_inter:
  assumes "∀S∈I. convex (S :: 'n::euclidean_space set)"
    and "\<Inter>{rel_interior S |S. S ∈ I} ≠ {}"
  shows "closure (\<Inter>I) = \<Inter>{closure S |S. S ∈ I}"
proof -
  have "\<Inter>{closure S |S. S ∈ I} ≤ closure (\<Inter>{rel_interior S |S. S ∈ I})"
    using convex_closure_rel_interior_inter assms by auto
  moreover
  have "closure (\<Inter>{rel_interior S |S. S ∈ I}) ≤ closure (\<Inter> I)"
    using rel_interior_inter_aux closure_mono[of "\<Inter>{rel_interior S |S. S ∈ I}" "\<Inter>I"]
    by auto
  ultimately show ?thesis
    using closure_inter[of I] by auto
qed

lemma convex_inter_rel_interior_same_closure:
  assumes "∀S∈I. convex (S :: 'n::euclidean_space set)"
    and "\<Inter>{rel_interior S |S. S ∈ I} ≠ {}"
  shows "closure (\<Inter>{rel_interior S |S. S ∈ I}) = closure (\<Inter>I)"
proof -
  have "\<Inter>{closure S |S. S ∈ I} ≤ closure (\<Inter>{rel_interior S |S. S ∈ I})"
    using convex_closure_rel_interior_inter assms by auto
  moreover
  have "closure (\<Inter>{rel_interior S |S. S ∈ I}) ≤ closure (\<Inter>I)"
    using rel_interior_inter_aux closure_mono[of "\<Inter>{rel_interior S |S. S ∈ I}" "\<Inter>I"]
    by auto
  ultimately show ?thesis
    using closure_inter[of I] by auto
qed

lemma convex_rel_interior_inter:
  assumes "∀S∈I. convex (S :: 'n::euclidean_space set)"
    and "\<Inter>{rel_interior S |S. S ∈ I} ≠ {}"
  shows "rel_interior (\<Inter>I) ⊆ \<Inter>{rel_interior S |S. S ∈ I}"
proof -
  have "convex (\<Inter>I)"
    using assms convex_Inter by auto
  moreover
  have "convex (\<Inter>{rel_interior S |S. S ∈ I})"
    apply (rule convex_Inter)
    using assms convex_rel_interior
    apply auto
    done
  ultimately
  have "rel_interior (\<Inter>{rel_interior S |S. S ∈ I}) = rel_interior (\<Inter>I)"
    using convex_inter_rel_interior_same_closure assms
      closure_eq_rel_interior_eq[of "\<Inter>{rel_interior S |S. S ∈ I}" "\<Inter>I"]
    by blast
  then show ?thesis
    using rel_interior_subset[of "\<Inter>{rel_interior S |S. S ∈ I}"] by auto
qed

lemma convex_rel_interior_finite_inter:
  assumes "∀S∈I. convex (S :: 'n::euclidean_space set)"
    and "\<Inter>{rel_interior S |S. S ∈ I} ≠ {}"
    and "finite I"
  shows "rel_interior (\<Inter>I) = \<Inter>{rel_interior S |S. S ∈ I}"
proof -
  have "\<Inter>I ≠ {}"
    using assms rel_interior_inter_aux[of I] by auto
  have "convex (\<Inter>I)"
    using convex_Inter assms by auto
  show ?thesis
  proof (cases "I = {}")
    case True
    then show ?thesis
      using Inter_empty rel_interior_univ2 by auto
  next
    case False
    {
      fix z
      assume z: "z ∈ \<Inter>{rel_interior S |S. S ∈ I}"
      {
        fix x
        assume x: "x ∈ Inter I"
        {
          fix S
          assume S: "S ∈ I"
          then have "z ∈ rel_interior S" "x ∈ S"
            using z x by auto
          then have "∃m. m > 1 ∧ (∀e. e > 1 ∧ e ≤ m --> (1 - e)*R x + e *R z ∈ S)"
            using convex_rel_interior_if[of S z] S assms hull_subset[of S] by auto
        }
        then obtain mS where
          mS: "∀S∈I. mS S > 1 ∧ (∀e. e > 1 ∧ e ≤ mS S --> (1 - e) *R x + e *R z ∈ S)" by metis
        def e  "Min (mS ` I)"
        then have "e ∈ mS ` I" using assms `I ≠ {}` by simp
        then have "e > 1" using mS by auto
        moreover have "∀S∈I. e ≤ mS S"
          using e_def assms by auto
        ultimately have "∃e > 1. (1 - e) *R x + e *R z ∈ \<Inter>I"
          using mS by auto
      }
      then have "z ∈ rel_interior (\<Inter>I)"
        using convex_rel_interior_iff[of "\<Inter>I" z] `\<Inter>I ≠ {}` `convex (\<Inter>I)` by auto
    }
    then show ?thesis
      using convex_rel_interior_inter[of I] assms by auto
  qed
qed

lemma convex_closure_inter_two:
  fixes S T :: "'n::euclidean_space set"
  assumes "convex S"
    and "convex T"
  assumes "rel_interior S ∩ rel_interior T ≠ {}"
  shows "closure (S ∩ T) = closure S ∩ closure T"
  using convex_closure_inter[of "{S,T}"] assms by auto

lemma convex_rel_interior_inter_two:
  fixes S T :: "'n::euclidean_space set"
  assumes "convex S"
    and "convex T"
    and "rel_interior S ∩ rel_interior T ≠ {}"
  shows "rel_interior (S ∩ T) = rel_interior S ∩ rel_interior T"
  using convex_rel_interior_finite_inter[of "{S,T}"] assms by auto

lemma convex_affine_closure_inter:
  fixes S T :: "'n::euclidean_space set"
  assumes "convex S"
    and "affine T"
    and "rel_interior S ∩ T ≠ {}"
  shows "closure (S ∩ T) = closure S ∩ T"
proof -
  have "affine hull T = T"
    using assms by auto
  then have "rel_interior T = T"
    using rel_interior_univ[of T] by metis
  moreover have "closure T = T"
    using assms affine_closed[of T] by auto
  ultimately show ?thesis
    using convex_closure_inter_two[of S T] assms affine_imp_convex by auto
qed

lemma convex_affine_rel_interior_inter:
  fixes S T :: "'n::euclidean_space set"
  assumes "convex S"
    and "affine T"
    and "rel_interior S ∩ T ≠ {}"
  shows "rel_interior (S ∩ T) = rel_interior S ∩ T"
proof -
  have "affine hull T = T"
    using assms by auto
  then have "rel_interior T = T"
    using rel_interior_univ[of T] by metis
  moreover have "closure T = T"
    using assms affine_closed[of T] by auto
  ultimately show ?thesis
    using convex_rel_interior_inter_two[of S T] assms affine_imp_convex by auto
qed

lemma subset_rel_interior_convex:
  fixes S T :: "'n::euclidean_space set"
  assumes "convex S"
    and "convex T"
    and "S ≤ closure T"
    and "¬ S ⊆ rel_frontier T"
  shows "rel_interior S ⊆ rel_interior T"
proof -
  have *: "S ∩ closure T = S"
    using assms by auto
  have "¬ rel_interior S ⊆ rel_frontier T"
    using closure_mono[of "rel_interior S" "rel_frontier T"] closed_rel_frontier[of T]
      closure_closed[of S] convex_closure_rel_interior[of S] closure_subset[of S] assms
    by auto
  then have "rel_interior S ∩ rel_interior (closure T) ≠ {}"
    using assms rel_frontier_def[of T] rel_interior_subset convex_rel_interior_closure[of T]
    by auto
  then have "rel_interior S ∩ rel_interior T = rel_interior (S ∩ closure T)"
    using assms convex_closure convex_rel_interior_inter_two[of S "closure T"]
      convex_rel_interior_closure[of T]
    by auto
  also have "… = rel_interior S"
    using * by auto
  finally show ?thesis
    by auto
qed

lemma rel_interior_convex_linear_image:
  fixes f :: "'m::euclidean_space => 'n::euclidean_space"
  assumes "linear f"
    and "convex S"
  shows "f ` (rel_interior S) = rel_interior (f ` S)"
proof (cases "S = {}")
  case True
  then show ?thesis
    using assms rel_interior_empty rel_interior_convex_nonempty by auto
next
  case False
  have *: "f ` (rel_interior S) ⊆ f ` S"
    unfolding image_mono using rel_interior_subset by auto
  have "f ` S ⊆ f ` (closure S)"
    unfolding image_mono using closure_subset by auto
  also have "… = f ` (closure (rel_interior S))"
    using convex_closure_rel_interior assms by auto
  also have "… ⊆ closure (f ` (rel_interior S))"
    using closure_linear_image assms by auto
  finally have "closure (f ` S) = closure (f ` rel_interior S)"
    using closure_mono[of "f ` S" "closure (f ` rel_interior S)"] closure_closure
      closure_mono[of "f ` rel_interior S" "f ` S"] *
    by auto
  then have "rel_interior (f ` S) = rel_interior (f ` rel_interior S)"
    using assms convex_rel_interior
      linear_conv_bounded_linear[of f] convex_linear_image[of _ S]
      convex_linear_image[of _ "rel_interior S"]
      closure_eq_rel_interior_eq[of "f ` S" "f ` rel_interior S"]
    by auto
  then have "rel_interior (f ` S) ⊆ f ` rel_interior S"
    using rel_interior_subset by auto
  moreover
  {
    fix z
    assume "z ∈ f ` rel_interior S"
    then obtain z1 where z1: "z1 ∈ rel_interior S" "f z1 = z" by auto
    {
      fix x
      assume "x ∈ f ` S"
      then obtain x1 where x1: "x1 ∈ S" "f x1 = x" by auto
      then obtain e where e: "e > 1" "(1 - e) *R x1 + e *R z1 : S"
        using convex_rel_interior_iff[of S z1] `convex S` x1 z1 by auto
      moreover have "f ((1 - e) *R x1 + e *R z1) = (1 - e) *R x + e *R z"
        using x1 z1 `linear f` by (simp add: linear_add_cmul)
      ultimately have "(1 - e) *R x + e *R z : f ` S"
        using imageI[of "(1 - e) *R x1 + e *R z1" S f] by auto
      then have "∃e. e > 1 ∧ (1 - e) *R x + e *R z : f ` S"
        using e by auto
    }
    then have "z ∈ rel_interior (f ` S)"
      using convex_rel_interior_iff[of "f ` S" z] `convex S`
        `linear f` `S ≠ {}` convex_linear_image[of f S]  linear_conv_bounded_linear[of f]
      by auto
  }
  ultimately show ?thesis by auto
qed

lemma rel_interior_convex_linear_preimage:
  fixes f :: "'m::euclidean_space => 'n::euclidean_space"
  assumes "linear f"
    and "convex S"
    and "f -` (rel_interior S) ≠ {}"
  shows "rel_interior (f -` S) = f -` (rel_interior S)"
proof -
  have "S ≠ {}"
    using assms rel_interior_empty by auto
  have nonemp: "f -` S ≠ {}"
    by (metis assms(3) rel_interior_subset subset_empty vimage_mono)
  then have "S ∩ (range f) ≠ {}"
    by auto
  have conv: "convex (f -` S)"
    using convex_linear_vimage assms by auto
  then have "convex (S ∩ range f)"
    by (metis assms(1) assms(2) convex_Int subspace_UNIV subspace_imp_convex subspace_linear_image)
  {
    fix z
    assume "z ∈ f -` (rel_interior S)"
    then have z: "f z : rel_interior S"
      by auto
    {
      fix x
      assume "x ∈ f -` S"
      then have "f x ∈ S" by auto
      then obtain e where e: "e > 1" "(1 - e) *R f x + e *R f z ∈ S"
        using convex_rel_interior_iff[of S "f z"] z assms `S ≠ {}` by auto
      moreover have "(1 - e) *R f x + e *R f z = f ((1 - e) *R x + e *R z)"
        using `linear f` by (simp add: linear_iff)
      ultimately have "∃e. e > 1 ∧ (1 - e) *R x + e *R z ∈ f -` S"
        using e by auto
    }
    then have "z ∈ rel_interior (f -` S)"
      using convex_rel_interior_iff[of "f -` S" z] conv nonemp by auto
  }
  moreover
  {
    fix z
    assume z: "z ∈ rel_interior (f -` S)"
    {
      fix x
      assume "x ∈ S ∩ range f"
      then obtain y where y: "f y = x" "y ∈ f -` S" by auto
      then obtain e where e: "e > 1" "(1 - e) *R y + e *R z ∈ f -` S"
        using convex_rel_interior_iff[of "f -` S" z] z conv by auto
      moreover have "(1 - e) *R x + e *R f z = f ((1 - e) *R y + e *R z)"
        using `linear f` y by (simp add: linear_iff)
      ultimately have "∃e. e > 1 ∧ (1 - e) *R x + e *R f z ∈ S ∩ range f"
        using e by auto
    }
    then have "f z ∈ rel_interior (S ∩ range f)"
      using `convex (S ∩ (range f))` `S ∩ range f ≠ {}`
        convex_rel_interior_iff[of "S ∩ (range f)" "f z"]
      by auto
    moreover have "affine (range f)"
      by (metis assms(1) subspace_UNIV subspace_imp_affine subspace_linear_image)
    ultimately have "f z ∈ rel_interior S"
      using convex_affine_rel_interior_inter[of S "range f"] assms by auto
    then have "z ∈ f -` (rel_interior S)"
      by auto
  }
  ultimately show ?thesis by auto
qed

lemma rel_interior_direct_sum:
  fixes S :: "'n::euclidean_space set"
    and T :: "'m::euclidean_space set"
  assumes "convex S"
    and "convex T"
  shows "rel_interior (S × T) = rel_interior S × rel_interior T"
proof -
  {
    assume "S = {}"
    then have ?thesis
      apply auto
      using rel_interior_empty
      apply auto
      done
  }
  moreover
  {
    assume "T = {}"
    then have ?thesis
      apply auto
      using rel_interior_empty
      apply auto
      done
  }
  moreover
  {
    assume "S ≠ {}" "T ≠ {}"
    then have ri: "rel_interior S ≠ {}" "rel_interior T ≠ {}"
      using rel_interior_convex_nonempty assms by auto
    then have "fst -` rel_interior S ≠ {}"
      using fst_vimage_eq_Times[of "rel_interior S"] by auto
    then have "rel_interior ((fst :: 'n * 'm => 'n) -` S) = fst -` rel_interior S"
      using fst_linear `convex S` rel_interior_convex_linear_preimage[of fst S] by auto
    then have s: "rel_interior (S × (UNIV :: 'm set)) = rel_interior S × UNIV"
      by (simp add: fst_vimage_eq_Times)
    from ri have "snd -` rel_interior T ≠ {}"
      using snd_vimage_eq_Times[of "rel_interior T"] by auto
    then have "rel_interior ((snd :: 'n * 'm => 'm) -` T) = snd -` rel_interior T"
      using snd_linear `convex T` rel_interior_convex_linear_preimage[of snd T] by auto
    then have t: "rel_interior ((UNIV :: 'n set) × T) = UNIV × rel_interior T"
      by (simp add: snd_vimage_eq_Times)
    from s t have *: "rel_interior (S × (UNIV :: 'm set)) ∩ rel_interior ((UNIV :: 'n set) × T) =
      rel_interior S × rel_interior T" by auto
    have "S × T = S × (UNIV :: 'm set) ∩ (UNIV :: 'n set) × T"
      by auto
    then have "rel_interior (S × T) = rel_interior ((S × (UNIV :: 'm set)) ∩ ((UNIV :: 'n set) × T))"
      by auto
    also have "… = rel_interior (S × (UNIV :: 'm set)) ∩ rel_interior ((UNIV :: 'n set) × T)"
       apply (subst convex_rel_interior_inter_two[of "S × (UNIV :: 'm set)" "(UNIV :: 'n set) × T"])
       using * ri assms convex_Times
       apply auto
       done
    finally have ?thesis using * by auto
  }
  ultimately show ?thesis by blast
qed

lemma rel_interior_scaleR:
  fixes S :: "'n::euclidean_space set"
  assumes "c ≠ 0"
  shows "(op *R c) ` (rel_interior S) = rel_interior ((op *R c) ` S)"
  using rel_interior_injective_linear_image[of "(op *R c)" S]
    linear_conv_bounded_linear[of "op *R c"] linear_scaleR injective_scaleR[of c] assms
  by auto

lemma rel_interior_convex_scaleR:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
  shows "(op *R c) ` (rel_interior S) = rel_interior ((op *R c) ` S)"
  by (metis assms linear_scaleR rel_interior_convex_linear_image)

lemma convex_rel_open_scaleR:
  fixes S :: "'n::euclidean_space set"
  assumes "convex S"
    and "rel_open S"
  shows "convex ((op *R c) ` S) ∧ rel_open ((op *R c) ` S)"
  by (metis assms convex_scaling rel_interior_convex_scaleR rel_open_def)

lemma convex_rel_open_finite_inter:
  assumes "∀S∈I. convex (S :: 'n::euclidean_space set) ∧ rel_open S"
    and "finite I"
  shows "convex (\<Inter>I) ∧ rel_open (\<Inter>I)"
proof (cases "\<Inter>{rel_interior S |S. S ∈ I} = {}")
  case True
  then have "\<Inter>I = {}"
    using assms unfolding rel_open_def by auto
  then show ?thesis
    unfolding rel_open_def using rel_interior_empty by auto
next
  case False
  then have "rel_open (\<Inter>I)"
    using assms unfolding rel_open_def
    using convex_rel_interior_finite_inter[of I]
    by auto
  then show ?thesis
    using convex_Inter assms by auto
qed

lemma convex_rel_open_linear_image:
  fixes f :: "'m::euclidean_space => 'n::euclidean_space"
  assumes "linear f"
    and "convex S"
    and "rel_open S"
  shows "convex (f ` S) ∧ rel_open (f ` S)"
  by (metis assms convex_linear_image rel_interior_convex_linear_image rel_open_def)

lemma convex_rel_open_linear_preimage:
  fixes f :: "'m::euclidean_space => 'n::euclidean_space"
  assumes "linear f"
    and "convex S"
    and "rel_open S"
  shows "convex (f -` S) ∧ rel_open (f -` S)"
proof (cases "f -` (rel_interior S) = {}")
  case True
  then have "f -` S = {}"
    using assms unfolding rel_open_def by auto
  then show ?thesis
    unfolding rel_open_def using rel_interior_empty by auto
next
  case False
  then have "rel_open (f -` S)"
    using assms unfolding rel_open_def
    using rel_interior_convex_linear_preimage[of f S]
    by auto
  then show ?thesis
    using convex_linear_vimage assms
    by auto
qed

lemma rel_interior_projection:
  fixes S :: "('m::euclidean_space × 'n::euclidean_space) set"
    and f :: "'m::euclidean_space => 'n::euclidean_space set"
  assumes "convex S"
    and "f = (λy. {z. (y, z) ∈ S})"
  shows "(y, z) ∈ rel_interior S <-> (y ∈ rel_interior {y. (f y ≠ {})} ∧ z ∈ rel_interior (f y))"
proof -
  {
    fix y
    assume "y ∈ {y. f y ≠ {}}"
    then obtain z where "(y, z) ∈ S"
      using assms by auto
    then have "∃x. x ∈ S ∧ y = fst x"
      apply (rule_tac x="(y, z)" in exI)
      apply auto
      done
    then obtain x where "x ∈ S" "y = fst x"
      by blast
    then have "y ∈ fst ` S"
      unfolding image_def by auto
  }
  then have "fst ` S = {y. f y ≠ {}}"
    unfolding fst_def using assms by auto
  then have h1: "fst ` rel_interior S = rel_interior {y. f y ≠ {}}"
    using rel_interior_convex_linear_image[of fst S] assms fst_linear by auto
  {
    fix y
    assume "y ∈ rel_interior {y. f y ≠ {}}"
    then have "y ∈ fst ` rel_interior S"
      using h1 by auto
    then have *: "rel_interior S ∩ fst -` {y} ≠ {}"
      by auto
    moreover have aff: "affine (fst -` {y})"
      unfolding affine_alt by (simp add: algebra_simps)
    ultimately have **: "rel_interior (S ∩ fst -` {y}) = rel_interior S ∩ fst -` {y}"
      using convex_affine_rel_interior_inter[of S "fst -` {y}"] assms by auto
    have conv: "convex (S ∩ fst -` {y})"
      using convex_Int assms aff affine_imp_convex by auto
    {
      fix x
      assume "x ∈ f y"
      then have "(y, x) ∈ S ∩ (fst -` {y})"
        using assms by auto
      moreover have "x = snd (y, x)" by auto
      ultimately have "x ∈ snd ` (S ∩ fst -` {y})"
        by blast
    }
    then have "snd ` (S ∩ fst -` {y}) = f y"
      using assms by auto
    then have ***: "rel_interior (f y) = snd ` rel_interior (S ∩ fst -` {y})"
      using rel_interior_convex_linear_image[of snd "S ∩ fst -` {y}"] snd_linear conv
      by auto
    {
      fix z
      assume "z ∈ rel_interior (f y)"
      then have "z ∈ snd ` rel_interior (S ∩ fst -` {y})"
        using *** by auto
      moreover have "{y} = fst ` rel_interior (S ∩ fst -` {y})"
        using * ** rel_interior_subset by auto
      ultimately have "(y, z) ∈ rel_interior (S ∩ fst -` {y})"
        by force
      then have "(y,z) ∈ rel_interior S"
        using ** by auto
    }
    moreover
    {
      fix z
      assume "(y, z) ∈ rel_interior S"
      then have "(y, z) ∈ rel_interior (S ∩ fst -` {y})"
        using ** by auto
      then have "z ∈ snd ` rel_interior (S ∩ fst -` {y})"
        by (metis Range_iff snd_eq_Range)
      then have "z ∈ rel_interior (f y)"
        using *** by auto
    }
    ultimately have "!!z. (y, z) ∈ rel_interior S <-> z ∈ rel_interior (f y)"
      by auto
  }
  then have h2: "!!y z. y ∈ rel_interior {t. f t ≠ {}} ==>
    (y, z) ∈ rel_interior S <-> z ∈ rel_interior (f y)"
    by auto
  {
    fix y z
    assume asm: "(y, z) ∈ rel_interior S"
    then have "y ∈ fst ` rel_interior S"
      by (metis Domain_iff fst_eq_Domain)
    then have "y ∈ rel_interior {t. f t ≠ {}}"
      using h1 by auto
    then have "y ∈ rel_interior {t. f t ≠ {}}" and "(z : rel_interior (f y))"
      using h2 asm by auto
  }
  then show ?thesis using h2 by blast
qed


subsubsection {* Relative interior of convex cone *}

lemma cone_rel_interior:
  fixes S :: "'m::euclidean_space set"
  assumes "cone S"
  shows "cone ({0} ∪ rel_interior S)"
proof (cases "S = {}")
  case True
  then show ?thesis
    by (simp add: rel_interior_empty cone_0)
next
  case False
  then have *: "0 ∈ S ∧ (∀c. c > 0 --> op *R c ` S = S)"
    using cone_iff[of S] assms by auto
  then have *: "0 ∈ ({0} ∪ rel_interior S)"
    and "∀c. c > 0 --> op *R c ` ({0} ∪ rel_interior S) = ({0} ∪ rel_interior S)"
    by (auto simp add: rel_interior_scaleR)
  then show ?thesis
    using cone_iff[of "{0} ∪ rel_interior S"] by auto
qed

lemma rel_interior_convex_cone_aux:
  fixes S :: "'m::euclidean_space set"
  assumes "convex S"
  shows "(c, x) ∈ rel_interior (cone hull ({(1 :: real)} × S)) <->
    c > 0 ∧ x ∈ ((op *R c) ` (rel_interior S))"
proof (cases "S = {}")
  case True
  then show ?thesis
    by (simp add: rel_interior_empty cone_hull_empty)
next
  case False
  then obtain s where "s ∈ S" by auto
  have conv: "convex ({(1 :: real)} × S)"
    using convex_Times[of "{(1 :: real)}" S] assms convex_singleton[of "1 :: real"]
    by auto
  def f  "λy. {z. (y, z) ∈ cone hull ({1 :: real} × S)}"
  then have *: "(c, x) ∈ rel_interior (cone hull ({(1 :: real)} × S)) =
    (c ∈ rel_interior {y. f y ≠ {}} ∧ x ∈ rel_interior (f c))"
    apply (subst rel_interior_projection[of "cone hull ({(1 :: real)} × S)" f c x])
    using convex_cone_hull[of "{(1 :: real)} × S"] conv
    apply auto
    done
  {
    fix y :: real
    assume "y ≥ 0"
    then have "y *R (1,s) ∈ cone hull ({1 :: real} × S)"
      using cone_hull_expl[of "{(1 :: real)} × S"] `s ∈ S` by auto
    then have "f y ≠ {}"
      using f_def by auto
  }
  then have "{y. f y ≠ {}} = {0..}"
    using f_def cone_hull_expl[of "{1 :: real} × S"] by auto
  then have **: "rel_interior {y. f y ≠ {}} = {0<..}"
    using rel_interior_real_semiline by auto
  {
    fix c :: real
    assume "c > 0"
    then have "f c = (op *R c ` S)"
      using f_def cone_hull_expl[of "{1 :: real} × S"] by auto
    then have "rel_interior (f c) = op *R c ` rel_interior S"
      using rel_interior_convex_scaleR[of S c] assms by auto
  }
  then show ?thesis using * ** by auto
qed

lemma rel_interior_convex_cone:
  fixes S :: "'m::euclidean_space set"
  assumes "convex S"
  shows "rel_interior (cone hull ({1 :: real} × S)) =
    {(c, c *R x) | c x. c > 0 ∧ x ∈ rel_interior S}"
  (is "?lhs = ?rhs")
proof -
  {
    fix z
    assume "z ∈ ?lhs"
    have *: "z = (fst z, snd z)"
      by auto
    have "z ∈ ?rhs"
      using rel_interior_convex_cone_aux[of S "fst z" "snd z"] assms `z ∈ ?lhs`
      apply auto
      apply (rule_tac x = "fst z" in exI)
      apply (rule_tac x = x in exI)
      using *
      apply auto
      done
  }
  moreover
  {
    fix z
    assume "z ∈ ?rhs"
    then have "z ∈ ?lhs"
      using rel_interior_convex_cone_aux[of S "fst z" "snd z"] assms
      by auto
  }
  ultimately show ?thesis by blast
qed

lemma convex_hull_finite_union:
  assumes "finite I"
  assumes "∀i∈I. convex (S i) ∧ (S i) ≠ {}"
  shows "convex hull (\<Union>(S ` I)) =
    {setsum (λi. c i *R s i) I | c s. (∀i∈I. c i ≥ 0) ∧ setsum c I = 1 ∧ (∀i∈I. s i ∈ S i)}"
  (is "?lhs = ?rhs")
proof -
  have "?lhs ⊇ ?rhs"
  proof
    fix x
    assume "x : ?rhs"
    then obtain c s where *: "setsum (λi. c i *R s i) I = x" "setsum c I = 1"
      "(∀i∈I. c i ≥ 0) ∧ (∀i∈I. s i ∈ S i)" by auto
    then have "∀i∈I. s i ∈ convex hull (\<Union>(S ` I))"
      using hull_subset[of "\<Union>(S ` I)" convex] by auto
    then show "x ∈ ?lhs"
      unfolding *(1)[symmetric]
      apply (subst convex_setsum[of I "convex hull \<Union>(S ` I)" c s])
      using * assms convex_convex_hull
      apply auto
      done
  qed

  {
    fix i
    assume "i ∈ I"
    with assms have "∃p. p ∈ S i" by auto
  }
  then obtain p where p: "∀i∈I. p i ∈ S i" by metis

  {
    fix i
    assume "i ∈ I"
    {
      fix x
      assume "x ∈ S i"
      def c  "λj. if j = i then 1::real else 0"
      then have *: "setsum c I = 1"
        using `finite I` `i ∈ I` setsum.delta[of I i "λj::'a. 1::real"]
        by auto
      def s  "λj. if j = i then x else p j"
      then have "∀j. c j *R s j = (if j = i then x else 0)"
        using c_def by (auto simp add: algebra_simps)
      then have "x = setsum (λi. c i *R s i) I"
        using s_def c_def `finite I` `i ∈ I` setsum.delta[of I i "λj::'a. x"]
        by auto
      then have "x ∈ ?rhs"
        apply auto
        apply (rule_tac x = c in exI)
        apply (rule_tac x = s in exI)
        using * c_def s_def p `x ∈ S i`
        apply auto
        done
    }
    then have "?rhs ⊇ S i" by auto
  }
  then have *: "?rhs ⊇ \<Union>(S ` I)" by auto

  {
    fix u v :: real
    assume uv: "u ≥ 0 ∧ v ≥ 0 ∧ u + v = 1"
    fix x y
    assume xy: "x ∈ ?rhs ∧ y ∈ ?rhs"
    from xy obtain c s where
      xc: "x = setsum (λi. c i *R s i) I ∧ (∀i∈I. c i ≥ 0) ∧ setsum c I = 1 ∧ (∀i∈I. s i ∈ S i)"
      by auto