Theory Fundamental_Theorem_Algebra

theory Fundamental_Theorem_Algebra
imports Polynomial Complex_Main
(* Author: Amine Chaieb, TU Muenchen *)

header{*Fundamental Theorem of Algebra*}

theory Fundamental_Theorem_Algebra
imports Polynomial Complex_Main
begin

subsection {* Square root of complex numbers *}
definition csqrt :: "complex => complex" where
"csqrt z = (if Im z = 0 then
if 0 ≤ Re z then Complex (sqrt(Re z)) 0
else Complex 0 (sqrt(- Re z))
else Complex (sqrt((cmod z + Re z) /2))
((Im z / abs(Im z)) * sqrt((cmod z - Re z) /2)))"


lemma csqrt[algebra]: "(csqrt z)2 = z"
proof-
obtain x y where xy: "z = Complex x y" by (cases z)
{assume y0: "y = 0"
{assume x0: "x ≥ 0"
then have ?thesis using y0 xy real_sqrt_pow2[OF x0]
by (simp add: csqrt_def power2_eq_square)}
moreover
{assume "¬ x ≥ 0" hence x0: "- x ≥ 0" by arith
then have ?thesis using y0 xy real_sqrt_pow2[OF x0]
by (simp add: csqrt_def power2_eq_square) }
ultimately have ?thesis by blast}
moreover
{assume y0: "y≠0"
{fix x y
let ?z = "Complex x y"
from abs_Re_le_cmod[of ?z] have tha: "abs x ≤ cmod ?z" by auto
hence "cmod ?z - x ≥ 0" "cmod ?z + x ≥ 0" by arith+
hence "(sqrt (x * x + y * y) + x) / 2 ≥ 0" "(sqrt (x * x + y * y) - x) / 2 ≥ 0" by (simp_all add: power2_eq_square) }
note th = this
have sq4: "!!x::real. x2 / 4 = (x / 2)2"
by (simp add: power2_eq_square)
from th[of x y]
have sq4': "sqrt (((sqrt (x * x + y * y) + x)2 / 4)) = (sqrt (x * x + y * y) + x) / 2"
"sqrt (((sqrt (x * x + y * y) - x)2 / 4)) = (sqrt (x * x + y * y) - x) / 2"
unfolding sq4 by simp_all
then have th1: "sqrt ((sqrt (x * x + y * y) + x) * (sqrt (x * x + y * y) + x) / 4) - sqrt ((sqrt (x * x + y * y) - x) * (sqrt (x * x + y * y) - x) / 4) = x"
unfolding power2_eq_square by simp
have "sqrt 4 = sqrt (22)" by simp
hence sqrt4: "sqrt 4 = 2" by (simp only: real_sqrt_abs)
have th2: "2 *(y * sqrt ((sqrt (x * x + y * y) - x) * (sqrt (x * x + y * y) + x) / 4)) / ¦y¦ = y"
using iffD2[OF real_sqrt_pow2_iff sum_power2_ge_zero[of x y]] y0
unfolding power2_eq_square
by (simp add: algebra_simps real_sqrt_divide sqrt4)
from y0 xy have ?thesis apply (simp add: csqrt_def power2_eq_square)
apply (simp add: real_sqrt_sum_squares_mult_ge_zero[of x y] real_sqrt_pow2[OF th(1)[of x y], unfolded power2_eq_square] real_sqrt_pow2[OF th(2)[of x y], unfolded power2_eq_square] real_sqrt_mult[symmetric])
using th1 th2 ..}
ultimately show ?thesis by blast
qed


subsection{* More lemmas about module of complex numbers *}

lemma complex_of_real_power: "complex_of_real x ^ n = complex_of_real (x^n)"
by (rule of_real_power [symmetric])

lemma real_down2: "(0::real) < d1 ==> 0 < d2 ==> EX e. 0 < e & e < d1 & e < d2"
apply (rule exI[where x = "min d1 d2 / 2"])
by (simp add: field_simps min_def)

text{* The triangle inequality for cmod *}
lemma complex_mod_triangle_sub: "cmod w ≤ cmod (w + z) + norm z"
using complex_mod_triangle_ineq2[of "w + z" "-z"] by auto

subsection{* Basic lemmas about complex polynomials *}

lemma poly_bound_exists:
shows "∃m. m > 0 ∧ (∀z. cmod z <= r --> cmod (poly p z) ≤ m)"
proof(induct p)
case 0 thus ?case by (rule exI[where x=1], simp)
next
case (pCons c cs)
from pCons.hyps obtain m where m: "∀z. cmod z ≤ r --> cmod (poly cs z) ≤ m"
by blast
let ?k = " 1 + cmod c + ¦r * m¦"
have kp: "?k > 0" using abs_ge_zero[of "r*m"] norm_ge_zero[of c] by arith
{fix z
assume H: "cmod z ≤ r"
from m H have th: "cmod (poly cs z) ≤ m" by blast
from H have rp: "r ≥ 0" using norm_ge_zero[of z] by arith
have "cmod (poly (pCons c cs) z) ≤ cmod c + cmod (z* poly cs z)"
using norm_triangle_ineq[of c "z* poly cs z"] by simp
also have "… ≤ cmod c + r*m" using mult_mono[OF H th rp norm_ge_zero[of "poly cs z"]] by (simp add: norm_mult)
also have "… ≤ ?k" by simp
finally have "cmod (poly (pCons c cs) z) ≤ ?k" .}
with kp show ?case by blast
qed


text{* Offsetting the variable in a polynomial gives another of same degree *}

definition offset_poly :: "'a::comm_semiring_0 poly => 'a => 'a poly"
where
"offset_poly p h = fold_coeffs (λa q. smult h q + pCons a q) p 0"

lemma offset_poly_0: "offset_poly 0 h = 0"
by (simp add: offset_poly_def)

lemma offset_poly_pCons:
"offset_poly (pCons a p) h =
smult h (offset_poly p h) + pCons a (offset_poly p h)"

by (cases "p = 0 ∧ a = 0") (auto simp add: offset_poly_def)

lemma offset_poly_single: "offset_poly [:a:] h = [:a:]"
by (simp add: offset_poly_pCons offset_poly_0)

lemma poly_offset_poly: "poly (offset_poly p h) x = poly p (h + x)"
apply (induct p)
apply (simp add: offset_poly_0)
apply (simp add: offset_poly_pCons algebra_simps)
done

lemma offset_poly_eq_0_lemma: "smult c p + pCons a p = 0 ==> p = 0"
by (induct p arbitrary: a, simp, force)

lemma offset_poly_eq_0_iff: "offset_poly p h = 0 <-> p = 0"
apply (safe intro!: offset_poly_0)
apply (induct p, simp)
apply (simp add: offset_poly_pCons)
apply (frule offset_poly_eq_0_lemma, simp)
done

lemma degree_offset_poly: "degree (offset_poly p h) = degree p"
apply (induct p)
apply (simp add: offset_poly_0)
apply (case_tac "p = 0")
apply (simp add: offset_poly_0 offset_poly_pCons)
apply (simp add: offset_poly_pCons)
apply (subst degree_add_eq_right)
apply (rule le_less_trans [OF degree_smult_le])
apply (simp add: offset_poly_eq_0_iff)
apply (simp add: offset_poly_eq_0_iff)
done

definition
"psize p = (if p = 0 then 0 else Suc (degree p))"

lemma psize_eq_0_iff [simp]: "psize p = 0 <-> p = 0"
unfolding psize_def by simp

lemma poly_offset: "∃ q. psize q = psize p ∧ (∀x. poly q (x::complex) = poly p (a + x))"
proof (intro exI conjI)
show "psize (offset_poly p a) = psize p"
unfolding psize_def
by (simp add: offset_poly_eq_0_iff degree_offset_poly)
show "∀x. poly (offset_poly p a) x = poly p (a + x)"
by (simp add: poly_offset_poly)
qed

text{* An alternative useful formulation of completeness of the reals *}
lemma real_sup_exists: assumes ex: "∃x. P x" and bz: "∃z. ∀x. P x --> x < z"
shows "∃(s::real). ∀y. (∃x. P x ∧ y < x) <-> y < s"
proof-
from ex bz obtain x Y where x: "P x" and Y: "!!x. P x ==> x < Y" by blast
from ex have thx:"∃x. x ∈ Collect P" by blast
from bz have thY: "∃Y. isUb UNIV (Collect P) Y"
by(auto simp add: isUb_def isLub_def setge_def setle_def leastP_def Ball_def order_le_less)
from reals_complete[OF thx thY] obtain L where L: "isLub UNIV (Collect P) L"
by blast
from Y[OF x] have xY: "x < Y" .
from L have L': "∀x. P x --> x ≤ L" by (auto simp add: isUb_def isLub_def setge_def setle_def leastP_def Ball_def)
from Y have Y': "∀x. P x --> x ≤ Y"
apply (clarsimp, atomize (full)) by auto
from L Y' have "L ≤ Y" by (auto simp add: isUb_def isLub_def setge_def setle_def leastP_def Ball_def)
{fix y
{fix z assume z: "P z" "y < z"
from L' z have "y < L" by auto }
moreover
{assume yL: "y < L" "∀z. P z --> ¬ y < z"
hence nox: "∀z. P z --> y ≥ z" by auto
from nox L have "y ≥ L" by (auto simp add: isUb_def isLub_def setge_def setle_def leastP_def Ball_def)
with yL(1) have False by arith}
ultimately have "(∃x. P x ∧ y < x) <-> y < L" by blast}
thus ?thesis by blast
qed

subsection {* Fundamental theorem of algebra *}
lemma unimodular_reduce_norm:
assumes md: "cmod z = 1"
shows "cmod (z + 1) < 1 ∨ cmod (z - 1) < 1 ∨ cmod (z + ii) < 1 ∨ cmod (z - ii) < 1"
proof-
obtain x y where z: "z = Complex x y " by (cases z, auto)
from md z have xy: "x2 + y2 = 1" by (simp add: cmod_def)
{assume C: "cmod (z + 1) ≥ 1" "cmod (z - 1) ≥ 1" "cmod (z + ii) ≥ 1" "cmod (z - ii) ≥ 1"
from C z xy have "2*x ≤ 1" "2*x ≥ -1" "2*y ≤ 1" "2*y ≥ -1"
by (simp_all add: cmod_def power2_eq_square algebra_simps)
hence "abs (2*x) ≤ 1" "abs (2*y) ≤ 1" by simp_all
hence "(abs (2 * x))2 <= 12" "(abs (2 * y))2 <= 12"
by - (rule power_mono, simp, simp)+
hence th0: "4*x2 ≤ 1" "4*y2 ≤ 1"
by (simp_all add: power_mult_distrib)
from add_mono[OF th0] xy have False by simp }
thus ?thesis unfolding linorder_not_le[symmetric] by blast
qed

text{* Hence we can always reduce modulus of @{text "1 + b z^n"} if nonzero *}
lemma reduce_poly_simple:
assumes b: "b ≠ 0" and n: "n≠0"
shows "∃z. cmod (1 + b * z^n) < 1"
using n
proof(induct n rule: nat_less_induct)
fix n
assume IH: "∀m<n. m ≠ 0 --> (∃z. cmod (1 + b * z ^ m) < 1)" and n: "n ≠ 0"
let ?P = "λz n. cmod (1 + b * z ^ n) < 1"
{assume e: "even n"
hence "∃m. n = 2*m" by presburger
then obtain m where m: "n = 2*m" by blast
from n m have "m≠0" "m < n" by presburger+
with IH[rule_format, of m] obtain z where z: "?P z m" by blast
from z have "?P (csqrt z) n" by (simp add: m power_mult csqrt)
hence "∃z. ?P z n" ..}
moreover
{assume o: "odd n"
have th0: "cmod (complex_of_real (cmod b) / b) = 1"
using b by (simp add: norm_divide)
from o have "∃m. n = Suc (2*m)" by presburger+
then obtain m where m: "n = Suc (2*m)" by blast
from unimodular_reduce_norm[OF th0] o
have "∃v. cmod (complex_of_real (cmod b) / b + v^n) < 1"
apply (cases "cmod (complex_of_real (cmod b) / b + 1) < 1", rule_tac x="1" in exI, simp)
apply (cases "cmod (complex_of_real (cmod b) / b - 1) < 1", rule_tac x="-1" in exI, simp add: diff_minus)
apply (cases "cmod (complex_of_real (cmod b) / b + ii) < 1")
apply (cases "even m", rule_tac x="ii" in exI, simp add: m power_mult)
apply (rule_tac x="- ii" in exI, simp add: m power_mult)
apply (cases "even m", rule_tac x="- ii" in exI, simp add: m power_mult diff_minus)
apply (rule_tac x="ii" in exI, simp add: m power_mult diff_minus)
done
then obtain v where v: "cmod (complex_of_real (cmod b) / b + v^n) < 1" by blast
let ?w = "v / complex_of_real (root n (cmod b))"
from odd_real_root_pow[OF o, of "cmod b"]
have th1: "?w ^ n = v^n / complex_of_real (cmod b)"
by (simp add: power_divide complex_of_real_power)
have th2:"cmod (complex_of_real (cmod b) / b) = 1" using b by (simp add: norm_divide)
hence th3: "cmod (complex_of_real (cmod b) / b) ≥ 0" by simp
have th4: "cmod (complex_of_real (cmod b) / b) *
cmod (1 + b * (v ^ n / complex_of_real (cmod b)))
< cmod (complex_of_real (cmod b) / b) * 1"

apply (simp only: norm_mult[symmetric] distrib_left)
using b v by (simp add: th2)

from mult_less_imp_less_left[OF th4 th3]
have "?P ?w n" unfolding th1 .
hence "∃z. ?P z n" .. }
ultimately show "∃z. ?P z n" by blast
qed

text{* Bolzano-Weierstrass type property for closed disc in complex plane. *}

lemma metric_bound_lemma: "cmod (x - y) <= ¦Re x - Re y¦ + ¦Im x - Im y¦"
using real_sqrt_sum_squares_triangle_ineq[of "Re x - Re y" 0 0 "Im x - Im y" ]
unfolding cmod_def by simp

lemma bolzano_weierstrass_complex_disc:
assumes r: "∀n. cmod (s n) ≤ r"
shows "∃f z. subseq f ∧ (∀e >0. ∃N. ∀n ≥ N. cmod (s (f n) - z) < e)"
proof-
from seq_monosub[of "Re o s"]
obtain f g where f: "subseq f" "monoseq (λn. Re (s (f n)))"
unfolding o_def by blast
from seq_monosub[of "Im o s o f"]
obtain g where g: "subseq g" "monoseq (λn. Im (s(f(g n))))" unfolding o_def by blast
let ?h = "f o g"
from r[rule_format, of 0] have rp: "r ≥ 0" using norm_ge_zero[of "s 0"] by arith
have th:"∀n. r + 1 ≥ ¦ Re (s n)¦"
proof
fix n
from abs_Re_le_cmod[of "s n"] r[rule_format, of n] show "¦Re (s n)¦ ≤ r + 1" by arith
qed
have conv1: "convergent (λn. Re (s ( f n)))"
apply (rule Bseq_monoseq_convergent)
apply (simp add: Bseq_def)
apply (rule exI[where x= "r + 1"])
using th rp apply simp
using f(2) .
have th:"∀n. r + 1 ≥ ¦ Im (s n)¦"
proof
fix n
from abs_Im_le_cmod[of "s n"] r[rule_format, of n] show "¦Im (s n)¦ ≤ r + 1" by arith
qed

have conv2: "convergent (λn. Im (s (f (g n))))"
apply (rule Bseq_monoseq_convergent)
apply (simp add: Bseq_def)
apply (rule exI[where x= "r + 1"])
using th rp apply simp
using g(2) .

from conv1[unfolded convergent_def] obtain x where "LIMSEQ (λn. Re (s (f n))) x"
by blast
hence x: "∀r>0. ∃n0. ∀n≥n0. ¦ Re (s (f n)) - x ¦ < r"
unfolding LIMSEQ_iff real_norm_def .

from conv2[unfolded convergent_def] obtain y where "LIMSEQ (λn. Im (s (f (g n)))) y"
by blast
hence y: "∀r>0. ∃n0. ∀n≥n0. ¦ Im (s (f (g n))) - y ¦ < r"
unfolding LIMSEQ_iff real_norm_def .
let ?w = "Complex x y"
from f(1) g(1) have hs: "subseq ?h" unfolding subseq_def by auto
{fix e assume ep: "e > (0::real)"
hence e2: "e/2 > 0" by simp
from x[rule_format, OF e2] y[rule_format, OF e2]
obtain N1 N2 where N1: "∀n≥N1. ¦Re (s (f n)) - x¦ < e / 2" and N2: "∀n≥N2. ¦Im (s (f (g n))) - y¦ < e / 2" by blast
{fix n assume nN12: "n ≥ N1 + N2"
hence nN1: "g n ≥ N1" and nN2: "n ≥ N2" using seq_suble[OF g(1), of n] by arith+
from add_strict_mono[OF N1[rule_format, OF nN1] N2[rule_format, OF nN2]]
have "cmod (s (?h n) - ?w) < e"
using metric_bound_lemma[of "s (f (g n))" ?w] by simp }
hence "∃N. ∀n≥N. cmod (s (?h n) - ?w) < e" by blast }
with hs show ?thesis by blast
qed

text{* Polynomial is continuous. *}

lemma poly_cont:
assumes ep: "e > 0"
shows "∃d >0. ∀w. 0 < cmod (w - z) ∧ cmod (w - z) < d --> cmod (poly p w - poly p z) < e"
proof-
obtain q where q: "degree q = degree p" "!!x. poly q x = poly p (z + x)"
proof
show "degree (offset_poly p z) = degree p"
by (rule degree_offset_poly)
show "!!x. poly (offset_poly p z) x = poly p (z + x)"
by (rule poly_offset_poly)
qed
{fix w
note q(2)[of "w - z", simplified]}
note th = this
show ?thesis unfolding th[symmetric]
proof(induct q)
case 0 thus ?case using ep by auto
next
case (pCons c cs)
from poly_bound_exists[of 1 "cs"]
obtain m where m: "m > 0" "!!z. cmod z ≤ 1 ==> cmod (poly cs z) ≤ m" by blast
from ep m(1) have em0: "e/m > 0" by (simp add: field_simps)
have one0: "1 > (0::real)" by arith
from real_lbound_gt_zero[OF one0 em0]
obtain d where d: "d >0" "d < 1" "d < e / m" by blast
from d(1,3) m(1) have dm: "d*m > 0" "d*m < e"
by (simp_all add: field_simps mult_pos_pos)
show ?case
proof(rule ex_forward[OF real_lbound_gt_zero[OF one0 em0]], clarsimp simp add: norm_mult)
fix d w
assume H: "d > 0" "d < 1" "d < e/m" "w≠z" "cmod (w-z) < d"
hence d1: "cmod (w-z) ≤ 1" "d ≥ 0" by simp_all
from H(3) m(1) have dme: "d*m < e" by (simp add: field_simps)
from H have th: "cmod (w-z) ≤ d" by simp
from mult_mono[OF th m(2)[OF d1(1)] d1(2) norm_ge_zero] dme
show "cmod (w - z) * cmod (poly cs (w - z)) < e" by simp
qed
qed
qed

text{* Hence a polynomial attains minimum on a closed disc
in the complex plane. *}

lemma poly_minimum_modulus_disc:
"∃z. ∀w. cmod w ≤ r --> cmod (poly p z) ≤ cmod (poly p w)"
proof-
{assume "¬ r ≥ 0" hence ?thesis unfolding linorder_not_le
apply -
apply (rule exI[where x=0])
apply auto
apply (subgoal_tac "cmod w < 0")
apply simp
apply arith
done }
moreover
{assume rp: "r ≥ 0"
from rp have "cmod 0 ≤ r ∧ cmod (poly p 0) = - (- cmod (poly p 0))" by simp
hence mth1: "∃x z. cmod z ≤ r ∧ cmod (poly p z) = - x" by blast
{fix x z
assume H: "cmod z ≤ r" "cmod (poly p z) = - x" "¬x < 1"
hence "- x < 0 " by arith
with H(2) norm_ge_zero[of "poly p z"] have False by simp }
then have mth2: "∃z. ∀x. (∃z. cmod z ≤ r ∧ cmod (poly p z) = - x) --> x < z" by blast
from real_sup_exists[OF mth1 mth2] obtain s where
s: "∀y. (∃x. (∃z. cmod z ≤ r ∧ cmod (poly p z) = - x) ∧ y < x) <->(y < s)" by blast
let ?m = "-s"
{fix y
from s[rule_format, of "-y"] have
"(∃z x. cmod z ≤ r ∧ -(- cmod (poly p z)) < y) <-> ?m < y"
unfolding minus_less_iff[of y ] equation_minus_iff by blast }
note s1 = this[unfolded minus_minus]
from s1[of ?m] have s1m: "!!z x. cmod z ≤ r ==> cmod (poly p z) ≥ ?m"
by auto
{fix n::nat
from s1[rule_format, of "?m + 1/real (Suc n)"]
have "∃z. cmod z ≤ r ∧ cmod (poly p z) < - s + 1 / real (Suc n)"
by simp}
hence th: "∀n. ∃z. cmod z ≤ r ∧ cmod (poly p z) < - s + 1 / real (Suc n)" ..
from choice[OF th] obtain g where
g: "∀n. cmod (g n) ≤ r" "∀n. cmod (poly p (g n)) <?m+1 /real(Suc n)"
by blast
from bolzano_weierstrass_complex_disc[OF g(1)]
obtain f z where fz: "subseq f" "∀e>0. ∃N. ∀n≥N. cmod (g (f n) - z) < e"
by blast
{fix w
assume wr: "cmod w ≤ r"
let ?e = "¦cmod (poly p z) - ?m¦"
{assume e: "?e > 0"
hence e2: "?e/2 > 0" by simp
from poly_cont[OF e2, of z p] obtain d where
d: "d>0" "∀w. 0<cmod (w - z)∧ cmod(w - z) < d --> cmod(poly p w - poly p z) < ?e/2" by blast
{fix w assume w: "cmod (w - z) < d"
have "cmod(poly p w - poly p z) < ?e / 2"
using d(2)[rule_format, of w] w e by (cases "w=z", simp_all)}
note th1 = this

from fz(2)[rule_format, OF d(1)] obtain N1 where
N1: "∀n≥N1. cmod (g (f n) - z) < d" by blast
from reals_Archimedean2[of "2/?e"] obtain N2::nat where
N2: "2/?e < real N2" by blast
have th2: "cmod(poly p (g(f(N1 + N2))) - poly p z) < ?e/2"
using N1[rule_format, of "N1 + N2"] th1 by simp
{fix a b e2 m :: real
have "a < e2 ==> abs(b - m) < e2 ==> 2 * e2 <= abs(b - m) + a
==> False"
by arith}
note th0 = this
have ath:
"!!m x e. m <= x ==> x < m + e ==> abs(x - m::real) < e" by arith
from s1m[OF g(1)[rule_format]]
have th31: "?m ≤ cmod(poly p (g (f (N1 + N2))))" .
from seq_suble[OF fz(1), of "N1+N2"]
have th00: "real (Suc (N1+N2)) ≤ real (Suc (f (N1+N2)))" by simp
have th000: "0 ≤ (1::real)" "(1::real) ≤ 1" "real (Suc (N1+N2)) > 0"
using N2 by auto
from frac_le[OF th000 th00] have th00: "?m +1 / real (Suc (f (N1 + N2))) ≤ ?m + 1 / real (Suc (N1 + N2))" by simp
from g(2)[rule_format, of "f (N1 + N2)"]
have th01:"cmod (poly p (g (f (N1 + N2)))) < - s + 1 / real (Suc (f (N1 + N2)))" .
from order_less_le_trans[OF th01 th00]
have th32: "cmod(poly p (g (f (N1 + N2)))) < ?m + (1/ real(Suc (N1 + N2)))" .
from N2 have "2/?e < real (Suc (N1 + N2))" by arith
with e2 less_imp_inverse_less[of "2/?e" "real (Suc (N1 + N2))"]
have "?e/2 > 1/ real (Suc (N1 + N2))" by (simp add: inverse_eq_divide)
with ath[OF th31 th32]
have thc1:"¦cmod(poly p (g (f (N1 + N2)))) - ?m¦< ?e/2" by arith
have ath2: "!!(a::real) b c m. ¦a - b¦ <= c ==> ¦b - m¦ <= ¦a - m¦ + c"
by arith
have th22: "¦cmod (poly p (g (f (N1 + N2)))) - cmod (poly p z)¦
≤ cmod (poly p (g (f (N1 + N2))) - poly p z)"

by (simp add: norm_triangle_ineq3)
from ath2[OF th22, of ?m]
have thc2: "2*(?e/2) ≤ ¦cmod(poly p (g (f (N1 + N2)))) - ?m¦ + cmod (poly p (g (f (N1 + N2))) - poly p z)" by simp
from th0[OF th2 thc1 thc2] have False .}
hence "?e = 0" by auto
then have "cmod (poly p z) = ?m" by simp
with s1m[OF wr]
have "cmod (poly p z) ≤ cmod (poly p w)" by simp }
hence ?thesis by blast}
ultimately show ?thesis by blast
qed

lemma "(rcis (sqrt (abs r)) (a/2))2 = rcis (abs r) a"
unfolding power2_eq_square
apply (simp add: rcis_mult)
apply (simp add: power2_eq_square[symmetric])
done

lemma cispi: "cis pi = -1"
unfolding cis_def
by simp

lemma "(rcis (sqrt (abs r)) ((pi + a)/2))2 = rcis (- abs r) a"
unfolding power2_eq_square
apply (simp add: rcis_mult add_divide_distrib)
apply (simp add: power2_eq_square[symmetric] rcis_def cispi cis_mult[symmetric])
done

text {* Nonzero polynomial in z goes to infinity as z does. *}

lemma poly_infinity:
assumes ex: "p ≠ 0"
shows "∃r. ∀z. r ≤ cmod z --> d ≤ cmod (poly (pCons a p) z)"
using ex
proof(induct p arbitrary: a d)
case (pCons c cs a d)
{assume H: "cs ≠ 0"
with pCons.hyps obtain r where r: "∀z. r ≤ cmod z --> d + cmod a ≤ cmod (poly (pCons c cs) z)" by blast
let ?r = "1 + ¦r¦"
{fix z assume h: "1 + ¦r¦ ≤ cmod z"
have r0: "r ≤ cmod z" using h by arith
from r[rule_format, OF r0]
have th0: "d + cmod a ≤ 1 * cmod(poly (pCons c cs) z)" by arith
from h have z1: "cmod z ≥ 1" by arith
from order_trans[OF th0 mult_right_mono[OF z1 norm_ge_zero[of "poly (pCons c cs) z"]]]
have th1: "d ≤ cmod(z * poly (pCons c cs) z) - cmod a"
unfolding norm_mult by (simp add: algebra_simps)
from complex_mod_triangle_sub[of "z * poly (pCons c cs) z" a]
have th2: "cmod(z * poly (pCons c cs) z) - cmod a ≤ cmod (poly (pCons a (pCons c cs)) z)"
by (simp add: algebra_simps)
from th1 th2 have "d ≤ cmod (poly (pCons a (pCons c cs)) z)" by arith}
hence ?case by blast}
moreover
{assume cs0: "¬ (cs ≠ 0)"
with pCons.prems have c0: "c ≠ 0" by simp
from cs0 have cs0': "cs = 0" by simp
{fix z
assume h: "(¦d¦ + cmod a) / cmod c ≤ cmod z"
from c0 have "cmod c > 0" by simp
from h c0 have th0: "¦d¦ + cmod a ≤ cmod (z*c)"
by (simp add: field_simps norm_mult)
have ath: "!!mzh mazh ma. mzh <= mazh + ma ==> abs(d) + ma <= mzh ==> d <= mazh" by arith
from complex_mod_triangle_sub[of "z*c" a ]
have th1: "cmod (z * c) ≤ cmod (a + z * c) + cmod a"
by (simp add: algebra_simps)
from ath[OF th1 th0] have "d ≤ cmod (poly (pCons a (pCons c cs)) z)"
using cs0' by simp}
then have ?case by blast}
ultimately show ?case by blast
qed simp

text {* Hence polynomial's modulus attains its minimum somewhere. *}
lemma poly_minimum_modulus:
"∃z.∀w. cmod (poly p z) ≤ cmod (poly p w)"
proof(induct p)
case (pCons c cs)
{assume cs0: "cs ≠ 0"
from poly_infinity[OF cs0, of "cmod (poly (pCons c cs) 0)" c]
obtain r where r: "!!z. r ≤ cmod z ==> cmod (poly (pCons c cs) 0) ≤ cmod (poly (pCons c cs) z)" by blast
have ath: "!!z r. r ≤ cmod z ∨ cmod z ≤ ¦r¦" by arith
from poly_minimum_modulus_disc[of "¦r¦" "pCons c cs"]
obtain v where v: "!!w. cmod w ≤ ¦r¦ ==> cmod (poly (pCons c cs) v) ≤ cmod (poly (pCons c cs) w)" by blast
{fix z assume z: "r ≤ cmod z"
from v[of 0] r[OF z]
have "cmod (poly (pCons c cs) v) ≤ cmod (poly (pCons c cs) z)"
by simp }
note v0 = this
from v0 v ath[of r] have ?case by blast}
moreover
{assume cs0: "¬ (cs ≠ 0)"
hence th:"cs = 0" by simp
from th pCons.hyps have ?case by simp}
ultimately show ?case by blast
qed simp

text{* Constant function (non-syntactic characterization). *}
definition "constant f = (∀x y. f x = f y)"

lemma nonconstant_length: "¬ (constant (poly p)) ==> psize p ≥ 2"
unfolding constant_def psize_def
apply (induct p, auto)
done

lemma poly_replicate_append:
"poly (monom 1 n * p) (x::'a::{comm_ring_1}) = x^n * poly p x"
by (simp add: poly_monom)

text {* Decomposition of polynomial, skipping zero coefficients
after the first. *}


lemma poly_decompose_lemma:
assumes nz: "¬(∀z. z≠0 --> poly p z = (0::'a::{idom}))"
shows "∃k a q. a≠0 ∧ Suc (psize q + k) = psize p ∧
(∀z. poly p z = z^k * poly (pCons a q) z)"

unfolding psize_def
using nz
proof(induct p)
case 0 thus ?case by simp
next
case (pCons c cs)
{assume c0: "c = 0"
from pCons.hyps pCons.prems c0 have ?case
apply (auto)
apply (rule_tac x="k+1" in exI)
apply (rule_tac x="a" in exI, clarsimp)
apply (rule_tac x="q" in exI)
by (auto)}
moreover
{assume c0: "c≠0"
hence ?case apply-
apply (rule exI[where x=0])
apply (rule exI[where x=c], clarsimp)
apply (rule exI[where x=cs])
apply auto
done}
ultimately show ?case by blast
qed

lemma poly_decompose:
assumes nc: "~constant(poly p)"
shows "∃k a q. a≠(0::'a::{idom}) ∧ k≠0 ∧
psize q + k + 1 = psize p ∧
(∀z. poly p z = poly p 0 + z^k * poly (pCons a q) z)"

using nc
proof(induct p)
case 0 thus ?case by (simp add: constant_def)
next
case (pCons c cs)
{assume C:"∀z. z ≠ 0 --> poly cs z = 0"
{fix x y
from C have "poly (pCons c cs) x = poly (pCons c cs) y" by (cases "x=0", auto)}
with pCons.prems have False by (auto simp add: constant_def)}
hence th: "¬ (∀z. z ≠ 0 --> poly cs z = 0)" ..
from poly_decompose_lemma[OF th]
show ?case
apply clarsimp
apply (rule_tac x="k+1" in exI)
apply (rule_tac x="a" in exI)
apply simp
apply (rule_tac x="q" in exI)
apply (auto simp add: psize_def split: if_splits)
done
qed

text{* Fundamental theorem of algebra *}

lemma fundamental_theorem_of_algebra:
assumes nc: "~constant(poly p)"
shows "∃z::complex. poly p z = 0"
using nc
proof(induct "psize p" arbitrary: p rule: less_induct)
case less
let ?p = "poly p"
let ?ths = "∃z. ?p z = 0"

from nonconstant_length[OF less(2)] have n2: "psize p ≥ 2" .
from poly_minimum_modulus obtain c where
c: "∀w. cmod (?p c) ≤ cmod (?p w)" by blast
{assume pc: "?p c = 0" hence ?ths by blast}
moreover
{assume pc0: "?p c ≠ 0"
from poly_offset[of p c] obtain q where
q: "psize q = psize p" "∀x. poly q x = ?p (c+x)" by blast
{assume h: "constant (poly q)"
from q(2) have th: "∀x. poly q (x - c) = ?p x" by auto
{fix x y
from th have "?p x = poly q (x - c)" by auto
also have "… = poly q (y - c)"
using h unfolding constant_def by blast
also have "… = ?p y" using th by auto
finally have "?p x = ?p y" .}
with less(2) have False unfolding constant_def by blast }
hence qnc: "¬ constant (poly q)" by blast
from q(2) have pqc0: "?p c = poly q 0" by simp
from c pqc0 have cq0: "∀w. cmod (poly q 0) ≤ cmod (?p w)" by simp
let ?a0 = "poly q 0"
from pc0 pqc0 have a00: "?a0 ≠ 0" by simp
from a00
have qr: "∀z. poly q z = poly (smult (inverse ?a0) q) z * ?a0"
by simp
let ?r = "smult (inverse ?a0) q"
have lgqr: "psize q = psize ?r"
using a00 unfolding psize_def degree_def
by (simp add: poly_eq_iff)
{assume h: "!!x y. poly ?r x = poly ?r y"
{fix x y
from qr[rule_format, of x]
have "poly q x = poly ?r x * ?a0" by auto
also have "… = poly ?r y * ?a0" using h by simp
also have "… = poly q y" using qr[rule_format, of y] by simp
finally have "poly q x = poly q y" .}
with qnc have False unfolding constant_def by blast}
hence rnc: "¬ constant (poly ?r)" unfolding constant_def by blast
from qr[rule_format, of 0] a00 have r01: "poly ?r 0 = 1" by auto
{fix w
have "cmod (poly ?r w) < 1 <-> cmod (poly q w / ?a0) < 1"
using qr[rule_format, of w] a00 by (simp add: divide_inverse mult_ac)
also have "… <-> cmod (poly q w) < cmod ?a0"
using a00 unfolding norm_divide by (simp add: field_simps)
finally have "cmod (poly ?r w) < 1 <-> cmod (poly q w) < cmod ?a0" .}
note mrmq_eq = this
from poly_decompose[OF rnc] obtain k a s where
kas: "a≠0" "k≠0" "psize s + k + 1 = psize ?r"
"∀z. poly ?r z = poly ?r 0 + z^k* poly (pCons a s) z" by blast
{assume "psize p = k + 1"
with kas(3) lgqr[symmetric] q(1) have s0:"s=0" by auto
{fix w
have "cmod (poly ?r w) = cmod (1 + a * w ^ k)"
using kas(4)[rule_format, of w] s0 r01 by (simp add: algebra_simps)}
note hth = this [symmetric]
from reduce_poly_simple[OF kas(1,2)]
have "∃w. cmod (poly ?r w) < 1" unfolding hth by blast}
moreover
{assume kn: "psize p ≠ k+1"
from kn kas(3) q(1) lgqr have k1n: "k + 1 < psize p" by simp
have th01: "¬ constant (poly (pCons 1 (monom a (k - 1))))"
unfolding constant_def poly_pCons poly_monom
using kas(1) apply simp
by (rule exI[where x=0], rule exI[where x=1], simp)
from kas(1) kas(2) have th02: "k+1 = psize (pCons 1 (monom a (k - 1)))"
by (simp add: psize_def degree_monom_eq)
from less(1) [OF k1n [simplified th02] th01]
obtain w where w: "1 + w^k * a = 0"
unfolding poly_pCons poly_monom
using kas(2) by (cases k, auto simp add: algebra_simps)
from poly_bound_exists[of "cmod w" s] obtain m where
m: "m > 0" "∀z. cmod z ≤ cmod w --> cmod (poly s z) ≤ m" by blast
have w0: "w≠0" using kas(2) w by (auto simp add: power_0_left)
from w have "(1 + w ^ k * a) - 1 = 0 - 1" by simp
then have wm1: "w^k * a = - 1" by simp
have inv0: "0 < inverse (cmod w ^ (k + 1) * m)"
using norm_ge_zero[of w] w0 m(1)
by (simp add: inverse_eq_divide zero_less_mult_iff)
with real_down2[OF zero_less_one] obtain t where
t: "t > 0" "t < 1" "t < inverse (cmod w ^ (k + 1) * m)" by blast
let ?ct = "complex_of_real t"
let ?w = "?ct * w"
have "1 + ?w^k * (a + ?w * poly s ?w) = 1 + ?ct^k * (w^k * a) + ?w^k * ?w * poly s ?w" using kas(1) by (simp add: algebra_simps power_mult_distrib)
also have "… = complex_of_real (1 - t^k) + ?w^k * ?w * poly s ?w"
unfolding wm1 by (simp)
finally have "cmod (1 + ?w^k * (a + ?w * poly s ?w)) = cmod (complex_of_real (1 - t^k) + ?w^k * ?w * poly s ?w)"
apply -
apply (rule cong[OF refl[of cmod]])
apply assumption
done
with norm_triangle_ineq[of "complex_of_real (1 - t^k)" "?w^k * ?w * poly s ?w"]
have th11: "cmod (1 + ?w^k * (a + ?w * poly s ?w)) ≤ ¦1 - t^k¦ + cmod (?w^k * ?w * poly s ?w)" unfolding norm_of_real by simp
have ath: "!!x (t::real). 0≤ x ==> x < t ==> t≤1 ==> ¦1 - t¦ + x < 1" by arith
have "t *cmod w ≤ 1 * cmod w" apply (rule mult_mono) using t(1,2) by auto
then have tw: "cmod ?w ≤ cmod w" using t(1) by (simp add: norm_mult)
from t inv0 have "t* (cmod w ^ (k + 1) * m) < 1"
by (simp add: inverse_eq_divide field_simps)
with zero_less_power[OF t(1), of k]
have th30: "t^k * (t* (cmod w ^ (k + 1) * m)) < t^k * 1"
apply - apply (rule mult_strict_left_mono) by simp_all
have "cmod (?w^k * ?w * poly s ?w) = t^k * (t* (cmod w ^ (k+1) * cmod (poly s ?w)))" using w0 t(1)
by (simp add: algebra_simps power_mult_distrib norm_power norm_mult)
then have "cmod (?w^k * ?w * poly s ?w) ≤ t^k * (t* (cmod w ^ (k + 1) * m))"
using t(1,2) m(2)[rule_format, OF tw] w0
apply (simp only: )
apply auto
done
with th30 have th120: "cmod (?w^k * ?w * poly s ?w) < t^k" by simp
from power_strict_mono[OF t(2), of k] t(1) kas(2) have th121: "t^k ≤ 1"
by auto
from ath[OF norm_ge_zero[of "?w^k * ?w * poly s ?w"] th120 th121]
have th12: "¦1 - t^k¦ + cmod (?w^k * ?w * poly s ?w) < 1" .
from th11 th12
have "cmod (1 + ?w^k * (a + ?w * poly s ?w)) < 1" by arith
then have "cmod (poly ?r ?w) < 1"
unfolding kas(4)[rule_format, of ?w] r01 by simp
then have "∃w. cmod (poly ?r w) < 1" by blast}
ultimately have cr0_contr: "∃w. cmod (poly ?r w) < 1" by blast
from cr0_contr cq0 q(2)
have ?ths unfolding mrmq_eq not_less[symmetric] by auto}
ultimately show ?ths by blast
qed

text {* Alternative version with a syntactic notion of constant polynomial. *}

lemma fundamental_theorem_of_algebra_alt:
assumes nc: "~(∃a l. a≠ 0 ∧ l = 0 ∧ p = pCons a l)"
shows "∃z. poly p z = (0::complex)"
using nc
proof(induct p)
case (pCons c cs)
{assume "c=0" hence ?case by auto}
moreover
{assume c0: "c≠0"
{assume nc: "constant (poly (pCons c cs))"
from nc[unfolded constant_def, rule_format, of 0]
have "∀w. w ≠ 0 --> poly cs w = 0" by auto
hence "cs = 0"
proof(induct cs)
case (pCons d ds)
{assume "d=0" hence ?case using pCons.prems pCons.hyps by simp}
moreover
{assume d0: "d≠0"
from poly_bound_exists[of 1 ds] obtain m where
m: "m > 0" "∀z. ∀z. cmod z ≤ 1 --> cmod (poly ds z) ≤ m" by blast
have dm: "cmod d / m > 0" using d0 m(1) by (simp add: field_simps)
from real_down2[OF dm zero_less_one] obtain x where
x: "x > 0" "x < cmod d / m" "x < 1" by blast
let ?x = "complex_of_real x"
from x have cx: "?x ≠ 0" "cmod ?x ≤ 1" by simp_all
from pCons.prems[rule_format, OF cx(1)]
have cth: "cmod (?x*poly ds ?x) = cmod d" by (simp add: eq_diff_eq[symmetric])
from m(2)[rule_format, OF cx(2)] x(1)
have th0: "cmod (?x*poly ds ?x) ≤ x*m"
by (simp add: norm_mult)
from x(2) m(1) have "x*m < cmod d" by (simp add: field_simps)
with th0 have "cmod (?x*poly ds ?x) ≠ cmod d" by auto
with cth have ?case by blast}
ultimately show ?case by blast
qed simp}
then have nc: "¬ constant (poly (pCons c cs))" using pCons.prems c0
by blast
from fundamental_theorem_of_algebra[OF nc] have ?case .}
ultimately show ?case by blast
qed simp


subsection{* Nullstellensatz, degrees and divisibility of polynomials *}

lemma nullstellensatz_lemma:
fixes p :: "complex poly"
assumes "∀x. poly p x = 0 --> poly q x = 0"
and "degree p = n" and "n ≠ 0"
shows "p dvd (q ^ n)"
using assms
proof(induct n arbitrary: p q rule: nat_less_induct)
fix n::nat fix p q :: "complex poly"
assume IH: "∀m<n. ∀p q.
(∀x. poly p x = (0::complex) --> poly q x = 0) -->
degree p = m --> m ≠ 0 --> p dvd (q ^ m)"

and pq0: "∀x. poly p x = 0 --> poly q x = 0"
and dpn: "degree p = n" and n0: "n ≠ 0"
from dpn n0 have pne: "p ≠ 0" by auto
let ?ths = "p dvd (q ^ n)"
{fix a assume a: "poly p a = 0"
{assume oa: "order a p ≠ 0"
let ?op = "order a p"
from pne have ap: "([:- a, 1:] ^ ?op) dvd p"
"¬ [:- a, 1:] ^ (Suc ?op) dvd p" using order by blast+
note oop = order_degree[OF pne, unfolded dpn]
{assume q0: "q = 0"
hence ?ths using n0
by (simp add: power_0_left)}
moreover
{assume q0: "q ≠ 0"
from pq0[rule_format, OF a, unfolded poly_eq_0_iff_dvd]
obtain r where r: "q = [:- a, 1:] * r" by (rule dvdE)
from ap(1) obtain s where
s: "p = [:- a, 1:] ^ ?op * s" by (rule dvdE)
have sne: "s ≠ 0"
using s pne by auto
{assume ds0: "degree s = 0"
from ds0 obtain k where kpn: "s = [:k:]"
by (cases s) (auto split: if_splits)
from sne kpn have k: "k ≠ 0" by simp
let ?w = "([:1/k:] * ([:-a,1:] ^ (n - ?op))) * (r ^ n)"
from k oop [of a] have "q ^ n = p * ?w"
apply -
apply (subst r, subst s, subst kpn)
apply (subst power_mult_distrib, simp)
apply (subst power_add [symmetric], simp)
done
hence ?ths unfolding dvd_def by blast}
moreover
{assume ds0: "degree s ≠ 0"
from ds0 sne dpn s oa
have dsn: "degree s < n" apply auto
apply (erule ssubst)
apply (simp add: degree_mult_eq degree_linear_power)
done
{fix x assume h: "poly s x = 0"
{assume xa: "x = a"
from h[unfolded xa poly_eq_0_iff_dvd] obtain u where
u: "s = [:- a, 1:] * u" by (rule dvdE)
have "p = [:- a, 1:] ^ (Suc ?op) * u"
by (subst s, subst u, simp only: power_Suc mult_ac)
with ap(2)[unfolded dvd_def] have False by blast}
note xa = this
from h have "poly p x = 0" by (subst s, simp)
with pq0 have "poly q x = 0" by blast
with r xa have "poly r x = 0"
by (auto simp add: uminus_add_conv_diff)}
note impth = this
from IH[rule_format, OF dsn, of s r] impth ds0
have "s dvd (r ^ (degree s))" by blast
then obtain u where u: "r ^ (degree s) = s * u" ..
hence u': "!!x. poly s x * poly u x = poly r x ^ degree s"
by (simp only: poly_mult[symmetric] poly_power[symmetric])
let ?w = "(u * ([:-a,1:] ^ (n - ?op))) * (r ^ (n - degree s))"
from oop[of a] dsn have "q ^ n = p * ?w"
apply -
apply (subst s, subst r)
apply (simp only: power_mult_distrib)
apply (subst mult_assoc [where b=s])
apply (subst mult_assoc [where a=u])
apply (subst mult_assoc [where b=u, symmetric])
apply (subst u [symmetric])
apply (simp add: mult_ac power_add [symmetric])
done
hence ?ths unfolding dvd_def by blast}
ultimately have ?ths by blast }
ultimately have ?ths by blast}
then have ?ths using a order_root pne by blast}
moreover
{assume exa: "¬ (∃a. poly p a = 0)"
from fundamental_theorem_of_algebra_alt[of p] exa obtain c where
ccs: "c≠0" "p = pCons c 0" by blast

then have pp: "!!x. poly p x = c" by simp
let ?w = "[:1/c:] * (q ^ n)"
from ccs have "(q ^ n) = (p * ?w)" by simp
hence ?ths unfolding dvd_def by blast}
ultimately show ?ths by blast
qed

lemma nullstellensatz_univariate:
"(∀x. poly p x = (0::complex) --> poly q x = 0) <->
p dvd (q ^ (degree p)) ∨ (p = 0 ∧ q = 0)"

proof-
{assume pe: "p = 0"
hence eq: "(∀x. poly p x = (0::complex) --> poly q x = 0) <-> q = 0"
by (auto simp add: poly_all_0_iff_0)
{assume "p dvd (q ^ (degree p))"
then obtain r where r: "q ^ (degree p) = p * r" ..
from r pe have False by simp}
with eq pe have ?thesis by blast}
moreover
{assume pe: "p ≠ 0"
{assume dp: "degree p = 0"
then obtain k where k: "p = [:k:]" "k≠0" using pe
by (cases p) (simp split: if_splits)
hence th1: "∀x. poly p x ≠ 0" by simp
from k dp have "q ^ (degree p) = p * [:1/k:]"
by (simp add: one_poly_def)
hence th2: "p dvd (q ^ (degree p))" ..
from th1 th2 pe have ?thesis by blast}
moreover
{assume dp: "degree p ≠ 0"
then obtain n where n: "degree p = Suc n " by (cases "degree p", auto)
{assume "p dvd (q ^ (Suc n))"
then obtain u where u: "q ^ (Suc n) = p * u" ..
{fix x assume h: "poly p x = 0" "poly q x ≠ 0"
hence "poly (q ^ (Suc n)) x ≠ 0" by simp
hence False using u h(1) by (simp only: poly_mult) simp}}
with n nullstellensatz_lemma[of p q "degree p"] dp
have ?thesis by auto}
ultimately have ?thesis by blast}
ultimately show ?thesis by blast
qed

text{* Useful lemma *}

lemma constant_degree:
fixes p :: "'a::{idom,ring_char_0} poly"
shows "constant (poly p) <-> degree p = 0" (is "?lhs = ?rhs")
proof
assume l: ?lhs
from l[unfolded constant_def, rule_format, of _ "0"]
have th: "poly p = poly [:poly p 0:]" apply - by (rule ext, simp)
then have "p = [:poly p 0:]" by (simp add: poly_eq_poly_eq_iff)
then have "degree p = degree [:poly p 0:]" by simp
then show ?rhs by simp
next
assume r: ?rhs
then obtain k where "p = [:k:]"
by (cases p) (simp split: if_splits)
then show ?lhs unfolding constant_def by auto
qed

lemma divides_degree: assumes pq: "p dvd (q:: complex poly)"
shows "degree p ≤ degree q ∨ q = 0"
apply (cases "q = 0", simp_all)
apply (erule dvd_imp_degree_le [OF pq])
done

(* Arithmetic operations on multivariate polynomials. *)

lemma mpoly_base_conv:
"(0::complex) ≡ poly 0 x" "c ≡ poly [:c:] x" "x ≡ poly [:0,1:] x" by simp_all

lemma mpoly_norm_conv:
"poly [:0:] (x::complex) ≡ poly 0 x" "poly [:poly 0 y:] x ≡ poly 0 x" by simp_all

lemma mpoly_sub_conv:
"poly p (x::complex) - poly q x ≡ poly p x + -1 * poly q x"
by (simp add: diff_minus)

lemma poly_pad_rule: "poly p x = 0 ==> poly (pCons 0 p) x = (0::complex)" by simp

lemma poly_cancel_eq_conv: "p = (0::complex) ==> a ≠ 0 ==> (q = 0) ≡ (a * q - b * p = 0)" apply (atomize (full)) by auto

lemma resolve_eq_raw: "poly 0 x ≡ 0" "poly [:c:] x ≡ (c::complex)" by auto
lemma resolve_eq_then: "(P ==> (Q ≡ Q1)) ==> (¬P ==> (Q ≡ Q2))
==> Q ≡ P ∧ Q1 ∨ ¬P∧ Q2"
apply (atomize (full)) by blast

lemma poly_divides_pad_rule:
fixes p q :: "complex poly"
assumes pq: "p dvd q"
shows "p dvd (pCons (0::complex) q)"
proof-
have "pCons 0 q = q * [:0,1:]" by simp
then have "q dvd (pCons 0 q)" ..
with pq show ?thesis by (rule dvd_trans)
qed

lemma poly_divides_pad_const_rule:
fixes p q :: "complex poly"
assumes pq: "p dvd q"
shows "p dvd (smult a q)"
proof-
have "smult a q = q * [:a:]" by simp
then have "q dvd smult a q" ..
with pq show ?thesis by (rule dvd_trans)
qed


lemma poly_divides_conv0:
fixes p :: "complex poly"
assumes lgpq: "degree q < degree p" and lq:"p ≠ 0"
shows "p dvd q ≡ q = 0" (is "?lhs ≡ ?rhs")
proof-
{assume r: ?rhs
hence "q = p * 0" by simp
hence ?lhs ..}
moreover
{assume l: ?lhs
{assume q0: "q = 0"
hence ?rhs by simp}
moreover
{assume q0: "q ≠ 0"
from l q0 have "degree p ≤ degree q"
by (rule dvd_imp_degree_le)
with lgpq have ?rhs by simp }
ultimately have ?rhs by blast }
ultimately show "?lhs ≡ ?rhs" by - (atomize (full), blast)
qed

lemma poly_divides_conv1:
assumes a0: "a≠ (0::complex)" and pp': "(p::complex poly) dvd p'"
and qrp': "smult a q - p' ≡ r"
shows "p dvd q ≡ p dvd (r::complex poly)" (is "?lhs ≡ ?rhs")
proof-
{
from pp' obtain t where t: "p' = p * t" ..
{assume l: ?lhs
then obtain u where u: "q = p * u" ..
have "r = p * (smult a u - t)"
using u qrp' [symmetric] t by (simp add: algebra_simps)
then have ?rhs ..}
moreover
{assume r: ?rhs
then obtain u where u: "r = p * u" ..
from u [symmetric] t qrp' [symmetric] a0
have "q = p * smult (1/a) (u + t)" by (simp add: algebra_simps)
hence ?lhs ..}
ultimately have "?lhs = ?rhs" by blast }
thus "?lhs ≡ ?rhs" by - (atomize(full), blast)
qed

lemma basic_cqe_conv1:
"(∃x. poly p x = 0 ∧ poly 0 x ≠ 0) ≡ False"
"(∃x. poly 0 x ≠ 0) ≡ False"
"(∃x. poly [:c:] x ≠ 0) ≡ c≠0"
"(∃x. poly 0 x = 0) ≡ True"
"(∃x. poly [:c:] x = 0) ≡ c = 0" by simp_all

lemma basic_cqe_conv2:
assumes l:"p ≠ 0"
shows "(∃x. poly (pCons a (pCons b p)) x = (0::complex)) ≡ True"
proof-
{fix h t
assume h: "h≠0" "t=0" "pCons a (pCons b p) = pCons h t"
with l have False by simp}
hence th: "¬ (∃ h t. h≠0 ∧ t=0 ∧ pCons a (pCons b p) = pCons h t)"
by blast
from fundamental_theorem_of_algebra_alt[OF th]
show "(∃x. poly (pCons a (pCons b p)) x = (0::complex)) ≡ True" by auto
qed

lemma basic_cqe_conv_2b: "(∃x. poly p x ≠ (0::complex)) ≡ (p ≠ 0)"
proof-
have "p = 0 <-> poly p = poly 0"
by (simp add: poly_eq_poly_eq_iff)
also have "… <-> (¬ (∃x. poly p x ≠ 0))" by auto
finally show "(∃x. poly p x ≠ (0::complex)) ≡ p ≠ 0"
by - (atomize (full), blast)
qed

lemma basic_cqe_conv3:
fixes p q :: "complex poly"
assumes l: "p ≠ 0"
shows "(∃x. poly (pCons a p) x = 0 ∧ poly q x ≠ 0) ≡ ¬ ((pCons a p) dvd (q ^ (psize p)))"
proof-
from l have dp:"degree (pCons a p) = psize p" by (simp add: psize_def)
from nullstellensatz_univariate[of "pCons a p" q] l
show "(∃x. poly (pCons a p) x = 0 ∧ poly q x ≠ 0) ≡ ¬ ((pCons a p) dvd (q ^ (psize p)))"
unfolding dp
by - (atomize (full), auto)
qed

lemma basic_cqe_conv4:
fixes p q :: "complex poly"
assumes h: "!!x. poly (q ^ n) x ≡ poly r x"
shows "p dvd (q ^ n) ≡ p dvd r"
proof-
from h have "poly (q ^ n) = poly r" by auto
then have "(q ^ n) = r" by (simp add: poly_eq_poly_eq_iff)
thus "p dvd (q ^ n) ≡ p dvd r" by simp
qed

lemma pmult_Cons_Cons: "(pCons (a::complex) (pCons b p) * q = (smult a q) + (pCons 0 (pCons b p * q)))"
by simp

lemma elim_neg_conv: "- z ≡ (-1) * (z::complex)" by simp
lemma eqT_intr: "PROP P ==> (True ==> PROP P )" "PROP P ==> True" by blast+
lemma negate_negate_rule: "Trueprop P ≡ (¬ P ≡ False)" by (atomize (full), auto)

lemma complex_entire: "(z::complex) ≠ 0 ∧ w ≠ 0 ≡ z*w ≠ 0" by simp
lemma resolve_eq_ne: "(P ≡ True) ≡ (¬P ≡ False)" "(P ≡ False) ≡ (¬P ≡ True)"
by (atomize (full)) simp_all
lemma cqe_conv1: "poly 0 x = 0 <-> True" by simp
lemma cqe_conv2: "(p ==> (q ≡ r)) ≡ ((p ∧ q) ≡ (p ∧ r))" (is "?l ≡ ?r")
proof
assume "p ==> q ≡ r" thus "p ∧ q ≡ p ∧ r" apply - apply (atomize (full)) by blast
next
assume "p ∧ q ≡ p ∧ r" "p"
thus "q ≡ r" apply - apply (atomize (full)) apply blast done
qed
lemma poly_const_conv: "poly [:c:] (x::complex) = y <-> c = y" by simp

end