Theory Cartesian_Euclidean_Space

theory Cartesian_Euclidean_Space
imports Finite_Cartesian_Product Integration
header {*Instanciates the finite cartesian product of euclidean spaces as a euclidean space.*}

theory Cartesian_Euclidean_Space
imports Finite_Cartesian_Product Integration
begin

lemma delta_mult_idempotent:
"(if k=a then 1 else (0::'a::semiring_1)) * (if k=a then 1 else 0) = (if k=a then 1 else 0)"
by (cases "k=a") auto

lemma setsum_Plus:
"[|finite A; finite B|] ==>
(∑x∈A <+> B. g x) = (∑x∈A. g (Inl x)) + (∑x∈B. g (Inr x))"

unfolding Plus_def
by (subst setsum_Un_disjoint, auto simp add: setsum_reindex)

lemma setsum_UNIV_sum:
fixes g :: "'a::finite + 'b::finite => _"
shows "(∑x∈UNIV. g x) = (∑x∈UNIV. g (Inl x)) + (∑x∈UNIV. g (Inr x))"
apply (subst UNIV_Plus_UNIV [symmetric])
apply (rule setsum_Plus [OF finite finite])
done

lemma setsum_mult_product:
"setsum h {..<A * B :: nat} = (∑i∈{..<A}. ∑j∈{..<B}. h (j + i * B))"
unfolding sumr_group[of h B A, unfolded atLeast0LessThan, symmetric]
proof (rule setsum_cong, simp, rule setsum_reindex_cong)
fix i
show "inj_on (λj. j + i * B) {..<B}" by (auto intro!: inj_onI)
show "{i * B..<i * B + B} = (λj. j + i * B) ` {..<B}"
proof safe
fix j assume "j ∈ {i * B..<i * B + B}"
then show "j ∈ (λj. j + i * B) ` {..<B}"
by (auto intro!: image_eqI[of _ _ "j - i * B"])
qed simp
qed simp


subsection{* Basic componentwise operations on vectors. *}

instantiation vec :: (times, finite) times
begin

definition "op * ≡ (λ x y. (χ i. (x$i) * (y$i)))"
instance ..

end

instantiation vec :: (one, finite) one
begin

definition "1 ≡ (χ i. 1)"
instance ..

end

instantiation vec :: (ord, finite) ord
begin

definition "x ≤ y <-> (∀i. x$i ≤ y$i)"
definition "x < y <-> (∀i. x$i < y$i)"
instance ..

end

text{* The ordering on one-dimensional vectors is linear. *}

class cart_one =
assumes UNIV_one: "card (UNIV :: 'a set) = Suc 0"
begin

subclass finite
proof
from UNIV_one show "finite (UNIV :: 'a set)"
by (auto intro!: card_ge_0_finite)
qed

end

instantiation vec :: (linorder, cart_one) linorder
begin

instance
proof
obtain a :: 'b where all: "!!P. (∀i. P i) <-> P a"
proof -
have "card (UNIV :: 'b set) = Suc 0" by (rule UNIV_one)
then obtain b :: 'b where "UNIV = {b}" by (auto iff: card_Suc_eq)
then have "!!P. (∀i∈UNIV. P i) <-> P b" by auto
then show thesis by (auto intro: that)
qed

note [simp] = less_eq_vec_def less_vec_def all vec_eq_iff field_simps
fix x y z :: "'a^'b::cart_one"
show "x ≤ x" "(x < y) = (x ≤ y ∧ ¬ y ≤ x)" "x ≤ y ∨ y ≤ x" by auto
{ assume "x≤y" "y≤z" then show "x≤z" by auto }
{ assume "x≤y" "y≤x" then show "x=y" by auto }
qed

end

text{* Constant Vectors *}

definition "vec x = (χ i. x)"

text{* Also the scalar-vector multiplication. *}

definition vector_scalar_mult:: "'a::times => 'a ^ 'n => 'a ^ 'n" (infixl "*s" 70)
where "c *s x = (χ i. c * (x$i))"


subsection {* A naive proof procedure to lift really trivial arithmetic stuff from the basis of the vector space. *}

method_setup vector = {*
let
val ss1 =
simpset_of (put_simpset HOL_basic_ss @{context}
addsimps [@{thm setsum_addf} RS sym,
@{thm setsum_subtractf} RS sym, @{thm setsum_right_distrib},
@{thm setsum_left_distrib}, @{thm setsum_negf} RS sym])
val ss2 =
simpset_of (@{context} addsimps
[@{thm plus_vec_def}, @{thm times_vec_def},
@{thm minus_vec_def}, @{thm uminus_vec_def},
@{thm one_vec_def}, @{thm zero_vec_def}, @{thm vec_def},
@{thm scaleR_vec_def},
@{thm vec_lambda_beta}, @{thm vector_scalar_mult_def}])
fun vector_arith_tac ctxt ths =
simp_tac (put_simpset ss1 ctxt)
THEN' (fn i => rtac @{thm setsum_cong2} i
ORELSE rtac @{thm setsum_0'} i
ORELSE simp_tac (put_simpset HOL_basic_ss ctxt addsimps [@{thm vec_eq_iff}]) i)
(* THEN' TRY o clarify_tac HOL_cs THEN' (TRY o rtac @{thm iffI}) *)
THEN' asm_full_simp_tac (put_simpset ss2 ctxt addsimps ths)
in
Attrib.thms >> (fn ths => fn ctxt => SIMPLE_METHOD' (vector_arith_tac ctxt ths))
end
*}
"lift trivial vector statements to real arith statements"

lemma vec_0[simp]: "vec 0 = 0" by (vector zero_vec_def)
lemma vec_1[simp]: "vec 1 = 1" by (vector one_vec_def)

lemma vec_inj[simp]: "vec x = vec y <-> x = y" by vector

lemma vec_in_image_vec: "vec x ∈ (vec ` S) <-> x ∈ S" by auto

lemma vec_add: "vec(x + y) = vec x + vec y" by (vector vec_def)
lemma vec_sub: "vec(x - y) = vec x - vec y" by (vector vec_def)
lemma vec_cmul: "vec(c * x) = c *s vec x " by (vector vec_def)
lemma vec_neg: "vec(- x) = - vec x " by (vector vec_def)

lemma vec_setsum:
assumes "finite S"
shows "vec(setsum f S) = setsum (vec o f) S"
using assms
proof induct
case empty
then show ?case by simp
next
case insert
then show ?case by (auto simp add: vec_add)
qed

text{* Obvious "component-pushing". *}

lemma vec_component [simp]: "vec x $ i = x"
by (vector vec_def)

lemma vector_mult_component [simp]: "(x * y)$i = x$i * y$i"
by vector

lemma vector_smult_component [simp]: "(c *s y)$i = c * (y$i)"
by vector

lemma cond_component: "(if b then x else y)$i = (if b then x$i else y$i)" by vector

lemmas vector_component =
vec_component vector_add_component vector_mult_component
vector_smult_component vector_minus_component vector_uminus_component
vector_scaleR_component cond_component


subsection {* Some frequently useful arithmetic lemmas over vectors. *}

instance vec :: (semigroup_mult, finite) semigroup_mult
by default (vector mult_assoc)

instance vec :: (monoid_mult, finite) monoid_mult
by default vector+

instance vec :: (ab_semigroup_mult, finite) ab_semigroup_mult
by default (vector mult_commute)

instance vec :: (comm_monoid_mult, finite) comm_monoid_mult
by default vector

instance vec :: (semiring, finite) semiring
by default (vector field_simps)+

instance vec :: (semiring_0, finite) semiring_0
by default (vector field_simps)+
instance vec :: (semiring_1, finite) semiring_1
by default vector
instance vec :: (comm_semiring, finite) comm_semiring
by default (vector field_simps)+

instance vec :: (comm_semiring_0, finite) comm_semiring_0 ..
instance vec :: (cancel_comm_monoid_add, finite) cancel_comm_monoid_add ..
instance vec :: (semiring_0_cancel, finite) semiring_0_cancel ..
instance vec :: (comm_semiring_0_cancel, finite) comm_semiring_0_cancel ..
instance vec :: (ring, finite) ring ..
instance vec :: (semiring_1_cancel, finite) semiring_1_cancel ..
instance vec :: (comm_semiring_1, finite) comm_semiring_1 ..

instance vec :: (ring_1, finite) ring_1 ..

instance vec :: (real_algebra, finite) real_algebra
by default (simp_all add: vec_eq_iff)

instance vec :: (real_algebra_1, finite) real_algebra_1 ..

lemma of_nat_index: "(of_nat n :: 'a::semiring_1 ^'n)$i = of_nat n"
proof (induct n)
case 0
then show ?case by vector
next
case Suc
then show ?case by vector
qed

lemma one_index[simp]: "(1 :: 'a::one ^'n)$i = 1"
by vector

instance vec :: (semiring_char_0, finite) semiring_char_0
proof
fix m n :: nat
show "inj (of_nat :: nat => 'a ^ 'b)"
by (auto intro!: injI simp add: vec_eq_iff of_nat_index)
qed

instance vec :: (numeral, finite) numeral ..
instance vec :: (semiring_numeral, finite) semiring_numeral ..

lemma numeral_index [simp]: "numeral w $ i = numeral w"
by (induct w) (simp_all only: numeral.simps vector_add_component one_index)

lemma neg_numeral_index [simp]: "neg_numeral w $ i = neg_numeral w"
by (simp only: neg_numeral_def vector_uminus_component numeral_index)

instance vec :: (comm_ring_1, finite) comm_ring_1 ..
instance vec :: (ring_char_0, finite) ring_char_0 ..

lemma vector_smult_assoc: "a *s (b *s x) = ((a::'a::semigroup_mult) * b) *s x"
by (vector mult_assoc)
lemma vector_sadd_rdistrib: "((a::'a::semiring) + b) *s x = a *s x + b *s x"
by (vector field_simps)
lemma vector_add_ldistrib: "(c::'a::semiring) *s (x + y) = c *s x + c *s y"
by (vector field_simps)
lemma vector_smult_lzero[simp]: "(0::'a::mult_zero) *s x = 0" by vector
lemma vector_smult_lid[simp]: "(1::'a::monoid_mult) *s x = x" by vector
lemma vector_ssub_ldistrib: "(c::'a::ring) *s (x - y) = c *s x - c *s y"
by (vector field_simps)
lemma vector_smult_rneg: "(c::'a::ring) *s -x = -(c *s x)" by vector
lemma vector_smult_lneg: "- (c::'a::ring) *s x = -(c *s x)" by vector
lemma vector_sneg_minus1: "-x = (-1::'a::ring_1) *s x" by vector
lemma vector_smult_rzero[simp]: "c *s 0 = (0::'a::mult_zero ^ 'n)" by vector
lemma vector_sub_rdistrib: "((a::'a::ring) - b) *s x = a *s x - b *s x"
by (vector field_simps)

lemma vec_eq[simp]: "(vec m = vec n) <-> (m = n)"
by (simp add: vec_eq_iff)

lemma norm_eq_0_imp: "norm x = 0 ==> x = (0::real ^'n)" by (metis norm_eq_zero)
lemma vector_mul_eq_0[simp]: "(a *s x = 0) <-> a = (0::'a::idom) ∨ x = 0"
by vector
lemma vector_mul_lcancel[simp]: "a *s x = a *s y <-> a = (0::real) ∨ x = y"
by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_ssub_ldistrib)
lemma vector_mul_rcancel[simp]: "a *s x = b *s x <-> (a::real) = b ∨ x = 0"
by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_sub_rdistrib)
lemma vector_mul_lcancel_imp: "a ≠ (0::real) ==> a *s x = a *s y ==> (x = y)"
by (metis vector_mul_lcancel)
lemma vector_mul_rcancel_imp: "x ≠ 0 ==> (a::real) *s x = b *s x ==> a = b"
by (metis vector_mul_rcancel)

lemma component_le_norm_cart: "¦x$i¦ <= norm x"
apply (simp add: norm_vec_def)
apply (rule member_le_setL2, simp_all)
done

lemma norm_bound_component_le_cart: "norm x <= e ==> ¦x$i¦ <= e"
by (metis component_le_norm_cart order_trans)

lemma norm_bound_component_lt_cart: "norm x < e ==> ¦x$i¦ < e"
by (metis component_le_norm_cart le_less_trans)

lemma norm_le_l1_cart: "norm x <= setsum(λi. ¦x$i¦) UNIV"
by (simp add: norm_vec_def setL2_le_setsum)

lemma scalar_mult_eq_scaleR: "c *s x = c *R x"
unfolding scaleR_vec_def vector_scalar_mult_def by simp

lemma dist_mul[simp]: "dist (c *s x) (c *s y) = ¦c¦ * dist x y"
unfolding dist_norm scalar_mult_eq_scaleR
unfolding scaleR_right_diff_distrib[symmetric] by simp

lemma setsum_component [simp]:
fixes f:: " 'a => ('b::comm_monoid_add) ^'n"
shows "(setsum f S)$i = setsum (λx. (f x)$i) S"
proof (cases "finite S")
case True
then show ?thesis by induct simp_all
next
case False
then show ?thesis by simp
qed

lemma setsum_eq: "setsum f S = (χ i. setsum (λx. (f x)$i ) S)"
by (simp add: vec_eq_iff)

lemma setsum_cmul:
fixes f:: "'c => ('a::semiring_1)^'n"
shows "setsum (λx. c *s f x) S = c *s setsum f S"
by (simp add: vec_eq_iff setsum_right_distrib)

lemma setsum_norm_allsubsets_bound_cart:
fixes f:: "'a => real ^'n"
assumes fP: "finite P" and fPs: "!!Q. Q ⊆ P ==> norm (setsum f Q) ≤ e"
shows "setsum (λx. norm (f x)) P ≤ 2 * real CARD('n) * e"
using setsum_norm_allsubsets_bound[OF assms]
by (simp add: DIM_cart Basis_real_def)

instance vec :: (ordered_euclidean_space, finite) ordered_euclidean_space
proof
fix x y::"'a^'b"
show "(x ≤ y) = (∀i∈Basis. x • i ≤ y • i)"
unfolding less_eq_vec_def apply(subst eucl_le) by (simp add: Basis_vec_def inner_axis)
show"(x < y) = (∀i∈Basis. x • i < y • i)"
unfolding less_vec_def apply(subst eucl_less) by (simp add: Basis_vec_def inner_axis)
qed

subsection {* Matrix operations *}

text{* Matrix notation. NB: an MxN matrix is of type @{typ "'a^'n^'m"}, not @{typ "'a^'m^'n"} *}

definition matrix_matrix_mult :: "('a::semiring_1) ^'n^'m => 'a ^'p^'n => 'a ^ 'p ^'m"
(infixl "**" 70)
where "m ** m' == (χ i j. setsum (λk. ((m$i)$k) * ((m'$k)$j)) (UNIV :: 'n set)) ::'a ^ 'p ^'m"

definition matrix_vector_mult :: "('a::semiring_1) ^'n^'m => 'a ^'n => 'a ^ 'm"
(infixl "*v" 70)
where "m *v x ≡ (χ i. setsum (λj. ((m$i)$j) * (x$j)) (UNIV ::'n set)) :: 'a^'m"

definition vector_matrix_mult :: "'a ^ 'm => ('a::semiring_1) ^'n^'m => 'a ^'n "
(infixl "v*" 70)
where "v v* m == (χ j. setsum (λi. ((m$i)$j) * (v$i)) (UNIV :: 'm set)) :: 'a^'n"

definition "(mat::'a::zero => 'a ^'n^'n) k = (χ i j. if i = j then k else 0)"
definition transpose where
"(transpose::'a^'n^'m => 'a^'m^'n) A = (χ i j. ((A$j)$i))"
definition "(row::'m => 'a ^'n^'m => 'a ^'n) i A = (χ j. ((A$i)$j))"
definition "(column::'n =>'a^'n^'m =>'a^'m) j A = (χ i. ((A$i)$j))"
definition "rows(A::'a^'n^'m) = { row i A | i. i ∈ (UNIV :: 'm set)}"
definition "columns(A::'a^'n^'m) = { column i A | i. i ∈ (UNIV :: 'n set)}"

lemma mat_0[simp]: "mat 0 = 0" by (vector mat_def)
lemma matrix_add_ldistrib: "(A ** (B + C)) = (A ** B) + (A ** C)"
by (vector matrix_matrix_mult_def setsum_addf[symmetric] field_simps)

lemma matrix_mul_lid:
fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
shows "mat 1 ** A = A"
apply (simp add: matrix_matrix_mult_def mat_def)
apply vector
apply (auto simp only: if_distrib cond_application_beta setsum_delta'[OF finite]
mult_1_left mult_zero_left if_True UNIV_I)
done


lemma matrix_mul_rid:
fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
shows "A ** mat 1 = A"
apply (simp add: matrix_matrix_mult_def mat_def)
apply vector
apply (auto simp only: if_distrib cond_application_beta setsum_delta[OF finite]
mult_1_right mult_zero_right if_True UNIV_I cong: if_cong)
done

lemma matrix_mul_assoc: "A ** (B ** C) = (A ** B) ** C"
apply (vector matrix_matrix_mult_def setsum_right_distrib setsum_left_distrib mult_assoc)
apply (subst setsum_commute)
apply simp
done

lemma matrix_vector_mul_assoc: "A *v (B *v x) = (A ** B) *v x"
apply (vector matrix_matrix_mult_def matrix_vector_mult_def
setsum_right_distrib setsum_left_distrib mult_assoc)
apply (subst setsum_commute)
apply simp
done

lemma matrix_vector_mul_lid: "mat 1 *v x = (x::'a::semiring_1 ^ 'n)"
apply (vector matrix_vector_mult_def mat_def)
apply (simp add: if_distrib cond_application_beta setsum_delta' cong del: if_weak_cong)
done

lemma matrix_transpose_mul:
"transpose(A ** B) = transpose B ** transpose (A::'a::comm_semiring_1^_^_)"
by (simp add: matrix_matrix_mult_def transpose_def vec_eq_iff mult_commute)

lemma matrix_eq:
fixes A B :: "'a::semiring_1 ^ 'n ^ 'm"
shows "A = B <-> (∀x. A *v x = B *v x)" (is "?lhs <-> ?rhs")
apply auto
apply (subst vec_eq_iff)
apply clarify
apply (clarsimp simp add: matrix_vector_mult_def if_distrib cond_application_beta vec_eq_iff cong del: if_weak_cong)
apply (erule_tac x="axis ia 1" in allE)
apply (erule_tac x="i" in allE)
apply (auto simp add: if_distrib cond_application_beta axis_def
setsum_delta[OF finite] cong del: if_weak_cong)
done

lemma matrix_vector_mul_component: "((A::real^_^_) *v x)$k = (A$k) • x"
by (simp add: matrix_vector_mult_def inner_vec_def)

lemma dot_lmul_matrix: "((x::real ^_) v* A) • y = x • (A *v y)"
apply (simp add: inner_vec_def matrix_vector_mult_def vector_matrix_mult_def setsum_left_distrib setsum_right_distrib mult_ac)
apply (subst setsum_commute)
apply simp
done

lemma transpose_mat: "transpose (mat n) = mat n"
by (vector transpose_def mat_def)

lemma transpose_transpose: "transpose(transpose A) = A"
by (vector transpose_def)

lemma row_transpose:
fixes A:: "'a::semiring_1^_^_"
shows "row i (transpose A) = column i A"
by (simp add: row_def column_def transpose_def vec_eq_iff)

lemma column_transpose:
fixes A:: "'a::semiring_1^_^_"
shows "column i (transpose A) = row i A"
by (simp add: row_def column_def transpose_def vec_eq_iff)

lemma rows_transpose: "rows(transpose (A::'a::semiring_1^_^_)) = columns A"
by (auto simp add: rows_def columns_def row_transpose intro: set_eqI)

lemma columns_transpose: "columns(transpose (A::'a::semiring_1^_^_)) = rows A"
by (metis transpose_transpose rows_transpose)

text{* Two sometimes fruitful ways of looking at matrix-vector multiplication. *}

lemma matrix_mult_dot: "A *v x = (χ i. A$i • x)"
by (simp add: matrix_vector_mult_def inner_vec_def)

lemma matrix_mult_vsum:
"(A::'a::comm_semiring_1^'n^'m) *v x = setsum (λi. (x$i) *s column i A) (UNIV:: 'n set)"
by (simp add: matrix_vector_mult_def vec_eq_iff column_def mult_commute)

lemma vector_componentwise:
"(x::'a::ring_1^'n) = (χ j. ∑i∈UNIV. (x$i) * (axis i 1 :: 'a^'n) $ j)"
by (simp add: axis_def if_distrib setsum_cases vec_eq_iff)

lemma basis_expansion: "setsum (λi. (x$i) *s axis i 1) UNIV = (x::('a::ring_1) ^'n)"
by (auto simp add: axis_def vec_eq_iff if_distrib setsum_cases cong del: if_weak_cong)

lemma linear_componentwise:
fixes f:: "real ^'m => real ^ _"
assumes lf: "linear f"
shows "(f x)$j = setsum (λi. (x$i) * (f (axis i 1)$j)) (UNIV :: 'm set)" (is "?lhs = ?rhs")
proof -
let ?M = "(UNIV :: 'm set)"
let ?N = "(UNIV :: 'n set)"
have fM: "finite ?M" by simp
have "?rhs = (setsum (λi.(x$i) *R f (axis i 1) ) ?M)$j"
unfolding setsum_component by simp
then show ?thesis
unfolding linear_setsum_mul[OF lf fM, symmetric]
unfolding scalar_mult_eq_scaleR[symmetric]
unfolding basis_expansion
by simp
qed

text{* Inverse matrices (not necessarily square) *}

definition
"invertible(A::'a::semiring_1^'n^'m) <-> (∃A'::'a^'m^'n. A ** A' = mat 1 ∧ A' ** A = mat 1)"

definition
"matrix_inv(A:: 'a::semiring_1^'n^'m) =
(SOME A'::'a^'m^'n. A ** A' = mat 1 ∧ A' ** A = mat 1)"


text{* Correspondence between matrices and linear operators. *}

definition matrix :: "('a::{plus,times, one, zero}^'m => 'a ^ 'n) => 'a^'m^'n"
where "matrix f = (χ i j. (f(axis j 1))$i)"

lemma matrix_vector_mul_linear: "linear(λx. A *v (x::real ^ _))"
by (simp add: linear_iff matrix_vector_mult_def vec_eq_iff
field_simps setsum_right_distrib setsum_addf)

lemma matrix_works:
assumes lf: "linear f"
shows "matrix f *v x = f (x::real ^ 'n)"
apply (simp add: matrix_def matrix_vector_mult_def vec_eq_iff mult_commute)
apply clarify
apply (rule linear_componentwise[OF lf, symmetric])
done

lemma matrix_vector_mul: "linear f ==> f = (λx. matrix f *v (x::real ^ 'n))"
by (simp add: ext matrix_works)

lemma matrix_of_matrix_vector_mul: "matrix(λx. A *v (x :: real ^ 'n)) = A"
by (simp add: matrix_eq matrix_vector_mul_linear matrix_works)

lemma matrix_compose:
assumes lf: "linear (f::real^'n => real^'m)"
and lg: "linear (g::real^'m => real^_)"
shows "matrix (g o f) = matrix g ** matrix f"
using lf lg linear_compose[OF lf lg] matrix_works[OF linear_compose[OF lf lg]]
by (simp add: matrix_eq matrix_works matrix_vector_mul_assoc[symmetric] o_def)

lemma matrix_vector_column:
"(A::'a::comm_semiring_1^'n^_) *v x = setsum (λi. (x$i) *s ((transpose A)$i)) (UNIV:: 'n set)"
by (simp add: matrix_vector_mult_def transpose_def vec_eq_iff mult_commute)

lemma adjoint_matrix: "adjoint(λx. (A::real^'n^'m) *v x) = (λx. transpose A *v x)"
apply (rule adjoint_unique)
apply (simp add: transpose_def inner_vec_def matrix_vector_mult_def
setsum_left_distrib setsum_right_distrib)
apply (subst setsum_commute)
apply (auto simp add: mult_ac)
done

lemma matrix_adjoint: assumes lf: "linear (f :: real^'n => real ^'m)"
shows "matrix(adjoint f) = transpose(matrix f)"
apply (subst matrix_vector_mul[OF lf])
unfolding adjoint_matrix matrix_of_matrix_vector_mul
apply rule
done


subsection {* lambda skolemization on cartesian products *}

(* FIXME: rename do choice_cart *)

lemma lambda_skolem: "(∀i. ∃x. P i x) <->
(∃x::'a ^ 'n. ∀i. P i (x $ i))"
(is "?lhs <-> ?rhs")
proof -
let ?S = "(UNIV :: 'n set)"
{ assume H: "?rhs"
then have ?lhs by auto }
moreover
{ assume H: "?lhs"
then obtain f where f:"∀i. P i (f i)" unfolding choice_iff by metis
let ?x = "(χ i. (f i)) :: 'a ^ 'n"
{ fix i
from f have "P i (f i)" by metis
then have "P i (?x $ i)" by auto
}
hence "∀i. P i (?x$i)" by metis
hence ?rhs by metis }
ultimately show ?thesis by metis
qed

lemma vector_sub_project_orthogonal_cart: "(b::real^'n) • (x - ((b • x) / (b • b)) *s b) = 0"
unfolding inner_simps scalar_mult_eq_scaleR by auto

lemma left_invertible_transpose:
"(∃(B). B ** transpose (A) = mat (1::'a::comm_semiring_1)) <-> (∃(B). A ** B = mat 1)"
by (metis matrix_transpose_mul transpose_mat transpose_transpose)

lemma right_invertible_transpose:
"(∃(B). transpose (A) ** B = mat (1::'a::comm_semiring_1)) <-> (∃(B). B ** A = mat 1)"
by (metis matrix_transpose_mul transpose_mat transpose_transpose)

lemma matrix_left_invertible_injective:
"(∃B. (B::real^'m^'n) ** (A::real^'n^'m) = mat 1) <-> (∀x y. A *v x = A *v y --> x = y)"
proof -
{ fix B:: "real^'m^'n" and x y assume B: "B ** A = mat 1" and xy: "A *v x = A*v y"
from xy have "B*v (A *v x) = B *v (A*v y)" by simp
hence "x = y"
unfolding matrix_vector_mul_assoc B matrix_vector_mul_lid . }
moreover
{ assume A: "∀x y. A *v x = A *v y --> x = y"
hence i: "inj (op *v A)" unfolding inj_on_def by auto
from linear_injective_left_inverse[OF matrix_vector_mul_linear i]
obtain g where g: "linear g" "g o op *v A = id" by blast
have "matrix g ** A = mat 1"
unfolding matrix_eq matrix_vector_mul_lid matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
using g(2) by (simp add: fun_eq_iff)
then have "∃B. (B::real ^'m^'n) ** A = mat 1" by blast }
ultimately show ?thesis by blast
qed

lemma matrix_left_invertible_ker:
"(∃B. (B::real ^'m^'n) ** (A::real^'n^'m) = mat 1) <-> (∀x. A *v x = 0 --> x = 0)"
unfolding matrix_left_invertible_injective
using linear_injective_0[OF matrix_vector_mul_linear, of A]
by (simp add: inj_on_def)

lemma matrix_right_invertible_surjective:
"(∃B. (A::real^'n^'m) ** (B::real^'m^'n) = mat 1) <-> surj (λx. A *v x)"
proof -
{ fix B :: "real ^'m^'n"
assume AB: "A ** B = mat 1"
{ fix x :: "real ^ 'm"
have "A *v (B *v x) = x"
by (simp add: matrix_vector_mul_lid matrix_vector_mul_assoc AB) }
hence "surj (op *v A)" unfolding surj_def by metis }
moreover
{ assume sf: "surj (op *v A)"
from linear_surjective_right_inverse[OF matrix_vector_mul_linear sf]
obtain g:: "real ^'m => real ^'n" where g: "linear g" "op *v A o g = id"
by blast

have "A ** (matrix g) = mat 1"
unfolding matrix_eq matrix_vector_mul_lid
matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
using g(2) unfolding o_def fun_eq_iff id_def
.
hence "∃B. A ** (B::real^'m^'n) = mat 1" by blast
}
ultimately show ?thesis unfolding surj_def by blast
qed

lemma matrix_left_invertible_independent_columns:
fixes A :: "real^'n^'m"
shows "(∃(B::real ^'m^'n). B ** A = mat 1) <->
(∀c. setsum (λi. c i *s column i A) (UNIV :: 'n set) = 0 --> (∀i. c i = 0))"

(is "?lhs <-> ?rhs")
proof -
let ?U = "UNIV :: 'n set"
{ assume k: "∀x. A *v x = 0 --> x = 0"
{ fix c i
assume c: "setsum (λi. c i *s column i A) ?U = 0" and i: "i ∈ ?U"
let ?x = "χ i. c i"
have th0:"A *v ?x = 0"
using c
unfolding matrix_mult_vsum vec_eq_iff
by auto
from k[rule_format, OF th0] i
have "c i = 0" by (vector vec_eq_iff)}
hence ?rhs by blast }
moreover
{ assume H: ?rhs
{ fix x assume x: "A *v x = 0"
let ?c = "λi. ((x$i ):: real)"
from H[rule_format, of ?c, unfolded matrix_mult_vsum[symmetric], OF x]
have "x = 0" by vector }
}
ultimately show ?thesis unfolding matrix_left_invertible_ker by blast
qed

lemma matrix_right_invertible_independent_rows:
fixes A :: "real^'n^'m"
shows "(∃(B::real^'m^'n). A ** B = mat 1) <->
(∀c. setsum (λi. c i *s row i A) (UNIV :: 'm set) = 0 --> (∀i. c i = 0))"

unfolding left_invertible_transpose[symmetric]
matrix_left_invertible_independent_columns
by (simp add: column_transpose)

lemma matrix_right_invertible_span_columns:
"(∃(B::real ^'n^'m). (A::real ^'m^'n) ** B = mat 1) <->
span (columns A) = UNIV"
(is "?lhs = ?rhs")
proof -
let ?U = "UNIV :: 'm set"
have fU: "finite ?U" by simp
have lhseq: "?lhs <-> (∀y. ∃(x::real^'m). setsum (λi. (x$i) *s column i A) ?U = y)"
unfolding matrix_right_invertible_surjective matrix_mult_vsum surj_def
apply (subst eq_commute)
apply rule
done
have rhseq: "?rhs <-> (∀x. x ∈ span (columns A))" by blast
{ assume h: ?lhs
{ fix x:: "real ^'n"
from h[unfolded lhseq, rule_format, of x] obtain y :: "real ^'m"
where y: "setsum (λi. (y$i) *s column i A) ?U = x" by blast
have "x ∈ span (columns A)"
unfolding y[symmetric]
apply (rule span_setsum[OF fU])
apply clarify
unfolding scalar_mult_eq_scaleR
apply (rule span_mul)
apply (rule span_superset)
unfolding columns_def
apply blast
done
}
then have ?rhs unfolding rhseq by blast }
moreover
{ assume h:?rhs
let ?P = "λ(y::real ^'n). ∃(x::real^'m). setsum (λi. (x$i) *s column i A) ?U = y"
{ fix y
have "?P y"
proof (rule span_induct_alt[of ?P "columns A", folded scalar_mult_eq_scaleR])
show "∃x::real ^ 'm. setsum (λi. (x$i) *s column i A) ?U = 0"
by (rule exI[where x=0], simp)
next
fix c y1 y2
assume y1: "y1 ∈ columns A" and y2: "?P y2"
from y1 obtain i where i: "i ∈ ?U" "y1 = column i A"
unfolding columns_def by blast
from y2 obtain x:: "real ^'m" where
x: "setsum (λi. (x$i) *s column i A) ?U = y2" by blast
let ?x = "(χ j. if j = i then c + (x$i) else (x$j))::real^'m"
show "?P (c*s y1 + y2)"
proof (rule exI[where x= "?x"], vector, auto simp add: i x[symmetric] if_distrib distrib_left cond_application_beta cong del: if_weak_cong)
fix j
have th: "∀xa ∈ ?U. (if xa = i then (c + (x$i)) * ((column xa A)$j)
else (x$xa) * ((column xa A$j))) = (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))"

using i(1) by (simp add: field_simps)
have "setsum (λxa. if xa = i then (c + (x$i)) * ((column xa A)$j)
else (x$xa) * ((column xa A$j))) ?U = setsum (λxa. (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))) ?U"

apply (rule setsum_cong[OF refl])
using th apply blast
done
also have "… = setsum (λxa. if xa = i then c * ((column i A)$j) else 0) ?U + setsum (λxa. ((x$xa) * ((column xa A)$j))) ?U"
by (simp add: setsum_addf)
also have "… = c * ((column i A)$j) + setsum (λxa. ((x$xa) * ((column xa A)$j))) ?U"
unfolding setsum_delta[OF fU]
using i(1) by simp
finally show "setsum (λxa. if xa = i then (c + (x$i)) * ((column xa A)$j)
else (x$xa) * ((column xa A$j))) ?U = c * ((column i A)$j) + setsum (λxa. ((x$xa) * ((column xa A)$j))) ?U"
.
qed
next
show "y ∈ span (columns A)"
unfolding h by blast
qed
}
then have ?lhs unfolding lhseq ..
}
ultimately show ?thesis by blast
qed

lemma matrix_left_invertible_span_rows:
"(∃(B::real^'m^'n). B ** (A::real^'n^'m) = mat 1) <-> span (rows A) = UNIV"
unfolding right_invertible_transpose[symmetric]
unfolding columns_transpose[symmetric]
unfolding matrix_right_invertible_span_columns
..

text {* The same result in terms of square matrices. *}

lemma matrix_left_right_inverse:
fixes A A' :: "real ^'n^'n"
shows "A ** A' = mat 1 <-> A' ** A = mat 1"
proof -
{ fix A A' :: "real ^'n^'n"
assume AA': "A ** A' = mat 1"
have sA: "surj (op *v A)"
unfolding surj_def
apply clarify
apply (rule_tac x="(A' *v y)" in exI)
apply (simp add: matrix_vector_mul_assoc AA' matrix_vector_mul_lid)
done
from linear_surjective_isomorphism[OF matrix_vector_mul_linear sA]
obtain f' :: "real ^'n => real ^'n"
where f': "linear f'" "∀x. f' (A *v x) = x" "∀x. A *v f' x = x" by blast
have th: "matrix f' ** A = mat 1"
by (simp add: matrix_eq matrix_works[OF f'(1)]
matrix_vector_mul_assoc[symmetric] matrix_vector_mul_lid f'(2)[rule_format])
hence "(matrix f' ** A) ** A' = mat 1 ** A'" by simp
hence "matrix f' = A'"
by (simp add: matrix_mul_assoc[symmetric] AA' matrix_mul_rid matrix_mul_lid)
hence "matrix f' ** A = A' ** A" by simp
hence "A' ** A = mat 1" by (simp add: th)
}
then show ?thesis by blast
qed

text {* Considering an n-element vector as an n-by-1 or 1-by-n matrix. *}

definition "rowvector v = (χ i j. (v$j))"

definition "columnvector v = (χ i j. (v$i))"

lemma transpose_columnvector: "transpose(columnvector v) = rowvector v"
by (simp add: transpose_def rowvector_def columnvector_def vec_eq_iff)

lemma transpose_rowvector: "transpose(rowvector v) = columnvector v"
by (simp add: transpose_def columnvector_def rowvector_def vec_eq_iff)

lemma dot_rowvector_columnvector: "columnvector (A *v v) = A ** columnvector v"
by (vector columnvector_def matrix_matrix_mult_def matrix_vector_mult_def)

lemma dot_matrix_product:
"(x::real^'n) • y = (((rowvector x ::real^'n^1) ** (columnvector y :: real^1^'n))$1)$1"
by (vector matrix_matrix_mult_def rowvector_def columnvector_def inner_vec_def)

lemma dot_matrix_vector_mul:
fixes A B :: "real ^'n ^'n" and x y :: "real ^'n"
shows "(A *v x) • (B *v y) =
(((rowvector x :: real^'n^1) ** ((transpose A ** B) ** (columnvector y :: real ^1^'n)))$1)$1"

unfolding dot_matrix_product transpose_columnvector[symmetric]
dot_rowvector_columnvector matrix_transpose_mul matrix_mul_assoc ..


lemma infnorm_cart:"infnorm (x::real^'n) = Sup {abs(x$i) |i. i∈UNIV}"
by (simp add: infnorm_def inner_axis Basis_vec_def) (metis (lifting) inner_axis real_inner_1_right)

lemma component_le_infnorm_cart: "¦x$i¦ ≤ infnorm (x::real^'n)"
using Basis_le_infnorm[of "axis i 1" x]
by (simp add: Basis_vec_def axis_eq_axis inner_axis)

lemma continuous_component: "continuous F f ==> continuous F (λx. f x $ i)"
unfolding continuous_def by (rule tendsto_vec_nth)

lemma continuous_on_component: "continuous_on s f ==> continuous_on s (λx. f x $ i)"
unfolding continuous_on_def by (fast intro: tendsto_vec_nth)

lemma closed_positive_orthant: "closed {x::real^'n. ∀i. 0 ≤x$i}"
by (simp add: Collect_all_eq closed_INT closed_Collect_le)

lemma bounded_component_cart: "bounded s ==> bounded ((λx. x $ i) ` s)"
unfolding bounded_def
apply clarify
apply (rule_tac x="x $ i" in exI)
apply (rule_tac x="e" in exI)
apply clarify
apply (rule order_trans [OF dist_vec_nth_le], simp)
done

lemma compact_lemma_cart:
fixes f :: "nat => 'a::heine_borel ^ 'n"
assumes f: "bounded (range f)"
shows "∀d.
∃l r. subseq r ∧
(∀e>0. eventually (λn. ∀i∈d. dist (f (r n) $ i) (l $ i) < e) sequentially)"

proof
fix d :: "'n set"
have "finite d" by simp
thus "∃l::'a ^ 'n. ∃r. subseq r ∧
(∀e>0. eventually (λn. ∀i∈d. dist (f (r n) $ i) (l $ i) < e) sequentially)"

proof (induct d)
case empty
thus ?case unfolding subseq_def by auto
next
case (insert k d)
obtain l1::"'a^'n" and r1 where r1:"subseq r1"
and lr1:"∀e>0. eventually (λn. ∀i∈d. dist (f (r1 n) $ i) (l1 $ i) < e) sequentially"
using insert(3) by auto
have s': "bounded ((λx. x $ k) ` range f)" using `bounded (range f)`
by (auto intro!: bounded_component_cart)
have f': "∀n. f (r1 n) $ k ∈ (λx. x $ k) ` range f" by simp
have "bounded (range (λi. f (r1 i) $ k))"
by (metis (lifting) bounded_subset image_subsetI f' s')
then obtain l2 r2 where r2: "subseq r2"
and lr2: "((λi. f (r1 (r2 i)) $ k) ---> l2) sequentially"
using bounded_imp_convergent_subsequence[of "λi. f (r1 i) $ k"] by (auto simp: o_def)
def r "r1 o r2"
have r: "subseq r"
using r1 and r2 unfolding r_def o_def subseq_def by auto
moreover
def l "(χ i. if i = k then l2 else l1$i)::'a^'n"
{ fix e :: real assume "e > 0"
from lr1 `e>0` have N1:"eventually (λn. ∀i∈d. dist (f (r1 n) $ i) (l1 $ i) < e) sequentially"
by blast
from lr2 `e>0` have N2:"eventually (λn. dist (f (r1 (r2 n)) $ k) l2 < e) sequentially"
by (rule tendstoD)
from r2 N1 have N1': "eventually (λn. ∀i∈d. dist (f (r1 (r2 n)) $ i) (l1 $ i) < e) sequentially"
by (rule eventually_subseq)
have "eventually (λn. ∀i∈(insert k d). dist (f (r n) $ i) (l $ i) < e) sequentially"
using N1' N2 by (rule eventually_elim2, simp add: l_def r_def)
}
ultimately show ?case by auto
qed
qed

instance vec :: (heine_borel, finite) heine_borel
proof
fix f :: "nat => 'a ^ 'b"
assume f: "bounded (range f)"
then obtain l r where r: "subseq r"
and l: "∀e>0. eventually (λn. ∀i∈UNIV. dist (f (r n) $ i) (l $ i) < e) sequentially"
using compact_lemma_cart [OF f] by blast
let ?d = "UNIV::'b set"
{ fix e::real assume "e>0"
hence "0 < e / (real_of_nat (card ?d))"
using zero_less_card_finite divide_pos_pos[of e, of "real_of_nat (card ?d)"] by auto
with l have "eventually (λn. ∀i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))) sequentially"
by simp
moreover
{ fix n
assume n: "∀i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))"
have "dist (f (r n)) l ≤ (∑i∈?d. dist (f (r n) $ i) (l $ i))"
unfolding dist_vec_def using zero_le_dist by (rule setL2_le_setsum)
also have "… < (∑i∈?d. e / (real_of_nat (card ?d)))"
by (rule setsum_strict_mono) (simp_all add: n)
finally have "dist (f (r n)) l < e" by simp
}
ultimately have "eventually (λn. dist (f (r n)) l < e) sequentially"
by (rule eventually_elim1)
}
hence "((f o r) ---> l) sequentially" unfolding o_def tendsto_iff by simp
with r show "∃l r. subseq r ∧ ((f o r) ---> l) sequentially" by auto
qed

lemma interval_cart:
fixes a :: "'a::ord^'n"
shows "{a <..< b} = {x::'a^'n. ∀i. a$i < x$i ∧ x$i < b$i}"
and "{a .. b} = {x::'a^'n. ∀i. a$i ≤ x$i ∧ x$i ≤ b$i}"
by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def)

lemma mem_interval_cart:
fixes a :: "'a::ord^'n"
shows "x ∈ {a<..<b} <-> (∀i. a$i < x$i ∧ x$i < b$i)"
and "x ∈ {a .. b} <-> (∀i. a$i ≤ x$i ∧ x$i ≤ b$i)"
using interval_cart[of a b] by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def)

lemma interval_eq_empty_cart:
fixes a :: "real^'n"
shows "({a <..< b} = {} <-> (∃i. b$i ≤ a$i))" (is ?th1)
and "({a .. b} = {} <-> (∃i. b$i < a$i))" (is ?th2)
proof -
{ fix i x assume as:"b$i ≤ a$i" and x:"x∈{a <..< b}"
hence "a $ i < x $ i ∧ x $ i < b $ i" unfolding mem_interval_cart by auto
hence "a$i < b$i" by auto
hence False using as by auto }
moreover
{ assume as:"∀i. ¬ (b$i ≤ a$i)"
let ?x = "(1/2) *R (a + b)"
{ fix i
have "a$i < b$i" using as[THEN spec[where x=i]] by auto
hence "a$i < ((1/2) *R (a+b)) $ i" "((1/2) *R (a+b)) $ i < b$i"
unfolding vector_smult_component and vector_add_component
by auto }
hence "{a <..< b} ≠ {}" using mem_interval_cart(1)[of "?x" a b] by auto }
ultimately show ?th1 by blast

{ fix i x assume as:"b$i < a$i" and x:"x∈{a .. b}"
hence "a $ i ≤ x $ i ∧ x $ i ≤ b $ i" unfolding mem_interval_cart by auto
hence "a$i ≤ b$i" by auto
hence False using as by auto }
moreover
{ assume as:"∀i. ¬ (b$i < a$i)"
let ?x = "(1/2) *R (a + b)"
{ fix i
have "a$i ≤ b$i" using as[THEN spec[where x=i]] by auto
hence "a$i ≤ ((1/2) *R (a+b)) $ i" "((1/2) *R (a+b)) $ i ≤ b$i"
unfolding vector_smult_component and vector_add_component
by auto }
hence "{a .. b} ≠ {}" using mem_interval_cart(2)[of "?x" a b] by auto }
ultimately show ?th2 by blast
qed

lemma interval_ne_empty_cart:
fixes a :: "real^'n"
shows "{a .. b} ≠ {} <-> (∀i. a$i ≤ b$i)"
and "{a <..< b} ≠ {} <-> (∀i. a$i < b$i)"
unfolding interval_eq_empty_cart[of a b] by (auto simp add: not_less not_le)
(* BH: Why doesn't just "auto" work here? *)

lemma subset_interval_imp_cart:
fixes a :: "real^'n"
shows "(∀i. a$i ≤ c$i ∧ d$i ≤ b$i) ==> {c .. d} ⊆ {a .. b}"
and "(∀i. a$i < c$i ∧ d$i < b$i) ==> {c .. d} ⊆ {a<..<b}"
and "(∀i. a$i ≤ c$i ∧ d$i ≤ b$i) ==> {c<..<d} ⊆ {a .. b}"
and "(∀i. a$i ≤ c$i ∧ d$i ≤ b$i) ==> {c<..<d} ⊆ {a<..<b}"
unfolding subset_eq[unfolded Ball_def] unfolding mem_interval_cart
by (auto intro: order_trans less_le_trans le_less_trans less_imp_le) (* BH: Why doesn't just "auto" work here? *)

lemma interval_sing:
fixes a :: "'a::linorder^'n"
shows "{a .. a} = {a} ∧ {a<..<a} = {}"
apply (auto simp add: set_eq_iff less_vec_def less_eq_vec_def vec_eq_iff)
apply (simp add: order_eq_iff)
apply (auto simp add: not_less less_imp_le)
done

lemma interval_open_subset_closed_cart:
fixes a :: "'a::preorder^'n"
shows "{a<..<b} ⊆ {a .. b}"
proof (simp add: subset_eq, rule)
fix x
assume x: "x ∈{a<..<b}"
{ fix i
have "a $ i ≤ x $ i"
using x order_less_imp_le[of "a$i" "x$i"]
by(simp add: set_eq_iff less_vec_def less_eq_vec_def vec_eq_iff)
}
moreover
{ fix i
have "x $ i ≤ b $ i"
using x order_less_imp_le[of "x$i" "b$i"]
by(simp add: set_eq_iff less_vec_def less_eq_vec_def vec_eq_iff)
}
ultimately
show "a ≤ x ∧ x ≤ b"
by(simp add: set_eq_iff less_vec_def less_eq_vec_def vec_eq_iff)
qed

lemma subset_interval_cart:
fixes a :: "real^'n"
shows "{c .. d} ⊆ {a .. b} <-> (∀i. c$i ≤ d$i) --> (∀i. a$i ≤ c$i ∧ d$i ≤ b$i)" (is ?th1)
and "{c .. d} ⊆ {a<..<b} <-> (∀i. c$i ≤ d$i) --> (∀i. a$i < c$i ∧ d$i < b$i)" (is ?th2)
and "{c<..<d} ⊆ {a .. b} <-> (∀i. c$i < d$i) --> (∀i. a$i ≤ c$i ∧ d$i ≤ b$i)" (is ?th3)
and "{c<..<d} ⊆ {a<..<b} <-> (∀i. c$i < d$i) --> (∀i. a$i ≤ c$i ∧ d$i ≤ b$i)" (is ?th4)
using subset_interval[of c d a b] by (simp_all add: Basis_vec_def inner_axis)

lemma disjoint_interval_cart:
fixes a::"real^'n"
shows "{a .. b} ∩ {c .. d} = {} <-> (∃i. (b$i < a$i ∨ d$i < c$i ∨ b$i < c$i ∨ d$i < a$i))" (is ?th1)
and "{a .. b} ∩ {c<..<d} = {} <-> (∃i. (b$i < a$i ∨ d$i ≤ c$i ∨ b$i ≤ c$i ∨ d$i ≤ a$i))" (is ?th2)
and "{a<..<b} ∩ {c .. d} = {} <-> (∃i. (b$i ≤ a$i ∨ d$i < c$i ∨ b$i ≤ c$i ∨ d$i ≤ a$i))" (is ?th3)
and "{a<..<b} ∩ {c<..<d} = {} <-> (∃i. (b$i ≤ a$i ∨ d$i ≤ c$i ∨ b$i ≤ c$i ∨ d$i ≤ a$i))" (is ?th4)
using disjoint_interval[of a b c d] by (simp_all add: Basis_vec_def inner_axis)

lemma inter_interval_cart:
fixes a :: "'a::linorder^'n"
shows "{a .. b} ∩ {c .. d} = {(χ i. max (a$i) (c$i)) .. (χ i. min (b$i) (d$i))}"
unfolding set_eq_iff and Int_iff and mem_interval_cart
by auto

lemma closed_interval_left_cart:
fixes b :: "real^'n"
shows "closed {x::real^'n. ∀i. x$i ≤ b$i}"
by (simp add: Collect_all_eq closed_INT closed_Collect_le)

lemma closed_interval_right_cart:
fixes a::"real^'n"
shows "closed {x::real^'n. ∀i. a$i ≤ x$i}"
by (simp add: Collect_all_eq closed_INT closed_Collect_le)

lemma is_interval_cart:
"is_interval (s::(real^'n) set) <->
(∀a∈s. ∀b∈s. ∀x. (∀i. ((a$i ≤ x$i ∧ x$i ≤ b$i) ∨ (b$i ≤ x$i ∧ x$i ≤ a$i))) --> x ∈ s)"

by (simp add: is_interval_def Ball_def Basis_vec_def inner_axis imp_ex)

lemma closed_halfspace_component_le_cart: "closed {x::real^'n. x$i ≤ a}"
by (simp add: closed_Collect_le)

lemma closed_halfspace_component_ge_cart: "closed {x::real^'n. x$i ≥ a}"
by (simp add: closed_Collect_le)

lemma open_halfspace_component_lt_cart: "open {x::real^'n. x$i < a}"
by (simp add: open_Collect_less)

lemma open_halfspace_component_gt_cart: "open {x::real^'n. x$i > a}"
by (simp add: open_Collect_less)

lemma Lim_component_le_cart:
fixes f :: "'a => real^'n"
assumes "(f ---> l) net" "¬ (trivial_limit net)" "eventually (λx. f x $i ≤ b) net"
shows "l$i ≤ b"
by (rule tendsto_le[OF assms(2) tendsto_const tendsto_vec_nth, OF assms(1, 3)])

lemma Lim_component_ge_cart:
fixes f :: "'a => real^'n"
assumes "(f ---> l) net" "¬ (trivial_limit net)" "eventually (λx. b ≤ (f x)$i) net"
shows "b ≤ l$i"
by (rule tendsto_le[OF assms(2) tendsto_vec_nth tendsto_const, OF assms(1, 3)])

lemma Lim_component_eq_cart:
fixes f :: "'a => real^'n"
assumes net: "(f ---> l) net" "~(trivial_limit net)" and ev:"eventually (λx. f(x)$i = b) net"
shows "l$i = b"
using ev[unfolded order_eq_iff eventually_conj_iff] and
Lim_component_ge_cart[OF net, of b i] and
Lim_component_le_cart[OF net, of i b] by auto

lemma connected_ivt_component_cart:
fixes x :: "real^'n"
shows "connected s ==> x ∈ s ==> y ∈ s ==> x$k ≤ a ==> a ≤ y$k ==> (∃z∈s. z$k = a)"
using connected_ivt_hyperplane[of s x y "axis k 1" a]
by (auto simp add: inner_axis inner_commute)

lemma subspace_substandard_cart: "subspace {x::real^_. (∀i. P i --> x$i = 0)}"
unfolding subspace_def by auto

lemma closed_substandard_cart:
"closed {x::'a::real_normed_vector ^ 'n. ∀i. P i --> x$i = 0}"
proof -
{ fix i::'n
have "closed {x::'a ^ 'n. P i --> x$i = 0}"
by (cases "P i") (simp_all add: closed_Collect_eq) }
thus ?thesis
unfolding Collect_all_eq by (simp add: closed_INT)
qed

lemma dim_substandard_cart: "dim {x::real^'n. ∀i. i ∉ d --> x$i = 0} = card d"
(is "dim ?A = _")
proof -
let ?a = "λx. axis x 1 :: real^'n"
have *: "{x. ∀i∈Basis. i ∉ ?a ` d --> x • i = 0} = ?A"
by (auto simp: image_iff Basis_vec_def axis_eq_axis inner_axis)
have "?a ` d ⊆ Basis"
by (auto simp: Basis_vec_def)
thus ?thesis
using dim_substandard[of "?a ` d"] card_image[of ?a d]
by (auto simp: axis_eq_axis inj_on_def *)
qed

lemma affinity_inverses:
assumes m0: "m ≠ (0::'a::field)"
shows "(λx. m *s x + c) o (λx. inverse(m) *s x + (-(inverse(m) *s c))) = id"
"(λx. inverse(m) *s x + (-(inverse(m) *s c))) o (λx. m *s x + c) = id"
using m0
apply (auto simp add: fun_eq_iff vector_add_ldistrib)
apply (simp_all add: vector_smult_lneg[symmetric] vector_smult_assoc vector_sneg_minus1[symmetric])
done

lemma vector_affinity_eq:
assumes m0: "(m::'a::field) ≠ 0"
shows "m *s x + c = y <-> x = inverse m *s y + -(inverse m *s c)"
proof
assume h: "m *s x + c = y"
hence "m *s x = y - c" by (simp add: field_simps)
hence "inverse m *s (m *s x) = inverse m *s (y - c)" by simp
then show "x = inverse m *s y + - (inverse m *s c)"
using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
next
assume h: "x = inverse m *s y + - (inverse m *s c)"
show "m *s x + c = y" unfolding h diff_minus[symmetric]
using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
qed

lemma vector_eq_affinity:
"(m::'a::field) ≠ 0 ==> (y = m *s x + c <-> inverse(m) *s y + -(inverse(m) *s c) = x)"
using vector_affinity_eq[where m=m and x=x and y=y and c=c]
by metis

lemma vector_cart:
fixes f :: "real^'n => real"
shows "(χ i. f (axis i 1)) = (∑i∈Basis. f i *R i)"
unfolding euclidean_eq_iff[where 'a="real^'n"]
by simp (simp add: Basis_vec_def inner_axis)

lemma const_vector_cart:"((χ i. d)::real^'n) = (∑i∈Basis. d *R i)"
by (rule vector_cart)

subsection "Convex Euclidean Space"

lemma Cart_1:"(1::real^'n) = ∑Basis"
using const_vector_cart[of 1] by (simp add: one_vec_def)

declare vector_add_ldistrib[simp] vector_ssub_ldistrib[simp] vector_smult_assoc[simp] vector_smult_rneg[simp]
declare vector_sadd_rdistrib[simp] vector_sub_rdistrib[simp]

lemmas vector_component_simps = vector_minus_component vector_smult_component vector_add_component less_eq_vec_def vec_lambda_beta vector_uminus_component

lemma convex_box_cart:
assumes "!!i. convex {x. P i x}"
shows "convex {x. ∀i. P i (x$i)}"
using assms unfolding convex_def by auto

lemma convex_positive_orthant_cart: "convex {x::real^'n. (∀i. 0 ≤ x$i)}"
by (rule convex_box_cart) (simp add: atLeast_def[symmetric] convex_real_interval)

lemma unit_interval_convex_hull_cart:
"{0::real^'n .. 1} = convex hull {x. ∀i. (x$i = 0) ∨ (x$i = 1)}" (is "?int = convex hull ?points")
unfolding Cart_1 unit_interval_convex_hull[where 'a="real^'n"]
by (rule arg_cong[where f="λx. convex hull x"]) (simp add: Basis_vec_def inner_axis)

lemma cube_convex_hull_cart:
assumes "0 < d"
obtains s::"(real^'n) set"
where "finite s" "{x - (χ i. d) .. x + (χ i. d)} = convex hull s"
proof -
from cube_convex_hull [OF assms, of x] guess s .
with that[of s] show thesis by (simp add: const_vector_cart)
qed


subsection "Derivative"

lemma differentiable_at_imp_differentiable_on:
"(∀x∈(s::(real^'n) set). f differentiable at x) ==> f differentiable_on s"
by (metis differentiable_at_withinI differentiable_on_def)

definition "jacobian f net = matrix(frechet_derivative f net)"

lemma jacobian_works:
"(f::(real^'a) => (real^'b)) differentiable net <->
(f has_derivative (λh. (jacobian f net) *v h)) net"

apply rule
unfolding jacobian_def
apply (simp only: matrix_works[OF linear_frechet_derivative]) defer
apply (rule differentiableI)
apply assumption
unfolding frechet_derivative_works
apply assumption
done


subsection {* Component of the differential must be zero if it exists at a local
maximum or minimum for that corresponding component. *}


lemma differential_zero_maxmin_cart:
fixes f::"real^'a => real^'b"
assumes "0 < e" "((∀y ∈ ball x e. (f y)$k ≤ (f x)$k) ∨ (∀y∈ball x e. (f x)$k ≤ (f y)$k))"
"f differentiable (at x)"
shows "jacobian f (at x) $ k = 0"
using differential_zero_maxmin_component[of "axis k 1" e x f] assms
vector_cart[of "λj. frechet_derivative f (at x) j $ k"]
by (simp add: Basis_vec_def axis_eq_axis inner_axis jacobian_def matrix_def)

subsection {* Lemmas for working on @{typ "real^1"} *}

lemma forall_1[simp]: "(∀i::1. P i) <-> P 1"
by (metis (full_types) num1_eq_iff)

lemma ex_1[simp]: "(∃x::1. P x) <-> P 1"
by auto (metis (full_types) num1_eq_iff)

lemma exhaust_2:
fixes x :: 2
shows "x = 1 ∨ x = 2"
proof (induct x)
case (of_int z)
then have "0 <= z" and "z < 2" by simp_all
then have "z = 0 | z = 1" by arith
then show ?case by auto
qed

lemma forall_2: "(∀i::2. P i) <-> P 1 ∧ P 2"
by (metis exhaust_2)

lemma exhaust_3:
fixes x :: 3
shows "x = 1 ∨ x = 2 ∨ x = 3"
proof (induct x)
case (of_int z)
then have "0 <= z" and "z < 3" by simp_all
then have "z = 0 ∨ z = 1 ∨ z = 2" by arith
then show ?case by auto
qed

lemma forall_3: "(∀i::3. P i) <-> P 1 ∧ P 2 ∧ P 3"
by (metis exhaust_3)

lemma UNIV_1 [simp]: "UNIV = {1::1}"
by (auto simp add: num1_eq_iff)

lemma UNIV_2: "UNIV = {1::2, 2::2}"
using exhaust_2 by auto

lemma UNIV_3: "UNIV = {1::3, 2::3, 3::3}"
using exhaust_3 by auto

lemma setsum_1: "setsum f (UNIV::1 set) = f 1"
unfolding UNIV_1 by simp

lemma setsum_2: "setsum f (UNIV::2 set) = f 1 + f 2"
unfolding UNIV_2 by simp

lemma setsum_3: "setsum f (UNIV::3 set) = f 1 + f 2 + f 3"
unfolding UNIV_3 by (simp add: add_ac)

instantiation num1 :: cart_one
begin

instance
proof
show "CARD(1) = Suc 0" by auto
qed

end

subsection{* The collapse of the general concepts to dimension one. *}

lemma vector_one: "(x::'a ^1) = (χ i. (x$1))"
by (simp add: vec_eq_iff)

lemma forall_one: "(∀(x::'a ^1). P x) <-> (∀x. P(χ i. x))"
apply auto
apply (erule_tac x= "x$1" in allE)
apply (simp only: vector_one[symmetric])
done

lemma norm_vector_1: "norm (x :: _^1) = norm (x$1)"
by (simp add: norm_vec_def)

lemma norm_real: "norm(x::real ^ 1) = abs(x$1)"
by (simp add: norm_vector_1)

lemma dist_real: "dist(x::real ^ 1) y = abs((x$1) - (y$1))"
by (auto simp add: norm_real dist_norm)


subsection{* Explicit vector construction from lists. *}

definition "vector l = (χ i. foldr (λx f n. fun_upd (f (n+1)) n x) l (λn x. 0) 1 i)"

lemma vector_1: "(vector[x]) $1 = x"
unfolding vector_def by simp

lemma vector_2:
"(vector[x,y]) $1 = x"
"(vector[x,y] :: 'a^2)$2 = (y::'a::zero)"
unfolding vector_def by simp_all

lemma vector_3:
"(vector [x,y,z] ::('a::zero)^3)$1 = x"
"(vector [x,y,z] ::('a::zero)^3)$2 = y"
"(vector [x,y,z] ::('a::zero)^3)$3 = z"
unfolding vector_def by simp_all

lemma forall_vector_1: "(∀v::'a::zero^1. P v) <-> (∀x. P(vector[x]))"
apply auto
apply (erule_tac x="v$1" in allE)
apply (subgoal_tac "vector [v$1] = v")
apply simp
apply (vector vector_def)
apply simp
done

lemma forall_vector_2: "(∀v::'a::zero^2. P v) <-> (∀x y. P(vector[x, y]))"
apply auto
apply (erule_tac x="v$1" in allE)
apply (erule_tac x="v$2" in allE)
apply (subgoal_tac "vector [v$1, v$2] = v")
apply simp
apply (vector vector_def)
apply (simp add: forall_2)
done

lemma forall_vector_3: "(∀v::'a::zero^3. P v) <-> (∀x y z. P(vector[x, y, z]))"
apply auto
apply (erule_tac x="v$1" in allE)
apply (erule_tac x="v$2" in allE)
apply (erule_tac x="v$3" in allE)
apply (subgoal_tac "vector [v$1, v$2, v$3] = v")
apply simp
apply (vector vector_def)
apply (simp add: forall_3)
done

lemma bounded_linear_component_cart[intro]: "bounded_linear (λx::real^'n. x $ k)"
apply (rule bounded_linearI[where K=1])
using component_le_norm_cart[of _ k] unfolding real_norm_def by auto

lemma integral_component_eq_cart[simp]:
fixes f :: "'n::ordered_euclidean_space => real^'m"
assumes "f integrable_on s"
shows "integral s (λx. f x $ k) = integral s f $ k"
using integral_linear[OF assms(1) bounded_linear_component_cart,unfolded o_def] .

lemma interval_split_cart:
"{a..b::real^'n} ∩ {x. x$k ≤ c} = {a .. (χ i. if i = k then min (b$k) c else b$i)}"
"{a..b} ∩ {x. x$k ≥ c} = {(χ i. if i = k then max (a$k) c else a$i) .. b}"
apply (rule_tac[!] set_eqI)
unfolding Int_iff mem_interval_cart mem_Collect_eq
unfolding vec_lambda_beta
by auto

lemma interval_bij_bij_cart: fixes x::"real^'n" assumes "∀i. a$i < b$i ∧ u$i < v$i"
shows "interval_bij (a,b) (u,v) (interval_bij (u,v) (a,b) x) = x"
using assms by (intro interval_bij_bij) (auto simp: Basis_vec_def inner_axis)

end