Theory Permutations

theory Permutations
imports Binomial Multiset Disjoint_Sets
(*  Title:      HOL/Library/Permutations.thy
    Author:     Amine Chaieb, University of Cambridge
*)

section ‹Permutations, both general and specifically on finite sets.›

theory Permutations
imports Binomial Multiset Disjoint_Sets
begin

subsection ‹Transpositions›

lemma swap_id_idempotent [simp]:
  "Fun.swap a b id ∘ Fun.swap a b id = id"
  by (rule ext, auto simp add: Fun.swap_def)

lemma inv_swap_id:
  "inv (Fun.swap a b id) = Fun.swap a b id"
  by (rule inv_unique_comp) simp_all

lemma swap_id_eq:
  "Fun.swap a b id x = (if x = a then b else if x = b then a else x)"
  by (simp add: Fun.swap_def)

lemma bij_inv_eq_iff: "bij p ⟹ x = inv p y ⟷ p x = y"
  using surj_f_inv_f[of p] by (auto simp add: bij_def)

lemma bij_swap_comp:
  assumes bp: "bij p"
  shows "Fun.swap a b id ∘ p = Fun.swap (inv p a) (inv p b) p"
  using surj_f_inv_f[OF bij_is_surj[OF bp]]
  by (simp add: fun_eq_iff Fun.swap_def bij_inv_eq_iff[OF bp])

lemma bij_swap_ompose_bij: "bij p ⟹ bij (Fun.swap a b id ∘ p)"
proof -
  assume H: "bij p"
  show ?thesis
    unfolding bij_swap_comp[OF H] bij_swap_iff
    using H .
qed


subsection ‹Basic consequences of the definition›

definition permutes  (infixr "permutes" 41)
  where "(p permutes S) ⟷ (∀x. x ∉ S ⟶ p x = x) ∧ (∀y. ∃!x. p x = y)"

lemma permutes_in_image: "p permutes S ⟹ p x ∈ S ⟷ x ∈ S"
  unfolding permutes_def by metis

lemma permutes_not_in:
  assumes "f permutes S" "x ∉ S" shows "f x = x"
  using assms by (auto simp: permutes_def)

lemma permutes_image: "p permutes S ⟹ p ` S = S"
  unfolding permutes_def
  apply (rule set_eqI)
  apply (simp add: image_iff)
  apply metis
  done

lemma permutes_inj: "p permutes S ⟹ inj p"
  unfolding permutes_def inj_on_def by blast

lemma permutes_inj_on: "f permutes S ⟹ inj_on f A"
  unfolding permutes_def inj_on_def by auto

lemma permutes_surj: "p permutes s ⟹ surj p"
  unfolding permutes_def surj_def by metis

lemma permutes_bij: "p permutes s ⟹ bij p"
unfolding bij_def by (metis permutes_inj permutes_surj)

lemma permutes_imp_bij: "p permutes S ⟹ bij_betw p S S"
by (metis UNIV_I bij_betw_subset permutes_bij permutes_image subsetI)

lemma bij_imp_permutes: "bij_betw p S S ⟹ (⋀x. x ∉ S ⟹ p x = x) ⟹ p permutes S"
  unfolding permutes_def bij_betw_def inj_on_def
  by auto (metis image_iff)+

lemma permutes_inv_o:
  assumes pS: "p permutes S"
  shows "p ∘ inv p = id"
    and "inv p ∘ p = id"
  using permutes_inj[OF pS] permutes_surj[OF pS]
  unfolding inj_iff[symmetric] surj_iff[symmetric] by blast+

lemma permutes_inverses:
  fixes p :: "'a ⇒ 'a"
  assumes pS: "p permutes S"
  shows "p (inv p x) = x"
    and "inv p (p x) = x"
  using permutes_inv_o[OF pS, unfolded fun_eq_iff o_def] by auto

lemma permutes_subset: "p permutes S ⟹ S ⊆ T ⟹ p permutes T"
  unfolding permutes_def by blast

lemma permutes_empty[simp]: "p permutes {} ⟷ p = id"
  unfolding fun_eq_iff permutes_def by simp metis

lemma permutes_sing[simp]: "p permutes {a} ⟷ p = id"
  unfolding fun_eq_iff permutes_def by simp metis

lemma permutes_univ: "p permutes UNIV ⟷ (∀y. ∃!x. p x = y)"
  unfolding permutes_def by simp

lemma permutes_inv_eq: "p permutes S ⟹ inv p y = x ⟷ p x = y"
  unfolding permutes_def inv_def
  apply auto
  apply (erule allE[where x=y])
  apply (erule allE[where x=y])
  apply (rule someI_ex)
  apply blast
  apply (rule some1_equality)
  apply blast
  apply blast
  done

lemma permutes_swap_id: "a ∈ S ⟹ b ∈ S ⟹ Fun.swap a b id permutes S"
  unfolding permutes_def Fun.swap_def fun_upd_def by auto metis

lemma permutes_superset: "p permutes S ⟹ (∀x ∈ S - T. p x = x) ⟹ p permutes T"
  by (simp add: Ball_def permutes_def) metis

(* Next three lemmas contributed by Lukas Bulwahn *)
lemma permutes_bij_inv_into:
  fixes A :: "'a set" and B :: "'b set"
  assumes "p permutes A"
  assumes "bij_betw f A B"
  shows "(λx. if x ∈ B then f (p (inv_into A f x)) else x) permutes B"
proof (rule bij_imp_permutes)
  have "bij_betw p A A" "bij_betw f A B" "bij_betw (inv_into A f) B A"
    using assms by (auto simp add: permutes_imp_bij bij_betw_inv_into)
  from this have "bij_betw (f o p o inv_into A f) B B" by (simp add: bij_betw_trans)
  from this show "bij_betw (λx. if x ∈ B then f (p (inv_into A f x)) else x) B B"
    by (subst bij_betw_cong[where g="f o p o inv_into A f"]) auto
next
  fix x
  assume "x ∉ B"
  from this show "(if x ∈ B then f (p (inv_into A f x)) else x) = x" by auto
qed

lemma permutes_image_mset:
  assumes "p permutes A"
  shows "image_mset p (mset_set A) = mset_set A"
using assms by (metis image_mset_mset_set bij_betw_imp_inj_on permutes_imp_bij permutes_image)

lemma permutes_implies_image_mset_eq:
  assumes "p permutes A" "⋀x. x ∈ A ⟹ f x = f' (p x)"
  shows "image_mset f' (mset_set A) = image_mset f (mset_set A)"
proof -
  have "f x = f' (p x)" if x: "x ∈# mset_set A" for x
    using assms(2)[of x] x by (cases "finite A") auto
  from this have "image_mset f (mset_set A) = image_mset (f' o p) (mset_set A)"
    using assms by (auto intro!: image_mset_cong)
  also have "… = image_mset f' (image_mset p (mset_set A))"
    by (simp add: image_mset.compositionality)
  also have "… = image_mset f' (mset_set A)"
  proof -
    from assms have "image_mset p (mset_set A) = mset_set A"
      using permutes_image_mset by blast
    from this show ?thesis by simp
  qed
  finally show ?thesis ..
qed


subsection ‹Group properties›

lemma permutes_id: "id permutes S"
  unfolding permutes_def by simp

lemma permutes_compose: "p permutes S ⟹ q permutes S ⟹ q ∘ p permutes S"
  unfolding permutes_def o_def by metis

lemma permutes_inv:
  assumes pS: "p permutes S"
  shows "inv p permutes S"
  using pS unfolding permutes_def permutes_inv_eq[OF pS] by metis

lemma permutes_inv_inv:
  assumes pS: "p permutes S"
  shows "inv (inv p) = p"
  unfolding fun_eq_iff permutes_inv_eq[OF pS] permutes_inv_eq[OF permutes_inv[OF pS]]
  by blast

lemma permutes_invI:
  assumes perm: "p permutes S"
      and inv:  "⋀x. x ∈ S ⟹ p' (p x) = x"
      and outside: "⋀x. x ∉ S ⟹ p' x = x"
  shows   "inv p = p'"
proof
  fix x show "inv p x = p' x"
  proof (cases "x ∈ S")
    assume [simp]: "x ∈ S"
    from assms have "p' x = p' (p (inv p x))" by (simp add: permutes_inverses)
    also from permutes_inv[OF perm]
      have "… = inv p x" by (subst inv) (simp_all add: permutes_in_image)
    finally show "inv p x = p' x" ..
  qed (insert permutes_inv[OF perm], simp_all add: outside permutes_not_in)
qed

lemma permutes_vimage: "f permutes A ⟹ f -` A = A"
  by (simp add: bij_vimage_eq_inv_image permutes_bij permutes_image[OF permutes_inv])


subsection ‹The number of permutations on a finite set›

lemma permutes_insert_lemma:
  assumes pS: "p permutes (insert a S)"
  shows "Fun.swap a (p a) id ∘ p permutes S"
  apply (rule permutes_superset[where S = "insert a S"])
  apply (rule permutes_compose[OF pS])
  apply (rule permutes_swap_id, simp)
  using permutes_in_image[OF pS, of a]
  apply simp
  apply (auto simp add: Ball_def Fun.swap_def)
  done

lemma permutes_insert: "{p. p permutes (insert a S)} =
  (λ(b,p). Fun.swap a b id ∘ p) ` {(b,p). b ∈ insert a S ∧ p ∈ {p. p permutes S}}"
proof -
  {
    fix p
    {
      assume pS: "p permutes insert a S"
      let ?b = "p a"
      let ?q = "Fun.swap a (p a) id ∘ p"
      have th0: "p = Fun.swap a ?b id ∘ ?q"
        unfolding fun_eq_iff o_assoc by simp
      have th1: "?b ∈ insert a S"
        unfolding permutes_in_image[OF pS] by simp
      from permutes_insert_lemma[OF pS] th0 th1
      have "∃b q. p = Fun.swap a b id ∘ q ∧ b ∈ insert a S ∧ q permutes S" by blast
    }
    moreover
    {
      fix b q
      assume bq: "p = Fun.swap a b id ∘ q" "b ∈ insert a S" "q permutes S"
      from permutes_subset[OF bq(3), of "insert a S"]
      have qS: "q permutes insert a S"
        by auto
      have aS: "a ∈ insert a S"
        by simp
      from bq(1) permutes_compose[OF qS permutes_swap_id[OF aS bq(2)]]
      have "p permutes insert a S"
        by simp
    }
    ultimately have "p permutes insert a S ⟷
        (∃b q. p = Fun.swap a b id ∘ q ∧ b ∈ insert a S ∧ q permutes S)"
      by blast
  }
  then show ?thesis
    by auto
qed

lemma card_permutations:
  assumes Sn: "card S = n"
    and fS: "finite S"
  shows "card {p. p permutes S} = fact n"
  using fS Sn
proof (induct arbitrary: n)
  case empty
  then show ?case by simp
next
  case (insert x F)
  {
    fix n
    assume H0: "card (insert x F) = n"
    let ?xF = "{p. p permutes insert x F}"
    let ?pF = "{p. p permutes F}"
    let ?pF' = "{(b, p). b ∈ insert x F ∧ p ∈ ?pF}"
    let ?g = "(λ(b, p). Fun.swap x b id ∘ p)"
    from permutes_insert[of x F]
    have xfgpF': "?xF = ?g ` ?pF'" .
    have Fs: "card F = n - 1"
      using ‹x ∉ F› H0 ‹finite F› by auto
    from insert.hyps Fs have pFs: "card ?pF = fact (n - 1)"
      using ‹finite F› by auto
    then have "finite ?pF"
      by (auto intro: card_ge_0_finite)
    then have pF'f: "finite ?pF'"
      using H0 ‹finite F›
      apply (simp only: Collect_case_prod Collect_mem_eq)
      apply (rule finite_cartesian_product)
      apply simp_all
      done

    have ginj: "inj_on ?g ?pF'"
    proof -
      {
        fix b p c q
        assume bp: "(b,p) ∈ ?pF'"
        assume cq: "(c,q) ∈ ?pF'"
        assume eq: "?g (b,p) = ?g (c,q)"
        from bp cq have ths: "b ∈ insert x F" "c ∈ insert x F" "x ∈ insert x F"
          "p permutes F" "q permutes F"
          by auto
        from ths(4) ‹x ∉ F› eq have "b = ?g (b,p) x"
          unfolding permutes_def
          by (auto simp add: Fun.swap_def fun_upd_def fun_eq_iff)
        also have "… = ?g (c,q) x"
          using ths(5) ‹x ∉ F› eq
          by (auto simp add: swap_def fun_upd_def fun_eq_iff)
        also have "… = c"
          using ths(5) ‹x ∉ F›
          unfolding permutes_def
          by (auto simp add: Fun.swap_def fun_upd_def fun_eq_iff)
        finally have bc: "b = c" .
        then have "Fun.swap x b id = Fun.swap x c id"
          by simp
        with eq have "Fun.swap x b id ∘ p = Fun.swap x b id ∘ q"
          by simp
        then have "Fun.swap x b id ∘ (Fun.swap x b id ∘ p) =
          Fun.swap x b id ∘ (Fun.swap x b id ∘ q)"
          by simp
        then have "p = q"
          by (simp add: o_assoc)
        with bc have "(b, p) = (c, q)"
          by simp
      }
      then show ?thesis
        unfolding inj_on_def by blast
    qed
    from ‹x ∉ F› H0 have n0: "n ≠ 0"
      using ‹finite F› by auto
    then have "∃m. n = Suc m"
      by presburger
    then obtain m where n[simp]: "n = Suc m"
      by blast
    from pFs H0 have xFc: "card ?xF = fact n"
      unfolding xfgpF' card_image[OF ginj]
      using ‹finite F› ‹finite ?pF›
      apply (simp only: Collect_case_prod Collect_mem_eq card_cartesian_product)
      apply simp
      done
    from finite_imageI[OF pF'f, of ?g] have xFf: "finite ?xF"
      unfolding xfgpF' by simp
    have "card ?xF = fact n"
      using xFf xFc unfolding xFf by blast
  }
  then show ?case
    using insert by simp
qed

lemma finite_permutations:
  assumes fS: "finite S"
  shows "finite {p. p permutes S}"
  using card_permutations[OF refl fS]
  by (auto intro: card_ge_0_finite)


subsection ‹Permutations of index set for iterated operations›

lemma (in comm_monoid_set) permute:
  assumes "p permutes S"
  shows "F g S = F (g ∘ p) S"
proof -
  from ‹p permutes S› have "inj p"
    by (rule permutes_inj)
  then have "inj_on p S"
    by (auto intro: subset_inj_on)
  then have "F g (p ` S) = F (g ∘ p) S"
    by (rule reindex)
  moreover from ‹p permutes S› have "p ` S = S"
    by (rule permutes_image)
  ultimately show ?thesis
    by simp
qed


subsection ‹Various combinations of transpositions with 2, 1 and 0 common elements›

lemma swap_id_common:" a ≠ c ⟹ b ≠ c ⟹
  Fun.swap a b id ∘ Fun.swap a c id = Fun.swap b c id ∘ Fun.swap a b id"
  by (simp add: fun_eq_iff Fun.swap_def)

lemma swap_id_common': "a ≠ b ⟹ a ≠ c ⟹
  Fun.swap a c id ∘ Fun.swap b c id = Fun.swap b c id ∘ Fun.swap a b id"
  by (simp add: fun_eq_iff Fun.swap_def)

lemma swap_id_independent: "a ≠ c ⟹ a ≠ d ⟹ b ≠ c ⟹ b ≠ d ⟹
  Fun.swap a b id ∘ Fun.swap c d id = Fun.swap c d id ∘ Fun.swap a b id"
  by (simp add: fun_eq_iff Fun.swap_def)


subsection ‹Permutations as transposition sequences›

inductive swapidseq :: "nat ⇒ ('a ⇒ 'a) ⇒ bool"
where
  id[simp]: "swapidseq 0 id"
| comp_Suc: "swapidseq n p ⟹ a ≠ b ⟹ swapidseq (Suc n) (Fun.swap a b id ∘ p)"

declare id[unfolded id_def, simp]

definition "permutation p ⟷ (∃n. swapidseq n p)"


subsection ‹Some closure properties of the set of permutations, with lengths›

lemma permutation_id[simp]: "permutation id"
  unfolding permutation_def by (rule exI[where x=0]) simp

declare permutation_id[unfolded id_def, simp]

lemma swapidseq_swap: "swapidseq (if a = b then 0 else 1) (Fun.swap a b id)"
  apply clarsimp
  using comp_Suc[of 0 id a b]
  apply simp
  done

lemma permutation_swap_id: "permutation (Fun.swap a b id)"
  apply (cases "a = b")
  apply simp_all
  unfolding permutation_def
  using swapidseq_swap[of a b]
  apply blast
  done

lemma swapidseq_comp_add: "swapidseq n p ⟹ swapidseq m q ⟹ swapidseq (n + m) (p ∘ q)"
proof (induct n p arbitrary: m q rule: swapidseq.induct)
  case (id m q)
  then show ?case by simp
next
  case (comp_Suc n p a b m q)
  have th: "Suc n + m = Suc (n + m)"
    by arith
  show ?case
    unfolding th comp_assoc
    apply (rule swapidseq.comp_Suc)
    using comp_Suc.hyps(2)[OF comp_Suc.prems] comp_Suc.hyps(3)
    apply blast+
    done
qed

lemma permutation_compose: "permutation p ⟹ permutation q ⟹ permutation (p ∘ q)"
  unfolding permutation_def using swapidseq_comp_add[of _ p _ q] by metis

lemma swapidseq_endswap: "swapidseq n p ⟹ a ≠ b ⟹ swapidseq (Suc n) (p ∘ Fun.swap a b id)"
  apply (induct n p rule: swapidseq.induct)
  using swapidseq_swap[of a b]
  apply (auto simp add: comp_assoc intro: swapidseq.comp_Suc)
  done

lemma swapidseq_inverse_exists: "swapidseq n p ⟹ ∃q. swapidseq n q ∧ p ∘ q = id ∧ q ∘ p = id"
proof (induct n p rule: swapidseq.induct)
  case id
  then show ?case
    by (rule exI[where x=id]) simp
next
  case (comp_Suc n p a b)
  from comp_Suc.hyps obtain q where q: "swapidseq n q" "p ∘ q = id" "q ∘ p = id"
    by blast
  let ?q = "q ∘ Fun.swap a b id"
  note H = comp_Suc.hyps
  from swapidseq_swap[of a b] H(3) have th0: "swapidseq 1 (Fun.swap a b id)"
    by simp
  from swapidseq_comp_add[OF q(1) th0] have th1: "swapidseq (Suc n) ?q"
    by simp
  have "Fun.swap a b id ∘ p ∘ ?q = Fun.swap a b id ∘ (p ∘ q) ∘ Fun.swap a b id"
    by (simp add: o_assoc)
  also have "… = id"
    by (simp add: q(2))
  finally have th2: "Fun.swap a b id ∘ p ∘ ?q = id" .
  have "?q ∘ (Fun.swap a b id ∘ p) = q ∘ (Fun.swap a b id ∘ Fun.swap a b id) ∘ p"
    by (simp only: o_assoc)
  then have "?q ∘ (Fun.swap a b id ∘ p) = id"
    by (simp add: q(3))
  with th1 th2 show ?case
    by blast
qed

lemma swapidseq_inverse:
  assumes H: "swapidseq n p"
  shows "swapidseq n (inv p)"
  using swapidseq_inverse_exists[OF H] inv_unique_comp[of p] by auto

lemma permutation_inverse: "permutation p ⟹ permutation (inv p)"
  using permutation_def swapidseq_inverse by blast


subsection ‹The identity map only has even transposition sequences›

lemma symmetry_lemma:
  assumes "⋀a b c d. P a b c d ⟹ P a b d c"
    and "⋀a b c d. a ≠ b ⟹ c ≠ d ⟹
      a = c ∧ b = d ∨ a = c ∧ b ≠ d ∨ a ≠ c ∧ b = d ∨ a ≠ c ∧ a ≠ d ∧ b ≠ c ∧ b ≠ d ⟹
      P a b c d"
  shows "⋀a b c d. a ≠ b ⟶ c ≠ d ⟶  P a b c d"
  using assms by metis

lemma swap_general: "a ≠ b ⟹ c ≠ d ⟹
  Fun.swap a b id ∘ Fun.swap c d id = id ∨
  (∃x y z. x ≠ a ∧ y ≠ a ∧ z ≠ a ∧ x ≠ y ∧
    Fun.swap a b id ∘ Fun.swap c d id = Fun.swap x y id ∘ Fun.swap a z id)"
proof -
  assume H: "a ≠ b" "c ≠ d"
  have "a ≠ b ⟶ c ≠ d ⟶
    (Fun.swap a b id ∘ Fun.swap c d id = id ∨
      (∃x y z. x ≠ a ∧ y ≠ a ∧ z ≠ a ∧ x ≠ y ∧
        Fun.swap a b id ∘ Fun.swap c d id = Fun.swap x y id ∘ Fun.swap a z id))"
    apply (rule symmetry_lemma[where a=a and b=b and c=c and d=d])
    apply (simp_all only: swap_commute)
    apply (case_tac "a = c ∧ b = d")
    apply (clarsimp simp only: swap_commute swap_id_idempotent)
    apply (case_tac "a = c ∧ b ≠ d")
    apply (rule disjI2)
    apply (rule_tac x="b" in exI)
    apply (rule_tac x="d" in exI)
    apply (rule_tac x="b" in exI)
    apply (clarsimp simp add: fun_eq_iff Fun.swap_def)
    apply (case_tac "a ≠ c ∧ b = d")
    apply (rule disjI2)
    apply (rule_tac x="c" in exI)
    apply (rule_tac x="d" in exI)
    apply (rule_tac x="c" in exI)
    apply (clarsimp simp add: fun_eq_iff Fun.swap_def)
    apply (rule disjI2)
    apply (rule_tac x="c" in exI)
    apply (rule_tac x="d" in exI)
    apply (rule_tac x="b" in exI)
    apply (clarsimp simp add: fun_eq_iff Fun.swap_def)
    done
  with H show ?thesis by metis
qed

lemma swapidseq_id_iff[simp]: "swapidseq 0 p ⟷ p = id"
  using swapidseq.cases[of 0 p "p = id"]
  by auto

lemma swapidseq_cases: "swapidseq n p ⟷
  n = 0 ∧ p = id ∨ (∃a b q m. n = Suc m ∧ p = Fun.swap a b id ∘ q ∧ swapidseq m q ∧ a ≠ b)"
  apply (rule iffI)
  apply (erule swapidseq.cases[of n p])
  apply simp
  apply (rule disjI2)
  apply (rule_tac x= "a" in exI)
  apply (rule_tac x= "b" in exI)
  apply (rule_tac x= "pa" in exI)
  apply (rule_tac x= "na" in exI)
  apply simp
  apply auto
  apply (rule comp_Suc, simp_all)
  done

lemma fixing_swapidseq_decrease:
  assumes spn: "swapidseq n p"
    and ab: "a ≠ b"
    and pa: "(Fun.swap a b id ∘ p) a = a"
  shows "n ≠ 0 ∧ swapidseq (n - 1) (Fun.swap a b id ∘ p)"
  using spn ab pa
proof (induct n arbitrary: p a b)
  case 0
  then show ?case
    by (auto simp add: Fun.swap_def fun_upd_def)
next
  case (Suc n p a b)
  from Suc.prems(1) swapidseq_cases[of "Suc n" p]
  obtain c d q m where
    cdqm: "Suc n = Suc m" "p = Fun.swap c d id ∘ q" "swapidseq m q" "c ≠ d" "n = m"
    by auto
  {
    assume H: "Fun.swap a b id ∘ Fun.swap c d id = id"
    have ?case by (simp only: cdqm o_assoc H) (simp add: cdqm)
  }
  moreover
  {
    fix x y z
    assume H: "x ≠ a" "y ≠ a" "z ≠ a" "x ≠ y"
      "Fun.swap a b id ∘ Fun.swap c d id = Fun.swap x y id ∘ Fun.swap a z id"
    from H have az: "a ≠ z"
      by simp

    {
      fix h
      have "(Fun.swap x y id ∘ h) a = a ⟷ h a = a"
        using H by (simp add: Fun.swap_def)
    }
    note th3 = this
    from cdqm(2) have "Fun.swap a b id ∘ p = Fun.swap a b id ∘ (Fun.swap c d id ∘ q)"
      by simp
    then have "Fun.swap a b id ∘ p = Fun.swap x y id ∘ (Fun.swap a z id ∘ q)"
      by (simp add: o_assoc H)
    then have "(Fun.swap a b id ∘ p) a = (Fun.swap x y id ∘ (Fun.swap a z id ∘ q)) a"
      by simp
    then have "(Fun.swap x y id ∘ (Fun.swap a z id ∘ q)) a = a"
      unfolding Suc by metis
    then have th1: "(Fun.swap a z id ∘ q) a = a"
      unfolding th3 .
    from Suc.hyps[OF cdqm(3)[ unfolded cdqm(5)[symmetric]] az th1]
    have th2: "swapidseq (n - 1) (Fun.swap a z id ∘ q)" "n ≠ 0"
      by blast+
    have th: "Suc n - 1 = Suc (n - 1)"
      using th2(2) by auto
    have ?case
      unfolding cdqm(2) H o_assoc th
      apply (simp only: Suc_not_Zero simp_thms comp_assoc)
      apply (rule comp_Suc)
      using th2 H
      apply blast+
      done
  }
  ultimately show ?case
    using swap_general[OF Suc.prems(2) cdqm(4)] by metis
qed

lemma swapidseq_identity_even:
  assumes "swapidseq n (id :: 'a ⇒ 'a)"
  shows "even n"
  using ‹swapidseq n id›
proof (induct n rule: nat_less_induct)
  fix n
  assume H: "∀m<n. swapidseq m (id::'a ⇒ 'a) ⟶ even m" "swapidseq n (id :: 'a ⇒ 'a)"
  {
    assume "n = 0"
    then have "even n" by presburger
  }
  moreover
  {
    fix a b :: 'a and q m
    assume h: "n = Suc m" "(id :: 'a ⇒ 'a) = Fun.swap a b id ∘ q" "swapidseq m q" "a ≠ b"
    from fixing_swapidseq_decrease[OF h(3,4), unfolded h(2)[symmetric]]
    have m: "m ≠ 0" "swapidseq (m - 1) (id :: 'a ⇒ 'a)"
      by auto
    from h m have mn: "m - 1 < n"
      by arith
    from H(1)[rule_format, OF mn m(2)] h(1) m(1) have "even n"
      by presburger
  }
  ultimately show "even n"
    using H(2)[unfolded swapidseq_cases[of n id]] by auto
qed


subsection ‹Therefore we have a welldefined notion of parity›

definition "evenperm p = even (SOME n. swapidseq n p)"

lemma swapidseq_even_even:
  assumes m: "swapidseq m p"
    and n: "swapidseq n p"
  shows "even m ⟷ even n"
proof -
  from swapidseq_inverse_exists[OF n]
  obtain q where q: "swapidseq n q" "p ∘ q = id" "q ∘ p = id"
    by blast
  from swapidseq_identity_even[OF swapidseq_comp_add[OF m q(1), unfolded q]]
  show ?thesis
    by arith
qed

lemma evenperm_unique:
  assumes p: "swapidseq n p"
    and n:"even n = b"
  shows "evenperm p = b"
  unfolding n[symmetric] evenperm_def
  apply (rule swapidseq_even_even[where p = p])
  apply (rule someI[where x = n])
  using p
  apply blast+
  done


subsection ‹And it has the expected composition properties›

lemma evenperm_id[simp]: "evenperm id = True"
  by (rule evenperm_unique[where n = 0]) simp_all

lemma evenperm_swap: "evenperm (Fun.swap a b id) = (a = b)"
  by (rule evenperm_unique[where n="if a = b then 0 else 1"]) (simp_all add: swapidseq_swap)

lemma evenperm_comp:
  assumes p: "permutation p"
    and q:"permutation q"
  shows "evenperm (p ∘ q) = (evenperm p = evenperm q)"
proof -
  from p q obtain n m where n: "swapidseq n p" and m: "swapidseq m q"
    unfolding permutation_def by blast
  note nm =  swapidseq_comp_add[OF n m]
  have th: "even (n + m) = (even n ⟷ even m)"
    by arith
  from evenperm_unique[OF n refl] evenperm_unique[OF m refl]
    evenperm_unique[OF nm th]
  show ?thesis
    by blast
qed

lemma evenperm_inv:
  assumes p: "permutation p"
  shows "evenperm (inv p) = evenperm p"
proof -
  from p obtain n where n: "swapidseq n p"
    unfolding permutation_def by blast
  from evenperm_unique[OF swapidseq_inverse[OF n] evenperm_unique[OF n refl, symmetric]]
  show ?thesis .
qed


subsection ‹A more abstract characterization of permutations›

lemma bij_iff: "bij f ⟷ (∀x. ∃!y. f y = x)"
  unfolding bij_def inj_on_def surj_def
  apply auto
  apply metis
  apply metis
  done

lemma permutation_bijective:
  assumes p: "permutation p"
  shows "bij p"
proof -
  from p obtain n where n: "swapidseq n p"
    unfolding permutation_def by blast
  from swapidseq_inverse_exists[OF n]
  obtain q where q: "swapidseq n q" "p ∘ q = id" "q ∘ p = id"
    by blast
  then show ?thesis unfolding bij_iff
    apply (auto simp add: fun_eq_iff)
    apply metis
    done
qed

lemma permutation_finite_support:
  assumes p: "permutation p"
  shows "finite {x. p x ≠ x}"
proof -
  from p obtain n where n: "swapidseq n p"
    unfolding permutation_def by blast
  from n show ?thesis
  proof (induct n p rule: swapidseq.induct)
    case id
    then show ?case by simp
  next
    case (comp_Suc n p a b)
    let ?S = "insert a (insert b {x. p x ≠ x})"
    from comp_Suc.hyps(2) have fS: "finite ?S"
      by simp
    from ‹a ≠ b› have th: "{x. (Fun.swap a b id ∘ p) x ≠ x} ⊆ ?S"
      by (auto simp add: Fun.swap_def)
    from finite_subset[OF th fS] show ?case  .
  qed
qed

lemma permutation_lemma:
  assumes fS: "finite S"
    and p: "bij p"
    and pS: "∀x. x∉ S ⟶ p x = x"
  shows "permutation p"
  using fS p pS
proof (induct S arbitrary: p rule: finite_induct)
  case (empty p)
  then show ?case by simp
next
  case (insert a F p)
  let ?r = "Fun.swap a (p a) id ∘ p"
  let ?q = "Fun.swap a (p a) id ∘ ?r"
  have raa: "?r a = a"
    by (simp add: Fun.swap_def)
  from bij_swap_ompose_bij[OF insert(4)]
  have br: "bij ?r"  .

  from insert raa have th: "∀x. x ∉ F ⟶ ?r x = x"
    apply (clarsimp simp add: Fun.swap_def)
    apply (erule_tac x="x" in allE)
    apply auto
    unfolding bij_iff
    apply metis
    done
  from insert(3)[OF br th]
  have rp: "permutation ?r" .
  have "permutation ?q"
    by (simp add: permutation_compose permutation_swap_id rp)
  then show ?case
    by (simp add: o_assoc)
qed

lemma permutation: "permutation p ⟷ bij p ∧ finite {x. p x ≠ x}"
  (is "?lhs ⟷ ?b ∧ ?f")
proof
  assume p: ?lhs
  from p permutation_bijective permutation_finite_support show "?b ∧ ?f"
    by auto
next
  assume "?b ∧ ?f"
  then have "?f" "?b" by blast+
  from permutation_lemma[OF this] show ?lhs
    by blast
qed

lemma permutation_inverse_works:
  assumes p: "permutation p"
  shows "inv p ∘ p = id"
    and "p ∘ inv p = id"
  using permutation_bijective [OF p]
  unfolding bij_def inj_iff surj_iff by auto

lemma permutation_inverse_compose:
  assumes p: "permutation p"
    and q: "permutation q"
  shows "inv (p ∘ q) = inv q ∘ inv p"
proof -
  note ps = permutation_inverse_works[OF p]
  note qs = permutation_inverse_works[OF q]
  have "p ∘ q ∘ (inv q ∘ inv p) = p ∘ (q ∘ inv q) ∘ inv p"
    by (simp add: o_assoc)
  also have "… = id"
    by (simp add: ps qs)
  finally have th0: "p ∘ q ∘ (inv q ∘ inv p) = id" .
  have "inv q ∘ inv p ∘ (p ∘ q) = inv q ∘ (inv p ∘ p) ∘ q"
    by (simp add: o_assoc)
  also have "… = id"
    by (simp add: ps qs)
  finally have th1: "inv q ∘ inv p ∘ (p ∘ q) = id" .
  from inv_unique_comp[OF th0 th1] show ?thesis .
qed


subsection ‹Relation to "permutes"›

lemma permutation_permutes: "permutation p ⟷ (∃S. finite S ∧ p permutes S)"
  unfolding permutation permutes_def bij_iff[symmetric]
  apply (rule iffI, clarify)
  apply (rule exI[where x="{x. p x ≠ x}"])
  apply simp
  apply clarsimp
  apply (rule_tac B="S" in finite_subset)
  apply auto
  done


subsection ‹Hence a sort of induction principle composing by swaps›

lemma permutes_induct: "finite S ⟹ P id ⟹
  (⋀ a b p. a ∈ S ⟹ b ∈ S ⟹ P p ⟹ P p ⟹ permutation p ⟹ P (Fun.swap a b id ∘ p)) ⟹
  (⋀p. p permutes S ⟹ P p)"
proof (induct S rule: finite_induct)
  case empty
  then show ?case by auto
next
  case (insert x F p)
  let ?r = "Fun.swap x (p x) id ∘ p"
  let ?q = "Fun.swap x (p x) id ∘ ?r"
  have qp: "?q = p"
    by (simp add: o_assoc)
  from permutes_insert_lemma[OF insert.prems(3)] insert have Pr: "P ?r"
    by blast
  from permutes_in_image[OF insert.prems(3), of x]
  have pxF: "p x ∈ insert x F"
    by simp
  have xF: "x ∈ insert x F"
    by simp
  have rp: "permutation ?r"
    unfolding permutation_permutes using insert.hyps(1)
      permutes_insert_lemma[OF insert.prems(3)]
    by blast
  from insert.prems(2)[OF xF pxF Pr Pr rp]
  show ?case
    unfolding qp .
qed


subsection ‹Sign of a permutation as a real number›

definition "sign p = (if evenperm p then (1::int) else -1)"

lemma sign_nz: "sign p ≠ 0"
  by (simp add: sign_def)

lemma sign_id: "sign id = 1"
  by (simp add: sign_def)

lemma sign_inverse: "permutation p ⟹ sign (inv p) = sign p"
  by (simp add: sign_def evenperm_inv)

lemma sign_compose: "permutation p ⟹ permutation q ⟹ sign (p ∘ q) = sign p * sign q"
  by (simp add: sign_def evenperm_comp)

lemma sign_swap_id: "sign (Fun.swap a b id) = (if a = b then 1 else -1)"
  by (simp add: sign_def evenperm_swap)

lemma sign_idempotent: "sign p * sign p = 1"
  by (simp add: sign_def)


subsection ‹Permuting a list›

text ‹This function permutes a list by applying a permutation to the indices.›

definition permute_list :: "(nat ⇒ nat) ⇒ 'a list ⇒ 'a list" where
  "permute_list f xs = map (λi. xs ! (f i)) [0..<length xs]"

lemma permute_list_map:
  assumes "f permutes {..<length xs}"
  shows   "permute_list f (map g xs) = map g (permute_list f xs)"
  using permutes_in_image[OF assms] by (auto simp: permute_list_def)

lemma permute_list_nth:
  assumes "f permutes {..<length xs}" "i < length xs"
  shows   "permute_list f xs ! i = xs ! f i"
  using permutes_in_image[OF assms(1)] assms(2)
  by (simp add: permute_list_def)

lemma permute_list_Nil [simp]: "permute_list f [] = []"
  by (simp add: permute_list_def)

lemma length_permute_list [simp]: "length (permute_list f xs) = length xs"
  by (simp add: permute_list_def)

lemma permute_list_compose:
  assumes "g permutes {..<length xs}"
  shows   "permute_list (f ∘ g) xs = permute_list g (permute_list f xs)"
  using assms[THEN permutes_in_image] by (auto simp add: permute_list_def)

lemma permute_list_ident [simp]: "permute_list (λx. x) xs = xs"
  by (simp add: permute_list_def map_nth)

lemma permute_list_id [simp]: "permute_list id xs = xs"
  by (simp add: id_def)

lemma mset_permute_list [simp]:
  assumes "f permutes {..<length (xs :: 'a list)}"
  shows   "mset (permute_list f xs) = mset xs"
proof (rule multiset_eqI)
  fix y :: 'a
  from assms have [simp]: "f x < length xs ⟷ x < length xs" for x
    using permutes_in_image[OF assms] by auto
  have "count (mset (permute_list f xs)) y =
          card ((λi. xs ! f i) -` {y} ∩ {..<length xs})"
    by (simp add: permute_list_def mset_map count_image_mset atLeast0LessThan)
  also have "(λi. xs ! f i) -` {y} ∩ {..<length xs} = f -` {i. i < length xs ∧ y = xs ! i}"
    by auto
  also from assms have "card … = card {i. i < length xs ∧ y = xs ! i}"
    by (intro card_vimage_inj) (auto simp: permutes_inj permutes_surj)
  also have "… = count (mset xs) y" by (simp add: count_mset length_filter_conv_card)
  finally show "count (mset (permute_list f xs)) y = count (mset xs) y" by simp
qed

lemma set_permute_list [simp]:
  assumes "f permutes {..<length xs}"
  shows   "set (permute_list f xs) = set xs"
  by (rule mset_eq_setD[OF mset_permute_list]) fact

lemma distinct_permute_list [simp]:
  assumes "f permutes {..<length xs}"
  shows   "distinct (permute_list f xs) = distinct xs"
  by (simp add: distinct_count_atmost_1 assms)

lemma permute_list_zip:
  assumes "f permutes A" "A = {..<length xs}"
  assumes [simp]: "length xs = length ys"
  shows   "permute_list f (zip xs ys) = zip (permute_list f xs) (permute_list f ys)"
proof -
  from permutes_in_image[OF assms(1)] assms(2)
    have [simp]: "f i < length ys ⟷ i < length ys" for i by simp
  have "permute_list f (zip xs ys) = map (λi. zip xs ys ! f i) [0..<length ys]"
    by (simp_all add: permute_list_def zip_map_map)
  also have "… = map (λ(x, y). (xs ! f x, ys ! f y)) (zip [0..<length ys] [0..<length ys])"
    by (intro nth_equalityI) simp_all
  also have "… = zip (permute_list f xs) (permute_list f ys)"
    by (simp_all add: permute_list_def zip_map_map)
  finally show ?thesis .
qed

lemma map_of_permute:
  assumes "σ permutes fst ` set xs"
  shows   "map_of xs ∘ σ = map_of (map (λ(x,y). (inv σ x, y)) xs)" (is "_ = map_of (map ?f _)")
proof
  fix x
  from assms have "inj σ" "surj σ" by (simp_all add: permutes_inj permutes_surj)
  thus "(map_of xs ∘ σ) x = map_of (map ?f xs) x"
    by (induction xs) (auto simp: inv_f_f surj_f_inv_f)
qed


subsection ‹More lemmas about permutations›

text ‹
  The following few lemmas were contributed by Lukas Bulwahn.
›

lemma count_image_mset_eq_card_vimage:
  assumes "finite A"
  shows "count (image_mset f (mset_set A)) b = card {a ∈ A. f a = b}"
  using assms
proof (induct A)
  case empty
  show ?case by simp
next
  case (insert x F)
  show ?case
  proof cases
    assume "f x = b"
    from this have "count (image_mset f (mset_set (insert x F))) b = Suc (card {a ∈ F. f a = f x})"
      using insert.hyps by auto
    also have "… = card (insert x {a ∈ F. f a = f x})"
      using insert.hyps(1,2) by simp
    also have "card (insert x {a ∈ F. f a = f x}) = card {a ∈ insert x F. f a = b}"
      using ‹f x = b› by (auto intro: arg_cong[where f="card"])
    finally show ?thesis using insert by auto
  next
    assume A: "f x ≠ b"
    hence "{a ∈ F. f a = b} = {a ∈ insert x F. f a = b}" by auto
    with insert A show ?thesis by simp
  qed
qed

(* Prove image_mset_eq_implies_permutes *)
lemma image_mset_eq_implies_permutes:
  fixes f :: "'a ⇒ 'b"
  assumes "finite A"
  assumes mset_eq: "image_mset f (mset_set A) = image_mset f' (mset_set A)"
  obtains p where "p permutes A" and "∀x∈A. f x = f' (p x)"
proof -
  from ‹finite A› have [simp]: "finite {a ∈ A. f a = (b::'b)}" for f b by auto
  have "f ` A = f' ` A"
  proof -
    have "f ` A = f ` (set_mset (mset_set A))" using ‹finite A› by simp
    also have "… = f' ` (set_mset (mset_set A))"
      by (metis mset_eq multiset.set_map)
    also have "… = f' ` A" using ‹finite A› by simp
    finally show ?thesis .
  qed
  have "∀b∈(f ` A). ∃p. bij_betw p {a ∈ A. f a = b} {a ∈ A. f' a = b}"
  proof
    fix b
    from mset_eq have
      "count (image_mset f (mset_set A)) b = count (image_mset f' (mset_set A)) b" by simp
    from this  have "card {a ∈ A. f a = b} = card {a ∈ A. f' a = b}"
      using ‹finite A›
      by (simp add: count_image_mset_eq_card_vimage)
    from this show "∃p. bij_betw p {a∈A. f a = b} {a ∈ A. f' a = b}"
      by (intro finite_same_card_bij) simp_all
  qed
  hence "∃p. ∀b∈f ` A. bij_betw (p b) {a ∈ A. f a = b} {a ∈ A. f' a = b}"
    by (rule bchoice)
  then guess p .. note p = this
  define p' where "p' = (λa. if a ∈ A then p (f a) a else a)"
  have "p' permutes A"
  proof (rule bij_imp_permutes)
    have "disjoint_family_on (λi. {a ∈ A. f' a = i}) (f ` A)"
      unfolding disjoint_family_on_def by auto
    moreover have "bij_betw (λa. p (f a) a) {a ∈ A. f a = b} {a ∈ A. f' a = b}" if b: "b ∈ f ` A" for b
      using p b by (subst bij_betw_cong[where g="p b"]) auto
    ultimately have "bij_betw (λa. p (f a) a) (⋃b∈f ` A. {a ∈ A. f a = b}) (⋃b∈f ` A. {a ∈ A. f' a = b})"
      by (rule bij_betw_UNION_disjoint)
    moreover have "(⋃b∈f ` A. {a ∈ A. f a = b}) = A" by auto
    moreover have "(⋃b∈f ` A. {a ∈ A. f' a = b}) = A" using ‹f ` A = f' ` A› by auto
    ultimately show "bij_betw p' A A"
      unfolding p'_def by (subst bij_betw_cong[where g="(λa. p (f a) a)"]) auto
  next
    fix x
    assume "x ∉ A"
    from this show "p' x = x"
      unfolding p'_def by simp
  qed
  moreover from p have "∀x∈A. f x = f' (p' x)"
    unfolding p'_def using bij_betwE by fastforce
  ultimately show ?thesis by (rule that)
qed

lemma mset_set_upto_eq_mset_upto:
  "mset_set {..<n} = mset [0..<n]"
  by (induct n) (auto simp add: add.commute lessThan_Suc)

(* and derive the existing property: *)
lemma mset_eq_permutation:
  assumes mset_eq: "mset (xs::'a list) = mset ys"
  obtains p where "p permutes {..<length ys}" "permute_list p ys = xs"
proof -
  from mset_eq have length_eq: "length xs = length ys"
    using mset_eq_length by blast
  have "mset_set {..<length ys} = mset [0..<length ys]"
    using mset_set_upto_eq_mset_upto by blast
  from mset_eq length_eq this have
    "image_mset (λi. xs ! i) (mset_set {..<length ys}) = image_mset (λi. ys ! i) (mset_set {..<length ys})"
    by (metis map_nth mset_map)
  from image_mset_eq_implies_permutes[OF _ this]
    obtain p where "p permutes {..<length ys}"
    and "∀i∈{..<length ys}. xs ! i = ys ! (p i)" by auto
  moreover from this length_eq have "permute_list p ys = xs"
    by (auto intro!: nth_equalityI simp add: permute_list_nth)
  ultimately show thesis using that by blast
qed

lemma permutes_natset_le:
  fixes S :: "'a::wellorder set"
  assumes p: "p permutes S"
    and le: "∀i ∈ S. p i ≤ i"
  shows "p = id"
proof -
  {
    fix n
    have "p n = n"
      using p le
    proof (induct n arbitrary: S rule: less_induct)
      fix n S
      assume H:
        "⋀m S. m < n ⟹ p permutes S ⟹ ∀i∈S. p i ≤ i ⟹ p m = m"
        "p permutes S" "∀i ∈S. p i ≤ i"
      {
        assume "n ∉ S"
        with H(2) have "p n = n"
          unfolding permutes_def by metis
      }
      moreover
      {
        assume ns: "n ∈ S"
        from H(3)  ns have "p n < n ∨ p n = n"
          by auto
        moreover {
          assume h: "p n < n"
          from H h have "p (p n) = p n"
            by metis
          with permutes_inj[OF H(2)] have "p n = n"
            unfolding inj_on_def by blast
          with h have False
            by simp
        }
        ultimately have "p n = n"
          by blast
      }
      ultimately show "p n = n"
        by blast
    qed
  }
  then show ?thesis
    by (auto simp add: fun_eq_iff)
qed

lemma permutes_natset_ge:
  fixes S :: "'a::wellorder set"
  assumes p: "p permutes S"
    and le: "∀i ∈ S. p i ≥ i"
  shows "p = id"
proof -
  {
    fix i
    assume i: "i ∈ S"
    from i permutes_in_image[OF permutes_inv[OF p]] have "inv p i ∈ S"
      by simp
    with le have "p (inv p i) ≥ inv p i"
      by blast
    with permutes_inverses[OF p] have "i ≥ inv p i"
      by simp
  }
  then have th: "∀i∈S. inv p i ≤ i"
    by blast
  from permutes_natset_le[OF permutes_inv[OF p] th]
  have "inv p = inv id"
    by simp
  then show ?thesis
    apply (subst permutes_inv_inv[OF p, symmetric])
    apply (rule inv_unique_comp)
    apply simp_all
    done
qed

lemma image_inverse_permutations: "{inv p |p. p permutes S} = {p. p permutes S}"
  apply (rule set_eqI)
  apply auto
  using permutes_inv_inv permutes_inv
  apply auto
  apply (rule_tac x="inv x" in exI)
  apply auto
  done

lemma image_compose_permutations_left:
  assumes q: "q permutes S"
  shows "{q ∘ p | p. p permutes S} = {p . p permutes S}"
  apply (rule set_eqI)
  apply auto
  apply (rule permutes_compose)
  using q
  apply auto
  apply (rule_tac x = "inv q ∘ x" in exI)
  apply (simp add: o_assoc permutes_inv permutes_compose permutes_inv_o)
  done

lemma image_compose_permutations_right:
  assumes q: "q permutes S"
  shows "{p ∘ q | p. p permutes S} = {p . p permutes S}"
  apply (rule set_eqI)
  apply auto
  apply (rule permutes_compose)
  using q
  apply auto
  apply (rule_tac x = "x ∘ inv q" in exI)
  apply (simp add: o_assoc permutes_inv permutes_compose permutes_inv_o comp_assoc)
  done

lemma permutes_in_seg: "p permutes {1 ..n} ⟹ i ∈ {1..n} ⟹ 1 ≤ p i ∧ p i ≤ n"
  by (simp add: permutes_def) metis

lemma sum_permutations_inverse:
  "sum f {p. p permutes S} = sum (λp. f(inv p)) {p. p permutes S}"
  (is "?lhs = ?rhs")
proof -
  let ?S = "{p . p permutes S}"
  have th0: "inj_on inv ?S"
  proof (auto simp add: inj_on_def)
    fix q r
    assume q: "q permutes S"
      and r: "r permutes S"
      and qr: "inv q = inv r"
    then have "inv (inv q) = inv (inv r)"
      by simp
    with permutes_inv_inv[OF q] permutes_inv_inv[OF r] show "q = r"
      by metis
  qed
  have th1: "inv ` ?S = ?S"
    using image_inverse_permutations by blast
  have th2: "?rhs = sum (f ∘ inv) ?S"
    by (simp add: o_def)
  from sum.reindex[OF th0, of f] show ?thesis unfolding th1 th2 .
qed

lemma setum_permutations_compose_left:
  assumes q: "q permutes S"
  shows "sum f {p. p permutes S} = sum (λp. f(q ∘ p)) {p. p permutes S}"
  (is "?lhs = ?rhs")
proof -
  let ?S = "{p. p permutes S}"
  have th0: "?rhs = sum (f ∘ (op ∘ q)) ?S"
    by (simp add: o_def)
  have th1: "inj_on (op ∘ q) ?S"
  proof (auto simp add: inj_on_def)
    fix p r
    assume "p permutes S"
      and r: "r permutes S"
      and rp: "q ∘ p = q ∘ r"
    then have "inv q ∘ q ∘ p = inv q ∘ q ∘ r"
      by (simp add: comp_assoc)
    with permutes_inj[OF q, unfolded inj_iff] show "p = r"
      by simp
  qed
  have th3: "(op ∘ q) ` ?S = ?S"
    using image_compose_permutations_left[OF q] by auto
  from sum.reindex[OF th1, of f] show ?thesis unfolding th0 th1 th3 .
qed

lemma sum_permutations_compose_right:
  assumes q: "q permutes S"
  shows "sum f {p. p permutes S} = sum (λp. f(p ∘ q)) {p. p permutes S}"
  (is "?lhs = ?rhs")
proof -
  let ?S = "{p. p permutes S}"
  have th0: "?rhs = sum (f ∘ (λp. p ∘ q)) ?S"
    by (simp add: o_def)
  have th1: "inj_on (λp. p ∘ q) ?S"
  proof (auto simp add: inj_on_def)
    fix p r
    assume "p permutes S"
      and r: "r permutes S"
      and rp: "p ∘ q = r ∘ q"
    then have "p ∘ (q ∘ inv q) = r ∘ (q ∘ inv q)"
      by (simp add: o_assoc)
    with permutes_surj[OF q, unfolded surj_iff] show "p = r"
      by simp
  qed
  have th3: "(λp. p ∘ q) ` ?S = ?S"
    using image_compose_permutations_right[OF q] by auto
  from sum.reindex[OF th1, of f]
  show ?thesis unfolding th0 th1 th3 .
qed


subsection ‹Sum over a set of permutations (could generalize to iteration)›

lemma sum_over_permutations_insert:
  assumes fS: "finite S"
    and aS: "a ∉ S"
  shows "sum f {p. p permutes (insert a S)} =
    sum (λb. sum (λq. f (Fun.swap a b id ∘ q)) {p. p permutes S}) (insert a S)"
proof -
  have th0: "⋀f a b. (λ(b,p). f (Fun.swap a b id ∘ p)) = f ∘ (λ(b,p). Fun.swap a b id ∘ p)"
    by (simp add: fun_eq_iff)
  have th1: "⋀P Q. P × Q = {(a,b). a ∈ P ∧ b ∈ Q}"
    by blast
  have th2: "⋀P Q. P ⟹ (P ⟹ Q) ⟹ P ∧ Q"
    by blast
  show ?thesis
    unfolding permutes_insert
    unfolding sum.cartesian_product
    unfolding th1[symmetric]
    unfolding th0
  proof (rule sum.reindex)
    let ?f = "(λ(b, y). Fun.swap a b id ∘ y)"
    let ?P = "{p. p permutes S}"
    {
      fix b c p q
      assume b: "b ∈ insert a S"
      assume c: "c ∈ insert a S"
      assume p: "p permutes S"
      assume q: "q permutes S"
      assume eq: "Fun.swap a b id ∘ p = Fun.swap a c id ∘ q"
      from p q aS have pa: "p a = a" and qa: "q a = a"
        unfolding permutes_def by metis+
      from eq have "(Fun.swap a b id ∘ p) a  = (Fun.swap a c id ∘ q) a"
        by simp
      then have bc: "b = c"
        by (simp add: permutes_def pa qa o_def fun_upd_def Fun.swap_def id_def
            cong del: if_weak_cong split: if_split_asm)
      from eq[unfolded bc] have "(λp. Fun.swap a c id ∘ p) (Fun.swap a c id ∘ p) =
        (λp. Fun.swap a c id ∘ p) (Fun.swap a c id ∘ q)" by simp
      then have "p = q"
        unfolding o_assoc swap_id_idempotent
        by (simp add: o_def)
      with bc have "b = c ∧ p = q"
        by blast
    }
    then show "inj_on ?f (insert a S × ?P)"
      unfolding inj_on_def by clarify metis
  qed
qed


subsection ‹Constructing permutations from association lists›

definition list_permutes where
  "list_permutes xs A ⟷ set (map fst xs) ⊆ A ∧ set (map snd xs) = set (map fst xs) ∧
     distinct (map fst xs) ∧ distinct (map snd xs)"

lemma list_permutesI [simp]:
  assumes "set (map fst xs) ⊆ A" "set (map snd xs) = set (map fst xs)" "distinct (map fst xs)"
  shows   "list_permutes xs A"
proof -
  from assms(2,3) have "distinct (map snd xs)"
    by (intro card_distinct) (simp_all add: distinct_card del: set_map)
  with assms show ?thesis by (simp add: list_permutes_def)
qed

definition permutation_of_list where
  "permutation_of_list xs x = (case map_of xs x of None ⇒ x | Some y ⇒ y)"

lemma permutation_of_list_Cons:
  "permutation_of_list ((x,y) # xs) x' = (if x = x' then y else permutation_of_list xs x')"
  by (simp add: permutation_of_list_def)

fun inverse_permutation_of_list where
  "inverse_permutation_of_list [] x = x"
| "inverse_permutation_of_list ((y,x')#xs) x =
     (if x = x' then y else inverse_permutation_of_list xs x)"

declare inverse_permutation_of_list.simps [simp del]

lemma inj_on_map_of:
  assumes "distinct (map snd xs)"
  shows   "inj_on (map_of xs) (set (map fst xs))"
proof (rule inj_onI)
  fix x y assume xy: "x ∈ set (map fst xs)" "y ∈ set (map fst xs)"
  assume eq: "map_of xs x = map_of xs y"
  from xy obtain x' y'
    where x'y': "map_of xs x = Some x'" "map_of xs y = Some y'"
    by (cases "map_of xs x"; cases "map_of xs y")
       (simp_all add: map_of_eq_None_iff)
  moreover from x'y' have *: "(x,x') ∈ set xs" "(y,y') ∈ set xs"
    by (force dest: map_of_SomeD)+
  moreover from * eq x'y' have "x' = y'" by simp
  ultimately show "x = y" using assms
    by (force simp: distinct_map dest: inj_onD[of _ _ "(x,x')" "(y,y')"])
qed

lemma inj_on_the: "None ∉ A ⟹ inj_on the A"
  by (auto simp: inj_on_def option.the_def split: option.splits)

lemma inj_on_map_of':
  assumes "distinct (map snd xs)"
  shows   "inj_on (the ∘ map_of xs) (set (map fst xs))"
  by (intro comp_inj_on inj_on_map_of assms inj_on_the)
     (force simp: eq_commute[of None] map_of_eq_None_iff)

lemma image_map_of:
  assumes "distinct (map fst xs)"
  shows   "map_of xs ` set (map fst xs) = Some ` set (map snd xs)"
  using assms by (auto simp: rev_image_eqI)

lemma the_Some_image [simp]: "the ` Some ` A = A"
  by (subst image_image) simp

lemma image_map_of':
  assumes "distinct (map fst xs)"
  shows   "(the ∘ map_of xs) ` set (map fst xs) = set (map snd xs)"
  by (simp only: image_comp [symmetric] image_map_of assms the_Some_image)

lemma permutation_of_list_permutes [simp]:
  assumes "list_permutes xs A"
  shows   "permutation_of_list xs permutes A" (is "?f permutes _")
proof (rule permutes_subset[OF bij_imp_permutes])
  from assms show "set (map fst xs) ⊆ A"
    by (simp add: list_permutes_def)
  from assms have "inj_on (the ∘ map_of xs) (set (map fst xs))" (is ?P)
    by (intro inj_on_map_of') (simp_all add: list_permutes_def)
  also have "?P ⟷ inj_on ?f (set (map fst xs))"
    by (intro inj_on_cong)
       (auto simp: permutation_of_list_def map_of_eq_None_iff split: option.splits)
  finally have "bij_betw ?f (set (map fst xs)) (?f ` set (map fst xs))"
    by (rule inj_on_imp_bij_betw)
  also from assms have "?f ` set (map fst xs) = (the ∘ map_of xs) ` set (map fst xs)"
    by (intro image_cong refl)
       (auto simp: permutation_of_list_def map_of_eq_None_iff split: option.splits)
  also from assms have "… = set (map fst xs)"
    by (subst image_map_of') (simp_all add: list_permutes_def)
  finally show "bij_betw ?f (set (map fst xs)) (set (map fst xs))" .
qed (force simp: permutation_of_list_def dest!: map_of_SomeD split: option.splits)+

lemma eval_permutation_of_list [simp]:
  "permutation_of_list [] x = x"
  "x = x' ⟹ permutation_of_list ((x',y)#xs) x = y"
  "x ≠ x' ⟹ permutation_of_list ((x',y')#xs) x = permutation_of_list xs x"
  by (simp_all add: permutation_of_list_def)

lemma eval_inverse_permutation_of_list [simp]:
  "inverse_permutation_of_list [] x = x"
  "x = x' ⟹ inverse_permutation_of_list ((y,x')#xs) x = y"
  "x ≠ x' ⟹ inverse_permutation_of_list ((y',x')#xs) x = inverse_permutation_of_list xs x"
  by (simp_all add: inverse_permutation_of_list.simps)

lemma permutation_of_list_id:
  assumes "x ∉ set (map fst xs)"
  shows   "permutation_of_list xs x = x"
  using assms by (induction xs) (auto simp: permutation_of_list_Cons)

lemma permutation_of_list_unique':
  assumes "distinct (map fst xs)" "(x, y) ∈ set xs"
  shows   "permutation_of_list xs x = y"
  using assms by (induction xs) (force simp: permutation_of_list_Cons)+

lemma permutation_of_list_unique:
  assumes "list_permutes xs A" "(x,y) ∈ set xs"
  shows   "permutation_of_list xs x = y"
  using assms by (intro permutation_of_list_unique') (simp_all add: list_permutes_def)

lemma inverse_permutation_of_list_id:
  assumes "x ∉ set (map snd xs)"
  shows   "inverse_permutation_of_list xs x = x"
  using assms by (induction xs) auto

lemma inverse_permutation_of_list_unique':
  assumes "distinct (map snd xs)" "(x, y) ∈ set xs"
  shows   "inverse_permutation_of_list xs y = x"
  using assms by (induction xs) (force simp: inverse_permutation_of_list.simps)+

lemma inverse_permutation_of_list_unique:
  assumes "list_permutes xs A" "(x,y) ∈ set xs"
  shows   "inverse_permutation_of_list xs y = x"
  using assms by (intro inverse_permutation_of_list_unique') (simp_all add: list_permutes_def)

lemma inverse_permutation_of_list_correct:
  assumes "list_permutes xs (A :: 'a set)"
  shows   "inverse_permutation_of_list xs = inv (permutation_of_list xs)"
proof (rule ext, rule sym, subst permutes_inv_eq)
  from assms show "permutation_of_list xs permutes A" by simp
next
  fix x
  show "permutation_of_list xs (inverse_permutation_of_list xs x) = x"
  proof (cases "x ∈ set (map snd xs)")
    case True
    then obtain y where "(y, x) ∈ set xs" by force
    with assms show ?thesis
      by (simp add: inverse_permutation_of_list_unique permutation_of_list_unique)
  qed (insert assms, auto simp: list_permutes_def
         inverse_permutation_of_list_id permutation_of_list_id)
qed

end