Theory Convex_Euclidean_Space

theory Convex_Euclidean_Space
imports Topology_Euclidean_Space Convex Set_Algebras
(*  Title:      HOL/Multivariate_Analysis/Convex_Euclidean_Space.thy
    Author:     Robert Himmelmann, TU Muenchen
    Author:     Bogdan Grechuk, University of Edinburgh
*)

section ‹Convex sets, functions and related things.›

theory Convex_Euclidean_Space
imports
  Topology_Euclidean_Space
  "~~/src/HOL/Library/Convex"
  "~~/src/HOL/Library/Set_Algebras"
begin

lemma independent_injective_on_span_image:
  assumes iS: "independent S"
    and lf: "linear f"
    and fi: "inj_on f (span S)"
  shows "independent (f ` S)"
proof -
  {
    fix a
    assume a: "a ∈ S" "f a ∈ span (f ` S - {f a})"
    have eq: "f ` S - {f a} = f ` (S - {a})"
      using fi a span_inc by (auto simp add: inj_on_def)
    from a have "f a ∈ f ` span (S -{a})"
      unfolding eq span_linear_image [OF lf, of "S - {a}"] by blast
    moreover have "span (S - {a}) ⊆ span S"
      using span_mono[of "S - {a}" S] by auto
    ultimately have "a ∈ span (S - {a})"
      using fi a span_inc by (auto simp add: inj_on_def)
    with a(1) iS have False
      by (simp add: dependent_def)
  }
  then show ?thesis
    unfolding dependent_def by blast
qed

lemma dim_image_eq:
  fixes f :: "'n::euclidean_space ⇒ 'm::euclidean_space"
  assumes lf: "linear f"
    and fi: "inj_on f (span S)"
  shows "dim (f ` S) = dim (S::'n::euclidean_space set)"
proof -
  obtain B where B: "B ⊆ S" "independent B" "S ⊆ span B" "card B = dim S"
    using basis_exists[of S] by auto
  then have "span S = span B"
    using span_mono[of B S] span_mono[of S "span B"] span_span[of B] by auto
  then have "independent (f ` B)"
    using independent_injective_on_span_image[of B f] B assms by auto
  moreover have "card (f ` B) = card B"
    using assms card_image[of f B] subset_inj_on[of f "span S" B] B span_inc by auto
  moreover have "(f ` B) ⊆ (f ` S)"
    using B by auto
  ultimately have "dim (f ` S) ≥ dim S"
    using independent_card_le_dim[of "f ` B" "f ` S"] B by auto
  then show ?thesis
    using dim_image_le[of f S] assms by auto
qed

lemma linear_injective_on_subspace_0:
  assumes lf: "linear f"
    and "subspace S"
  shows "inj_on f S ⟷ (∀x ∈ S. f x = 0 ⟶ x = 0)"
proof -
  have "inj_on f S ⟷ (∀x ∈ S. ∀y ∈ S. f x = f y ⟶ x = y)"
    by (simp add: inj_on_def)
  also have "… ⟷ (∀x ∈ S. ∀y ∈ S. f x - f y = 0 ⟶ x - y = 0)"
    by simp
  also have "… ⟷ (∀x ∈ S. ∀y ∈ S. f (x - y) = 0 ⟶ x - y = 0)"
    by (simp add: linear_sub[OF lf])
  also have "… ⟷ (∀x ∈ S. f x = 0 ⟶ x = 0)"
    using ‹subspace S› subspace_def[of S] subspace_sub[of S] by auto
  finally show ?thesis .
qed

lemma subspace_Inter: "∀s ∈ f. subspace s ⟹ subspace (⋂f)"
  unfolding subspace_def by auto

lemma span_eq[simp]: "span s = s ⟷ subspace s"
  unfolding span_def by (rule hull_eq) (rule subspace_Inter)

lemma substdbasis_expansion_unique:
  assumes d: "d ⊆ Basis"
  shows "(∑i∈d. f i *R i) = (x::'a::euclidean_space) ⟷
    (∀i∈Basis. (i ∈ d ⟶ f i = x ∙ i) ∧ (i ∉ d ⟶ x ∙ i = 0))"
proof -
  have *: "⋀x a b P. x * (if P then a else b) = (if P then x * a else x * b)"
    by auto
  have **: "finite d"
    by (auto intro: finite_subset[OF assms])
  have ***: "⋀i. i ∈ Basis ⟹ (∑i∈d. f i *R i) ∙ i = (∑x∈d. if x = i then f x else 0)"
    using d
    by (auto intro!: setsum.cong simp: inner_Basis inner_setsum_left)
  show ?thesis
    unfolding euclidean_eq_iff[where 'a='a] by (auto simp: setsum.delta[OF **] ***)
qed

lemma independent_substdbasis: "d ⊆ Basis ⟹ independent d"
  by (rule independent_mono[OF independent_Basis])

lemma dim_cball:
  assumes "e > 0"
  shows "dim (cball (0 :: 'n::euclidean_space) e) = DIM('n)"
proof -
  {
    fix x :: "'n::euclidean_space"
    def y  "(e / norm x) *R x"
    then have "y ∈ cball 0 e"
      using cball_def dist_norm[of 0 y] assms by auto
    moreover have *: "x = (norm x / e) *R y"
      using y_def assms by simp
    moreover from * have "x = (norm x/e) *R y"
      by auto
    ultimately have "x ∈ span (cball 0 e)"
      using span_mul[of y "cball 0 e" "norm x/e"] span_inc[of "cball 0 e"] by auto
  }
  then have "span (cball 0 e) = (UNIV :: 'n::euclidean_space set)"
    by auto
  then show ?thesis
    using dim_span[of "cball (0 :: 'n::euclidean_space) e"] by (auto simp add: dim_UNIV)
qed

lemma indep_card_eq_dim_span:
  fixes B :: "'n::euclidean_space set"
  assumes "independent B"
  shows "finite B ∧ card B = dim (span B)"
  using assms basis_card_eq_dim[of B "span B"] span_inc by auto

lemma setsum_not_0: "setsum f A ≠ 0 ⟹ ∃a ∈ A. f a ≠ 0"
  by (rule ccontr) auto

lemma subset_translation_eq [simp]:
    fixes a :: "'a::real_vector" shows "op + a ` s ⊆ op + a ` t ⟷ s ⊆ t"
  by auto

lemma translate_inj_on:
  fixes A :: "'a::ab_group_add set"
  shows "inj_on (λx. a + x) A"
  unfolding inj_on_def by auto

lemma translation_assoc:
  fixes a b :: "'a::ab_group_add"
  shows "(λx. b + x) ` ((λx. a + x) ` S) = (λx. (a + b) + x) ` S"
  by auto

lemma translation_invert:
  fixes a :: "'a::ab_group_add"
  assumes "(λx. a + x) ` A = (λx. a + x) ` B"
  shows "A = B"
proof -
  have "(λx. -a + x) ` ((λx. a + x) ` A) = (λx. - a + x) ` ((λx. a + x) ` B)"
    using assms by auto
  then show ?thesis
    using translation_assoc[of "-a" a A] translation_assoc[of "-a" a B] by auto
qed

lemma translation_galois:
  fixes a :: "'a::ab_group_add"
  shows "T = ((λx. a + x) ` S) ⟷ S = ((λx. (- a) + x) ` T)"
  using translation_assoc[of "-a" a S]
  apply auto
  using translation_assoc[of a "-a" T]
  apply auto
  done

lemma convex_translation_eq [simp]: "convex ((λx. a + x) ` s) ⟷ convex s"
  by (metis convex_translation translation_galois)

lemma translation_inverse_subset:
  assumes "((λx. - a + x) ` V) ≤ (S :: 'n::ab_group_add set)"
  shows "V ≤ ((λx. a + x) ` S)"
proof -
  {
    fix x
    assume "x ∈ V"
    then have "x-a ∈ S" using assms by auto
    then have "x ∈ {a + v |v. v ∈ S}"
      apply auto
      apply (rule exI[of _ "x-a"])
      apply simp
      done
    then have "x ∈ ((λx. a+x) ` S)" by auto
  }
  then show ?thesis by auto
qed

lemma convex_linear_image_eq [simp]:
    fixes f :: "'a::real_vector ⇒ 'b::real_vector"
    shows "⟦linear f; inj f⟧ ⟹ convex (f ` s) ⟷ convex s"
    by (metis (no_types) convex_linear_image convex_linear_vimage inj_vimage_image_eq)

lemma basis_to_basis_subspace_isomorphism:
  assumes s: "subspace (S:: ('n::euclidean_space) set)"
    and t: "subspace (T :: ('m::euclidean_space) set)"
    and d: "dim S = dim T"
    and B: "B ⊆ S" "independent B" "S ⊆ span B" "card B = dim S"
    and C: "C ⊆ T" "independent C" "T ⊆ span C" "card C = dim T"
  shows "∃f. linear f ∧ f ` B = C ∧ f ` S = T ∧ inj_on f S"
proof -
  from B independent_bound have fB: "finite B"
    by blast
  from C independent_bound have fC: "finite C"
    by blast
  from B(4) C(4) card_le_inj[of B C] d obtain f where
    f: "f ` B ⊆ C" "inj_on f B" using ‹finite B› ‹finite C› by auto
  from linear_independent_extend[OF B(2)] obtain g where
    g: "linear g" "∀x ∈ B. g x = f x" by blast
  from inj_on_iff_eq_card[OF fB, of f] f(2)
  have "card (f ` B) = card B" by simp
  with B(4) C(4) have ceq: "card (f ` B) = card C" using d
    by simp
  have "g ` B = f ` B" using g(2)
    by (auto simp add: image_iff)
  also have "… = C" using card_subset_eq[OF fC f(1) ceq] .
  finally have gBC: "g ` B = C" .
  have gi: "inj_on g B" using f(2) g(2)
    by (auto simp add: inj_on_def)
  note g0 = linear_indep_image_lemma[OF g(1) fB, unfolded gBC, OF C(2) gi]
  {
    fix x y
    assume x: "x ∈ S" and y: "y ∈ S" and gxy: "g x = g y"
    from B(3) x y have x': "x ∈ span B" and y': "y ∈ span B"
      by blast+
    from gxy have th0: "g (x - y) = 0"
      by (simp add: linear_sub[OF g(1)])
    have th1: "x - y ∈ span B" using x' y'
      by (metis span_sub)
    have "x = y" using g0[OF th1 th0] by simp
  }
  then have giS: "inj_on g S" unfolding inj_on_def by blast
  from span_subspace[OF B(1,3) s]
  have "g ` S = span (g ` B)"
    by (simp add: span_linear_image[OF g(1)])
  also have "… = span C"
    unfolding gBC ..
  also have "… = T"
    using span_subspace[OF C(1,3) t] .
  finally have gS: "g ` S = T" .
  from g(1) gS giS gBC show ?thesis
    by blast
qed

lemma closure_bounded_linear_image_subset:
  assumes f: "bounded_linear f"
  shows "f ` closure S ⊆ closure (f ` S)"
  using linear_continuous_on [OF f] closed_closure closure_subset
  by (rule image_closure_subset)

lemma closure_linear_image_subset:
  fixes f :: "'m::euclidean_space ⇒ 'n::real_normed_vector"
  assumes "linear f"
  shows "f ` (closure S) ⊆ closure (f ` S)"
  using assms unfolding linear_conv_bounded_linear
  by (rule closure_bounded_linear_image_subset)

lemma closed_injective_linear_image:
    fixes f :: "'a::euclidean_space ⇒ 'b::euclidean_space"
    assumes S: "closed S" and f: "linear f" "inj f"
    shows "closed (f ` S)"
proof -
  obtain g where g: "linear g" "g ∘ f = id"
    using linear_injective_left_inverse [OF f] by blast
  then have confg: "continuous_on (range f) g"
    using linear_continuous_on linear_conv_bounded_linear by blast
  have [simp]: "g ` f ` S = S"
    using g by (simp add: image_comp)
  have cgf: "closed (g ` f ` S)"
    by (simp add: ‹g ∘ f = id› S image_comp)
  have [simp]: "{x ∈ range f. g x ∈ S} = f ` S"
    using g by (simp add: o_def id_def image_def) metis
  show ?thesis
    apply (rule closedin_closed_trans [of "range f"])
    apply (rule continuous_closedin_preimage [OF confg cgf, simplified])
    apply (rule closed_injective_image_subspace)
    using f
    apply (auto simp: linear_linear linear_injective_0)
    done
qed

lemma closed_injective_linear_image_eq:
    fixes f :: "'a::euclidean_space ⇒ 'b::euclidean_space"
    assumes f: "linear f" "inj f"
      shows "(closed(image f s) ⟷ closed s)"
  by (metis closed_injective_linear_image closure_eq closure_linear_image_subset closure_subset_eq f(1) f(2) inj_image_subset_iff)

lemma closure_injective_linear_image:
    fixes f :: "'a::euclidean_space ⇒ 'b::euclidean_space"
    shows "⟦linear f; inj f⟧ ⟹ f ` (closure S) = closure (f ` S)"
  apply (rule subset_antisym)
  apply (simp add: closure_linear_image_subset)
  by (simp add: closure_minimal closed_injective_linear_image closure_subset image_mono)

lemma closure_bounded_linear_image:
    fixes f :: "'a::euclidean_space ⇒ 'b::euclidean_space"
    shows "⟦linear f; bounded S⟧ ⟹ f ` (closure S) = closure (f ` S)"
  apply (rule subset_antisym, simp add: closure_linear_image_subset)
  apply (rule closure_minimal, simp add: closure_subset image_mono)
  by (meson bounded_closure closed_closure compact_continuous_image compact_eq_bounded_closed linear_continuous_on linear_conv_bounded_linear)

lemma closure_scaleR:
  fixes S :: "'a::real_normed_vector set"
  shows "(op *R c) ` (closure S) = closure ((op *R c) ` S)"
proof
  show "(op *R c) ` (closure S) ⊆ closure ((op *R c) ` S)"
    using bounded_linear_scaleR_right
    by (rule closure_bounded_linear_image_subset)
  show "closure ((op *R c) ` S) ⊆ (op *R c) ` (closure S)"
    by (intro closure_minimal image_mono closure_subset closed_scaling closed_closure)
qed

lemma fst_linear: "linear fst"
  unfolding linear_iff by (simp add: algebra_simps)

lemma snd_linear: "linear snd"
  unfolding linear_iff by (simp add: algebra_simps)

lemma fst_snd_linear: "linear (λ(x,y). x + y)"
  unfolding linear_iff by (simp add: algebra_simps)

lemma scaleR_2:
  fixes x :: "'a::real_vector"
  shows "scaleR 2 x = x + x"
  unfolding one_add_one [symmetric] scaleR_left_distrib by simp

lemma vector_choose_size:
  "0 ≤ c ⟹ ∃x::'a::euclidean_space. norm x = c"
  apply (rule exI [where x="c *R (SOME i. i ∈ Basis)"])
  apply (auto simp: SOME_Basis)
  done

lemma setsum_delta_notmem:
  assumes "x ∉ s"
  shows "setsum (λy. if (y = x) then P x else Q y) s = setsum Q s"
    and "setsum (λy. if (x = y) then P x else Q y) s = setsum Q s"
    and "setsum (λy. if (y = x) then P y else Q y) s = setsum Q s"
    and "setsum (λy. if (x = y) then P y else Q y) s = setsum Q s"
  apply (rule_tac [!] setsum.cong)
  using assms
  apply auto
  done

lemma setsum_delta'':
  fixes s::"'a::real_vector set"
  assumes "finite s"
  shows "(∑x∈s. (if y = x then f x else 0) *R x) = (if y∈s then (f y) *R y else 0)"
proof -
  have *: "⋀x y. (if y = x then f x else (0::real)) *R x = (if x=y then (f x) *R x else 0)"
    by auto
  show ?thesis
    unfolding * using setsum.delta[OF assms, of y "λx. f x *R x"] by auto
qed

lemma if_smult: "(if P then x else (y::real)) *R v = (if P then x *R v else y *R v)"
  by (fact if_distrib)

lemma dist_triangle_eq:
  fixes x y z :: "'a::real_inner"
  shows "dist x z = dist x y + dist y z ⟷
    norm (x - y) *R (y - z) = norm (y - z) *R (x - y)"
proof -
  have *: "x - y + (y - z) = x - z" by auto
  show ?thesis unfolding dist_norm norm_triangle_eq[of "x - y" "y - z", unfolded *]
    by (auto simp add:norm_minus_commute)
qed

lemma norm_minus_eqI: "x = - y ⟹ norm x = norm y" by auto

lemma Min_grI:
  assumes "finite A" "A ≠ {}" "∀a∈A. x < a"
  shows "x < Min A"
  unfolding Min_gr_iff[OF assms(1,2)] using assms(3) by auto

lemma norm_lt: "norm x < norm y ⟷ inner x x < inner y y"
  unfolding norm_eq_sqrt_inner by simp

lemma norm_le: "norm x ≤ norm y ⟷ inner x x ≤ inner y y"
  unfolding norm_eq_sqrt_inner by simp


subsection ‹Affine set and affine hull›

definition affine :: "'a::real_vector set ⇒ bool"
  where "affine s ⟷ (∀x∈s. ∀y∈s. ∀u v. u + v = 1 ⟶ u *R x + v *R y ∈ s)"

lemma affine_alt: "affine s ⟷ (∀x∈s. ∀y∈s. ∀u::real. (1 - u) *R x + u *R y ∈ s)"
  unfolding affine_def by (metis eq_diff_eq')

lemma affine_empty[intro]: "affine {}"
  unfolding affine_def by auto

lemma affine_sing[intro]: "affine {x}"
  unfolding affine_alt by (auto simp add: scaleR_left_distrib [symmetric])

lemma affine_UNIV[intro]: "affine UNIV"
  unfolding affine_def by auto

lemma affine_Inter[intro]: "(∀s∈f. affine s) ⟹ affine (⋂f)"
  unfolding affine_def by auto

lemma affine_Int[intro]: "affine s ⟹ affine t ⟹ affine (s ∩ t)"
  unfolding affine_def by auto

lemma affine_affine_hull [simp]: "affine(affine hull s)"
  unfolding hull_def
  using affine_Inter[of "{t. affine t ∧ s ⊆ t}"] by auto

lemma affine_hull_eq[simp]: "(affine hull s = s) ⟷ affine s"
  by (metis affine_affine_hull hull_same)


subsubsection ‹Some explicit formulations (from Lars Schewe)›

lemma affine:
  fixes V::"'a::real_vector set"
  shows "affine V ⟷
    (∀s u. finite s ∧ s ≠ {} ∧ s ⊆ V ∧ setsum u s = 1 ⟶ (setsum (λx. (u x) *R x)) s ∈ V)"
  unfolding affine_def
  apply rule
  apply(rule, rule, rule)
  apply(erule conjE)+
  defer
  apply (rule, rule, rule, rule, rule)
proof -
  fix x y u v
  assume as: "x ∈ V" "y ∈ V" "u + v = (1::real)"
    "∀s u. finite s ∧ s ≠ {} ∧ s ⊆ V ∧ setsum u s = 1 ⟶ (∑x∈s. u x *R x) ∈ V"
  then show "u *R x + v *R y ∈ V"
    apply (cases "x = y")
    using as(4)[THEN spec[where x="{x,y}"], THEN spec[where x="λw. if w = x then u else v"]]
      and as(1-3)
    apply (auto simp add: scaleR_left_distrib[symmetric])
    done
next
  fix s u
  assume as: "∀x∈V. ∀y∈V. ∀u v. u + v = 1 ⟶ u *R x + v *R y ∈ V"
    "finite s" "s ≠ {}" "s ⊆ V" "setsum u s = (1::real)"
  def n  "card s"
  have "card s = 0 ∨ card s = 1 ∨ card s = 2 ∨ card s > 2" by auto
  then show "(∑x∈s. u x *R x) ∈ V"
  proof (auto simp only: disjE)
    assume "card s = 2"
    then have "card s = Suc (Suc 0)"
      by auto
    then obtain a b where "s = {a, b}"
      unfolding card_Suc_eq by auto
    then show ?thesis
      using as(1)[THEN bspec[where x=a], THEN bspec[where x=b]] using as(4,5)
      by (auto simp add: setsum_clauses(2))
  next
    assume "card s > 2"
    then show ?thesis using as and n_def
    proof (induct n arbitrary: u s)
      case 0
      then show ?case by auto
    next
      case (Suc n)
      fix s :: "'a set" and u :: "'a ⇒ real"
      assume IA:
        "⋀u s.  ⟦2 < card s; ∀x∈V. ∀y∈V. ∀u v. u + v = 1 ⟶ u *R x + v *R y ∈ V; finite s;
          s ≠ {}; s ⊆ V; setsum u s = 1; n = card s ⟧ ⟹ (∑x∈s. u x *R x) ∈ V"
        and as:
          "Suc n = card s" "2 < card s" "∀x∈V. ∀y∈V. ∀u v. u + v = 1 ⟶ u *R x + v *R y ∈ V"
           "finite s" "s ≠ {}" "s ⊆ V" "setsum u s = 1"
      have "∃x∈s. u x ≠ 1"
      proof (rule ccontr)
        assume "¬ ?thesis"
        then have "setsum u s = real_of_nat (card s)"
          unfolding card_eq_setsum by auto
        then show False
          using as(7) and ‹card s > 2›
          by (metis One_nat_def less_Suc0 Zero_not_Suc of_nat_1 of_nat_eq_iff numeral_2_eq_2)
      qed
      then obtain x where x:"x ∈ s" "u x ≠ 1" by auto

      have c: "card (s - {x}) = card s - 1"
        apply (rule card_Diff_singleton)
        using ‹x∈s› as(4)
        apply auto
        done
      have *: "s = insert x (s - {x})" "finite (s - {x})"
        using ‹x∈s› and as(4) by auto
      have **: "setsum u (s - {x}) = 1 - u x"
        using setsum_clauses(2)[OF *(2), of u x, unfolded *(1)[symmetric] as(7)] by auto
      have ***: "inverse (1 - u x) * setsum u (s - {x}) = 1"
        unfolding ** using ‹u x ≠ 1› by auto
      have "(∑xa∈s - {x}. (inverse (1 - u x) * u xa) *R xa) ∈ V"
      proof (cases "card (s - {x}) > 2")
        case True
        then have "s - {x} ≠ {}" "card (s - {x}) = n"
          unfolding c and as(1)[symmetric]
        proof (rule_tac ccontr)
          assume "¬ s - {x} ≠ {}"
          then have "card (s - {x}) = 0" unfolding card_0_eq[OF *(2)] by simp
          then show False using True by auto
        qed auto
        then show ?thesis
          apply (rule_tac IA[of "s - {x}" "λy. (inverse (1 - u x) * u y)"])
          unfolding setsum_right_distrib[symmetric]
          using as and *** and True
          apply auto
          done
      next
        case False
        then have "card (s - {x}) = Suc (Suc 0)"
          using as(2) and c by auto
        then obtain a b where "(s - {x}) = {a, b}" "a≠b"
          unfolding card_Suc_eq by auto
        then show ?thesis
          using as(3)[THEN bspec[where x=a], THEN bspec[where x=b]]
          using *** *(2) and ‹s ⊆ V›
          unfolding setsum_right_distrib
          by (auto simp add: setsum_clauses(2))
      qed
      then have "u x + (1 - u x) = 1 ⟹
          u x *R x + (1 - u x) *R ((∑xa∈s - {x}. u xa *R xa) /R (1 - u x)) ∈ V"
        apply -
        apply (rule as(3)[rule_format])
        unfolding  Real_Vector_Spaces.scaleR_right.setsum
        using x(1) as(6)
        apply auto
        done
      then show "(∑x∈s. u x *R x) ∈ V"
        unfolding scaleR_scaleR[symmetric] and scaleR_right.setsum [symmetric]
        apply (subst *)
        unfolding setsum_clauses(2)[OF *(2)]
        using ‹u x ≠ 1›
        apply auto
        done
    qed
  next
    assume "card s = 1"
    then obtain a where "s={a}"
      by (auto simp add: card_Suc_eq)
    then show ?thesis
      using as(4,5) by simp
  qed (insert ‹s≠{}› ‹finite s›, auto)
qed

lemma affine_hull_explicit:
  "affine hull p =
    {y. ∃s u. finite s ∧ s ≠ {} ∧ s ⊆ p ∧ setsum u s = 1 ∧ setsum (λv. (u v) *R v) s = y}"
  apply (rule hull_unique)
  apply (subst subset_eq)
  prefer 3
  apply rule
  unfolding mem_Collect_eq
  apply (erule exE)+
  apply (erule conjE)+
  prefer 2
  apply rule
proof -
  fix x
  assume "x∈p"
  then show "∃s u. finite s ∧ s ≠ {} ∧ s ⊆ p ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = x"
    apply (rule_tac x="{x}" in exI)
    apply (rule_tac x="λx. 1" in exI)
    apply auto
    done
next
  fix t x s u
  assume as: "p ⊆ t" "affine t" "finite s" "s ≠ {}"
    "s ⊆ p" "setsum u s = 1" "(∑v∈s. u v *R v) = x"
  then show "x ∈ t"
    using as(2)[unfolded affine, THEN spec[where x=s], THEN spec[where x=u]]
    by auto
next
  show "affine {y. ∃s u. finite s ∧ s ≠ {} ∧ s ⊆ p ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = y}"
    unfolding affine_def
    apply (rule, rule, rule, rule, rule)
    unfolding mem_Collect_eq
  proof -
    fix u v :: real
    assume uv: "u + v = 1"
    fix x
    assume "∃s u. finite s ∧ s ≠ {} ∧ s ⊆ p ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = x"
    then obtain sx ux where
      x: "finite sx" "sx ≠ {}" "sx ⊆ p" "setsum ux sx = 1" "(∑v∈sx. ux v *R v) = x"
      by auto
    fix y
    assume "∃s u. finite s ∧ s ≠ {} ∧ s ⊆ p ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = y"
    then obtain sy uy where
      y: "finite sy" "sy ≠ {}" "sy ⊆ p" "setsum uy sy = 1" "(∑v∈sy. uy v *R v) = y" by auto
    have xy: "finite (sx ∪ sy)"
      using x(1) y(1) by auto
    have **: "(sx ∪ sy) ∩ sx = sx" "(sx ∪ sy) ∩ sy = sy"
      by auto
    show "∃s ua. finite s ∧ s ≠ {} ∧ s ⊆ p ∧
        setsum ua s = 1 ∧ (∑v∈s. ua v *R v) = u *R x + v *R y"
      apply (rule_tac x="sx ∪ sy" in exI)
      apply (rule_tac x="λa. (if a∈sx then u * ux a else 0) + (if a∈sy then v * uy a else 0)" in exI)
      unfolding scaleR_left_distrib setsum.distrib if_smult scaleR_zero_left
        ** setsum.inter_restrict[OF xy, symmetric]
      unfolding scaleR_scaleR[symmetric] Real_Vector_Spaces.scaleR_right.setsum [symmetric]
        and setsum_right_distrib[symmetric]
      unfolding x y
      using x(1-3) y(1-3) uv
      apply simp
      done
  qed
qed

lemma affine_hull_finite:
  assumes "finite s"
  shows "affine hull s = {y. ∃u. setsum u s = 1 ∧ setsum (λv. u v *R v) s = y}"
  unfolding affine_hull_explicit and set_eq_iff and mem_Collect_eq
  apply (rule, rule)
  apply (erule exE)+
  apply (erule conjE)+
  defer
  apply (erule exE)
  apply (erule conjE)
proof -
  fix x u
  assume "setsum u s = 1" "(∑v∈s. u v *R v) = x"
  then show "∃sa u. finite sa ∧
      ¬ (∀x. (x ∈ sa) = (x ∈ {})) ∧ sa ⊆ s ∧ setsum u sa = 1 ∧ (∑v∈sa. u v *R v) = x"
    apply (rule_tac x=s in exI, rule_tac x=u in exI)
    using assms
    apply auto
    done
next
  fix x t u
  assume "t ⊆ s"
  then have *: "s ∩ t = t"
    by auto
  assume "finite t" "¬ (∀x. (x ∈ t) = (x ∈ {}))" "setsum u t = 1" "(∑v∈t. u v *R v) = x"
  then show "∃u. setsum u s = 1 ∧ (∑v∈s. u v *R v) = x"
    apply (rule_tac x="λx. if x∈t then u x else 0" in exI)
    unfolding if_smult scaleR_zero_left and setsum.inter_restrict[OF assms, symmetric] and *
    apply auto
    done
qed


subsubsection ‹Stepping theorems and hence small special cases›

lemma affine_hull_empty[simp]: "affine hull {} = {}"
  by (rule hull_unique) auto

lemma affine_hull_finite_step:
  fixes y :: "'a::real_vector"
  shows
    "(∃u. setsum u {} = w ∧ setsum (λx. u x *R x) {} = y) ⟷ w = 0 ∧ y = 0" (is ?th1)
    and
    "finite s ⟹
      (∃u. setsum u (insert a s) = w ∧ setsum (λx. u x *R x) (insert a s) = y) ⟷
      (∃v u. setsum u s = w - v ∧ setsum (λx. u x *R x) s = y - v *R a)" (is "_ ⟹ ?lhs = ?rhs")
proof -
  show ?th1 by simp
  assume fin: "finite s"
  show "?lhs = ?rhs"
  proof
    assume ?lhs
    then obtain u where u: "setsum u (insert a s) = w ∧ (∑x∈insert a s. u x *R x) = y"
      by auto
    show ?rhs
    proof (cases "a ∈ s")
      case True
      then have *: "insert a s = s" by auto
      show ?thesis
        using u[unfolded *]
        apply(rule_tac x=0 in exI)
        apply auto
        done
    next
      case False
      then show ?thesis
        apply (rule_tac x="u a" in exI)
        using u and fin
        apply auto
        done
    qed
  next
    assume ?rhs
    then obtain v u where vu: "setsum u s = w - v"  "(∑x∈s. u x *R x) = y - v *R a"
      by auto
    have *: "⋀x M. (if x = a then v else M) *R x = (if x = a then v *R x else M *R x)"
      by auto
    show ?lhs
    proof (cases "a ∈ s")
      case True
      then show ?thesis
        apply (rule_tac x="λx. (if x=a then v else 0) + u x" in exI)
        unfolding setsum_clauses(2)[OF fin]
        apply simp
        unfolding scaleR_left_distrib and setsum.distrib
        unfolding vu and * and scaleR_zero_left
        apply (auto simp add: setsum.delta[OF fin])
        done
    next
      case False
      then have **:
        "⋀x. x ∈ s ⟹ u x = (if x = a then v else u x)"
        "⋀x. x ∈ s ⟹ u x *R x = (if x = a then v *R x else u x *R x)" by auto
      from False show ?thesis
        apply (rule_tac x="λx. if x=a then v else u x" in exI)
        unfolding setsum_clauses(2)[OF fin] and * using vu
        using setsum.cong [of s _ "λx. u x *R x" "λx. if x = a then v *R x else u x *R x", OF _ **(2)]
        using setsum.cong [of s _ u "λx. if x = a then v else u x", OF _ **(1)]
        apply auto
        done
    qed
  qed
qed

lemma affine_hull_2:
  fixes a b :: "'a::real_vector"
  shows "affine hull {a,b} = {u *R a + v *R b| u v. (u + v = 1)}"
  (is "?lhs = ?rhs")
proof -
  have *:
    "⋀x y z. z = x - y ⟷ y + z = (x::real)"
    "⋀x y z. z = x - y ⟷ y + z = (x::'a)" by auto
  have "?lhs = {y. ∃u. setsum u {a, b} = 1 ∧ (∑v∈{a, b}. u v *R v) = y}"
    using affine_hull_finite[of "{a,b}"] by auto
  also have "… = {y. ∃v u. u b = 1 - v ∧ u b *R b = y - v *R a}"
    by (simp add: affine_hull_finite_step(2)[of "{b}" a])
  also have "… = ?rhs" unfolding * by auto
  finally show ?thesis by auto
qed

lemma affine_hull_3:
  fixes a b c :: "'a::real_vector"
  shows "affine hull {a,b,c} = { u *R a + v *R b + w *R c| u v w. u + v + w = 1}"
proof -
  have *:
    "⋀x y z. z = x - y ⟷ y + z = (x::real)"
    "⋀x y z. z = x - y ⟷ y + z = (x::'a)" by auto
  show ?thesis
    apply (simp add: affine_hull_finite affine_hull_finite_step)
    unfolding *
    apply auto
    apply (rule_tac x=v in exI)
    apply (rule_tac x=va in exI)
    apply auto
    apply (rule_tac x=u in exI)
    apply force
    done
qed

lemma mem_affine:
  assumes "affine S" "x ∈ S" "y ∈ S" "u + v = 1"
  shows "u *R x + v *R y ∈ S"
  using assms affine_def[of S] by auto

lemma mem_affine_3:
  assumes "affine S" "x ∈ S" "y ∈ S" "z ∈ S" "u + v + w = 1"
  shows "u *R x + v *R y + w *R z ∈ S"
proof -
  have "u *R x + v *R y + w *R z ∈ affine hull {x, y, z}"
    using affine_hull_3[of x y z] assms by auto
  moreover
  have "affine hull {x, y, z} ⊆ affine hull S"
    using hull_mono[of "{x, y, z}" "S"] assms by auto
  moreover
  have "affine hull S = S"
    using assms affine_hull_eq[of S] by auto
  ultimately show ?thesis by auto
qed

lemma mem_affine_3_minus:
  assumes "affine S" "x ∈ S" "y ∈ S" "z ∈ S"
  shows "x + v *R (y-z) ∈ S"
  using mem_affine_3[of S x y z 1 v "-v"] assms
  by (simp add: algebra_simps)

corollary mem_affine_3_minus2:
    "⟦affine S; x ∈ S; y ∈ S; z ∈ S⟧ ⟹ x - v *R (y-z) ∈ S"
  by (metis add_uminus_conv_diff mem_affine_3_minus real_vector.scale_minus_left)


subsubsection ‹Some relations between affine hull and subspaces›

lemma affine_hull_insert_subset_span:
  "affine hull (insert a s) ⊆ {a + v| v . v ∈ span {x - a | x . x ∈ s}}"
  unfolding subset_eq Ball_def
  unfolding affine_hull_explicit span_explicit mem_Collect_eq
  apply (rule, rule)
  apply (erule exE)+
  apply (erule conjE)+
proof -
  fix x t u
  assume as: "finite t" "t ≠ {}" "t ⊆ insert a s" "setsum u t = 1" "(∑v∈t. u v *R v) = x"
  have "(λx. x - a) ` (t - {a}) ⊆ {x - a |x. x ∈ s}"
    using as(3) by auto
  then show "∃v. x = a + v ∧ (∃S u. finite S ∧ S ⊆ {x - a |x. x ∈ s} ∧ (∑v∈S. u v *R v) = v)"
    apply (rule_tac x="x - a" in exI)
    apply (rule conjI, simp)
    apply (rule_tac x="(λx. x - a) ` (t - {a})" in exI)
    apply (rule_tac x="λx. u (x + a)" in exI)
    apply (rule conjI) using as(1) apply simp
    apply (erule conjI)
    using as(1)
    apply (simp add: setsum.reindex[unfolded inj_on_def] scaleR_right_diff_distrib
      setsum_subtractf scaleR_left.setsum[symmetric] setsum_diff1 scaleR_left_diff_distrib)
    unfolding as
    apply simp
    done
qed

lemma affine_hull_insert_span:
  assumes "a ∉ s"
  shows "affine hull (insert a s) = {a + v | v . v ∈ span {x - a | x.  x ∈ s}}"
  apply (rule, rule affine_hull_insert_subset_span)
  unfolding subset_eq Ball_def
  unfolding affine_hull_explicit and mem_Collect_eq
proof (rule, rule, erule exE, erule conjE)
  fix y v
  assume "y = a + v" "v ∈ span {x - a |x. x ∈ s}"
  then obtain t u where obt: "finite t" "t ⊆ {x - a |x. x ∈ s}" "a + (∑v∈t. u v *R v) = y"
    unfolding span_explicit by auto
  def f  "(λx. x + a) ` t"
  have f: "finite f" "f ⊆ s" "(∑v∈f. u (v - a) *R (v - a)) = y - a"
    unfolding f_def using obt by (auto simp add: setsum.reindex[unfolded inj_on_def])
  have *: "f ∩ {a} = {}" "f ∩ - {a} = f"
    using f(2) assms by auto
  show "∃sa u. finite sa ∧ sa ≠ {} ∧ sa ⊆ insert a s ∧ setsum u sa = 1 ∧ (∑v∈sa. u v *R v) = y"
    apply (rule_tac x = "insert a f" in exI)
    apply (rule_tac x = "λx. if x=a then 1 - setsum (λx. u (x - a)) f else u (x - a)" in exI)
    using assms and f
    unfolding setsum_clauses(2)[OF f(1)] and if_smult
    unfolding setsum.If_cases[OF f(1), of "λx. x = a"]
    apply (auto simp add: setsum_subtractf scaleR_left.setsum algebra_simps *)
    done
qed

lemma affine_hull_span:
  assumes "a ∈ s"
  shows "affine hull s = {a + v | v. v ∈ span {x - a | x. x ∈ s - {a}}}"
  using affine_hull_insert_span[of a "s - {a}", unfolded insert_Diff[OF assms]] by auto


subsubsection ‹Parallel affine sets›

definition affine_parallel :: "'a::real_vector set ⇒ 'a::real_vector set ⇒ bool"
  where "affine_parallel S T ⟷ (∃a. T = (λx. a + x) ` S)"

lemma affine_parallel_expl_aux:
  fixes S T :: "'a::real_vector set"
  assumes "∀x. x ∈ S ⟷ a + x ∈ T"
  shows "T = (λx. a + x) ` S"
proof -
  {
    fix x
    assume "x ∈ T"
    then have "( - a) + x ∈ S"
      using assms by auto
    then have "x ∈ ((λx. a + x) ` S)"
      using imageI[of "-a+x" S "(λx. a+x)"] by auto
  }
  moreover have "T ≥ (λx. a + x) ` S"
    using assms by auto
  ultimately show ?thesis by auto
qed

lemma affine_parallel_expl: "affine_parallel S T ⟷ (∃a. ∀x. x ∈ S ⟷ a + x ∈ T)"
  unfolding affine_parallel_def
  using affine_parallel_expl_aux[of S _ T] by auto

lemma affine_parallel_reflex: "affine_parallel S S"
  unfolding affine_parallel_def
  apply (rule exI[of _ "0"])
  apply auto
  done

lemma affine_parallel_commut:
  assumes "affine_parallel A B"
  shows "affine_parallel B A"
proof -
  from assms obtain a where B: "B = (λx. a + x) ` A"
    unfolding affine_parallel_def by auto
  have [simp]: "(λx. x - a) = plus (- a)" by (simp add: fun_eq_iff)
  from B show ?thesis
    using translation_galois [of B a A]
    unfolding affine_parallel_def by auto
qed

lemma affine_parallel_assoc:
  assumes "affine_parallel A B"
    and "affine_parallel B C"
  shows "affine_parallel A C"
proof -
  from assms obtain ab where "B = (λx. ab + x) ` A"
    unfolding affine_parallel_def by auto
  moreover
  from assms obtain bc where "C = (λx. bc + x) ` B"
    unfolding affine_parallel_def by auto
  ultimately show ?thesis
    using translation_assoc[of bc ab A] unfolding affine_parallel_def by auto
qed

lemma affine_translation_aux:
  fixes a :: "'a::real_vector"
  assumes "affine ((λx. a + x) ` S)"
  shows "affine S"
proof -
  {
    fix x y u v
    assume xy: "x ∈ S" "y ∈ S" "(u :: real) + v = 1"
    then have "(a + x) ∈ ((λx. a + x) ` S)" "(a + y) ∈ ((λx. a + x) ` S)"
      by auto
    then have h1: "u *R  (a + x) + v *R (a + y) ∈ (λx. a + x) ` S"
      using xy assms unfolding affine_def by auto
    have "u *R (a + x) + v *R (a + y) = (u + v) *R a + (u *R x + v *R y)"
      by (simp add: algebra_simps)
    also have "… = a + (u *R x + v *R y)"
      using ‹u + v = 1› by auto
    ultimately have "a + (u *R x + v *R y) ∈ (λx. a + x) ` S"
      using h1 by auto
    then have "u *R x + v *R y : S" by auto
  }
  then show ?thesis unfolding affine_def by auto
qed

lemma affine_translation:
  fixes a :: "'a::real_vector"
  shows "affine S ⟷ affine ((λx. a + x) ` S)"
proof -
  have "affine S ⟹ affine ((λx. a + x) ` S)"
    using affine_translation_aux[of "-a" "((λx. a + x) ` S)"]
    using translation_assoc[of "-a" a S] by auto
  then show ?thesis using affine_translation_aux by auto
qed

lemma parallel_is_affine:
  fixes S T :: "'a::real_vector set"
  assumes "affine S" "affine_parallel S T"
  shows "affine T"
proof -
  from assms obtain a where "T = (λx. a + x) ` S"
    unfolding affine_parallel_def by auto
  then show ?thesis
    using affine_translation assms by auto
qed

lemma subspace_imp_affine: "subspace s ⟹ affine s"
  unfolding subspace_def affine_def by auto


subsubsection ‹Subspace parallel to an affine set›

lemma subspace_affine: "subspace S ⟷ affine S ∧ 0 ∈ S"
proof -
  have h0: "subspace S ⟹ affine S ∧ 0 ∈ S"
    using subspace_imp_affine[of S] subspace_0 by auto
  {
    assume assm: "affine S ∧ 0 ∈ S"
    {
      fix c :: real
      fix x
      assume x: "x ∈ S"
      have "c *R x = (1-c) *R 0 + c *R x" by auto
      moreover
      have "(1 - c) *R 0 + c *R x ∈ S"
        using affine_alt[of S] assm x by auto
      ultimately have "c *R x ∈ S" by auto
    }
    then have h1: "∀c. ∀x ∈ S. c *R x ∈ S" by auto

    {
      fix x y
      assume xy: "x ∈ S" "y ∈ S"
      def u == "(1 :: real)/2"
      have "(1/2) *R (x+y) = (1/2) *R (x+y)"
        by auto
      moreover
      have "(1/2) *R (x+y)=(1/2) *R x + (1-(1/2)) *R y"
        by (simp add: algebra_simps)
      moreover
      have "(1 - u) *R x + u *R y ∈ S"
        using affine_alt[of S] assm xy by auto
      ultimately
      have "(1/2) *R (x+y) ∈ S"
        using u_def by auto
      moreover
      have "x + y = 2 *R ((1/2) *R (x+y))"
        by auto
      ultimately
      have "x + y ∈ S"
        using h1[rule_format, of "(1/2) *R (x+y)" "2"] by auto
    }
    then have "∀x ∈ S. ∀y ∈ S. x + y ∈ S"
      by auto
    then have "subspace S"
      using h1 assm unfolding subspace_def by auto
  }
  then show ?thesis using h0 by metis
qed

lemma affine_diffs_subspace:
  assumes "affine S" "a ∈ S"
  shows "subspace ((λx. (-a)+x) ` S)"
proof -
  have [simp]: "(λx. x - a) = plus (- a)" by (simp add: fun_eq_iff)
  have "affine ((λx. (-a)+x) ` S)"
    using  affine_translation assms by auto
  moreover have "0 : ((λx. (-a)+x) ` S)"
    using assms exI[of "(λx. x∈S ∧ -a+x = 0)" a] by auto
  ultimately show ?thesis using subspace_affine by auto
qed

lemma parallel_subspace_explicit:
  assumes "affine S"
    and "a ∈ S"
  assumes "L ≡ {y. ∃x ∈ S. (-a) + x = y}"
  shows "subspace L ∧ affine_parallel S L"
proof -
  from assms have "L = plus (- a) ` S" by auto
  then have par: "affine_parallel S L"
    unfolding affine_parallel_def ..
  then have "affine L" using assms parallel_is_affine by auto
  moreover have "0 ∈ L"
    using assms by auto
  ultimately show ?thesis
    using subspace_affine par by auto
qed

lemma parallel_subspace_aux:
  assumes "subspace A"
    and "subspace B"
    and "affine_parallel A B"
  shows "A ⊇ B"
proof -
  from assms obtain a where a: "∀x. x ∈ A ⟷ a + x ∈ B"
    using affine_parallel_expl[of A B] by auto
  then have "-a ∈ A"
    using assms subspace_0[of B] by auto
  then have "a ∈ A"
    using assms subspace_neg[of A "-a"] by auto
  then show ?thesis
    using assms a unfolding subspace_def by auto
qed

lemma parallel_subspace:
  assumes "subspace A"
    and "subspace B"
    and "affine_parallel A B"
  shows "A = B"
proof
  show "A ⊇ B"
    using assms parallel_subspace_aux by auto
  show "A ⊆ B"
    using assms parallel_subspace_aux[of B A] affine_parallel_commut by auto
qed

lemma affine_parallel_subspace:
  assumes "affine S" "S ≠ {}"
  shows "∃!L. subspace L ∧ affine_parallel S L"
proof -
  have ex: "∃L. subspace L ∧ affine_parallel S L"
    using assms parallel_subspace_explicit by auto
  {
    fix L1 L2
    assume ass: "subspace L1 ∧ affine_parallel S L1" "subspace L2 ∧ affine_parallel S L2"
    then have "affine_parallel L1 L2"
      using affine_parallel_commut[of S L1] affine_parallel_assoc[of L1 S L2] by auto
    then have "L1 = L2"
      using ass parallel_subspace by auto
  }
  then show ?thesis using ex by auto
qed


subsection ‹Cones›

definition cone :: "'a::real_vector set ⇒ bool"
  where "cone s ⟷ (∀x∈s. ∀c≥0. c *R x ∈ s)"

lemma cone_empty[intro, simp]: "cone {}"
  unfolding cone_def by auto

lemma cone_univ[intro, simp]: "cone UNIV"
  unfolding cone_def by auto

lemma cone_Inter[intro]: "∀s∈f. cone s ⟹ cone (⋂f)"
  unfolding cone_def by auto


subsubsection ‹Conic hull›

lemma cone_cone_hull: "cone (cone hull s)"
  unfolding hull_def by auto

lemma cone_hull_eq: "cone hull s = s ⟷ cone s"
  apply (rule hull_eq)
  using cone_Inter
  unfolding subset_eq
  apply auto
  done

lemma mem_cone:
  assumes "cone S" "x ∈ S" "c ≥ 0"
  shows "c *R x : S"
  using assms cone_def[of S] by auto

lemma cone_contains_0:
  assumes "cone S"
  shows "S ≠ {} ⟷ 0 ∈ S"
proof -
  {
    assume "S ≠ {}"
    then obtain a where "a ∈ S" by auto
    then have "0 ∈ S"
      using assms mem_cone[of S a 0] by auto
  }
  then show ?thesis by auto
qed

lemma cone_0: "cone {0}"
  unfolding cone_def by auto

lemma cone_Union[intro]: "(∀s∈f. cone s) ⟶ cone (⋃f)"
  unfolding cone_def by blast

lemma cone_iff:
  assumes "S ≠ {}"
  shows "cone S ⟷ 0 ∈ S ∧ (∀c. c > 0 ⟶ (op *R c) ` S = S)"
proof -
  {
    assume "cone S"
    {
      fix c :: real
      assume "c > 0"
      {
        fix x
        assume "x ∈ S"
        then have "x ∈ (op *R c) ` S"
          unfolding image_def
          using ‹cone S› ‹c>0› mem_cone[of S x "1/c"]
            exI[of "(λt. t ∈ S ∧ x = c *R t)" "(1 / c) *R x"]
          by auto
      }
      moreover
      {
        fix x
        assume "x ∈ (op *R c) ` S"
        then have "x ∈ S"
          using ‹cone S› ‹c > 0›
          unfolding cone_def image_def ‹c > 0› by auto
      }
      ultimately have "(op *R c) ` S = S" by auto
    }
    then have "0 ∈ S ∧ (∀c. c > 0 ⟶ (op *R c) ` S = S)"
      using ‹cone S› cone_contains_0[of S] assms by auto
  }
  moreover
  {
    assume a: "0 ∈ S ∧ (∀c. c > 0 ⟶ (op *R c) ` S = S)"
    {
      fix x
      assume "x ∈ S"
      fix c1 :: real
      assume "c1 ≥ 0"
      then have "c1 = 0 ∨ c1 > 0" by auto
      then have "c1 *R x ∈ S" using a ‹x ∈ S› by auto
    }
    then have "cone S" unfolding cone_def by auto
  }
  ultimately show ?thesis by blast
qed

lemma cone_hull_empty: "cone hull {} = {}"
  by (metis cone_empty cone_hull_eq)

lemma cone_hull_empty_iff: "S = {} ⟷ cone hull S = {}"
  by (metis bot_least cone_hull_empty hull_subset xtrans(5))

lemma cone_hull_contains_0: "S ≠ {} ⟷ 0 ∈ cone hull S"
  using cone_cone_hull[of S] cone_contains_0[of "cone hull S"] cone_hull_empty_iff[of S]
  by auto

lemma mem_cone_hull:
  assumes "x ∈ S" "c ≥ 0"
  shows "c *R x ∈ cone hull S"
  by (metis assms cone_cone_hull hull_inc mem_cone)

lemma cone_hull_expl: "cone hull S = {c *R x | c x. c ≥ 0 ∧ x ∈ S}"
  (is "?lhs = ?rhs")
proof -
  {
    fix x
    assume "x ∈ ?rhs"
    then obtain cx :: real and xx where x: "x = cx *R xx" "cx ≥ 0" "xx ∈ S"
      by auto
    fix c :: real
    assume c: "c ≥ 0"
    then have "c *R x = (c * cx) *R xx"
      using x by (simp add: algebra_simps)
    moreover
    have "c * cx ≥ 0" using c x by auto
    ultimately
    have "c *R x ∈ ?rhs" using x by auto
  }
  then have "cone ?rhs"
    unfolding cone_def by auto
  then have "?rhs ∈ Collect cone"
    unfolding mem_Collect_eq by auto
  {
    fix x
    assume "x ∈ S"
    then have "1 *R x ∈ ?rhs"
      apply auto
      apply (rule_tac x = 1 in exI)
      apply auto
      done
    then have "x ∈ ?rhs" by auto
  }
  then have "S ⊆ ?rhs" by auto
  then have "?lhs ⊆ ?rhs"
    using ‹?rhs ∈ Collect cone› hull_minimal[of S "?rhs" "cone"] by auto
  moreover
  {
    fix x
    assume "x ∈ ?rhs"
    then obtain cx :: real and xx where x: "x = cx *R xx" "cx ≥ 0" "xx ∈ S"
      by auto
    then have "xx ∈ cone hull S"
      using hull_subset[of S] by auto
    then have "x ∈ ?lhs"
      using x cone_cone_hull[of S] cone_def[of "cone hull S"] by auto
  }
  ultimately show ?thesis by auto
qed

lemma cone_closure:
  fixes S :: "'a::real_normed_vector set"
  assumes "cone S"
  shows "cone (closure S)"
proof (cases "S = {}")
  case True
  then show ?thesis by auto
next
  case False
  then have "0 ∈ S ∧ (∀c. c > 0 ⟶ op *R c ` S = S)"
    using cone_iff[of S] assms by auto
  then have "0 ∈ closure S ∧ (∀c. c > 0 ⟶ op *R c ` closure S = closure S)"
    using closure_subset by (auto simp add: closure_scaleR)
  then show ?thesis
    using False cone_iff[of "closure S"] by auto
qed


subsection ‹Affine dependence and consequential theorems (from Lars Schewe)›

definition affine_dependent :: "'a::real_vector set ⇒ bool"
  where "affine_dependent s ⟷ (∃x∈s. x ∈ affine hull (s - {x}))"

lemma affine_dependent_explicit:
  "affine_dependent p ⟷
    (∃s u. finite s ∧ s ⊆ p ∧ setsum u s = 0 ∧
      (∃v∈s. u v ≠ 0) ∧ setsum (λv. u v *R v) s = 0)"
  unfolding affine_dependent_def affine_hull_explicit mem_Collect_eq
  apply rule
  apply (erule bexE, erule exE, erule exE)
  apply (erule conjE)+
  defer
  apply (erule exE, erule exE)
  apply (erule conjE)+
  apply (erule bexE)
proof -
  fix x s u
  assume as: "x ∈ p" "finite s" "s ≠ {}" "s ⊆ p - {x}" "setsum u s = 1" "(∑v∈s. u v *R v) = x"
  have "x ∉ s" using as(1,4) by auto
  show "∃s u. finite s ∧ s ⊆ p ∧ setsum u s = 0 ∧ (∃v∈s. u v ≠ 0) ∧ (∑v∈s. u v *R v) = 0"
    apply (rule_tac x="insert x s" in exI, rule_tac x="λv. if v = x then - 1 else u v" in exI)
    unfolding if_smult and setsum_clauses(2)[OF as(2)] and setsum_delta_notmem[OF ‹x∉s›] and as
    using as
    apply auto
    done
next
  fix s u v
  assume as: "finite s" "s ⊆ p" "setsum u s = 0" "(∑v∈s. u v *R v) = 0" "v ∈ s" "u v ≠ 0"
  have "s ≠ {v}"
    using as(3,6) by auto
  then show "∃x∈p. ∃s u. finite s ∧ s ≠ {} ∧ s ⊆ p - {x} ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = x"
    apply (rule_tac x=v in bexI)
    apply (rule_tac x="s - {v}" in exI)
    apply (rule_tac x="λx. - (1 / u v) * u x" in exI)
    unfolding scaleR_scaleR[symmetric] and scaleR_right.setsum [symmetric]
    unfolding setsum_right_distrib[symmetric] and setsum_diff1[OF as(1)]
    using as
    apply auto
    done
qed

lemma affine_dependent_explicit_finite:
  fixes s :: "'a::real_vector set"
  assumes "finite s"
  shows "affine_dependent s ⟷
    (∃u. setsum u s = 0 ∧ (∃v∈s. u v ≠ 0) ∧ setsum (λv. u v *R v) s = 0)"
  (is "?lhs = ?rhs")
proof
  have *: "⋀vt u v. (if vt then u v else 0) *R v = (if vt then (u v) *R v else 0::'a)"
    by auto
  assume ?lhs
  then obtain t u v where
    "finite t" "t ⊆ s" "setsum u t = 0" "v∈t" "u v ≠ 0"  "(∑v∈t. u v *R v) = 0"
    unfolding affine_dependent_explicit by auto
  then show ?rhs
    apply (rule_tac x="λx. if x∈t then u x else 0" in exI)
    apply auto unfolding * and setsum.inter_restrict[OF assms, symmetric]
    unfolding Int_absorb1[OF ‹t⊆s›]
    apply auto
    done
next
  assume ?rhs
  then obtain u v where "setsum u s = 0"  "v∈s" "u v ≠ 0" "(∑v∈s. u v *R v) = 0"
    by auto
  then show ?lhs unfolding affine_dependent_explicit
    using assms by auto
qed


subsection ‹Connectedness of convex sets›

lemma connectedD:
  "connected S ⟹ open A ⟹ open B ⟹ S ⊆ A ∪ B ⟹ A ∩ B ∩ S = {} ⟹ A ∩ S = {} ∨ B ∩ S = {}"
  by (rule Topological_Spaces.topological_space_class.connectedD)

lemma convex_connected:
  fixes s :: "'a::real_normed_vector set"
  assumes "convex s"
  shows "connected s"
proof (rule connectedI)
  fix A B
  assume "open A" "open B" "A ∩ B ∩ s = {}" "s ⊆ A ∪ B"
  moreover
  assume "A ∩ s ≠ {}" "B ∩ s ≠ {}"
  then obtain a b where a: "a ∈ A" "a ∈ s" and b: "b ∈ B" "b ∈ s" by auto
  def f  "λu. u *R a + (1 - u) *R b"
  then have "continuous_on {0 .. 1} f"
    by (auto intro!: continuous_intros)
  then have "connected (f ` {0 .. 1})"
    by (auto intro!: connected_continuous_image)
  note connectedD[OF this, of A B]
  moreover have "a ∈ A ∩ f ` {0 .. 1}"
    using a by (auto intro!: image_eqI[of _ _ 1] simp: f_def)
  moreover have "b ∈ B ∩ f ` {0 .. 1}"
    using b by (auto intro!: image_eqI[of _ _ 0] simp: f_def)
  moreover have "f ` {0 .. 1} ⊆ s"
    using ‹convex s› a b unfolding convex_def f_def by auto
  ultimately show False by auto
qed

corollary connected_UNIV[intro]: "connected (UNIV :: 'a::real_normed_vector set)"
  by(simp add: convex_connected)

proposition clopen:
  fixes s :: "'a :: real_normed_vector set"
  shows "closed s ∧ open s ⟷ s = {} ∨ s = UNIV"
apply (rule iffI)
 apply (rule connected_UNIV [unfolded connected_clopen, rule_format])
 apply (force simp add: open_openin closed_closedin, force)
done

corollary compact_open:
  fixes s :: "'a :: euclidean_space set"
  shows "compact s ∧ open s ⟷ s = {}"
  by (auto simp: compact_eq_bounded_closed clopen)

text ‹Balls, being convex, are connected.›

lemma convex_prod:
  assumes "⋀i. i ∈ Basis ⟹ convex {x. P i x}"
  shows "convex {x. ∀i∈Basis. P i (x∙i)}"
  using assms unfolding convex_def
  by (auto simp: inner_add_left)

lemma convex_positive_orthant: "convex {x::'a::euclidean_space. (∀i∈Basis. 0 ≤ x∙i)}"
  by (rule convex_prod) (simp add: atLeast_def[symmetric] convex_real_interval)

lemma convex_local_global_minimum:
  fixes s :: "'a::real_normed_vector set"
  assumes "e > 0"
    and "convex_on s f"
    and "ball x e ⊆ s"
    and "∀y∈ball x e. f x ≤ f y"
  shows "∀y∈s. f x ≤ f y"
proof (rule ccontr)
  have "x ∈ s" using assms(1,3) by auto
  assume "¬ ?thesis"
  then obtain y where "y∈s" and y: "f x > f y" by auto
  then have xy: "0 < dist x y"  by auto
  then obtain u where "0 < u" "u ≤ 1" and u: "u < e / dist x y"
    using real_lbound_gt_zero[of 1 "e / dist x y"] xy ‹e>0› by auto
  then have "f ((1-u) *R x + u *R y) ≤ (1-u) * f x + u * f y"
    using ‹x∈s› ‹y∈s›
    using assms(2)[unfolded convex_on_def,
      THEN bspec[where x=x], THEN bspec[where x=y], THEN spec[where x="1-u"]]
    by auto
  moreover
  have *: "x - ((1 - u) *R x + u *R y) = u *R (x - y)"
    by (simp add: algebra_simps)
  have "(1 - u) *R x + u *R y ∈ ball x e"
    unfolding mem_ball dist_norm
    unfolding * and norm_scaleR and abs_of_pos[OF ‹0<u›]
    unfolding dist_norm[symmetric]
    using u
    unfolding pos_less_divide_eq[OF xy]
    by auto
  then have "f x ≤ f ((1 - u) *R x + u *R y)"
    using assms(4) by auto
  ultimately show False
    using mult_strict_left_mono[OF y ‹u>0›]
    unfolding left_diff_distrib
    by auto
qed

lemma convex_ball [iff]:
  fixes x :: "'a::real_normed_vector"
  shows "convex (ball x e)"
proof (auto simp add: convex_def)
  fix y z
  assume yz: "dist x y < e" "dist x z < e"
  fix u v :: real
  assume uv: "0 ≤ u" "0 ≤ v" "u + v = 1"
  have "dist x (u *R y + v *R z) ≤ u * dist x y + v * dist x z"
    using uv yz
    using convex_on_dist [of "ball x e" x, unfolded convex_on_def,
      THEN bspec[where x=y], THEN bspec[where x=z]]
    by auto
  then show "dist x (u *R y + v *R z) < e"
    using convex_bound_lt[OF yz uv] by auto
qed

lemma convex_cball [iff]:
  fixes x :: "'a::real_normed_vector"
  shows "convex (cball x e)"
proof -
  {
    fix y z
    assume yz: "dist x y ≤ e" "dist x z ≤ e"
    fix u v :: real
    assume uv: "0 ≤ u" "0 ≤ v" "u + v = 1"
    have "dist x (u *R y + v *R z) ≤ u * dist x y + v * dist x z"
      using uv yz
      using convex_on_dist [of "cball x e" x, unfolded convex_on_def,
        THEN bspec[where x=y], THEN bspec[where x=z]]
      by auto
    then have "dist x (u *R y + v *R z) ≤ e"
      using convex_bound_le[OF yz uv] by auto
  }
  then show ?thesis by (auto simp add: convex_def Ball_def)
qed

lemma connected_ball [iff]:
  fixes x :: "'a::real_normed_vector"
  shows "connected (ball x e)"
  using convex_connected convex_ball by auto

lemma connected_cball [iff]:
  fixes x :: "'a::real_normed_vector"
  shows "connected (cball x e)"
  using convex_connected convex_cball by auto


subsection ‹Convex hull›

lemma convex_convex_hull [iff]: "convex (convex hull s)"
  unfolding hull_def
  using convex_Inter[of "{t. convex t ∧ s ⊆ t}"]
  by auto

lemma convex_hull_eq: "convex hull s = s ⟷ convex s"
  by (metis convex_convex_hull hull_same)

lemma bounded_convex_hull:
  fixes s :: "'a::real_normed_vector set"
  assumes "bounded s"
  shows "bounded (convex hull s)"
proof -
  from assms obtain B where B: "∀x∈s. norm x ≤ B"
    unfolding bounded_iff by auto
  show ?thesis
    apply (rule bounded_subset[OF bounded_cball, of _ 0 B])
    unfolding subset_hull[of convex, OF convex_cball]
    unfolding subset_eq mem_cball dist_norm using B
    apply auto
    done
qed

lemma finite_imp_bounded_convex_hull:
  fixes s :: "'a::real_normed_vector set"
  shows "finite s ⟹ bounded (convex hull s)"
  using bounded_convex_hull finite_imp_bounded
  by auto


subsubsection ‹Convex hull is "preserved" by a linear function›

lemma convex_hull_linear_image:
  assumes f: "linear f"
  shows "f ` (convex hull s) = convex hull (f ` s)"
proof
  show "convex hull (f ` s) ⊆ f ` (convex hull s)"
    by (intro hull_minimal image_mono hull_subset convex_linear_image assms convex_convex_hull)
  show "f ` (convex hull s) ⊆ convex hull (f ` s)"
  proof (unfold image_subset_iff_subset_vimage, rule hull_minimal)
    show "s ⊆ f -` (convex hull (f ` s))"
      by (fast intro: hull_inc)
    show "convex (f -` (convex hull (f ` s)))"
      by (intro convex_linear_vimage [OF f] convex_convex_hull)
  qed
qed

lemma in_convex_hull_linear_image:
  assumes "linear f"
    and "x ∈ convex hull s"
  shows "f x ∈ convex hull (f ` s)"
  using convex_hull_linear_image[OF assms(1)] assms(2) by auto

lemma convex_hull_Times:
  "convex hull (s × t) = (convex hull s) × (convex hull t)"
proof
  show "convex hull (s × t) ⊆ (convex hull s) × (convex hull t)"
    by (intro hull_minimal Sigma_mono hull_subset convex_Times convex_convex_hull)
  have "∀x∈convex hull s. ∀y∈convex hull t. (x, y) ∈ convex hull (s × t)"
  proof (intro hull_induct)
    fix x y assume "x ∈ s" and "y ∈ t"
    then show "(x, y) ∈ convex hull (s × t)"
      by (simp add: hull_inc)
  next
    fix x let ?S = "((λy. (0, y)) -` (λp. (- x, 0) + p) ` (convex hull s × t))"
    have "convex ?S"
      by (intro convex_linear_vimage convex_translation convex_convex_hull,
        simp add: linear_iff)
    also have "?S = {y. (x, y) ∈ convex hull (s × t)}"
      by (auto simp add: image_def Bex_def)
    finally show "convex {y. (x, y) ∈ convex hull (s × t)}" .
  next
    show "convex {x. ∀y∈convex hull t. (x, y) ∈ convex hull (s × t)}"
    proof (unfold Collect_ball_eq, rule convex_INT [rule_format])
      fix y let ?S = "((λx. (x, 0)) -` (λp. (0, - y) + p) ` (convex hull s × t))"
      have "convex ?S"
      by (intro convex_linear_vimage convex_translation convex_convex_hull,
        simp add: linear_iff)
      also have "?S = {x. (x, y) ∈ convex hull (s × t)}"
        by (auto simp add: image_def Bex_def)
      finally show "convex {x. (x, y) ∈ convex hull (s × t)}" .
    qed
  qed
  then show "(convex hull s) × (convex hull t) ⊆ convex hull (s × t)"
    unfolding subset_eq split_paired_Ball_Sigma .
qed


subsubsection ‹Stepping theorems for convex hulls of finite sets›

lemma convex_hull_empty[simp]: "convex hull {} = {}"
  by (rule hull_unique) auto

lemma convex_hull_singleton[simp]: "convex hull {a} = {a}"
  by (rule hull_unique) auto

lemma convex_hull_insert:
  fixes s :: "'a::real_vector set"
  assumes "s ≠ {}"
  shows "convex hull (insert a s) =
    {x. ∃u≥0. ∃v≥0. ∃b. (u + v = 1) ∧ b ∈ (convex hull s) ∧ (x = u *R a + v *R b)}"
  (is "_ = ?hull")
  apply (rule, rule hull_minimal, rule)
  unfolding insert_iff
  prefer 3
  apply rule
proof -
  fix x
  assume x: "x = a ∨ x ∈ s"
  then show "x ∈ ?hull"
    apply rule
    unfolding mem_Collect_eq
    apply (rule_tac x=1 in exI)
    defer
    apply (rule_tac x=0 in exI)
    using assms hull_subset[of s convex]
    apply auto
    done
next
  fix x
  assume "x ∈ ?hull"
  then obtain u v b where obt: "u≥0" "v≥0" "u + v = 1" "b ∈ convex hull s" "x = u *R a + v *R b"
    by auto
  have "a ∈ convex hull insert a s" "b ∈ convex hull insert a s"
    using hull_mono[of s "insert a s" convex] hull_mono[of "{a}" "insert a s" convex] and obt(4)
    by auto
  then show "x ∈ convex hull insert a s"
    unfolding obt(5) using obt(1-3)
    by (rule convexD [OF convex_convex_hull])
next
  show "convex ?hull"
  proof (rule convexI)
    fix x y u v
    assume as: "(0::real) ≤ u" "0 ≤ v" "u + v = 1" "x∈?hull" "y∈?hull"
    from as(4) obtain u1 v1 b1 where
      obt1: "u1≥0" "v1≥0" "u1 + v1 = 1" "b1 ∈ convex hull s" "x = u1 *R a + v1 *R b1"
      by auto
    from as(5) obtain u2 v2 b2 where
      obt2: "u2≥0" "v2≥0" "u2 + v2 = 1" "b2 ∈ convex hull s" "y = u2 *R a + v2 *R b2"
      by auto
    have *: "⋀(x::'a) s1 s2. x - s1 *R x - s2 *R x = ((1::real) - (s1 + s2)) *R x"
      by (auto simp add: algebra_simps)
    have **: "∃b ∈ convex hull s. u *R x + v *R y =
      (u * u1) *R a + (v * u2) *R a + (b - (u * u1) *R b - (v * u2) *R b)"
    proof (cases "u * v1 + v * v2 = 0")
      case True
      have *: "⋀(x::'a) s1 s2. x - s1 *R x - s2 *R x = ((1::real) - (s1 + s2)) *R x"
        by (auto simp add: algebra_simps)
      from True have ***: "u * v1 = 0" "v * v2 = 0"
        using mult_nonneg_nonneg[OF ‹u≥0› ‹v1≥0›] mult_nonneg_nonneg[OF ‹v≥0› ‹v2≥0›]
        by arith+
      then have "u * u1 + v * u2 = 1"
        using as(3) obt1(3) obt2(3) by auto
      then show ?thesis
        unfolding obt1(5) obt2(5) *
        using assms hull_subset[of s convex]
        by (auto simp add: *** scaleR_right_distrib)
    next
      case False
      have "1 - (u * u1 + v * u2) = (u + v) - (u * u1 + v * u2)"
        using as(3) obt1(3) obt2(3) by (auto simp add: field_simps)
      also have "… = u * (v1 + u1 - u1) + v * (v2 + u2 - u2)"
        using as(3) obt1(3) obt2(3) by (auto simp add: field_simps)
      also have "… = u * v1 + v * v2"
        by simp
      finally have **:"1 - (u * u1 + v * u2) = u * v1 + v * v2" by auto
      have "0 ≤ u * v1 + v * v2" "0 ≤ u * v1" "0 ≤ u * v1 + v * v2" "0 ≤ v * v2"
        using as(1,2) obt1(1,2) obt2(1,2) by auto
      then show ?thesis
        unfolding obt1(5) obt2(5)
        unfolding * and **
        using False
        apply (rule_tac
          x = "((u * v1) / (u * v1 + v * v2)) *R b1 + ((v * v2) / (u * v1 + v * v2)) *R b2" in bexI)
        defer
        apply (rule convexD [OF convex_convex_hull])
        using obt1(4) obt2(4)
        unfolding add_divide_distrib[symmetric] and zero_le_divide_iff
        apply (auto simp add: scaleR_left_distrib scaleR_right_distrib)
        done
    qed
    have u1: "u1 ≤ 1"
      unfolding obt1(3)[symmetric] and not_le using obt1(2) by auto
    have u2: "u2 ≤ 1"
      unfolding obt2(3)[symmetric] and not_le using obt2(2) by auto
    have "u1 * u + u2 * v ≤ max u1 u2 * u + max u1 u2 * v"
      apply (rule add_mono)
      apply (rule_tac [!] mult_right_mono)
      using as(1,2) obt1(1,2) obt2(1,2)
      apply auto
      done
    also have "… ≤ 1"
      unfolding distrib_left[symmetric] and as(3) using u1 u2 by auto
    finally show "u *R x + v *R y ∈ ?hull"
      unfolding mem_Collect_eq
      apply (rule_tac x="u * u1 + v * u2" in exI)
      apply (rule conjI)
      defer
      apply (rule_tac x="1 - u * u1 - v * u2" in exI)
      unfolding Bex_def
      using as(1,2) obt1(1,2) obt2(1,2) **
      apply (auto simp add: algebra_simps)
      done
  qed
qed


subsubsection ‹Explicit expression for convex hull›

lemma convex_hull_indexed:
  fixes s :: "'a::real_vector set"
  shows "convex hull s =
    {y. ∃k u x.
      (∀i∈{1::nat .. k}. 0 ≤ u i ∧ x i ∈ s) ∧
      (setsum u {1..k} = 1) ∧ (setsum (λi. u i *R x i) {1..k} = y)}"
  (is "?xyz = ?hull")
  apply (rule hull_unique)
  apply rule
  defer
  apply (rule convexI)
proof -
  fix x
  assume "x∈s"
  then show "x ∈ ?hull"
    unfolding mem_Collect_eq
    apply (rule_tac x=1 in exI, rule_tac x="λx. 1" in exI)
    apply auto
    done
next
  fix t
  assume as: "s ⊆ t" "convex t"
  show "?hull ⊆ t"
    apply rule
    unfolding mem_Collect_eq
    apply (elim exE conjE)
  proof -
    fix x k u y
    assume assm:
      "∀i∈{1::nat..k}. 0 ≤ u i ∧ y i ∈ s"
      "setsum u {1..k} = 1" "(∑i = 1..k. u i *R y i) = x"
    show "x∈t"
      unfolding assm(3) [symmetric]
      apply (rule as(2)[unfolded convex, rule_format])
      using assm(1,2) as(1) apply auto
      done
  qed
next
  fix x y u v
  assume uv: "0 ≤ u" "0 ≤ v" "u + v = (1::real)"
  assume xy: "x ∈ ?hull" "y ∈ ?hull"
  from xy obtain k1 u1 x1 where
    x: "∀i∈{1::nat..k1}. 0≤u1 i ∧ x1 i ∈ s" "setsum u1 {Suc 0..k1} = 1" "(∑i = Suc 0..k1. u1 i *R x1 i) = x"
    by auto
  from xy obtain k2 u2 x2 where
    y: "∀i∈{1::nat..k2}. 0≤u2 i ∧ x2 i ∈ s" "setsum u2 {Suc 0..k2} = 1" "(∑i = Suc 0..k2. u2 i *R x2 i) = y"
    by auto
  have *: "⋀P (x1::'a) x2 s1 s2 i.
    (if P i then s1 else s2) *R (if P i then x1 else x2) = (if P i then s1 *R x1 else s2 *R x2)"
    "{1..k1 + k2} ∩ {1..k1} = {1..k1}" "{1..k1 + k2} ∩ - {1..k1} = (λi. i + k1) ` {1..k2}"
    prefer 3
    apply (rule, rule)
    unfolding image_iff
    apply (rule_tac x = "x - k1" in bexI)
    apply (auto simp add: not_le)
    done
  have inj: "inj_on (λi. i + k1) {1..k2}"
    unfolding inj_on_def by auto
  show "u *R x + v *R y ∈ ?hull"
    apply rule
    apply (rule_tac x="k1 + k2" in exI)
    apply (rule_tac x="λi. if i ∈ {1..k1} then u * u1 i else v * u2 (i - k1)" in exI)
    apply (rule_tac x="λi. if i ∈ {1..k1} then x1 i else x2 (i - k1)" in exI)
    apply (rule, rule)
    defer
    apply rule
    unfolding * and setsum.If_cases[OF finite_atLeastAtMost[of 1 "k1 + k2"]] and
      setsum.reindex[OF inj] and o_def Collect_mem_eq
    unfolding scaleR_scaleR[symmetric] scaleR_right.setsum [symmetric] setsum_right_distrib[symmetric]
  proof -
    fix i
    assume i: "i ∈ {1..k1+k2}"
    show "0 ≤ (if i ∈ {1..k1} then u * u1 i else v * u2 (i - k1)) ∧
      (if i ∈ {1..k1} then x1 i else x2 (i - k1)) ∈ s"
    proof (cases "i∈{1..k1}")
      case True
      then show ?thesis
        using uv(1) x(1)[THEN bspec[where x=i]] by auto
    next
      case False
      def j  "i - k1"
      from i False have "j ∈ {1..k2}"
        unfolding j_def by auto
      then show ?thesis
        using False uv(2) y(1)[THEN bspec[where x=j]]
        by (auto simp: j_def[symmetric])
    qed
  qed (auto simp add: not_le x(2,3) y(2,3) uv(3))
qed

lemma convex_hull_finite:
  fixes s :: "'a::real_vector set"
  assumes "finite s"
  shows "convex hull s = {y. ∃u. (∀x∈s. 0 ≤ u x) ∧
    setsum u s = 1 ∧ setsum (λx. u x *R x) s = y}"
  (is "?HULL = ?set")
proof (rule hull_unique, auto simp add: convex_def[of ?set])
  fix x
  assume "x ∈ s"
  then show "∃u. (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ (∑x∈s. u x *R x) = x"
    apply (rule_tac x="λy. if x=y then 1 else 0" in exI)
    apply auto
    unfolding setsum.delta'[OF assms] and setsum_delta''[OF assms]
    apply auto
    done
next
  fix u v :: real
  assume uv: "0 ≤ u" "0 ≤ v" "u + v = 1"
  fix ux assume ux: "∀x∈s. 0 ≤ ux x" "setsum ux s = (1::real)"
  fix uy assume uy: "∀x∈s. 0 ≤ uy x" "setsum uy s = (1::real)"
  {
    fix x
    assume "x∈s"
    then have "0 ≤ u * ux x + v * uy x"
      using ux(1)[THEN bspec[where x=x]] uy(1)[THEN bspec[where x=x]] and uv(1,2)
      by auto
  }
  moreover
  have "(∑x∈s. u * ux x + v * uy x) = 1"
    unfolding setsum.distrib and setsum_right_distrib[symmetric] and ux(2) uy(2)
    using uv(3) by auto
  moreover
  have "(∑x∈s. (u * ux x + v * uy x) *R x) = u *R (∑x∈s. ux x *R x) + v *R (∑x∈s. uy x *R x)"
    unfolding scaleR_left_distrib and setsum.distrib and scaleR_scaleR[symmetric]
      and scaleR_right.setsum [symmetric]
    by auto
  ultimately
  show "∃uc. (∀x∈s. 0 ≤ uc x) ∧ setsum uc s = 1 ∧
      (∑x∈s. uc x *R x) = u *R (∑x∈s. ux x *R x) + v *R (∑x∈s. uy x *R x)"
    apply (rule_tac x="λx. u * ux x + v * uy x" in exI)
    apply auto
    done
next
  fix t
  assume t: "s ⊆ t" "convex t"
  fix u
  assume u: "∀x∈s. 0 ≤ u x" "setsum u s = (1::real)"
  then show "(∑x∈s. u x *R x) ∈ t"
    using t(2)[unfolded convex_explicit, THEN spec[where x=s], THEN spec[where x=u]]
    using assms and t(1) by auto
qed


subsubsection ‹Another formulation from Lars Schewe›

lemma convex_hull_explicit:
  fixes p :: "'a::real_vector set"
  shows "convex hull p =
    {y. ∃s u. finite s ∧ s ⊆ p ∧ (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ setsum (λv. u v *R v) s = y}"
  (is "?lhs = ?rhs")
proof -
  {
    fix x
    assume "x∈?lhs"
    then obtain k u y where
        obt: "∀i∈{1::nat..k}. 0 ≤ u i ∧ y i ∈ p" "setsum u {1..k} = 1" "(∑i = 1..k. u i *R y i) = x"
      unfolding convex_hull_indexed by auto

    have fin: "finite {1..k}" by auto
    have fin': "⋀v. finite {i ∈ {1..k}. y i = v}" by auto
    {
      fix j
      assume "j∈{1..k}"
      then have "y j ∈ p" "0 ≤ setsum u {i. Suc 0 ≤ i ∧ i ≤ k ∧ y i = y j}"
        using obt(1)[THEN bspec[where x=j]] and obt(2)
        apply simp
        apply (rule setsum_nonneg)
        using obt(1)
        apply auto
        done
    }
    moreover
    have "(∑v∈y ` {1..k}. setsum u {i ∈ {1..k}. y i = v}) = 1"
      unfolding setsum_image_gen[OF fin, symmetric] using obt(2) by auto
    moreover have "(∑v∈y ` {1..k}. setsum u {i ∈ {1..k}. y i = v} *R v) = x"
      using setsum_image_gen[OF fin, of "λi. u i *R y i" y, symmetric]
      unfolding scaleR_left.setsum using obt(3) by auto
    ultimately
    have "∃s u. finite s ∧ s ⊆ p ∧ (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = x"
      apply (rule_tac x="y ` {1..k}" in exI)
      apply (rule_tac x="λv. setsum u {i∈{1..k}. y i = v}" in exI)
      apply auto
      done
    then have "x∈?rhs" by auto
  }
  moreover
  {
    fix y
    assume "y∈?rhs"
    then obtain s u where
      obt: "finite s" "s ⊆ p" "∀x∈s. 0 ≤ u x" "setsum u s = 1" "(∑v∈s. u v *R v) = y"
      by auto

    obtain f where f: "inj_on f {1..card s}" "f ` {1..card s} = s"
      using ex_bij_betw_nat_finite_1[OF obt(1)] unfolding bij_betw_def by auto

    {
      fix i :: nat
      assume "i∈{1..card s}"
      then have "f i ∈ s"
        apply (subst f(2)[symmetric])
        apply auto
        done
      then have "0 ≤ u (f i)" "f i ∈ p" using obt(2,3) by auto
    }
    moreover have *: "finite {1..card s}" by auto
    {
      fix y
      assume "y∈s"
      then obtain i where "i∈{1..card s}" "f i = y"
        using f using image_iff[of y f "{1..card s}"]
        by auto
      then have "{x. Suc 0 ≤ x ∧ x ≤ card s ∧ f x = y} = {i}"
        apply auto
        using f(1)[unfolded inj_on_def]
        apply(erule_tac x=x in ballE)
        apply auto
        done
      then have "card {x. Suc 0 ≤ x ∧ x ≤ card s ∧ f x = y} = 1" by auto
      then have "(∑x∈{x ∈ {1..card s}. f x = y}. u (f x)) = u y"
          "(∑x∈{x ∈ {1..card s}. f x = y}. u (f x) *R f x) = u y *R y"
        by (auto simp add: setsum_constant_scaleR)
    }
    then have "(∑x = 1..card s. u (f x)) = 1" "(∑i = 1..card s. u (f i) *R f i) = y"
      unfolding setsum_image_gen[OF *(1), of "λx. u (f x) *R f x" f]
        and setsum_image_gen[OF *(1), of "λx. u (f x)" f]
      unfolding f
      using setsum.cong [of s s "λy. (∑x∈{x ∈ {1..card s}. f x = y}. u (f x) *R f x)" "λv. u v *R v"]
      using setsum.cong [of s s "λy. (∑x∈{x ∈ {1..card s}. f x = y}. u (f x))" u]
      unfolding obt(4,5)
      by auto
    ultimately
    have "∃k u x. (∀i∈{1..k}. 0 ≤ u i ∧ x i ∈ p) ∧ setsum u {1..k} = 1 ∧
        (∑i::nat = 1..k. u i *R x i) = y"
      apply (rule_tac x="card s" in exI)
      apply (rule_tac x="u ∘ f" in exI)
      apply (rule_tac x=f in exI)
      apply fastforce
      done
    then have "y ∈ ?lhs"
      unfolding convex_hull_indexed by auto
  }
  ultimately show ?thesis
    unfolding set_eq_iff by blast
qed


subsubsection ‹A stepping theorem for that expansion›

lemma convex_hull_finite_step:
  fixes s :: "'a::real_vector set"
  assumes "finite s"
  shows
    "(∃u. (∀x∈insert a s. 0 ≤ u x) ∧ setsum u (insert a s) = w ∧ setsum (λx. u x *R x) (insert a s) = y)
      ⟷ (∃v≥0. ∃u. (∀x∈s. 0 ≤ u x) ∧ setsum u s = w - v ∧ setsum (λx. u x *R x) s = y - v *R a)"
  (is "?lhs = ?rhs")
proof (rule, case_tac[!] "a∈s")
  assume "a ∈ s"
  then have *: "insert a s = s" by auto
  assume ?lhs
  then show ?rhs
    unfolding *
    apply (rule_tac x=0 in exI)
    apply auto
    done
next
  assume ?lhs
  then obtain u where
      u: "∀x∈insert a s. 0 ≤ u x" "setsum u (insert a s) = w" "(∑x∈insert a s. u x *R x) = y"
    by auto
  assume "a ∉ s"
  then show ?rhs
    apply (rule_tac x="u a" in exI)
    using u(1)[THEN bspec[where x=a]]
    apply simp
    apply (rule_tac x=u in exI)
    using u[unfolded setsum_clauses(2)[OF assms]] and ‹a∉s›
    apply auto
    done
next
  assume "a ∈ s"
  then have *: "insert a s = s" by auto
  have fin: "finite (insert a s)" using assms by auto
  assume ?rhs
  then obtain v u where uv: "v≥0" "∀x∈s. 0 ≤ u x" "setsum u s = w - v" "(∑x∈s. u x *R x) = y - v *R a"
    by auto
  show ?lhs
    apply (rule_tac x = "λx. (if a = x then v else 0) + u x" in exI)
    unfolding scaleR_left_distrib and setsum.distrib and setsum_delta''[OF fin] and setsum.delta'[OF fin]
    unfolding setsum_clauses(2)[OF assms]
    using uv and uv(2)[THEN bspec[where x=a]] and ‹a∈s›
    apply auto
    done
next
  assume ?rhs
  then obtain v u where
    uv: "v≥0" "∀x∈s. 0 ≤ u x" "setsum u s = w - v" "(∑x∈s. u x *R x) = y - v *R a"
    by auto
  moreover
  assume "a ∉ s"
  moreover
  have "(∑x∈s. if a = x then v else u x) = setsum u s"
    and "(∑x∈s. (if a = x then v else u x) *R x) = (∑x∈s. u x *R x)"
    apply (rule_tac setsum.cong) apply rule
    defer
    apply (rule_tac setsum.cong) apply rule
    using ‹a ∉ s›
    apply auto
    done
  ultimately show ?lhs
    apply (rule_tac x="λx. if a = x then v else u x" in exI)
    unfolding setsum_clauses(2)[OF assms]
    apply auto
    done
qed


subsubsection ‹Hence some special cases›

lemma convex_hull_2:
  "convex hull {a,b} = {u *R a + v *R b | u v. 0 ≤ u ∧ 0 ≤ v ∧ u + v = 1}"
proof -
  have *: "⋀u. (∀x∈{a, b}. 0 ≤ u x) ⟷ 0 ≤ u a ∧ 0 ≤ u b"
    by auto
  have **: "finite {b}" by auto
  show ?thesis
    apply (simp add: convex_hull_finite)
    unfolding convex_hull_finite_step[OF **, of a 1, unfolded * conj_assoc]
    apply auto
    apply (rule_tac x=v in exI)
    apply (rule_tac x="1 - v" in exI)
    apply simp
    apply (rule_tac x=u in exI)
    apply simp
    apply (rule_tac x="λx. v" in exI)
    apply simp
    done
qed

lemma convex_hull_2_alt: "convex hull {a,b} = {a + u *R (b - a) | u.  0 ≤ u ∧ u ≤ 1}"
  unfolding convex_hull_2
proof (rule Collect_cong)
  have *: "⋀x y ::real. x + y = 1 ⟷ x = 1 - y"
    by auto
  fix x
  show "(∃v u. x = v *R a + u *R b ∧ 0 ≤ v ∧ 0 ≤ u ∧ v + u = 1) ⟷
    (∃u. x = a + u *R (b - a) ∧ 0 ≤ u ∧ u ≤ 1)"
    unfolding *
    apply auto
    apply (rule_tac[!] x=u in exI)
    apply (auto simp add: algebra_simps)
    done
qed

lemma convex_hull_3:
  "convex hull {a,b,c} = { u *R a + v *R b + w *R c | u v w. 0 ≤ u ∧ 0 ≤ v ∧ 0 ≤ w ∧ u + v + w = 1}"
proof -
  have fin: "finite {a,b,c}" "finite {b,c}" "finite {c}"
    by auto
  have *: "⋀x y z ::real. x + y + z = 1 ⟷ x = 1 - y - z"
    by (auto simp add: field_simps)
  show ?thesis
    unfolding convex_hull_finite[OF fin(1)] and convex_hull_finite_step[OF fin(2)] and *
    unfolding convex_hull_finite_step[OF fin(3)]
    apply (rule Collect_cong)
    apply simp
    apply auto
    apply (rule_tac x=va in exI)
    apply (rule_tac x="u c" in exI)
    apply simp
    apply (rule_tac x="1 - v - w" in exI)
    apply simp
    apply (rule_tac x=v in exI)
    apply simp
    apply (rule_tac x="λx. w" in exI)
    apply simp
    done
qed

lemma convex_hull_3_alt:
  "convex hull {a,b,c} = {a + u *R (b - a) + v *R (c - a) | u v.  0 ≤ u ∧ 0 ≤ v ∧ u + v ≤ 1}"
proof -
  have *: "⋀x y z ::real. x + y + z = 1 ⟷ x = 1 - y - z"
    by auto
  show ?thesis
    unfolding convex_hull_3
    apply (auto simp add: *)
    apply (rule_tac x=v in exI)
    apply (rule_tac x=w in exI)
    apply (simp add: algebra_simps)
    apply (rule_tac x=u in exI)
    apply (rule_tac x=v in exI)
    apply (simp add: algebra_simps)
    done
qed


subsection ‹Relations among closure notions and corresponding hulls›

lemma affine_imp_convex: "affine s ⟹ convex s"
  unfolding affine_def convex_def by auto

lemma subspace_imp_convex: "subspace s ⟹ convex s"
  using subspace_imp_affine affine_imp_convex by auto

lemma affine_hull_subset_span: "(affine hull s) ⊆ (span s)"
  by (metis hull_minimal span_inc subspace_imp_affine subspace_span)

lemma convex_hull_subset_span: "(convex hull s) ⊆ (span s)"
  by (metis hull_minimal span_inc subspace_imp_convex subspace_span)

lemma convex_hull_subset_affine_hull: "(convex hull s) ⊆ (affine hull s)"
  by (metis affine_affine_hull affine_imp_convex hull_minimal hull_subset)


lemma affine_dependent_imp_dependent: "affine_dependent s ⟹ dependent s"
  unfolding affine_dependent_def dependent_def
  using affine_hull_subset_span by auto

lemma dependent_imp_affine_dependent:
  assumes "dependent {x - a| x . x ∈ s}"
    and "a ∉ s"
  shows "affine_dependent (insert a s)"
proof -
  from assms(1)[unfolded dependent_explicit] obtain S u v
    where obt: "finite S" "S ⊆ {x - a |x. x ∈ s}" "v∈S" "u v  ≠ 0" "(∑v∈S. u v *R v) = 0"
    by auto
  def t  "(λx. x + a) ` S"

  have inj: "inj_on (λx. x + a) S"
    unfolding inj_on_def by auto
  have "0 ∉ S"
    using obt(2) assms(2) unfolding subset_eq by auto
  have fin: "finite t" and "t ⊆ s"
    unfolding t_def using obt(1,2) by auto
  then have "finite (insert a t)" and "insert a t ⊆ insert a s"
    by auto
  moreover have *: "⋀P Q. (∑x∈t. (if x = a then P x else Q x)) = (∑x∈t. Q x)"
    apply (rule setsum.cong)
    using ‹a∉s› ‹t⊆s›
    apply auto
    done
  have "(∑x∈insert a t. if x = a then - (∑x∈t. u (x - a)) else u (x - a)) = 0"
    unfolding setsum_clauses(2)[OF fin]
    using ‹a∉s› ‹t⊆s›
    apply auto
    unfolding *
    apply auto
    done
  moreover have "∃v∈insert a t. (if v = a then - (∑x∈t. u (x - a)) else u (v - a)) ≠ 0"
    apply (rule_tac x="v + a" in bexI)
    using obt(3,4) and ‹0∉S›
    unfolding t_def
    apply auto
    done
  moreover have *: "⋀P Q. (∑x∈t. (if x = a then P x else Q x) *R x) = (∑x∈t. Q x *R x)"
    apply (rule setsum.cong)
    using ‹a∉s› ‹t⊆s›
    apply auto
    done
  have "(∑x∈t. u (x - a)) *R a = (∑v∈t. u (v - a) *R v)"
    unfolding scaleR_left.setsum
    unfolding t_def and setsum.reindex[OF inj] and o_def
    using obt(5)
    by (auto simp add: setsum.distrib scaleR_right_distrib)
  then have "(∑v∈insert a t. (if v = a then - (∑x∈t. u (x - a)) else u (v - a)) *R v) = 0"
    unfolding setsum_clauses(2)[OF fin]
    using ‹a∉s› ‹t⊆s›
    by (auto simp add: *)
  ultimately show ?thesis
    unfolding affine_dependent_explicit
    apply (rule_tac x="insert a t" in exI)
    apply auto
    done
qed

lemma convex_cone:
  "convex s ∧ cone s ⟷ (∀x∈s. ∀y∈s. (x + y) ∈ s) ∧ (∀x∈s. ∀c≥0. (c *R x) ∈ s)"
  (is "?lhs = ?rhs")
proof -
  {
    fix x y
    assume "x∈s" "y∈s" and ?lhs
    then have "2 *R x ∈s" "2 *R y ∈ s"
      unfolding cone_def by auto
    then have "x + y ∈ s"
      using ‹?lhs›[unfolded convex_def, THEN conjunct1]
      apply (erule_tac x="2*R x" in ballE)
      apply (erule_tac x="2*R y" in ballE)
      apply (erule_tac x="1/2" in allE)
      apply simp
      apply (erule_tac x="1/2" in allE)
      apply auto
      done
  }
  then show ?thesis
    unfolding convex_def cone_def by blast
qed

lemma affine_dependent_biggerset:
  fixes s :: "'a::euclidean_space set"
  assumes "finite s" "card s ≥ DIM('a) + 2"
  shows "affine_dependent s"
proof -
  have "s ≠ {}" using assms by auto
  then obtain a where "a∈s" by auto
  have *: "{x - a |x. x ∈ s - {a}} = (λx. x - a) ` (s - {a})"
    by auto
  have "card {x - a |x. x ∈ s - {a}} = card (s - {a})"
    unfolding *
    apply (rule card_image)
    unfolding inj_on_def
    apply auto
    done
  also have "… > DIM('a)" using assms(2)
    unfolding card_Diff_singleton[OF assms(1) ‹a∈s›] by auto
  finally show ?thesis
    apply (subst insert_Diff[OF ‹a∈s›, symmetric])
    apply (rule dependent_imp_affine_dependent)
    apply (rule dependent_biggerset)
    apply auto
    done
qed

lemma affine_dependent_biggerset_general:
  assumes "finite (s :: 'a::euclidean_space set)"
    and "card s ≥ dim s + 2"
  shows "affine_dependent s"
proof -
  from assms(2) have "s ≠ {}" by auto
  then obtain a where "a∈s" by auto
  have *: "{x - a |x. x ∈ s - {a}} = (λx. x - a) ` (s - {a})"
    by auto
  have **: "card {x - a |x. x ∈ s - {a}} = card (s - {a})"
    unfolding *
    apply (rule card_image)
    unfolding inj_on_def
    apply auto
    done
  have "dim {x - a |x. x ∈ s - {a}} ≤ dim s"
    apply (rule subset_le_dim)
    unfolding subset_eq
    using ‹a∈s›
    apply (auto simp add:span_superset span_sub)
    done
  also have "… < dim s + 1" by auto
  also have "… ≤ card (s - {a})"
    using assms
    using card_Diff_singleton[OF assms(1) ‹a∈s›]
    by auto
  finally show ?thesis
    apply (subst insert_Diff[OF ‹a∈s›, symmetric])
    apply (rule dependent_imp_affine_dependent)
    apply (rule dependent_biggerset_general)
    unfolding **
    apply auto
    done
qed


subsection ‹Some Properties of Affine Dependent Sets›

lemma affine_independent_empty: "¬ affine_dependent {}"
  by (simp add: affine_dependent_def)

lemma affine_independent_sing: "¬ affine_dependent {a}"
  by (simp add: affine_dependent_def)

lemma affine_hull_translation: "affine hull ((λx. a + x) `  S) = (λx. a + x) ` (affine hull S)"
proof -
  have "affine ((λx. a + x) ` (affine hull S))"
    using affine_translation affine_affine_hull by blast
  moreover have "(λx. a + x) `  S ⊆ (λx. a + x) ` (affine hull S)"
    using hull_subset[of S] by auto
  ultimately have h1: "affine hull ((λx. a + x) `  S) ⊆ (λx. a + x) ` (affine hull S)"
    by (metis hull_minimal)
  have "affine((λx. -a + x) ` (affine hull ((λx. a + x) `  S)))"
    using affine_translation affine_affine_hull by blast
  moreover have "(λx. -a + x) ` (λx. a + x) `  S ⊆ (λx. -a + x) ` (affine hull ((λx. a + x) `  S))"
    using hull_subset[of "(λx. a + x) `  S"] by auto
  moreover have "S = (λx. -a + x) ` (λx. a + x) `  S"
    using translation_assoc[of "-a" a] by auto
  ultimately have "(λx. -a + x) ` (affine hull ((λx. a + x) `  S)) >= (affine hull S)"
    by (metis hull_minimal)
  then have "affine hull ((λx. a + x) ` S) >= (λx. a + x) ` (affine hull S)"
    by auto
  then show ?thesis using h1 by auto
qed

lemma affine_dependent_translation:
  assumes "affine_dependent S"
  shows "affine_dependent ((λx. a + x) ` S)"
proof -
  obtain x where x: "x ∈ S ∧ x ∈ affine hull (S - {x})"
    using assms affine_dependent_def by auto
  have "op + a ` (S - {x}) = op + a ` S - {a + x}"
    by auto
  then have "a + x ∈ affine hull ((λx. a + x) ` S - {a + x})"
    using affine_hull_translation[of a "S - {x}"] x by auto
  moreover have "a + x ∈ (λx. a + x) ` S"
    using x by auto
  ultimately show ?thesis
    unfolding affine_dependent_def by auto
qed

lemma affine_dependent_translation_eq:
  "affine_dependent S ⟷ affine_dependent ((λx. a + x) ` S)"
proof -
  {
    assume "affine_dependent ((λx. a + x) ` S)"
    then have "affine_dependent S"
      using affine_dependent_translation[of "((λx. a + x) ` S)" "-a"] translation_assoc[of "-a" a]
      by auto
  }
  then show ?thesis
    using affine_dependent_translation by auto
qed

lemma affine_hull_0_dependent:
  assumes "0 ∈ affine hull S"
  shows "dependent S"
proof -
  obtain s u where s_u: "finite s ∧ s ≠ {} ∧ s ⊆ S ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = 0"
    using assms affine_hull_explicit[of S] by auto
  then have "∃v∈s. u v ≠ 0"
    using setsum_not_0[of "u" "s"] by auto
  then have "finite s ∧ s ⊆ S ∧ (∃v∈s. u v ≠ 0 ∧ (∑v∈s. u v *R v) = 0)"
    using s_u by auto
  then show ?thesis
    unfolding dependent_explicit[of S] by auto
qed

lemma affine_dependent_imp_dependent2:
  assumes "affine_dependent (insert 0 S)"
  shows "dependent S"
proof -
  obtain x where x: "x ∈ insert 0 S ∧ x ∈ affine hull (insert 0 S - {x})"
    using affine_dependent_def[of "(insert 0 S)"] assms by blast
  then have "x ∈ span (insert 0 S - {x})"
    using affine_hull_subset_span by auto
  moreover have "span (insert 0 S - {x}) = span (S - {x})"
    using insert_Diff_if[of "0" S "{x}"] span_insert_0[of "S-{x}"] by auto
  ultimately have "x ∈ span (S - {x})" by auto
  then have "x ≠ 0 ⟹ dependent S"
    using x dependent_def by auto
  moreover
  {
    assume "x = 0"
    then have "0 ∈ affine hull S"
      using x hull_mono[of "S - {0}" S] by auto
    then have "dependent S"
      using affine_hull_0_dependent by auto
  }
  ultimately show ?thesis by auto
qed

lemma affine_dependent_iff_dependent:
  assumes "a ∉ S"
  shows "affine_dependent (insert a S) ⟷ dependent ((λx. -a + x) ` S)"
proof -
  have "(op + (- a) ` S) = {x - a| x . x : S}" by auto
  then show ?thesis
    using affine_dependent_translation_eq[of "(insert a S)" "-a"]
      affine_dependent_imp_dependent2 assms
      dependent_imp_affine_dependent[of a S]
    by (auto simp del: uminus_add_conv_diff)
qed

lemma affine_dependent_iff_dependent2:
  assumes "a ∈ S"
  shows "affine_dependent S ⟷ dependent ((λx. -a + x) ` (S-{a}))"
proof -
  have "insert a (S - {a}) = S"
    using assms by auto
  then show ?thesis
    using assms affine_dependent_iff_dependent[of a "S-{a}"] by auto
qed

lemma affine_hull_insert_span_gen:
  "affine hull (insert a s) = (λx. a + x) ` span ((λx. - a + x) ` s)"
proof -
  have h1: "{x - a |x. x ∈ s} = ((λx. -a+x) ` s)"
    by auto
  {
    assume "a ∉ s"
    then have ?thesis
      using affine_hull_insert_span[of a s] h1 by auto
  }
  moreover
  {
    assume a1: "a ∈ s"
    have "∃x. x ∈ s ∧ -a+x=0"
      apply (rule exI[of _ a])
      using a1
      apply auto
      done
    then have "insert 0 ((λx. -a+x) ` (s - {a})) = (λx. -a+x) ` s"
      by auto
    then have "span ((λx. -a+x) ` (s - {a}))=span ((λx. -a+x) ` s)"
      using span_insert_0[of "op + (- a) ` (s - {a})"] by (auto simp del: uminus_add_conv_diff)
    moreover have "{x - a |x. x ∈ (s - {a})} = ((λx. -a+x) ` (s - {a}))"
      by auto
    moreover have "insert a (s - {a}) = insert a s"
      using assms by auto
    ultimately have ?thesis
      using assms affine_hull_insert_span[of "a" "s-{a}"] by auto
  }
  ultimately show ?thesis by auto
qed

lemma affine_hull_span2:
  assumes "a ∈ s"
  shows "affine hull s = (λx. a+x) ` span ((λx. -a+x) ` (s-{a}))"
  using affine_hull_insert_span_gen[of a "s - {a}", unfolded insert_Diff[OF assms]]
  by auto

lemma affine_hull_span_gen:
  assumes "a ∈ affine hull s"
  shows "affine hull s = (λx. a+x) ` span ((λx. -a+x) ` s)"
proof -
  have "affine hull (insert a s) = affine hull s"
    using hull_redundant[of a affine s] assms by auto
  then show ?thesis
    using affine_hull_insert_span_gen[of a "s"] by auto
qed

lemma affine_hull_span_0:
  assumes "0 ∈ affine hull S"
  shows "affine hull S = span S"
  using affine_hull_span_gen[of "0" S] assms by auto


lemma extend_to_affine_basis:
  fixes S V :: "'n::euclidean_space set"
  assumes "¬ affine_dependent S" "S ⊆ V" "S ≠ {}"
  shows "∃T. ¬ affine_dependent T ∧ S ⊆ T ∧ T ⊆ V ∧ affine hull T = affine hull V"
proof -
  obtain a where a: "a ∈ S"
    using assms by auto
  then have h0: "independent  ((λx. -a + x) ` (S-{a}))"
    using affine_dependent_iff_dependent2 assms by auto
  then obtain B where B:
    "(λx. -a+x) ` (S - {a}) ⊆ B ∧ B ⊆ (λx. -a+x) ` V ∧ independent B ∧ (λx. -a+x) ` V ⊆ span B"
     using maximal_independent_subset_extend[of "(λx. -a+x) ` (S-{a})" "(λx. -a + x) ` V"] assms
     by blast
  def T  "(λx. a+x) ` insert 0 B"
  then have "T = insert a ((λx. a+x) ` B)"
    by auto
  then have "affine hull T = (λx. a+x) ` span B"
    using affine_hull_insert_span_gen[of a "((λx. a+x) ` B)"] translation_assoc[of "-a" a B]
    by auto
  then have "V ⊆ affine hull T"
    using B assms translation_inverse_subset[of a V "span B"]
    by auto
  moreover have "T ⊆ V"
    using T_def B a assms by auto
  ultimately have "affine hull T = affine hull V"
    by (metis Int_absorb1 Int_absorb2 hull_hull hull_mono)
  moreover have "S ⊆ T"
    using T_def B translation_inverse_subset[of a "S-{a}" B]
    by auto
  moreover have "¬ affine_dependent T"
    using T_def affine_dependent_translation_eq[of "insert 0 B"]
      affine_dependent_imp_dependent2 B
    by auto
  ultimately show ?thesis using ‹T ⊆ V› by auto
qed

lemma affine_basis_exists:
  fixes V :: "'n::euclidean_space set"
  shows "∃B. B ⊆ V ∧ ¬ affine_dependent B ∧ affine hull V = affine hull B"
proof (cases "V = {}")
  case True
  then show ?thesis
    using affine_independent_empty by auto
next
  case False
  then obtain x where "x ∈ V" by auto
  then show ?thesis
    using affine_dependent_def[of "{x}"] extend_to_affine_basis[of "{x}" V]
    by auto
qed


subsection ‹Affine Dimension of a Set›

definition aff_dim :: "('a::euclidean_space) set ⇒ int"
  where "aff_dim V =
  (SOME d :: int.
    ∃B. affine hull B = affine hull V ∧ ¬ affine_dependent B ∧ of_nat (card B) = d + 1)"

lemma aff_dim_basis_exists:
  fixes V :: "('n::euclidean_space) set"
  shows "∃B. affine hull B = affine hull V ∧ ¬ affine_dependent B ∧ of_nat (card B) = aff_dim V + 1"
proof -
  obtain B where "¬ affine_dependent B ∧ affine hull B = affine hull V"
    using affine_basis_exists[of V] by auto
  then show ?thesis
    unfolding aff_dim_def
      some_eq_ex[of "λd. ∃B. affine hull B = affine hull V ∧ ¬ affine_dependent B ∧ of_nat (card B) = d + 1"]
    apply auto
    apply (rule exI[of _ "int (card B) - (1 :: int)"])
    apply (rule exI[of _ "B"])
    apply auto
    done
qed

lemma affine_hull_nonempty: "S ≠ {} ⟷ affine hull S ≠ {}"
proof -
  have "S = {} ⟹ affine hull S = {}"
    using affine_hull_empty by auto
  moreover have "affine hull S = {} ⟹ S = {}"
    unfolding hull_def by auto
  ultimately show ?thesis by blast
qed

lemma aff_dim_parallel_subspace_aux:
  fixes B :: "'n::euclidean_space set"
  assumes "¬ affine_dependent B" "a ∈ B"
  shows "finite B ∧ ((card B) - 1 = dim (span ((λx. -a+x) ` (B-{a}))))"
proof -
  have "independent ((λx. -a + x) ` (B-{a}))"
    using affine_dependent_iff_dependent2 assms by auto
  then have fin: "dim (span ((λx. -a+x) ` (B-{a}))) = card ((λx. -a + x) ` (B-{a}))"
    "finite ((λx. -a + x) ` (B - {a}))"
    using indep_card_eq_dim_span[of "(λx. -a+x) ` (B-{a})"] by auto
  show ?thesis
  proof (cases "(λx. -a + x) ` (B - {a}) = {}")
    case True
    have "B = insert a ((λx. a + x) ` (λx. -a + x) ` (B - {a}))"
      using translation_assoc[of "a" "-a" "(B - {a})"] assms by auto
    then have "B = {a}" using True by auto
    then show ?thesis using assms fin by auto
  next
    case False
    then have "card ((λx. -a + x) ` (B - {a})) > 0"
      using fin by auto
    moreover have h1: "card ((λx. -a + x) ` (B-{a})) = card (B-{a})"
       apply (rule card_image)
       using translate_inj_on
       apply (auto simp del: uminus_add_conv_diff)
       done
    ultimately have "card (B-{a}) > 0" by auto
    then have *: "finite (B - {a})"
      using card_gt_0_iff[of "(B - {a})"] by auto
    then have "card (B - {a}) = card B - 1"
      using card_Diff_singleton assms by auto
    with * show ?thesis using fin h1 by auto
  qed
qed

lemma aff_dim_parallel_subspace:
  fixes V L :: "'n::euclidean_space set"
  assumes "V ≠ {}"
    and "subspace L"
    and "affine_parallel (affine hull V) L"
  shows "aff_dim V = int (dim L)"
proof -
  obtain B where
    B: "affine hull B = affine hull V ∧ ¬ affine_dependent B ∧ int (card B) = aff_dim V + 1"
    using aff_dim_basis_exists by auto
  then have "B ≠ {}"
    using assms B affine_hull_nonempty[of V] affine_hull_nonempty[of B]
    by auto
  then obtain a where a: "a ∈ B" by auto
  def Lb  "span ((λx. -a+x) ` (B-{a}))"
  moreover have "affine_parallel (affine hull B) Lb"
    using Lb_def B assms affine_hull_span2[of a B] a
      affine_parallel_commut[of "Lb" "(affine hull B)"]
    unfolding affine_parallel_def
    by auto
  moreover have "subspace Lb"
    using Lb_def subspace_span by auto
  moreover have "affine hull B ≠ {}"
    using assms B affine_hull_nonempty[of V] by auto
  ultimately have "L = Lb"
    using assms affine_parallel_subspace[of "affine hull B"] affine_affine_hull[of B] B
    by auto
  then have "dim L = dim Lb"
    by auto
  moreover have "card B - 1 = dim Lb" and "finite B"
    using Lb_def aff_dim_parallel_subspace_aux a B by auto
  ultimately show ?thesis
    using B ‹B ≠ {}› card_gt_0_iff[of B] by auto
qed

lemma aff_independent_finite:
  fixes B :: "'n::euclidean_space set"
  assumes "¬ affine_dependent B"
  shows "finite B"
proof -
  {
    assume "B ≠ {}"
    then obtain a where "a ∈ B" by auto
    then have ?thesis
      using aff_dim_parallel_subspace_aux assms by auto
  }
  then show ?thesis by auto
qed

lemma independent_finite:
  fixes B :: "'n::euclidean_space set"
  assumes "independent B"
  shows "finite B"
  using affine_dependent_imp_dependent[of B] aff_independent_finite[of B] assms
  by auto

lemma subspace_dim_equal:
  assumes "subspace (S :: ('n::euclidean_space) set)"
    and "subspace T"
    and "S ⊆ T"
    and "dim S ≥ dim T"
  shows "S = T"
proof -
  obtain B where B: "B ≤ S" "independent B ∧ S ⊆ span B" "card B = dim S"
    using basis_exists[of S] by auto
  then have "span B ⊆ S"
    using span_mono[of B S] span_eq[of S] assms by metis
  then have "span B = S"
    using B by auto
  have "dim S = dim T"
    using assms dim_subset[of S T] by auto
  then have "T ⊆ span B"
    using card_eq_dim[of B T] B independent_finite assms by auto
  then show ?thesis
    using assms ‹span B = S› by auto
qed

lemma span_substd_basis:
  assumes d: "d ⊆ Basis"
  shows "span d = {x. ∀i∈Basis. i ∉ d ⟶ x∙i = 0}"
  (is "_ = ?B")
proof -
  have "d ⊆ ?B"
    using d by (auto simp: inner_Basis)
  moreover have s: "subspace ?B"
    using subspace_substandard[of "λi. i ∉ d"] .
  ultimately have "span d ⊆ ?B"
    using span_mono[of d "?B"] span_eq[of "?B"] by blast
  moreover have *: "card d ≤ dim (span d)"
    using independent_card_le_dim[of d "span d"] independent_substdbasis[OF assms] span_inc[of d]
    by auto
  moreover from * have "dim ?B ≤ dim (span d)"
    using dim_substandard[OF assms] by auto
  ultimately show ?thesis
    using s subspace_dim_equal[of "span d" "?B"] subspace_span[of d] by auto
qed

lemma basis_to_substdbasis_subspace_isomorphism:
  fixes B :: "'a::euclidean_space set"
  assumes "independent B"
  shows "∃f d::'a set. card d = card B ∧ linear f ∧ f ` B = d ∧
    f ` span B = {x. ∀i∈Basis. i ∉ d ⟶ x ∙ i = 0} ∧ inj_on f (span B) ∧ d ⊆ Basis"
proof -
  have B: "card B = dim B"
    using dim_unique[of B B "card B"] assms span_inc[of B] by auto
  have "dim B ≤ card (Basis :: 'a set)"
    using dim_subset_UNIV[of B] by simp
  from ex_card[OF this] obtain d :: "'a set" where d: "d ⊆ Basis" and t: "card d = dim B"
    by auto
  let ?t = "{x::'a::euclidean_space. ∀i∈Basis. i ∉ d ⟶ x∙i = 0}"
  have "∃f. linear f ∧ f ` B = d ∧ f ` span B = ?t ∧ inj_on f (span B)"
    apply (rule basis_to_basis_subspace_isomorphism[of "span B" ?t B "d"])
    apply (rule subspace_span)
    apply (rule subspace_substandard)
    defer
    apply (rule span_inc)
    apply (rule assms)
    defer
    unfolding dim_span[of B]
    apply(rule B)
    unfolding span_substd_basis[OF d, symmetric]
    apply (rule span_inc)
    apply (rule independent_substdbasis[OF d])
    apply rule
    apply assumption
    unfolding t[symmetric] span_substd_basis[OF d] dim_substandard[OF d]
    apply auto
    done
  with t ‹card B = dim B› d show ?thesis by auto
qed

lemma aff_dim_empty:
  fixes S :: "'n::euclidean_space set"
  shows "S = {} ⟷ aff_dim S = -1"
proof -
  obtain B where *: "affine hull B = affine hull S"
    and "¬ affine_dependent B"
    and "int (card B) = aff_dim S + 1"
    using aff_dim_basis_exists by auto
  moreover
  from * have "S = {} ⟷ B = {}"
    using affine_hull_nonempty[of B] affine_hull_nonempty[of S] by auto
  ultimately show ?thesis
    using aff_independent_finite[of B] card_gt_0_iff[of B] by auto
qed

lemma aff_dim_empty_eq [simp]: "aff_dim ({}::'a::euclidean_space set) = -1"
  by (simp add: aff_dim_empty [symmetric])

lemma aff_dim_affine_hull: "aff_dim (affine hull S) = aff_dim S"
  unfolding aff_dim_def using hull_hull[of _ S] by auto

lemma aff_dim_affine_hull2:
  assumes "affine hull S = affine hull T"
  shows "aff_dim S = aff_dim T"
  unfolding aff_dim_def using assms by auto

lemma aff_dim_unique:
  fixes B V :: "'n::euclidean_space set"
  assumes "affine hull B = affine hull V ∧ ¬ affine_dependent B"
  shows "of_nat (card B) = aff_dim V + 1"
proof (cases "B = {}")
  case True
  then have "V = {}"
    using affine_hull_nonempty[of V] affine_hull_nonempty[of B] assms
    by auto
  then have "aff_dim V = (-1::int)"
    using aff_dim_empty by auto
  then show ?thesis
    using ‹B = {}› by auto
next
  case False
  then obtain a where a: "a ∈ B" by auto
  def Lb  "span ((λx. -a+x) ` (B-{a}))"
  have "affine_parallel (affine hull B) Lb"
    using Lb_def affine_hull_span2[of a B] a
      affine_parallel_commut[of "Lb" "(affine hull B)"]
    unfolding affine_parallel_def by auto
  moreover have "subspace Lb"
    using Lb_def subspace_span by auto
  ultimately have "aff_dim B = int(dim Lb)"
    using aff_dim_parallel_subspace[of B Lb] ‹B ≠ {}› by auto
  moreover have "(card B) - 1 = dim Lb" "finite B"
    using Lb_def aff_dim_parallel_subspace_aux a assms by auto
  ultimately have "of_nat (card B) = aff_dim B + 1"
    using ‹B ≠ {}› card_gt_0_iff[of B] by auto
  then show ?thesis
    using aff_dim_affine_hull2 assms by auto
qed

lemma aff_dim_affine_independent:
  fixes B :: "'n::euclidean_space set"
  assumes "¬ affine_dependent B"
  shows "of_nat (card B) = aff_dim B + 1"
  using aff_dim_unique[of B B] assms by auto

lemma affine_independent_iff_card:
    fixes s :: "'a::euclidean_space set"
    shows "~ affine_dependent s ⟷ finite s ∧ aff_dim s = int(card s) - 1"
  apply (rule iffI)
  apply (simp add: aff_dim_affine_independent aff_independent_finite)
  by (metis affine_basis_exists [of s] aff_dim_unique card_subset_eq diff_add_cancel of_nat_eq_iff)

lemma aff_dim_sing:
  fixes a :: "'n::euclidean_space"
  shows "aff_dim {a} = 0"
  using aff_dim_affine_independent[of "{a}"] affine_independent_sing by auto

lemma aff_dim_inner_basis_exists:
  fixes V :: "('n::euclidean_space) set"
  shows "∃B. B ⊆ V ∧ affine hull B = affine hull V ∧
    ¬ affine_dependent B ∧ of_nat (card B) = aff_dim V + 1"
proof -
  obtain B where B: "¬ affine_dependent B" "B ⊆ V" "affine hull B = affine hull V"
    using affine_basis_exists[of V] by auto
  then have "of_nat(card B) = aff_dim V+1" using aff_dim_unique by auto
  with B show ?thesis by auto
qed

lemma aff_dim_le_card:
  fixes V :: "'n::euclidean_space set"
  assumes "finite V"
  shows "aff_dim V ≤ of_nat (card V) - 1"
proof -
  obtain B where B: "B ⊆ V" "of_nat (card B) = aff_dim V + 1"
    using aff_dim_inner_basis_exists[of V] by auto
  then have "card B ≤ card V"
    using assms card_mono by auto
  with B show ?thesis by auto
qed

lemma aff_dim_parallel_eq:
  fixes S T :: "'n::euclidean_space set"
  assumes "affine_parallel (affine hull S) (affine hull T)"
  shows "aff_dim S = aff_dim T"
proof -
  {
    assume "T ≠ {}" "S ≠ {}"
    then obtain L where L: "subspace L ∧ affine_parallel (affine hull T) L"
      using affine_parallel_subspace[of "affine hull T"]
        affine_affine_hull[of T] affine_hull_nonempty
      by auto
    then have "aff_dim T = int (dim L)"
      using aff_dim_parallel_subspace ‹T ≠ {}› by auto
    moreover have *: "subspace L ∧ affine_parallel (affine hull S) L"
       using L affine_parallel_assoc[of "affine hull S" "affine hull T" L] assms by auto
    moreover from * have "aff_dim S = int (dim L)"
      using aff_dim_parallel_subspace ‹S ≠ {}› by auto
    ultimately have ?thesis by auto
  }
  moreover
  {
    assume "S = {}"
    then have "S = {}" and "T = {}"
      using assms affine_hull_nonempty
      unfolding affine_parallel_def
      by auto
    then have ?thesis using aff_dim_empty by auto
  }
  moreover
  {
    assume "T = {}"
    then have "S = {}" and "T = {}"
      using assms affine_hull_nonempty
      unfolding affine_parallel_def
      by auto
    then have ?thesis
      using aff_dim_empty by auto
  }
  ultimately show ?thesis by blast
qed

lemma aff_dim_translation_eq:
  fixes a :: "'n::euclidean_space"
  shows "aff_dim ((λx. a + x) ` S) = aff_dim S"
proof -
  have "affine_parallel (affine hull S) (affine hull ((λx. a + x) ` S))"
    unfolding affine_parallel_def
    apply (rule exI[of _ "a"])
    using affine_hull_translation[of a S]
    apply auto
    done
  then show ?thesis
    using aff_dim_parallel_eq[of S "(λx. a + x) ` S"] by auto
qed

lemma aff_dim_affine:
  fixes S L :: "'n::euclidean_space set"
  assumes "S ≠ {}"
    and "affine S"
    and "subspace L"
    and "affine_parallel S L"
  shows "aff_dim S = int (dim L)"
proof -
  have *: "affine hull S = S"
    using assms affine_hull_eq[of S] by auto
  then have "affine_parallel (affine hull S) L"
    using assms by (simp add: *)
  then show ?thesis
    using assms aff_dim_parallel_subspace[of S L] by blast
qed

lemma dim_affine_hull:
  fixes S :: "'n::euclidean_space set"
  shows "dim (affine hull S) = dim S"
proof -
  have "dim (affine hull S) ≥ dim S"
    using dim_subset by auto
  moreover have "dim (span S) ≥ dim (affine hull S)"
    using dim_subset affine_hull_subset_span by blast
  moreover have "dim (span S) = dim S"
    using dim_span by auto
  ultimately show ?thesis by auto
qed

lemma aff_dim_subspace:
  fixes S :: "'n::euclidean_space set"
  assumes "S ≠ {}"
    and "subspace S"
  shows "aff_dim S = int (dim S)"
  using aff_dim_affine[of S S] assms subspace_imp_affine[of S] affine_parallel_reflex[of S]
  by auto

lemma aff_dim_zero:
  fixes S :: "'n::euclidean_space set"
  assumes "0 ∈ affine hull S"
  shows "aff_dim S = int (dim S)"
proof -
  have "subspace (affine hull S)"
    using subspace_affine[of "affine hull S"] affine_affine_hull assms
    by auto
  then have "aff_dim (affine hull S) = int (dim (affine hull S))"
    using assms aff_dim_subspace[of "affine hull S"] by auto
  then show ?thesis
    using aff_dim_affine_hull[of S] dim_affine_hull[of S]
    by auto
qed

lemma aff_dim_univ: "aff_dim (UNIV :: 'n::euclidean_space set) = int(DIM('n))"
  using aff_dim_subspace[of "(UNIV :: 'n::euclidean_space set)"]
    dim_UNIV[where 'a="'n::euclidean_space"]
  by auto

lemma aff_dim_geq:
  fixes V :: "'n::euclidean_space set"
  shows "aff_dim V ≥ -1"
proof -
  obtain B where "affine hull B = affine hull V"
    and "¬ affine_dependent B"
    and "int (card B) = aff_dim V + 1"
    using aff_dim_basis_exists by auto
  then show ?thesis by auto
qed

lemma independent_card_le_aff_dim:
  fixes B :: "'n::euclidean_space set"
  assumes "B ⊆ V"
  assumes "¬ affine_dependent B"
  shows "int (card B) ≤ aff_dim V + 1"
proof (cases "B = {}")
  case True
  then have "-1 ≤ aff_dim V"
    using aff_dim_geq by auto
  with True show ?thesis by auto
next
  case False
  then obtain T where T: "¬ affine_dependent T ∧ B ⊆ T ∧ T ⊆ V ∧ affine hull T = affine hull V"
    using assms extend_to_affine_basis[of B V] by auto
  then have "of_nat (card T) = aff_dim V + 1"
    using aff_dim_unique by auto
  then show ?thesis
    using T card_mono[of T B] aff_independent_finite[of T] by auto
qed

lemma aff_dim_subset:
  fixes S T :: "'n::euclidean_space set"
  assumes "S ⊆ T"
  shows "aff_dim S ≤ aff_dim T"
proof -
  obtain B where B: "¬ affine_dependent B" "B ⊆ S" "affine hull B = affine hull S"
    "of_nat (card B) = aff_dim S + 1"
    using aff_dim_inner_basis_exists[of S] by auto
  then have "int (card B) ≤ aff_dim T + 1"
    using assms independent_card_le_aff_dim[of B T] by auto
  with B show ?thesis by auto
qed

lemma aff_dim_subset_univ:
  fixes S :: "'n::euclidean_space set"
  shows "aff_dim S ≤ int (DIM('n))"
proof -
  have "aff_dim (UNIV :: 'n::euclidean_space set) = int(DIM('n))"
    using aff_dim_univ by auto
  then show "aff_dim (S:: 'n::euclidean_space set) ≤ int(DIM('n))"
    using assms aff_dim_subset[of S "(UNIV :: ('n::euclidean_space) set)"] subset_UNIV by auto
qed

lemma affine_dim_equal:
  fixes S :: "'n::euclidean_space set"
  assumes "affine S" "affine T" "S ≠ {}" "S ⊆ T" "aff_dim S = aff_dim T"
  shows "S = T"
proof -
  obtain a where "a ∈ S" using assms by auto
  then have "a ∈ T" using assms by auto
  def LS  "{y. ∃x ∈ S. (-a) + x = y}"
  then have ls: "subspace LS" "affine_parallel S LS"
    using assms parallel_subspace_explicit[of S a LS] ‹a ∈ S› by auto
  then have h1: "int(dim LS) = aff_dim S"
    using assms aff_dim_affine[of S LS] by auto
  have "T ≠ {}" using assms by auto
  def LT  "{y. ∃x ∈ T. (-a) + x = y}"
  then have lt: "subspace LT ∧ affine_parallel T LT"
    using assms parallel_subspace_explicit[of T a LT] ‹a ∈ T› by auto
  then have "int(dim LT) = aff_dim T"
    using assms aff_dim_affine[of T LT] ‹T ≠ {}› by auto
  then have "dim LS = dim LT"
    using h1 assms by auto
  moreover have "LS ≤ LT"
    using LS_def LT_def assms by auto
  ultimately have "LS = LT"
    using subspace_dim_equal[of LS LT] ls lt by auto
  moreover have "S = {x. ∃y ∈ LS. a+y=x}"
    using LS_def by auto
  moreover have "T = {x. ∃y ∈ LT. a+y=x}"
    using LT_def by auto
  ultimately show ?thesis by auto
qed

lemma affine_hull_univ:
  fixes S :: "'n::euclidean_space set"
  assumes "aff_dim S = int(DIM('n))"
  shows "affine hull S = (UNIV :: ('n::euclidean_space) set)"
proof -
  have "S ≠ {}"
    using assms aff_dim_empty[of S] by auto
  have h0: "S ⊆ affine hull S"
    using hull_subset[of S _] by auto
  have h1: "aff_dim (UNIV :: ('n::euclidean_space) set) = aff_dim S"
    using aff_dim_univ assms by auto
  then have h2: "aff_dim (affine hull S) ≤ aff_dim (UNIV :: ('n::euclidean_space) set)"
    using aff_dim_subset_univ[of "affine hull S"] assms h0 by auto
  have h3: "aff_dim S ≤ aff_dim (affine hull S)"
    using h0 aff_dim_subset[of S "affine hull S"] assms by auto
  then have h4: "aff_dim (affine hull S) = aff_dim (UNIV :: ('n::euclidean_space) set)"
    using h0 h1 h2 by auto
  then show ?thesis
    using affine_dim_equal[of "affine hull S" "(UNIV :: ('n::euclidean_space) set)"]
      affine_affine_hull[of S] affine_UNIV assms h4 h0 ‹S ≠ {}›
    by auto
qed

lemma aff_dim_convex_hull:
  fixes S :: "'n::euclidean_space set"
  shows "aff_dim (convex hull S) = aff_dim S"
  using aff_dim_affine_hull[of S] convex_hull_subset_affine_hull[of S]
    hull_subset[of S "convex"] aff_dim_subset[of S "convex hull S"]
    aff_dim_subset[of "convex hull S" "affine hull S"]
  by auto

lemma aff_dim_cball:
  fixes a :: "'n::euclidean_space"
  assumes "e > 0"
  shows "aff_dim (cball a e) = int (DIM('n))"
proof -
  have "(λx. a + x) ` (cball 0 e) ⊆ cball a e"
    unfolding cball_def dist_norm by auto
  then have "aff_dim (cball (0 :: 'n::euclidean_space) e) ≤ aff_dim (cball a e)"
    using aff_dim_translation_eq[of a "cball 0 e"]
          aff_dim_subset[of "op + a ` cball 0 e" "cball a e"]
    by auto
  moreover have "aff_dim (cball (0 :: 'n::euclidean_space) e) = int (DIM('n))"
    using hull_inc[of "(0 :: 'n::euclidean_space)" "cball 0 e"]
      centre_in_cball[of "(0 :: 'n::euclidean_space)"] assms
    by (simp add: dim_cball[of e] aff_dim_zero[of "cball 0 e"])
  ultimately show ?thesis
    using aff_dim_subset_univ[of "cball a e"] by auto
qed

lemma aff_dim_open:
  fixes S :: "'n::euclidean_space set"
  assumes "open S"
    and "S ≠ {}"
  shows "aff_dim S = int (DIM('n))"
proof -
  obtain x where "x ∈ S"
    using assms by auto
  then obtain e where e: "e > 0" "cball x e ⊆ S"
    using open_contains_cball[of S] assms by auto
  then have "aff_dim (cball x e) ≤ aff_dim S"
    using aff_dim_subset by auto
  with e show ?thesis
    using aff_dim_cball[of e x] aff_dim_subset_univ[of S] by auto
qed

lemma low_dim_interior:
  fixes S :: "'n::euclidean_space set"
  assumes "¬ aff_dim S = int (DIM('n))"
  shows "interior S = {}"
proof -
  have "aff_dim(interior S) ≤ aff_dim S"
    using interior_subset aff_dim_subset[of "interior S" S] by auto
  then show ?thesis
    using aff_dim_open[of "interior S"] aff_dim_subset_univ[of S] assms by auto
qed

corollary empty_interior_lowdim:
  fixes S :: "'n::euclidean_space set"
  shows "dim S < DIM ('n) ⟹ interior S = {}"
by (metis low_dim_interior affine_hull_univ dim_affine_hull less_not_refl dim_UNIV)

subsection ‹Caratheodory's theorem.›

lemma convex_hull_caratheodory_aff_dim:
  fixes p :: "('a::euclidean_space) set"
  shows "convex hull p =
    {y. ∃s u. finite s ∧ s ⊆ p ∧ card s ≤ aff_dim p + 1 ∧
      (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ setsum (λv. u v *R v) s = y}"
  unfolding convex_hull_explicit set_eq_iff mem_Collect_eq
proof (intro allI iffI)
  fix y
  let ?P = "λn. ∃s u. finite s ∧ card s = n ∧ s ⊆ p ∧ (∀x∈s. 0 ≤ u x) ∧
    setsum u s = 1 ∧ (∑v∈s. u v *R v) = y"
  assume "∃s u. finite s ∧ s ⊆ p ∧ (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = y"
  then obtain N where "?P N" by auto
  then have "∃n≤N. (∀k<n. ¬ ?P k) ∧ ?P n"
    apply (rule_tac ex_least_nat_le)
    apply auto
    done
  then obtain n where "?P n" and smallest: "∀k<n. ¬ ?P k"
    by blast
  then obtain s u where obt: "finite s" "card s = n" "s⊆p" "∀x∈s. 0 ≤ u x"
    "setsum u s = 1"  "(∑v∈s. u v *R v) = y" by auto

  have "card s ≤ aff_dim p + 1"
  proof (rule ccontr, simp only: not_le)
    assume "aff_dim p + 1 < card s"
    then have "affine_dependent s"
      using affine_dependent_biggerset[OF obt(1)] independent_card_le_aff_dim not_less obt(3)
      by blast
    then obtain w v where wv: "setsum w s = 0" "v∈s" "w v ≠ 0" "(∑v∈s. w v *R v) = 0"
      using affine_dependent_explicit_finite[OF obt(1)] by auto
    def i  "(λv. (u v) / (- w v)) ` {v∈s. w v < 0}"
    def t  "Min i"
    have "∃x∈s. w x < 0"
    proof (rule ccontr, simp add: not_less)
      assume as:"∀x∈s. 0 ≤ w x"
      then have "setsum w (s - {v}) ≥ 0"
        apply (rule_tac setsum_nonneg)
        apply auto
        done
      then have "setsum w s > 0"
        unfolding setsum.remove[OF obt(1) ‹v∈s›]
        using as[THEN bspec[where x=v]]  ‹v∈s›  ‹w v ≠ 0› by auto
      then show False using wv(1) by auto
    qed
    then have "i ≠ {}" unfolding i_def by auto
    then have "t ≥ 0"
      using Min_ge_iff[of i 0 ] and obt(1)
      unfolding t_def i_def
      using obt(4)[unfolded le_less]
      by (auto simp: divide_le_0_iff)
    have t: "∀v∈s. u v + t * w v ≥ 0"
    proof
      fix v
      assume "v ∈ s"
      then have v: "0 ≤ u v"
        using obt(4)[THEN bspec[where x=v]] by auto
      show "0 ≤ u v + t * w v"
      proof (cases "w v < 0")
        case False
        thus ?thesis using v ‹t≥0› by auto
      next
        case True
        then have "t ≤ u v / (- w v)"
          using ‹v∈s› unfolding t_def i_def
          apply (rule_tac Min_le)
          using obt(1) apply auto
          done
        then show ?thesis
          unfolding real_0_le_add_iff
          using pos_le_divide_eq[OF True[unfolded neg_0_less_iff_less[symmetric]]]
          by auto
      qed
    qed
    obtain a where "a ∈ s" and "t = (λv. (u v) / (- w v)) a" and "w a < 0"
      using Min_in[OF _ ‹i≠{}›] and obt(1) unfolding i_def t_def by auto
    then have a: "a ∈ s" "u a + t * w a = 0" by auto
    have *: "⋀f. setsum f (s - {a}) = setsum f s - ((f a)::'b::ab_group_add)"
      unfolding setsum.remove[OF obt(1) ‹a∈s›] by auto
    have "(∑v∈s. u v + t * w v) = 1"
      unfolding setsum.distrib wv(1) setsum_right_distrib[symmetric] obt(5) by auto
    moreover have "(∑v∈s. u v *R v + (t * w v) *R v) - (u a *R a + (t * w a) *R a) = y"
      unfolding setsum.distrib obt(6) scaleR_scaleR[symmetric] scaleR_right.setsum [symmetric] wv(4)
      using a(2) [THEN eq_neg_iff_add_eq_0 [THEN iffD2]] by simp
    ultimately have "?P (n - 1)"
      apply (rule_tac x="(s - {a})" in exI)
      apply (rule_tac x="λv. u v + t * w v" in exI)
      using obt(1-3) and t and a
      apply (auto simp add: * scaleR_left_distrib)
      done
    then show False
      using smallest[THEN spec[where x="n - 1"]] by auto
  qed
  then show "∃s u. finite s ∧ s ⊆ p ∧ card s ≤ aff_dim p + 1 ∧
      (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ (∑v∈s. u v *R v) = y"
    using obt by auto
qed auto

lemma caratheodory_aff_dim:
  fixes p :: "('a::euclidean_space) set"
  shows "convex hull p = {x. ∃s. finite s ∧ s ⊆ p ∧ card s ≤ aff_dim p + 1 ∧ x ∈ convex hull s}"
        (is "?lhs = ?rhs")
proof
  show "?lhs ⊆ ?rhs"
    apply (subst convex_hull_caratheodory_aff_dim)
    apply clarify
    apply (rule_tac x="s" in exI)
    apply (simp add: hull_subset convex_explicit [THEN iffD1, OF convex_convex_hull])
    done
next
  show "?rhs ⊆ ?lhs"
    using hull_mono by blast
qed

lemma convex_hull_caratheodory:
  fixes p :: "('a::euclidean_space) set"
  shows "convex hull p =
            {y. ∃s u. finite s ∧ s ⊆ p ∧ card s ≤ DIM('a) + 1 ∧
              (∀x∈s. 0 ≤ u x) ∧ setsum u s = 1 ∧ setsum (λv. u v *R v) s = y}"
        (is "?lhs = ?rhs")
proof (intro set_eqI iffI)
  fix x
  assume "x ∈ ?lhs" then show "x ∈ ?rhs"
    apply (simp only: convex_hull_caratheodory_aff_dim Set.mem_Collect_eq)
    apply (erule ex_forward)+
    using aff_dim_subset_univ [of p]
    apply simp
    done
next
  fix x
  assume "x ∈ ?rhs" then show "x ∈ ?lhs"
    by (auto simp add: convex_hull_explicit)
qed

theorem caratheodory:
  "convex hull p =
    {x::'a::euclidean_space. ∃s. finite s ∧ s ⊆ p ∧
      card s ≤ DIM('a) + 1 ∧ x ∈ convex hull s}"
proof safe
  fix x
  assume "x ∈ convex hull p"
  then obtain s u where "finite s" "s ⊆ p" "card s ≤ DIM('a) + 1"
    "∀x∈s. 0 ≤ u x" "setsum u s = 1" "(∑v∈s. u v *R v) = x"
    unfolding convex_hull_caratheodory by auto
  then show "∃s. finite s ∧ s ⊆ p ∧ card s ≤ DIM('a) + 1 ∧ x ∈ convex hull s"
    apply (rule_tac x=s in exI)
    using hull_subset[of s convex]
    using convex_convex_hull[unfolded convex_explicit, of s,
      THEN spec[where x=s], THEN spec[where x=u]]
    apply auto
    done
next
  fix x s
  assume  "finite s" "s ⊆ p" "card s ≤ DIM('a) + 1" "x ∈ convex hull s"
  then show "x ∈ convex hull p"
    using hull_mono[OF ‹s⊆p›] by auto
qed


subsection ‹Relative interior of a set›

definition "rel_interior S =
  {x. ∃T. openin (subtopology euclidean (affine hull S)) T ∧ x ∈ T ∧ T ⊆ S}"

lemma rel_interior:
  "rel_interior S = {x ∈ S. ∃T. open T ∧ x ∈ T ∧ T ∩ affine hull S ⊆ S}"
  unfolding rel_interior_def[of S] openin_open[of "affine hull S"]
  apply auto
proof -
  fix x T
  assume *: "x ∈ S" "open T" "x ∈ T" "T ∩ affine hull S ⊆ S"
  then have **: "x ∈ T ∩ affine hull S"
    using hull_inc by auto
  show "∃Tb. (∃Ta. open Ta ∧ Tb = affine hull S ∩ Ta) ∧ x ∈ Tb ∧ Tb ⊆ S"
    apply (rule_tac x = "T ∩ (affine hull S)" in exI)
    using * **
    apply auto
    done
qed

lemma mem_rel_interior: "x ∈ rel_interior S ⟷ (∃T. open T ∧ x ∈ T ∩ S ∧ T ∩ affine hull S ⊆ S)"
  by (auto simp add: rel_interior)

lemma mem_rel_interior_ball:
  "x ∈ rel_interior S ⟷ x ∈ S ∧ (∃e. e > 0 ∧ ball x e ∩ affine hull S ⊆ S)"
  apply (simp add: rel_interior, safe)
  apply (force simp add: open_contains_ball)
  apply (rule_tac x = "ball x e" in exI)
  apply simp
  done

lemma rel_interior_ball:
  "rel_interior S = {x ∈ S. ∃e. e > 0 ∧ ball x e ∩ affine hull S ⊆ S}"
  using mem_rel_interior_ball [of _ S] by auto

lemma mem_rel_interior_cball:
  "x ∈ rel_interior S ⟷ x ∈ S ∧ (∃e. e > 0 ∧ cball x e ∩ affine hull S ⊆ S)"
  apply (simp add: rel_interior, safe)
  apply (force simp add: open_contains_cball)
  apply (rule_tac x = "ball x e" in exI)
  apply (simp add: subset_trans [OF ball_subset_cball])
  apply auto
  done

lemma rel_interior_cball:
  "rel_interior S = {x ∈ S. ∃e. e > 0 ∧ cball x e ∩ affine hull S ⊆ S}"
  using mem_rel_interior_cball [of _ S] by auto

lemma rel_interior_empty [simp]: "rel_interior {} = {}"
   by (auto simp add: rel_interior_def)

lemma affine_hull_sing [simp]: "affine hull {a :: 'n::euclidean_space} = {a}"
  by (metis affine_hull_eq affine_sing)

lemma rel_interior_sing [simp]: "rel_interior {a :: 'n::euclidean_space} = {a}"
  unfolding rel_interior_ball affine_hull_sing
  apply auto
  apply (rule_tac x = "1 :: real" in exI)
  apply simp
  done

lemma subset_rel_interior:
  fixes S T :: "'n::euclidean_space set"
  assumes "S ⊆ T"
    and "affine hull S = affine hull T"
  shows "rel_interior S ⊆ rel_interior T"
  using assms by (auto simp add: rel_interior_def)

lemma rel_interior_subset: "rel_interior S ⊆ S"
  by (auto simp add: rel_interior_def)

lemma rel_interior_subset_closure: "rel_interior S ⊆ closure S"
  using rel_interior_subset by (auto simp add: closure_def)

lemma interior_subset_rel_interior: "interior S ⊆ rel_interior S"
  by (auto simp add: rel_interior interior_def)

lemma interior_rel_interior:
  fixes S :: "'n::euclidean_space set"
  assumes "aff_dim S = int(DIM('n))"
  shows "rel_interior S = interior S"
proof -
  have "affine hull S = UNIV"
    using assms affine_hull_univ[of S] by auto
  then show ?thesis
    unfolding rel_interior interior_def by auto
qed

lemma rel_interior_interior:
  fixes S :: "'n::euclidean_space set"
  assumes "affine hull S = UNIV"
  shows "rel_interior S = interior S"
  using assms unfolding rel_interior interior_def by auto

lemma rel_interior_open:
  fixes S :: "'n::euclidean_space set"
  assumes "open S"
  shows "rel_interior S = S"
  by (metis assms interior_eq interior_subset_rel_interior rel_interior_subset set_eq_subset)

lemma interior_ball [simp]: "interior (ball x e) = ball x e"
  by (simp add: interior_open)

lemma interior_rel_interior_gen:
  fixes S :: "'n::euclidean_space set"
  shows "interior S = (if aff_dim S = int(DIM('n)) then rel_interior S else {})"
  by (metis interior_rel_interior low_dim_interior)

lemma rel_interior_univ:
  fixes S :: "'n::euclidean_space set"
  shows "rel_interior (affine hull S) = affine hull S"
proof -
  have *: "rel_interior (affine hull S) ⊆ affine hull S"
    using rel_interior_subset by auto
  {
    fix x
    assume x: "x ∈ affine hull S"
    def e  "1::real"
    then have "e > 0" "ball x e ∩ affine hull (affine hull S) ⊆ affine hull S"
      using hull_hull[of _ S] by auto
    then have "x ∈ rel_interior (affine hull S)"
      using x rel_interior_ball[of "affine hull S"] by auto
  }
  then show ?thesis using * by auto
qed

lemma rel_interior_univ2: "rel_interior (UNIV :: ('n::euclidean_space) set) = UNIV"
  by (metis open_UNIV rel_interior_open)

lemma rel_interior_convex_shrink:
  fixes S :: "'a::euclidean_space set"
  assumes "convex S"
    and "c ∈ rel_interior S"
    and "x ∈ S"
    and "0 < e"
    and "e ≤ 1"
  shows "x - e *R (x - c) ∈ rel_interior S"
proof -
  obtain d where "d > 0" and d: "ball c d ∩ affine hull S ⊆ S"
    using assms(2) unfolding  mem_rel_interior_ball by auto
  {
    fix y
    assume as: "dist (x - e *R (x - c)) y < e * d" "y ∈ affine hull S"
    have *: "y = (1 - (1 - e)) *R ((1 / e) *R y - ((1 - e) / e) *R x) + (1 - e) *R x"
      using ‹e > 0› by (auto simp add: scaleR_left_diff_distrib scaleR_right_diff_distrib)
    have "x ∈ affine hull S"
      using assms hull_subset[of S] by auto
    moreover have "1 / e + - ((1 - e) / e) = 1"
      using ‹e > 0› left_diff_distrib[of "1" "(1-e)" "1/e"] by auto
    ultimately have **: "(1 / e) *R y - ((1 - e) / e) *R x ∈ affine hull S"
      using as affine_affine_hull[of S] mem_affine[of "affine hull S" y x "(1 / e)" "-((1 - e) / e)"]
      by (simp add: algebra_simps)
    have "dist c ((1 / e) *R y - ((1 - e) / e) *R x) = ¦1/e¦ * norm (e *R c - y + (1 - e) *R x)"
      unfolding dist_norm norm_scaleR[symmetric]
      apply (rule arg_cong[where f=norm])
      using ‹e > 0›
      apply (auto simp add: euclidean_eq_iff[where 'a='a] field_simps inner_simps)
      done
    also have "… = ¦1/e¦ * norm (x - e *R (x - c) - y)"
      by (auto intro!:arg_cong[where f=norm] simp add: algebra_simps)
    also have "… < d"
      using as[unfolded dist_norm] and ‹e > 0›
      by (auto simp add:pos_divide_less_eq[OF ‹e > 0›] mult.commute)
    finally have "y ∈ S"
      apply (subst *)
      apply (rule assms(1)[unfolded convex_alt,rule_format])
      apply (rule d[unfolded subset_eq,rule_format])
      unfolding mem_ball
      using assms(3-5) **
      apply auto
      done
  }
  then have "ball (x - e *R (x - c)) (e*d) ∩ affine hull S ⊆ S"
    by auto
  moreover have "e * d > 0"
    using ‹e > 0› ‹d > 0› by simp
  moreover have c: "c ∈ S"
    using assms rel_interior_subset by auto
  moreover from c have "x - e *R (x - c) ∈ S"
    using convexD_alt[of S x c e]
    apply (simp add: algebra_simps)
    using assms
    apply auto
    done
  ultimately show ?thesis
    using mem_rel_interior_ball[of "x - e *R (x - c)" S] ‹e > 0› by auto
qed

lemma interior_real_semiline:
  fixes a :: real
  shows "interior {a..} = {a<..}"
proof -
  {
    fix y
    assume "a < y"
    then have "y ∈ interior {a..}"
      apply (simp add: mem_interior)
      apply (rule_tac x="(y-a)" in exI)
      apply (auto simp add: dist_norm)
      done
  }
  moreover
  {
    fix y
    assume "y ∈ interior {a..}"
    then obtain e where e: "e > 0" "cball y e ⊆ {a..}"
      using mem_interior_cball[of y "{a..}"] by auto
    moreover from e have "y - e ∈ cball y e"
      by (auto simp add: cball_def dist_norm)
    ultimately have "a ≤ y - e" by blast
    then have "a < y" using e by auto
  }
  ultimately show ?thesis by auto
qed

lemma continuous_ge_on_Ioo:
  assumes "continuous_on {c..d} g" "⋀x. x ∈ {c<..<d} ⟹ g x ≥ a" "c < d" "x ∈ {c..d}"
  shows "g (x::real) ≥ (a::real)"
proof-
  from assms(3) have "{c..d} = closure {c<..<d}" by (rule closure_greaterThanLessThan[symmetric])
  also from assms(2) have "{c<..<d} ⊆ (g -` {a..} ∩ {c..d})" by auto
  hence "closure {c<..<d} ⊆ closure (g -` {a..} ∩ {c..d})" by (rule closure_mono)
  also from assms(1) have "closed (g -` {a..} ∩ {c..d})"
    by (auto simp: continuous_on_closed_vimage)
  hence "closure (g -` {a..} ∩ {c..d}) = g -` {a..} ∩ {c..d}" by simp
  finally show ?thesis using ‹x ∈ {c..d}› by auto
qed

lemma interior_real_semiline':
  fixes a :: real
  shows "interior {..a} = {..<a}"
proof -
  {
    fix y
    assume "a > y"
    then have "y ∈ interior {..a}"
      apply (simp add: mem_interior)
      apply (rule_tac x="(a-y)" in exI)
      apply (auto simp add: dist_norm)
      done
  }
  moreover
  {
    fix y
    assume "y ∈ interior {..a}"
    then obtain e where e: "e > 0" "cball y e ⊆ {..a}"
      using mem_interior_cball[of y "{..a}"] by auto
    moreover from e have "y + e ∈ cball y e"
      by (auto simp add: cball_def dist_norm)
    ultimately have "a ≥ y + e" by auto
    then have "a > y" using e by auto
  }
  ultimately show ?thesis by auto
qed

lemma interior_atLeastAtMost_real: "interior {a..b} = {a<..<b :: real}"
proof-
  have "{a..b} = {a..} ∩ {..b}" by auto
  also have "interior ... = {a<..} ∩ {..<b}"
    by (simp add: interior_real_semiline interior_real_semiline')
  also have "... = {a<..<b}" by auto
  finally show ?thesis .
qed

lemma frontier_real_Iic:
  fixes a :: real
  shows "frontier {..a} = {a}"
  unfolding frontier_def by (auto simp add: interior_real_semiline')

lemma rel_interior_real_box:
  fixes a b :: real
  assumes "a < b"
  shows "rel_interior {a .. b} = {a <..< b}"
proof -
  have "box a b ≠ {}"
    using assms
    unfolding set_eq_iff
    by (auto intro!: exI[of _ "(a + b) / 2"] simp: box_def)
  then show ?thesis
    using interior_rel_interior_gen[of "cbox a b", symmetric]
    by (simp split: split_if_asm del: box_real add: box_real[symmetric] interior_cbox)
qed

lemma rel_interior_real_semiline:
  fixes a :: real
  shows "rel_interior {a..} = {a<..}"
proof -
  have *: "{a<..} ≠ {}"
    unfolding set_eq_iff by (auto intro!: exI[of _ "a + 1"])
  then show ?thesis using interior_real_semiline interior_rel_interior_gen[of "{a..}"]
    by (auto split: split_if_asm)
qed

subsubsection ‹Relative open sets›

definition "rel_open S ⟷ rel_interior S = S"

lemma rel_open: "rel_open S ⟷ openin (subtopology euclidean (affine hull S)) S"
  unfolding rel_open_def rel_interior_def
  apply auto
  using openin_subopen[of "subtopology euclidean (affine hull S)" S]
  apply auto
  done

lemma opein_rel_interior: "openin (subtopology euclidean (affine hull S)) (rel_interior S)"
  apply (simp add: rel_interior_def)
  apply (subst openin_subopen)
  apply blast
  done

lemma affine_rel_open:
  fixes S :: "'n::euclidean_space set"
  assumes "affine S"
  shows "rel_open S"
  unfolding rel_open_def
  using assms rel_interior_univ[of S] affine_hull_eq[of S]
  by metis

lemma affine_closed:
  fixes S :: "'n::euclidean_space set"
  assumes "affine S"
  shows "closed S"
proof -
  {
    assume "S ≠ {}"
    then obtain L where L: "subspace L" "affine_parallel S L"
      using assms affine_parallel_subspace[of S] by auto
    then obtain a where a: "S = (op + a ` L)"
      using affine_parallel_def[of L S] affine_parallel_commut by auto
    from L have "closed L" using closed_subspace by auto
    then have "closed S"
      using closed_translation a by auto
  }
  then show ?thesis by auto
qed

lemma closure_affine_hull:
  fixes S :: "'n::euclidean_space set"
  shows "closure S ⊆ affine hull S"
  by (intro closure_minimal hull_subset affine_closed affine_affine_hull)

lemma closure_same_affine_hull:
  fixes S :: "'n::euclidean_space set"
  shows "affine hull (closure S) = affine hull S"
proof -
  have "affine hull (closure S) ⊆ affine hull S"
    using hull_mono[of "closure S" "affine hull S" "affine"]
      closure_affine_hull[of S] hull_hull[of "affine" S]
    by auto
  moreover have "affine hull (closure S) ⊇ affine hull S"
    using hull_mono[of "S" "closure S" "affine"] closure_subset by auto
  ultimately show ?thesis by auto
qed

lemma closure_aff_dim:
  fixes S :: "'n::euclidean_space set"
  shows "aff_dim (closure S) = aff_dim S"
proof -
  have "aff_dim S ≤ aff_dim (closure S)"
    using aff_dim_subset closure_subset by auto
  moreover have "aff_dim (closure S) ≤ aff_dim (affine hull S)"
    using aff_dim_subset closure_affine_hull by auto
  moreover have "aff_dim (affine hull S) = aff_dim S"
    using aff_dim_affine_hull by auto
  ultimately show ?thesis by auto
qed

lemma rel_interior_closure_convex_shrink:
  fixes S :: "_::euclidean_space set"
  assumes "convex S"
    and "c ∈ rel_interior S"
    and "x ∈ closure S"
    and "e > 0"
    and "e ≤ 1"
  shows "x - e *R (x - c) ∈ rel_interior S"
proof -
  obtain d where "d > 0" and d: "ball c d ∩ affine hull S ⊆ S"
    using assms(2) unfolding mem_rel_interior_ball by auto
  have "∃y ∈ S. norm (y - x) * (1 - e) < e * d"
  proof (cases "x ∈ S")
    case True
    then show ?thesis using ‹e > 0› ‹d > 0›
      apply (rule_tac bexI[where x=x])
      apply (auto)
      done
  next
    case False
    then have x: "x islimpt S"
      using assms(3)[unfolded closure_def] by auto
    show ?thesis
    proof (cases "e = 1")
      case True
      obtain y where "y ∈ S" "y ≠ x" "dist y x < 1"
        using x[unfolded islimpt_approachable,THEN spec[where x=1]] by auto
      then show ?thesis
        apply (rule_tac x=y in bexI)
        unfolding True
        using ‹d > 0›
        apply auto
        done
    next
      case False
      then have "0 < e * d / (1 - e)" and *: "1 - e > 0"
        using ‹e ≤ 1› ‹e > 0› ‹d > 0› by (auto)
      then obtain y where "y ∈ S" "y ≠ x" "dist y x < e * d / (1 - e)"
        using x[unfolded islimpt_approachable,THEN spec[where x="e*d / (1 - e)"]] by auto
      then show ?thesis
        apply (rule_tac x=y in bexI)
        unfolding dist_norm
        using pos_less_divide_eq[OF *]
        apply auto
        done
    qed
  qed
  then obtain y where "y ∈ S" and y: "norm (y - x) * (1 - e) < e * d"
    by auto
  def z  "c + ((1 - e) / e) *R (x - y)"
  have *: "x - e *R (x - c) = y - e *R (y - z)"
    unfolding z_def using ‹e > 0›
    by (auto simp add: scaleR_right_diff_distrib scaleR_right_distrib scaleR_left_diff_distrib)
  have zball: "z ∈ ball c d"
    using mem_ball z_def dist_norm[of c]
    using y and assms(4,5)
    by (auto simp add:field_simps norm_minus_commute)
  have "x ∈ affine hull S"
    using closure_affine_hull assms by auto
  moreover have "y ∈ affine hull S"
    using ‹y ∈ S› hull_subset[of S] by auto
  moreover have "c ∈ affine hull S"
    using assms rel_interior_subset hull_subset[of S] by auto
  ultimately have "z ∈ affine hull S"
    using z_def affine_affine_hull[of S]
      mem_affine_3_minus [of "affine hull S" c x y "(1 - e) / e"]
      assms
    by (auto simp add: field_simps)
  then have "z ∈ S" using d zball by auto
  obtain d1 where "d1 > 0" and d1: "ball z d1 ≤ ball c d"
    using zball open_ball[of c d] openE[of "ball c d" z] by auto
  then have "ball z d1 ∩ affine hull S ⊆ ball c d ∩ affine hull S"
    by auto
  then have "ball z d1 ∩ affine hull S ⊆ S"
    using d by auto
  then have "z ∈ rel_interior S"
    using mem_rel_interior_ball using ‹d1 > 0› ‹z ∈ S› by auto
  then have "y - e *R (y - z) ∈ rel_interior S"
    using rel_interior_convex_shrink[of S z y e] assms ‹y ∈ S› by auto
  then show ?thesis using * by auto
qed


subsubsection‹Relative interior preserves under linear transformations›

lemma rel_interior_translation_aux:
  fixes a :: "'n::euclidean_space"
  shows "((λx. a + x) ` rel_interior S) ⊆ rel_interior ((λx. a + x) ` S)"
proof -
  {
    fix x
    assume x: "x ∈ rel_interior S"
    then obtain T where "open T" "x ∈ T ∩ S" "T ∩ affine hull S ⊆ S"
      using mem_rel_interior[of x S] by auto
    then have "open ((λx. a + x) ` T)"
      and "a + x ∈ ((λx. a + x) ` T) ∩ ((λx. a + x) ` S)"
      and "((λx. a + x) ` T) ∩ affine hull ((λx. a + x) ` S) ⊆ (λx. a + x) ` S"
      using affine_hull_translation[of a S] open_translation[of T a] x by auto
    then have "a + x ∈ rel_interior ((λx. a + x) ` S)"
      using mem_rel_interior[of "a+x" "((λx. a + x) ` S)"] by auto
  }
  then show ?thesis by auto
qed

lemma rel_interior_translation:
  fixes a :: "'n::euclidean_space"
  shows "rel_interior ((λx. a + x) ` S) = (λx. a + x) ` rel_interior S"
proof -
  have "(λx. (-a) + x) ` rel_interior ((λx. a + x) ` S) ⊆ rel_interior S"
    using rel_interior_translation_aux[of "-a" "(λx. a + x) ` S"]
      translation_assoc[of "-a" "a"]
    by auto
  then have "((λx. a + x) ` rel_interior S) ⊇ rel_interior ((λx. a + x) ` S)"
    using translation_inverse_subset[of a "rel_interior (op + a ` S)" "rel_interior S"]
    by auto
  then show ?thesis
    using rel_interior_translation_aux[of a S] by auto
qed


lemma affine_hull_linear_image:
  assumes "bounded_linear f"
  shows "f ` (affine hull s) = affine hull f ` s"
  apply rule
  unfolding subset_eq ball_simps
  apply (rule_tac[!] hull_induct, rule hull_inc)
  prefer 3
  apply (erule imageE)
  apply (rule_tac x=xa in image_eqI)
  apply assumption
  apply (rule hull_subset[unfolded subset_eq, rule_format])
  apply assumption
proof -
  interpret f: bounded_linear f by fact
  show "affine {x. f x ∈ affine hull f ` s}"
    unfolding affine_def
    by (auto simp add: f.scaleR f.add affine_affine_hull[unfolded affine_def, rule_format])
  show "affine {x. x ∈ f ` (affine hull s)}"
    using affine_affine_hull[unfolded affine_def, of s]
    unfolding affine_def by (auto simp add: f.scaleR [symmetric] f.add [symmetric])
qed auto


lemma rel_interior_injective_on_span_linear_image:
  fixes f :: "'m::euclidean_space ⇒ 'n::euclidean_space"
    and S :: "'m::euclidean_space set"
  assumes "bounded_linear f"
    and "inj_on f (span S)"
  shows "rel_interior (f ` S) = f ` (rel_interior S)"
proof -
  {
    fix z
    assume z: "z ∈ rel_interior (f ` S)"
    then have "z ∈ f ` S"
      using rel_interior_subset[of "f ` S"] by auto
    then obtain x where x: "x ∈ S" "f x = z" by auto
    obtain e2 where e2: "e2 > 0" "cball z e2 ∩ affine hull (f ` S) ⊆ (f ` S)"
      using z rel_interior_cball[of "f ` S"] by auto
    obtain K where K: "K > 0" "⋀x. norm (f x) ≤ norm x * K"
     using assms Real_Vector_Spaces.bounded_linear.pos_bounded[of f] by auto
    def e1  "1 / K"
    then have e1: "e1 > 0" "⋀x. e1 * norm (f x) ≤ norm x"
      using K pos_le_divide_eq[of e1] by auto
    def e  "e1 * e2"
    then have "e > 0" using e1 e2 by auto
    {
      fix y
      assume y: "y ∈ cball x e ∩ affine hull S"
      then have h1: "f y ∈ affine hull (f ` S)"
        using affine_hull_linear_image[of f S] assms by auto
      from y have "norm (x-y) ≤ e1 * e2"
        using cball_def[of x e] dist_norm[of x y] e_def by auto
      moreover have "f x - f y = f (x - y)"
        using assms linear_sub[of f x y] linear_conv_bounded_linear[of f] by auto
      moreover have "e1 * norm (f (x-y)) ≤ norm (x - y)"
        using e1 by auto
      ultimately have "e1 * norm ((f x)-(f y)) ≤ e1 * e2"
        by auto
      then have "f y ∈ cball z e2"
        using cball_def[of "f x" e2] dist_norm[of "f x" "f y"] e1 x by auto
      then have "f y ∈ f ` S"
        using y e2 h1 by auto
      then have "y ∈ S"
        using assms y hull_subset[of S] affine_hull_subset_span
          inj_on_image_mem_iff [OF ‹inj_on f (span S)›]
        by (metis Int_iff span_inc subsetCE)
    }
    then have "z ∈ f ` (rel_interior S)"
      using mem_rel_interior_cball[of x S] ‹e > 0› x by auto
  }
  moreover
  {
    fix x
    assume x: "x ∈ rel_interior S"
    then obtain e2 where e2: "e2 > 0" "cball x e2 ∩ affine hull S ⊆ S"
      using rel_interior_cball[of S] by auto
    have "x ∈ S" using x rel_interior_subset by auto
    then have *: "f x ∈ f ` S" by auto
    have "∀x∈span S. f x = 0 ⟶ x = 0"
      using assms subspace_span linear_conv_bounded_linear[of f]
        linear_injective_on_subspace_0[of f "span S"]
      by auto
    then obtain e1 where e1: "e1 > 0" "∀x ∈ span S. e1 * norm x ≤ norm (f x)"
      using assms injective_imp_isometric[of "span S" f]
        subspace_span[of S] closed_subspace[of "span S"]
      by auto
    def e  "e1 * e2"
    hence "e > 0" using e1 e2 by auto
    {
      fix y
      assume y: "y ∈ cball (f x) e ∩ affine hull (f ` S)"
      then have "y ∈ f ` (affine hull S)"
        using affine_hull_linear_image[of f S] assms by auto
      then obtain xy where xy: "xy ∈ affine hull S" "f xy = y" by auto
      with y have "norm (f x - f xy) ≤ e1 * e2"
        using cball_def[of "f x" e] dist_norm[of "f x" y] e_def by auto
      moreover have "f x - f xy = f (x - xy)"
        using assms linear_sub[of f x xy] linear_conv_bounded_linear[of f] by auto
      moreover have *: "x - xy ∈ span S"
        using subspace_sub[of "span S" x xy] subspace_span ‹x ∈ S› xy
          affine_hull_subset_span[of S] span_inc
        by auto
      moreover from * have "e1 * norm (x - xy) ≤ norm (f (x - xy))"
        using e1 by auto
      ultimately have "e1 * norm (x - xy) ≤ e1 * e2"
        by auto
      then have "xy ∈ cball x e2"
        using cball_def[of x e2] dist_norm[of x xy] e1 by auto
      then have "y ∈ f ` S"
        using xy e2 by auto
    }
    then have "f x ∈ rel_interior (f ` S)"
      using mem_rel_interior_cball[of "(f x)" "(f ` S)"] * ‹e > 0› by auto
  }
  ultimately show ?thesis by auto
qed

lemma rel_interior_injective_linear_image:
  fixes f :: "'m::euclidean_space ⇒ 'n::euclidean_space"
  assumes "bounded_linear f"
    and "inj f"
  shows "rel_interior (f ` S) = f ` (rel_interior S)"
  using assms rel_interior_injective_on_span_linear_image[of f S]
    subset_inj_on[of f "UNIV" "span S"]
  by auto


subsection‹Some Properties of subset of standard basis›

lemma affine_hull_substd_basis:
  assumes "d ⊆ Basis"
  shows "affine hull (insert 0 d) = {x::'a::euclidean_space. ∀i∈Basis. i ∉ d ⟶ x∙i = 0}"
  (is "affine hull (insert 0 ?A) = ?B")
proof -
  have *: "⋀A. op + (0::'a) ` A = A" "⋀A. op + (- (0::'a)) ` A = A"
    by auto
  show ?thesis
    unfolding affine_hull_insert_span_gen span_substd_basis[OF assms,symmetric] * ..
qed

lemma affine_hull_convex_hull [simp]: "affine hull (convex hull S) = affine hull S"
  by (metis Int_absorb1 Int_absorb2 convex_hull_subset_affine_hull hull_hull hull_mono hull_subset)


subsection ‹Openness and compactness are preserved by convex hull operation.›

lemma open_convex_hull[intro]:
  fixes s :: "'a::real_normed_vector set"
  assumes "open s"
  shows "open (convex hull s)"
  unfolding open_contains_cball convex_hull_explicit
  unfolding mem_Collect_eq ball_simps(8)
proof (rule, rule)
  fix a
  assume "∃sa u. finite sa ∧ sa ⊆ s ∧ (∀x∈sa. 0 ≤ u x) ∧ setsum u sa = 1 ∧ (∑v∈sa. u v *R v) = a"
  then obtain t u where obt: "finite t" "t⊆s" "∀x∈t. 0 ≤ u x" "setsum u t = 1" "(∑v∈t. u v *R v) = a"
    by auto

  from assms[unfolded open_contains_cball] obtain b
    where b: "∀x∈s. 0 < b x ∧ cball x (b x) ⊆ s"
    using bchoice[of s "λx e. e > 0 ∧ cball x e ⊆ s"] by auto
  have "b ` t ≠ {}"
    using obt by auto
  def i  "b ` t"

  show "∃e > 0.
    cball a e ⊆ {y. ∃sa u. finite sa ∧ sa ⊆ s ∧ (∀x∈sa. 0 ≤ u x) ∧ setsum u sa = 1 ∧ (∑v∈sa. u v *R v) = y}"
    apply (rule_tac x = "Min i" in exI)
    unfolding subset_eq
    apply rule
    defer
    apply rule
    unfolding mem_Collect_eq
  proof -
    show "0 < Min i"
      unfolding i_def and Min_gr_iff[OF finite_imageI[OF obt(1)] ‹b ` t≠{}›]
      using b
      apply simp
      apply rule
      apply (erule_tac x=x in ballE)
      using ‹t⊆s›
      apply auto
      done
  next
    fix y
    assume "y ∈ cball a (Min i)"
    then have y: "norm (a - y) ≤ Min i"
      unfolding dist_norm[symmetric] by auto
    {
      fix x
      assume "x ∈ t"
      then have "Min i ≤ b x"
        unfolding i_def
        apply (rule_tac Min_le)
        using obt(1)
        apply auto
        done
      then have "x + (y - a) ∈ cball x (b x)"
        using y unfolding mem_cball dist_norm by auto
      moreover from ‹x∈t› have "x ∈ s"
        using obt(2) by auto
      ultimately have "x + (y - a) ∈ s"
        using y and b[THEN bspec[where x=x]] unfolding subset_eq by fast
    }
    moreover
    have *: "inj_on (λv. v + (y - a)) t"
      unfolding inj_on_def by auto
    have "(∑v∈(λv. v + (y - a)) ` t. u (v - (y - a))) = 1"
      unfolding setsum.reindex[OF *] o_def using obt(4) by auto
    moreover have "(∑v∈(λv. v + (y - a)) ` t. u (v - (y - a)) *R v) = y"
      unfolding setsum.reindex[OF *] o_def using obt(4,5)
      by (simp add: setsum.distrib setsum_subtractf scaleR_left.setsum[symmetric] scaleR_right_distrib)
    ultimately
    show "∃sa u. finite sa ∧ (∀x∈sa. x ∈ s) ∧ (∀x∈sa. 0 ≤ u x) ∧ setsum u sa = 1 ∧ (∑v∈sa. u v *R v) = y"
      apply (rule_tac x="(λv. v + (y - a)) ` t" in exI)
      apply (rule_tac x="λv. u (v - (y - a))" in exI)
      using obt(1, 3)
      apply auto
      done
  qed
qed

lemma compact_convex_combinations:
  fixes s t :: "'a::real_normed_vector set"
  assumes "compact s" "compact t"
  shows "compact { (1 - u) *R x + u *R y | x y u. 0 ≤ u ∧ u ≤ 1 ∧ x ∈ s ∧ y ∈ t}"
proof -
  let ?X = "{0..1} × s × t"
  let ?h = "(λz. (1 - fst z) *R fst (snd z) + fst z *R snd (snd z))"
  have *: "{ (1 - u) *R x + u *R y | x y u. 0 ≤ u ∧ u ≤ 1 ∧ x ∈ s ∧ y ∈ t} = ?h ` ?X"
    apply (rule set_eqI)
    unfolding image_iff mem_Collect_eq
    apply rule
    apply auto
    apply (rule_tac x=u in rev_bexI)
    apply simp
    apply (erule rev_bexI)
    apply (erule rev_bexI)
    apply simp
    apply auto
    done
  have "continuous_on ?X (λz. (1 - fst z) *R fst (snd z) + fst z *R snd (snd z))"
    unfolding continuous_on by (rule ballI) (intro tendsto_intros)
  then show ?thesis
    unfolding *
    apply (rule compact_continuous_image)
    apply (intro compact_Times compact_Icc assms)
    done
qed

lemma finite_imp_compact_convex_hull:
  fixes s :: "'a::real_normed_vector set"
  assumes "finite s"
  shows "compact (convex hull s)"
proof (cases "s = {}")
  case True
  then show ?thesis by simp
next
  case False
  with assms show ?thesis
  proof (induct rule: finite_ne_induct)
    case (singleton x)
    show ?case by simp
  next
    case (insert x A)
    let ?f = "λ(u, y::'a). u *R x + (1 - u) *R y"
    let ?T = "{0..1::real} × (convex hull A)"
    have "continuous_on ?T ?f"
      unfolding split_def continuous_on by (intro ballI tendsto_intros)
    moreover have "compact ?T"
      by (intro compact_Times compact_Icc insert)
    ultimately have "compact (?f ` ?T)"
      by (rule compact_continuous_image)
    also have "?f ` ?T = convex hull (insert x A)"
      unfolding convex_hull_insert [OF ‹A ≠ {}›]
      apply safe
      apply (rule_tac x=a in exI, simp)
      apply (rule_tac x="1 - a" in exI, simp)
      apply fast
      apply (rule_tac x="(u, b)" in image_eqI, simp_all)
      done
    finally show "compact (convex hull (insert x A))" .
  qed
qed

lemma compact_convex_hull:
  fixes s :: "'a::euclidean_space set"
  assumes "compact s"
  shows "compact (convex hull s)"
proof (cases "s = {}")
  case True
  then show ?thesis using compact_empty by simp
next
  case False
  then obtain w where "w ∈ s" by auto
  show ?thesis
    unfolding caratheodory[of s]
  proof (induct ("DIM('a) + 1"))
    case 0
    have *: "{x.∃sa. finite sa ∧ sa ⊆ s ∧ card sa ≤ 0 ∧ x ∈ convex hull sa} = {}"
      using compact_empty by auto
    from 0 show ?case unfolding * by simp
  next
    case (Suc n)
    show ?case
    proof (cases "n = 0")
      case True
      have "{x. ∃t. finite t ∧ t ⊆ s ∧ card t ≤ Suc n ∧ x ∈ convex hull t} = s"
        unfolding set_eq_iff and mem_Collect_eq
      proof (rule, rule)
        fix x
        assume "∃t. finite t ∧ t ⊆ s ∧ card t ≤ Suc n ∧ x ∈ convex hull t"
        then obtain t where t: "finite t" "t ⊆ s" "card t ≤ Suc n" "x ∈ convex hull t"
          by auto
        show "x ∈ s"
        proof (cases "card t = 0")
          case True
          then show ?thesis
            using t(4) unfolding card_0_eq[OF t(1)] by simp
        next
          case False
          then have "card t = Suc 0" using t(3) ‹n=0› by auto
          then obtain a where "t = {a}" unfolding card_Suc_eq by auto
          then show ?thesis using t(2,4) by simp
        qed
      next
        fix x assume "x∈s"
        then show "∃t. finite t ∧ t ⊆ s ∧ card t ≤ Suc n ∧ x ∈ convex hull t"
          apply (rule_tac x="{x}" in exI)
          unfolding convex_hull_singleton
          apply auto
          done
      qed
      then show ?thesis using assms by simp
    next
      case False
      have "{x. ∃t. finite t ∧ t ⊆ s ∧ card t ≤ Suc n ∧ x ∈ convex hull t} =
        {(1 - u) *R x + u *R y | x y u.
          0 ≤ u ∧ u ≤ 1 ∧ x ∈ s ∧ y ∈ {x. ∃t. finite t ∧ t ⊆ s ∧ card t ≤ n ∧ x ∈ convex hull t}}"
        unfolding set_eq_iff and mem_Collect_eq
      proof (rule, rule)
        fix x
        assume "∃u v c. x = (1 - c) *R u + c *R v ∧
          0 ≤ c ∧ c ≤ 1 ∧ u ∈ s ∧ (∃t. finite t ∧ t ⊆ s ∧ card t ≤ n ∧ v ∈ convex hull t)"
        then obtain u v c t where obt: "x = (1 - c) *R u + c *R v"
          "0 ≤ c ∧ c ≤ 1" "u ∈ s" "finite t" "t ⊆ s" "card t ≤ n"  "v ∈ convex hull t"
          by auto
        moreover have "(1 - c) *R u + c *R v ∈ convex hull insert u t"
          apply (rule convexD_alt)
          using obt(2) and convex_convex_hull and hull_subset[of "insert u t" convex]
          using obt(7) and hull_mono[of t "insert u t"]
          apply auto
          done
        ultimately show "∃t. finite t ∧ t ⊆ s ∧ card t ≤ Suc n ∧ x ∈ convex hull t"
          apply (rule_tac x="insert u t" in exI)
          apply (auto simp add: card_insert_if)
          done
      next
        fix x
        assume "∃t. finite t ∧ t ⊆ s ∧ card t ≤ Suc n ∧ x ∈ convex hull t"
        then obtain t where t: "finite t" "t ⊆ s" "card t ≤ Suc n" "x ∈ convex hull t"
          by auto
        show "∃u v c. x = (1 - c) *R u + c *R v ∧
          0 ≤ c ∧ c ≤ 1 ∧ u ∈ s ∧ (∃t. finite t ∧ t ⊆ s ∧ card t ≤ n ∧ v ∈ convex hull t)"
        proof (cases "card t = Suc n")
          case False
          then have "card t ≤ n" using t(3) by auto
          then show ?thesis
            apply (rule_tac x=w in exI, rule_tac x=x in exI, rule_tac x=1 in exI)
            using ‹w∈s› and t
            apply (auto intro!: exI[where x=t])
            done
        next
          case True
          then obtain a u where au: "t = insert a u" "a∉u"
            apply (drule_tac card_eq_SucD)
            apply auto
            done
          show ?thesis
          proof (cases "u = {}")
            case True
            then have "x = a" using t(4)[unfolded au] by auto
            show ?thesis unfolding ‹x = a›
              apply (rule_tac x=a in exI)
              apply (rule_tac x=a in exI)
              apply (rule_tac x=1 in exI)
              using t and ‹n ≠ 0›
              unfolding au
              apply (auto intro!: exI[where x="{a}"])
              done
          next
            case False
            obtain ux vx b where obt: "ux≥0" "vx≥0" "ux + vx = 1"
              "b ∈ convex hull u" "x = ux *R a + vx *R b"
              using t(4)[unfolded au convex_hull_insert[OF False]]
              by auto
            have *: "1 - vx = ux" using obt(3) by auto
            show ?thesis
              apply (rule_tac x=a in exI)
              apply (rule_tac x=b in exI)
              apply (rule_tac x=vx in exI)
              using obt and t(1-3)
              unfolding au and * using card_insert_disjoint[OF _ au(2)]
              apply (auto intro!: exI[where x=u])
              done
          qed
        qed
      qed
      then show ?thesis
        using compact_convex_combinations[OF assms Suc] by simp
    qed
  qed
qed


subsection ‹Extremal points of a simplex are some vertices.›

lemma dist_increases_online:
  fixes a b d :: "'a::real_inner"
  assumes "d ≠ 0"
  shows "dist a (b + d) > dist a b ∨ dist a (b - d) > dist a b"
proof (cases "inner a d - inner b d > 0")
  case True
  then have "0 < inner d d + (inner a d * 2 - inner b d * 2)"
    apply (rule_tac add_pos_pos)
    using assms
    apply auto
    done
  then show ?thesis
    apply (rule_tac disjI2)
    unfolding dist_norm and norm_eq_sqrt_inner and real_sqrt_less_iff
    apply  (simp add: algebra_simps inner_commute)
    done
next
  case False
  then have "0 < inner d d + (inner b d * 2 - inner a d * 2)"
    apply (rule_tac add_pos_nonneg)
    using assms
    apply auto
    done
  then show ?thesis
    apply (rule_tac disjI1)
    unfolding dist_norm and norm_eq_sqrt_inner and real_sqrt_less_iff
    apply (simp add: algebra_simps inner_commute)
    done
qed

lemma norm_increases_online:
  fixes d :: "'a::real_inner"
  shows "d ≠ 0 ⟹ norm (a + d) > norm a ∨ norm(a - d) > norm a"
  using dist_increases_online[of d a 0] unfolding dist_norm by auto

lemma simplex_furthest_lt:
  fixes s :: "'a::real_inner set"
  assumes "finite s"
  shows "∀x ∈ convex hull s.  x ∉ s ⟶ (∃y ∈ convex hull s. norm (x - a) < norm(y - a))"
  using assms
proof induct
  fix x s
  assume as: "finite s" "x∉s" "∀x∈convex hull s. x ∉ s ⟶ (∃y∈convex hull s. norm (x - a) < norm (y - a))"
  show "∀xa∈convex hull insert x s. xa ∉ insert x s ⟶
    (∃y∈convex hull insert x s. norm (xa - a) < norm (y - a))"
  proof (rule, rule, cases "s = {}")
    case False
    fix y
    assume y: "y ∈ convex hull insert x s" "y ∉ insert x s"
    obtain u v b where obt: "u≥0" "v≥0" "u + v = 1" "b ∈ convex hull s" "y = u *R x + v *R b"
      using y(1)[unfolded convex_hull_insert[OF False]] by auto
    show "∃z∈convex hull insert x s. norm (y - a) < norm (z - a)"
    proof (cases "y ∈ convex hull s")
      case True
      then obtain z where "z ∈ convex hull s" "norm (y - a) < norm (z - a)"
        using as(3)[THEN bspec[where x=y]] and y(2) by auto
      then show ?thesis
        apply (rule_tac x=z in bexI)
        unfolding convex_hull_insert[OF False]
        apply auto
        done
    next
      case False
      show ?thesis
        using obt(3)
      proof (cases "u = 0", case_tac[!] "v = 0")
        assume "u = 0" "v ≠ 0"
        then have "y = b" using obt by auto
        then show ?thesis using False and obt(4) by auto
      next
        assume "u ≠ 0" "v = 0"
        then have "y = x" using obt by auto
        then show ?thesis using y(2) by auto
      next
        assume "u ≠ 0" "v ≠ 0"
        then obtain w where w: "w>0" "w<u" "w<v"
          using real_lbound_gt_zero[of u v] and obt(1,2) by auto
        have "x ≠ b"
        proof
          assume "x = b"
          then have "y = b" unfolding obt(5)
            using obt(3) by (auto simp add: scaleR_left_distrib[symmetric])
          then show False using obt(4) and False by simp
        qed
        then have *: "w *R (x - b) ≠ 0" using w(1) by auto
        show ?thesis
          using dist_increases_online[OF *, of a y]
        proof (elim disjE)
          assume "dist a y < dist a (y + w *R (x - b))"
          then have "norm (y - a) < norm ((u + w) *R x + (v - w) *R b - a)"
            unfolding dist_commute[of a]
            unfolding dist_norm obt(5)
            by (simp add: algebra_simps)
          moreover have "(u + w) *R x + (v - w) *R b ∈ convex hull insert x s"
            unfolding convex_hull_insert[OF ‹s≠{}›] and mem_Collect_eq
            apply (rule_tac x="u + w" in exI)
            apply rule
            defer
            apply (rule_tac x="v - w" in exI)
            using ‹u ≥ 0› and w and obt(3,4)
            apply auto
            done
          ultimately show ?thesis by auto
        next
          assume "dist a y < dist a (y - w *R (x - b))"
          then have "norm (y - a) < norm ((u - w) *R x + (v + w) *R b - a)"
            unfolding dist_commute[of a]
            unfolding dist_norm obt(5)
            by (simp add: algebra_simps)
          moreover have "(u - w) *R x + (v + w) *R b ∈ convex hull ins